最佳化效能

回報問題 查看原始碼 Nightly · 8.0 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

編寫規則時，最常見的效能陷阱是遍歷或複製從依附元件累積的資料。在整個建構作業中匯總時，這些作業很容易會耗用 O(N^2) 的時間或空間。為避免這種情況，請務必瞭解如何有效使用 depset。

這項作業可能很難正確執行，因此 Bazel 也提供記憶體分析器，協助您找出可能出錯的部分。請注意：編寫效率不彰的規則可能會造成成本，但只有在廣泛使用後才會顯現。

使用 depset

每當您從規則依附元件匯總資訊時，都應使用 depsets。請只使用純文字清單或字典，在目前規則的本機發布資訊。

depset 會以巢狀圖表的形式呈現資訊，方便分享。

請參考下列圖表：

C -> B -> A
D ---^

每個節點都會發布一個字串。使用 depset 時，資料會如下所示：

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

請注意，每個項目只會提及一次。使用清單時，您會看到以下畫面：

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

請注意，在本例中 'a' 被提及了四次！圖表越大，這個問題就會越嚴重。

以下是規則實作範例，說明如何正確使用 depset 來發布傳遞資訊。請注意，如果您想使用清單發布規則本機資訊，這並不會造成 O(N^2) 的情況，因此可以使用清單發布。

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

詳情請參閱 depset 總覽頁面。

避免呼叫 depset.to_list()

您可以使用 to_list() 將 depset 強制轉換為平面清單，但這通常會導致 O(N^2) 成本。盡可能避免對 depset 進行任何扁平化，除非是為了偵錯。

常見的誤解是，如果您只在頂層目標 (例如 <xx>_binary 規則) 上執行此操作，就可以自由地扁平化 depset，因為這樣不會在建構圖的每個層級累積成本。不過，當您建構一組具有重疊依附元件的目標時，這仍是 O(N^2)。這會發生在建構測試 //foo/tests/... 或匯入 IDE 專案時。

減少對 depset 的呼叫次數

在迴圈內呼叫 depset 通常是錯誤的做法。這可能會導致巢狀結構非常深的 depset，導致效能不佳。例如：

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

這段程式碼可以輕鬆替換。首先，收集傳遞依附集，並一次合併所有依附集：

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

有時可以使用清單函式來減少這類運算：

x = depset(transitive = [i.deps for i in inputs])

使用 ctx.actions.args() 指令列

建構指令列時，請使用 ctx.actions.args()。這樣一來，任何 depset 的擴充作業都會延後至執行階段。

除了速度明顯提升之外，這項做法還能減少規則的記憶體用量，有時甚至可減少 90% 以上。

以下提供一些訣竅：

  • 請直接將 depset 和清單做為引數傳遞，不要自行展開。ctx.actions.args() 會為您展開這些項目。如果需要對 depset 內容進行任何轉換，請查看 ctx.actions.args#add，看看是否有任何符合要求的項目。

  • 您是否將 File#path 做為引數傳遞？不需要。任何檔案都會自動轉換為路徑，並延後至擴充時間。

  • 請勿透過連接字串來建構字串。最適合的字串引數是常數，因為其記憶體會在規則的所有例項之間共用。

  • 如果 args 太長，指令列無法處理，您可以使用 ctx.actions.args#use_param_file，將 ctx.actions.args() 物件有條件或無條件地寫入參數檔案。這項作業會在執行動作時在幕後完成。如果您需要明確控制參數檔案，可以使用 ctx.actions.write 手動編寫。

範例：

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

轉置動作輸入內容應為 depset

使用 ctx.actions.run 建構動作時，請注意 inputs 欄位會接受 depset。只要從依附元件收集輸入內容，就使用這個方法。

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

懸掛式

如果 Bazel 似乎已停止運作，您可以按下 Ctrl-\ 鍵，或傳送 SIGQUIT 信號 (kill -3 $(bazel info server_pid)) 給 Bazel，以便在檔案 $(bazel info output_base)/server/jvm.out 中取得執行緒傾印內容。

由於在 Bazel 掛起時，您可能無法執行 bazel info，因此 output_base 目錄通常是工作區目錄中 bazel-<workspace> 符號連結的父項。

效能分析

JSON 追蹤記錄設定檔非常實用，可讓您快速瞭解 Bazel 在叫用期間花費的時間。

記憶體分析

Bazel 內建記憶體分析器，可協助您檢查規則的記憶體用量。如果發生問題，您可以轉儲堆積，找出導致問題的確切程式碼行。

啟用記憶體追蹤

您必須將這兩個啟動標記傳遞至每個 Bazel 叫用：

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

這些指令會在記憶體追蹤模式下啟動伺服器。如果您忘記了其中一個 Bazel 叫用作業，伺服器就會重新啟動，您必須重新開始。

使用記憶體追蹤器

舉例來說，請查看目標 foo 並瞭解其功能。如要只執行分析，而不執行建構執行階段，請新增 --nobuild 標記。

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

接著，查看整個 Bazel 例項會消耗多少記憶體：

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

使用 bazel dump --rules 依規則類別細分：

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

使用 bazel dump --skylark_memory 產生 pprof 檔案，查看記憶體的去向：

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

使用 pprof 工具調查堆積。建議您一開始使用 pprof -flame $HOME/prof.gz 取得火焰圖。

請從 https://github.com/google/pprof 取得 pprof。

取得熱門呼叫網站的文字傾印，並加上註解行：

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)