本页面介绍了 Starlark 配置(用于自定义项目构建方式的 Bazel 的 API)的优势和基本用法。其中介绍了如何定义构建设置,并提供了相关示例。
这样,您就可以:
- 为项目定义自定义标志,无需使用
--define
- 写入 transitions 来配置与其父项不同的配置(例如
--compilation_mode=opt
或--cpu=arm
) - 将更好的默认值纳入规则(例如,使用指定的 SDK 自动构建
//my:android_app
)
等等,全部来自 .bzl 文件(无需 Bazel 版本)。如需查看示例,请参阅 bazelbuild/examples
代码库。
用户定义的构建设置
build 设置是一条配置信息。可以将配置视为键值对映射。设置 --cpu=ppc
和 --copt="-DFoo"
会生成类似于 {cpu: ppc, copt: "-DFoo"}
的配置。每个条目都是一项构建设置。
cpu
和 copt
等传统标志是原生设置,它们的键在原生 bazel Java 代码中进行设置。Bazel 用户只能通过命令行和其他原生维护的 API 进行读取和写入。更改原生标志以及公开这些标志的 API 需要一个 Bazel 版本。用户定义的 build 设置在 .bzl
文件中定义(因此,不需要 Bazel 版本来注册更改)。您也可以通过命令行进行设置(如果它们被指定为 flags
,请参阅下文了解详情),但也可以通过用户定义的转换进行设置。
定义构建设置
build_setting
rule()
参数
build 设置是与其他规则一样的规则,通过 Starlark rule()
函数的 build_setting
属性加以区分。
# example/buildsettings/build_settings.bzl
string_flag = rule(
implementation = _impl,
build_setting = config.string(flag = True)
)
build_setting
属性接受一个用于指定 build 设置类型的函数。该类型仅限于一组基本的 Starlark 类型,例如 bool
和 string
。如需了解详情,请参阅 config
模块文档。您可以在规则的实现函数中完成更复杂的输入。有关详情,请参见下文。
config
模块的函数接受可选的布尔值参数 flag
,该参数默认设置为 false。如果 flag
设置为 true,则用户可以在命令行上以及规则写入者通过默认值和过渡在内部设置 build 设置。并非所有设置都应该由用户设定。例如,作为规则编写者,如果您想在测试规则内启用某种调试模式,就不要让用户能够在其他非测试规则中随意启用该功能。
使用 ctx.build_setting_value
与所有规则一样,构建设置规则具有实现函数。您可以通过 ctx.build_setting_value
方法访问 build 设置的基本 Starlark 类型值。此方法仅适用于 build 设置规则的 ctx
对象。这些实现方法可以直接转发 build 设置值,也可以对该值执行额外的操作,例如类型检查或创建更复杂的结构体。下面展示了如何实现 enum
类型的 build 设置:
# example/buildsettings/build_settings.bzl
TemperatureProvider = provider(fields = ['type'])
temperatures = ["HOT", "LUKEWARM", "ICED"]
def _impl(ctx):
raw_temperature = ctx.build_setting_value
if raw_temperature not in temperatures:
fail(str(ctx.label) + " build setting allowed to take values {"
+ ", ".join(temperatures) + "} but was set to unallowed value "
+ raw_temperature)
return TemperatureProvider(type = raw_temperature)
temperature = rule(
implementation = _impl,
build_setting = config.string(flag = True)
)
定义多组字符串标志
字符串设置有一个额外的 allow_multiple
参数,可用于在命令行或 bazelrcs 中多次设置该标志。它们的默认值仍使用字符串类型的属性进行设置:
# example/buildsettings/build_settings.bzl
allow_multiple_flag = rule(
implementation = _impl,
build_setting = config.string(flag = True, allow_multiple = True)
)
# example/BUILD
load("//example/buildsettings:build_settings.bzl", "allow_multiple_flag")
allow_multiple_flag(
name = "roasts",
build_setting_default = "medium"
)
标志的每项设置都被视为单个值:
$ bazel build //my/target --//example:roasts=blonde \
--//example:roasts=medium,dark
系统会将上述内容解析为 {"//example:roasts": ["blonde", "medium,dark"]}
,并且 ctx.build_setting_value
会返回列表 ["blonde", "medium,dark"]
。
实例化构建设置
使用 build_setting
参数定义的规则具有隐式强制性 build_setting_default
属性。此属性采用的类型与 build_setting
参数声明的类型相同。
# example/buildsettings/build_settings.bzl
FlavorProvider = provider(fields = ['type'])
def _impl(ctx):
return FlavorProvider(type = ctx.build_setting_value)
flavor = rule(
implementation = _impl,
build_setting = config.string(flag = True)
)
# example/BUILD
load("//example/buildsettings:build_settings.bzl", "flavor")
flavor(
name = "favorite_flavor",
build_setting_default = "APPLE"
)
预定义的设置
Skylib 库包含一组预定义的设置,您无需编写自定义 Starlark 即可实例化这些设置。
例如,要定义接受一组有限的字符串值的设置,请使用以下代码:
# example/BUILD
load("@bazel_skylib//rules:common_settings.bzl", "string_flag")
string_flag(
name = "myflag",
values = ["a", "b", "c"],
build_setting_default = "a",
)
如需查看完整列表,请参阅常见的 build 设置规则。
使用构建设置
取决于 build 设置
如果目标需要读取一段配置信息,可以通过常规属性依赖项直接依赖于 build 设置。
# example/rules.bzl
load("//example/buildsettings:build_settings.bzl", "FlavorProvider")
def _rule_impl(ctx):
if ctx.attr.flavor[FlavorProvider].type == "ORANGE":
...
drink_rule = rule(
implementation = _rule_impl,
attrs = {
"flavor": attr.label()
}
)
# example/BUILD
load("//example:rules.bzl", "drink_rule")
load("//example/buildsettings:build_settings.bzl", "flavor")
flavor(
name = "favorite_flavor",
build_setting_default = "APPLE"
)
drink_rule(
name = "my_drink",
flavor = ":favorite_flavor",
)
语言可能希望创建一组规范的 build 设置,而针对该语言的所有规则都依赖于这些设置。虽然 fragments
的原生概念在 Starlark 配置环境中不再以硬编码对象的形式存在,但转换此概念的一种方法是使用常见隐式属性集。例如:
# kotlin/rules.bzl
_KOTLIN_CONFIG = {
"_compiler": attr.label(default = "//kotlin/config:compiler-flag"),
"_mode": attr.label(default = "//kotlin/config:mode-flag"),
...
}
...
kotlin_library = rule(
implementation = _rule_impl,
attrs = dicts.add({
"library-attr": attr.string()
}, _KOTLIN_CONFIG)
)
kotlin_binary = rule(
implementation = _binary_impl,
attrs = dicts.add({
"binary-attr": attr.label()
}, _KOTLIN_CONFIG)
在命令行中使用构建设置
与大多数原生标志类似,您可以使用命令行来设置标记为标志的构建设置。build 设置的名称是使用 name=value
语法的完整目标路径:
$ bazel build //my/target --//example:string_flag=some-value # allowed
$ bazel build //my/target --//example:string_flag some-value # not allowed
支持特殊的布尔语法:
$ bazel build //my/target --//example:boolean_flag
$ bazel build //my/target --no//example:boolean_flag
使用 build 设置别名
您可以为构建设置目标路径设置别名,以便更轻松地在命令行中阅读。别名的功能与原生标志类似,还使用双短划线选项语法。
您可以通过向 .bazelrc
添加 --flag_alias=ALIAS_NAME=TARGET_PATH
来设置别名。例如,如需将别名设置为 coffee
,请使用以下代码:
# .bazelrc
build --flag_alias=coffee=//experimental/user/starlark_configurations/basic_build_setting:coffee-temp
最佳实践:多次设置别名会使最新的别名优先。使用唯一的别名名称,以避免意外的解析结果。
如需使用别名,请输入该别名来代替构建设置目标路径。
通过在用户的 .bazelrc
中设置上述 coffee
示例:
$ bazel build //my/target --coffee=ICED
来替代
$ bazel build //my/target --//experimental/user/starlark_configurations/basic_build_setting:coffee-temp=ICED
最佳实践:虽然可以在命令行中设置别名,但将它们放在 .bazelrc
中可以减少命令行的杂乱。
标签类型的 build 设置
与其他 build 设置不同,标签类型的设置无法使用 build_setting
规则参数进行定义。bazel 具有两条内置规则:label_flag
和 label_setting
。这些规则会将 build 设置设为实际目标的提供程序。label_flag
和 label_setting
可通过转换读取/写入,并且用户可以像其他 build_setting
规则一样设置 label_flag
。它们的唯一区别是它们不能以自定义方式定义。
标签类型的设置最终将取代后期绑定默认设置的功能。后期绑定默认属性是标签类型的属性,其最终值可能会受配置影响。在 Starlark 中,这将取代 configuration_field
API。
# example/rules.bzl
MyProvider = provider(fields = ["my_field"])
def _dep_impl(ctx):
return MyProvider(my_field = "yeehaw")
dep_rule = rule(
implementation = _dep_impl
)
def _parent_impl(ctx):
if ctx.attr.my_field_provider[MyProvider].my_field == "cowabunga":
...
parent_rule = rule(
implementation = _parent_impl,
attrs = { "my_field_provider": attr.label() }
)
# example/BUILD
load("//example:rules.bzl", "dep_rule", "parent_rule")
dep_rule(name = "dep")
parent_rule(name = "parent", my_field_provider = ":my_field_provider")
label_flag(
name = "my_field_provider",
build_setting_default = ":dep"
)
构建设置和 select()
用户可以使用 select()
在 build 设置中配置属性。build 设置目标可以传递给 config_setting
的 flag_values
属性。与配置匹配的值会作为 String
传递,然后解析为 build 设置的类型,以便进行匹配。
config_setting(
name = "my_config",
flag_values = {
"//example:favorite_flavor": "MANGO"
}
)
用户定义的过渡
配置转换会将构建图中从一个已配置目标映射到另一个目标的转换。
设置此类属性的规则必须包含一个特殊的属性:
"_allowlist_function_transition": attr.label(
default = "@bazel_tools//tools/allowlists/function_transition_allowlist"
)
通过添加过渡,您可以很容易地使构建图的大小增加。这会针对您可以在其中创建此规则目标的软件包设置许可名单。上述代码块中的默认值可将所有内容列入许可名单。但是,如果您想限制使用规则的用户,可以将该属性设置为指向您自己的自定义许可名单。如果您需要建议或协助了解转换对 build 性能的影响,请发送电子邮件至 bazel-discuss@googlegroups.com。
定义
过渡定义了规则之间的配置更改。例如,“针对与其父项不同的 CPU 编译我的依赖项”之类的请求由过渡处理。
正式地说,转换是指从输入配置到一种或多种输出配置的函数。大多数转换都是 1:1 的,例如“使用 --cpu=ppc
替换输入配置”。也可以存在 1:2+ 转换,但具有特殊限制。
在 Starlark 中,过渡的定义与规则非常相似,具有一个定义的 transition()
函数和一个实现函数。
# example/transitions/transitions.bzl
def _impl(settings, attr):
_ignore = (settings, attr)
return {"//example:favorite_flavor" : "MINT"}
hot_chocolate_transition = transition(
implementation = _impl,
inputs = [],
outputs = ["//example:favorite_flavor"]
)
transition()
函数接受一个实现函数、一组要读取的构建设置(inputs
) 以及一组要写入的构建设置 (outputs
)。该实现函数有两个参数:settings
和 attr
。settings
是 inputs
参数中声明到 transition()
的所有设置的字典 {String
:Object
}。
attr
是转换所关联规则的属性和值的字典。作为传出边缘过渡附加时,这些属性的值都是已配置的 select() 之后分辨率。作为传入边缘过渡附加时,attr
不包含任何使用选择器解析其值的属性。如果 --foo
上的传入边缘过渡读取属性 bar
,然后还选择 --foo
以设置属性 bar
,则传入边缘过渡可能会在过渡中读取错误的 bar
值。
实现函数必须返回一个要应用的新 build 设置值的字典(如果是具有多个输出配置的转换,则为字典列表)。返回的字典密钥集必须准确包含传递给转换函数的 outputs
参数的一组 build 设置。即使 build 设置在转换过程中实际上并未更改,也是如此,它的原始值必须在返回的字典中显式传递。
定义 1:2+ 过渡
传出边缘转换可将单个输入配置映射到两个或更多输出配置。这对于定义捆绑多架构代码的规则非常有用。
1:2+ 过渡是通过在过渡实现函数中返回字典列表来定义的。
# example/transitions/transitions.bzl
def _impl(settings, attr):
_ignore = (settings, attr)
return [
{"//example:favorite_flavor" : "LATTE"},
{"//example:favorite_flavor" : "MOCHA"},
]
coffee_transition = transition(
implementation = _impl,
inputs = [],
outputs = ["//example:favorite_flavor"]
)
这些方法还可以设置自定义键,供规则实现函数用来读取各个依赖项:
# example/transitions/transitions.bzl
def _impl(settings, attr):
_ignore = (settings, attr)
return {
"Apple deps": {"//command_line_option:cpu": "ppc"},
"Linux deps": {"//command_line_option:cpu": "x86"},
}
multi_arch_transition = transition(
implementation = _impl,
inputs = [],
outputs = ["//command_line_option:cpu"]
)
附加转场效果
过渡可以在两个位置附加:传入边缘和传出边缘。实际上,这意味着规则可以转换自己的配置(传入的边缘转换)并转换其依赖项的配置(传出边缘转换)。
注意:目前无法将 Starlark 转换附加到原生规则。如果您需要执行此操作,请与 bazel-discuss@googlegroups.com 联系,获取有关找出解决方法的帮助。
传入的边缘转换
通过将 transition
对象(由 transition()
创建)附加到 rule()
的 cfg
参数来激活传入的边缘过渡:
# example/rules.bzl
load("example/transitions:transitions.bzl", "hot_chocolate_transition")
drink_rule = rule(
implementation = _impl,
cfg = hot_chocolate_transition,
...
传入的边缘转换必须是 1:1 转换。
传出边缘转换
通过将 transition
对象(由 transition()
创建)附加到属性的 cfg
参数,可激活传出边缘过渡:
# example/rules.bzl
load("example/transitions:transitions.bzl", "coffee_transition")
drink_rule = rule(
implementation = _impl,
attrs = { "dep": attr.label(cfg = coffee_transition)}
...
传出边缘转换可以是 1:1 或 1:2+。
如需了解如何读取这些键,请参阅通过转换访问属性。
原生选项的过渡
Starlark 转换还可以通过在选项名称前添加一个特殊前缀来声明对原生 build 配置选项的读写操作。
# example/transitions/transitions.bzl
def _impl(settings, attr):
_ignore = (settings, attr)
return {"//command_line_option:cpu": "k8"}
cpu_transition = transition(
implementation = _impl,
inputs = [],
outputs = ["//command_line_option:cpu"]
不受支持的原生选项
Bazel 不支持使用 "//command_line_option:define"
在 --define
上进行转换。请改用自定义构建设置。一般来说,不建议使用新的 --define
,取而代之的是 build 设置。
Bazel 不支持在 --config
上进行转换。这是因为 --config
是一个会扩展为其他标志的“扩展”标志。
至关重要的是,--config
可能包含不会影响 build 配置的标志,例如 --spawn_strategy
。根据设计,Bazel 无法将此类标志绑定到单个目标。这意味着没有连贯的方法可以将它们应用于过渡。
如需解决此问题,您可以明确列举转换过程中属于配置的一部分的标志。这需要在两个位置维护 --config
的展开,这是已知的界面缺陷。
开启“允许多个构建设置”的转换
在设置允许多个值的 build 设置时,必须使用列表来设置设置的值。
# example/buildsettings/build_settings.bzl
string_flag = rule(
implementation = _impl,
build_setting = config.string(flag = True, allow_multiple = True)
)
# example/BUILD
load("//example/buildsettings:build_settings.bzl", "string_flag")
string_flag(name = "roasts", build_setting_default = "medium")
# example/transitions/rules.bzl
def _transition_impl(settings, attr):
# Using a value of just "dark" here will throw an error
return {"//example:roasts" : ["dark"]},
coffee_transition = transition(
implementation = _transition_impl,
inputs = [],
outputs = ["//example:roasts"]
)
无操作转换
如果转换返回 {}
、[]
或 None
,这是一种简写形式,可将所有设置保持为原始值。这比将每个输出明确设置为其自身更为方便。
# example/transitions/transitions.bzl
def _impl(settings, attr):
_ignore = (attr)
if settings["//example:already_chosen"] is True:
return {}
return {
"//example:favorite_flavor": "dark chocolate",
"//example:include_marshmallows": "yes",
"//example:desired_temperature": "38C",
}
hot_chocolate_transition = transition(
implementation = _impl,
inputs = ["//example:already_chosen"],
outputs = [
"//example:favorite_flavor",
"//example:include_marshmallows",
"//example:desired_temperature",
]
)
通过过渡访问属性
将过渡附加到传出边缘时(无论过渡是 1:1 还是 1:2+ 过渡),ctx.attr
将被强制设为一个列表(如果尚未这样做)。此列表中元素的顺序未指定。
# example/transitions/rules.bzl
def _transition_impl(settings, attr):
return {"//example:favorite_flavor" : "LATTE"},
coffee_transition = transition(
implementation = _transition_impl,
inputs = [],
outputs = ["//example:favorite_flavor"]
)
def _rule_impl(ctx):
# Note: List access even though "dep" is not declared as list
transitioned_dep = ctx.attr.dep[0]
# Note: Access doesn't change, other_deps was already a list
for other_dep in ctx.attr.other_deps:
# ...
coffee_rule = rule(
implementation = _rule_impl,
attrs = {
"dep": attr.label(cfg = coffee_transition)
"other_deps": attr.label_list(cfg = coffee_transition)
})
如果转换处于 1:2+
状态并设置了自定义键,则 ctx.split_attr
可用于读取每个键的各个依赖项:
# example/transitions/rules.bzl
def _impl(settings, attr):
_ignore = (settings, attr)
return {
"Apple deps": {"//command_line_option:cpu": "ppc"},
"Linux deps": {"//command_line_option:cpu": "x86"},
}
multi_arch_transition = transition(
implementation = _impl,
inputs = [],
outputs = ["//command_line_option:cpu"]
)
def _rule_impl(ctx):
apple_dep = ctx.split_attr.dep["Apple deps"]
linux_dep = ctx.split_attr.dep["Linux deps"]
# ctx.attr has a list of all deps for all keys. Order is not guaranteed.
all_deps = ctx.attr.dep
multi_arch_rule = rule(
implementation = _rule_impl,
attrs = {
"dep": attr.label(cfg = multi_arch_transition)
})
点击此处可查看完整示例。
与平台和工具链集成
当今的许多原生标志(如 --cpu
和 --crosstool_top
)与工具链解析有关。将来,针对这些类型的标志的显式转换可能会被在目标平台上转换所取代。
内存和性能注意事项
在 build 中添加转换以及因此添加新配置需要付出代价:build 图更大,build 图更不易理解,构建速度变慢。在构建规则中使用转换时,值得考虑这些开销。以下示例展示了转换可能如何使 build 图呈指数增长。
行为不当的 build:案例研究
图 1. 显示顶级目标及其依赖项的可伸缩性图。
此图表显示了一个顶级目标 //pkg:app
,该目标取决于两个目标://pkg:1_0
和 //pkg:1_1
。这两个目标都依赖于 //pkg:2_0
和 //pkg:2_1
这两个目标。这两个目标都依赖于 //pkg:3_0
和 //pkg:3_1
这两个目标。此过程会一直持续到 //pkg:n_0
和 //pkg:n_1
,它们都依赖于单个目标 //pkg:dep
。
构建“//pkg:app
”需要 \(2n+2\) 目标:
//pkg:app
//pkg:dep
//pkg:i_0
和//pkg:i_1
: \(i\) 在 \([1..n]\)内
假设您implement了一个标记 --//foo:owner=<STRING>
并应用了 //pkg:i_b
depConfig = myConfig + depConfig.owner="$(myConfig.owner)$(b)"
换句话说,//pkg:i_b
会将 b
附加到 --owner
的所有依赖项的旧值。
这样会生成以下已配置的目标:
//pkg:app //foo:owner=""
//pkg:1_0 //foo:owner=""
//pkg:1_1 //foo:owner=""
//pkg:2_0 (via //pkg:1_0) //foo:owner="0"
//pkg:2_0 (via //pkg:1_1) //foo:owner="1"
//pkg:2_1 (via //pkg:1_0) //foo:owner="0"
//pkg:2_1 (via //pkg:1_1) //foo:owner="1"
//pkg:3_0 (via //pkg:1_0 → //pkg:2_0) //foo:owner="00"
//pkg:3_0 (via //pkg:1_0 → //pkg:2_1) //foo:owner="01"
//pkg:3_0 (via //pkg:1_1 → //pkg:2_0) //foo:owner="10"
//pkg:3_0 (via //pkg:1_1 → //pkg:2_1) //foo:owner="11"
...
//pkg:dep
生成 \(2^n\) 已配置的目标:config.owner=
针对 \(b_i\) \(\{0,1\}\)中的所有项“\(b_0b_1...b_n\)”。
这会使构建图比目标图大,产生相应的内存和性能影响。
待办事项:添加衡量和缓解这些问题的策略。
深入阅读
如需详细了解如何修改 build 配置,请参阅:
- Starlark build 配置
- Bazel 可配置性路线图
- 一整套端到端示例