このチュートリアルでは、サンプル シナリオを使用して、プロジェクト用に C++ ツールチェーンを構成する方法について説明します。これは、clang を使用してエラーなしでビルドする C++ プロジェクトの例に基づいています。
学習内容
このチュートリアルでは、次の方法について学びます。
- ビルド環境をセットアップする
- C++ ツールチェーンを構成する
- Bazel で
clangを使用してアプリケーションをビルドできるように、cc_toolchainの追加構成を提供する Starlark ルールを作成します。 - Linux マシンで
bazel build --config=clang_config //main:hello-worldを実行して、予想される結果を確認します。 - C++ アプリケーションをビルドする
始める前に
ビルド環境をセットアップする
このチュートリアルでは、ユーザーが Linux を使用していて、C++ アプリケーションを正常にビルドし、適切なツールとライブラリがインストールされていることを前提としています。このチュートリアルでは、システムにインストールできる clang version 9.0.1 を使用します。
ビルド環境を次のように設定します。
まだインストールしていない場合は、Bazel 0.23 以降をダウンロードしてインストールしてください。
GitHub からサンプル C++ プロジェクトをダウンロードして、ローカルマシンの空のディレクトリに配置します。
次の
cc_binaryターゲットをmain/BUILDファイルに追加します。cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )ワークスペース ディレクトリのルートに次の内容の
.bazelrcファイルを作成し、--configフラグの使用を有効にします。# Use our custom-configured c++ toolchain. build:clang_config --crosstool_top=//toolchain:clang_suite # Use --cpu as a differentiator. build:clang_config --cpu=k8 # Use the default Bazel C++ toolchain to build the tools used during the # build. build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
エントリ build:{config_name} --flag=value の場合、コマンドライン フラグ --config={config_name} がその特定のフラグに関連付けられています。使用するフラグについては、crosstool_top、cpu、host_crosstool_top のドキュメントをご覧ください。
bazel build --config=clang_config //main:hello-world を使用してターゲットをビルドする場合、Bazel は cc_toolchain_suite
//toolchain:clang_suite のカスタム ツールチェーンを使用します。このスイートでは、ツールチェーンが CPU ごとに異なるため、フラグ --cpu=k8 で区別されています。
Bazel は、ビルド時に C++ で記述された多くの内部ツール（process-wrapper など）を使用するため、ホスト プラットフォーム用に既存のデフォルトの C++ ツールチェーンが指定されています。これらのツールは、このチュートリアルで作成されたツールチェーンではなく、そのツールチェーンを使用してビルドされます。
C++ ツールチェーンの構成
C++ ツールチェーンを構成するには、以下で説明するようにアプリを繰り返しビルドし、各エラーを 1 つずつ取り除きます。
次のコマンドを使用してビルドを実行します。
bazel build --config=clang_config //main:hello-world.bazelrcファイルで--crosstool_top=//toolchain:clang_suiteを指定したため、Bazel は次のエラーをスローします。No such package `toolchain`: BUILD file not found on package path.ワークスペース ディレクトリで、パッケージの
toolchainディレクトリを作成し、toolchainディレクトリ内に空のBUILDファイルを作成します。ビルドを再度実行します。
toolchainパッケージでまだclang_suiteターゲットが定義されていないため、Bazel は次のエラーをスローします。No such target '//toolchain:clang_suite': target 'clang_suite' not declared in package 'toolchain' defined by .../toolchain/BUILDtoolchain/BUILDファイルで、空のファイル グループを次のように定義します。package(default_visibility = ["//visibility:public"]) filegroup(name = "clang_suite")ビルドを再度実行します。Bazel は次のエラーをスローします。
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'Bazel は、必要な
ToolchainInfoプロバイダを提供していないルールを--crosstool_topフラグが指していることを検出しました。そのため、ToolchainInfoを提供するルール（cc_toolchain_suiteルール）を--crosstool_topで指定する必要があります。toolchain/BUILDファイルで、空のファイル グループを次の内容に置き換えます。cc_toolchain_suite( name = "clang_suite", toolchains = { "k8": ":k8_toolchain", }, )toolchains属性は、--cpu値（指定されている場合は--compilerも）を自動的にcc_toolchainにマッピングします。まだcc_toolchainターゲットを定義していないので、Bazel はすぐにこれについて不満を抱きます。ビルドを再度実行します。Bazel は次のエラーをスローします。
Rule '//toolchain:k8_toolchain' does not existcc_toolchain_suite.toolchains属性のすべての値に対してcc_toolchainターゲットを定義する必要があります。次のコードをtoolchain/BUILDファイルに追加します。filegroup(name = "empty") cc_toolchain( name = "k8_toolchain", toolchain_identifier = "k8-toolchain", toolchain_config = ":k8_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, )ビルドを再度実行します。Bazel は次のエラーをスローします。
Rule '//toolchain:k8_toolchain_config' does not exist次に、「:k8_ツールチェーン_config」ターゲットを
toolchain/BUILDファイルに追加します。filegroup(name = "k8_toolchain_config")ビルドを再度実行します。Bazel は次のエラーをスローします。
'//toolchain:k8_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'CcToolchainConfigInfoは、C++ ツールチェーンの構成に使用するプロバイダです。このエラーを修正するには、次の内容のtoolchain/cc_toolchain_config.bzlファイルを作成して、Bazel にCcToolchainConfigInfoを提供する Starlark ルールを作成します。def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )cc_common.create_cc_toolchain_config_info()は、必要なプロバイダCcToolchainConfigInfoを作成します。cc_toolchain_configルールを使用するには、パッケージ ステートメントのすぐ下のtoolchain/BUILDに読み込みステートメントを追加します。load(":cc_toolchain_config.bzl", "cc_toolchain_config")「k8_ツールチェーン_config」ファイル グループを
cc_toolchain_configルールの宣言に置き換えます。cc_toolchain_config(name = "k8_toolchain_config")ビルドを再度実行します。Bazel は次のエラーをスローします。
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`この時点で、Bazel にはコードのビルドを試みるのに十分な情報がありますが、必要なビルド アクションを実行するために使用できるツールはまだわかりません。Starlark ルールの実装を変更して、使用するツールを Bazel に指示します。そのためには、
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzlの tool_path() コンストラクタが必要です。# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )/usr/bin/clangと/usr/bin/ldがシステムに正しいパスであることを確認します。ビルドを再度実行します。Bazel は次のエラーをスローします。
..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world': this rule is missing dependency declarations for the following files included by 'main/hello-world.cc': '/usr/include/c++/9/ctime' '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h' ....Bazel は、含まれているヘッダーを検索する場所を認識する必要があります。これを解決するには、
cc_binaryのincludes属性を使用するなど、複数の方法がありますが、ここでは、cc_common.create_cc_toolchain_config_infoのcxx_builtin_include_directoriesパラメータを使用してツールチェーン レベルで解決します。別のバージョンのclangを使用している場合は、インクルード パスも異なることに注意してください。これらのパスは、ディストリビューションによって異なる場合もあります。toolchain/cc_toolchain_config.bzlの戻り値を次のように変更します。return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )ビルドコマンドを再度実行すると、次のようなエラーが表示されます。
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'これは、リンカーに C++ 標準ライブラリがなく、シンボルを見つけることができないためです。これを解決するには、
cc_binaryのlinkopts属性を使用するなど、多くの方法があります。ここでは、ツールチェーンを使用するターゲットがこのフラグを指定する必要がないようにすることで解決します。次のコードを
cc_toolchain_config.bzlにコピーします。# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", "flag_group", "flag_set", "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )bazel build --config=clang_config //main:hello-worldを実行すると、最終的にビルドされます。
作業内容を確認する
このチュートリアルでは、基本的な C++ ツールチェーンの構成方法を学びましたが、この単純な例よりもツールチェーンの方が優れています。
重要なポイントは次のとおりです。
- cc_toolchain_suite を指す --crosstool_top フラグをコマンドラインで指定する必要がある
- .bazelrc ファイルを使用して、特定の構成のショートカットを作成できる
- cc_ツールチェーン_suite はさまざまな CPU やコンパイラの cc_toolchains をリストできます。--cpu などのコマンドライン フラグを使用して、区別できます。- ツールが存在する場所をツールチェーンに通知する必要がある。このチュートリアルでは、システムからツールにアクセスする簡易版があります。より自己完結型のアプローチに関心をお持ちの場合は、こちらでワークスペースについてお読みください。ツールが別のワークスペースにある可能性があるため、compiler_files などの属性のターゲット依存関係を使用して、cc_toolchain でそれらのファイルを利用できるようにする必要があります。tool_paths も変更する必要があります。- 機能を作成して、さまざまなアクション（リンクやその他のアクション）に渡すフラグをカスタマイズできます。
参考資料
詳細については、C++ ツールチェーン構成をご覧ください。