このチュートリアルでは、プロジェクトの C++ ツールチェーンを構成する方法について、シナリオ例を使用して説明します。これは、clang を使用してエラーなしでビルドされるサンプル C++ プロジェクトに基づいています。
学習内容
このチュートリアルでは、次の方法について学習します。
- ビルド環境を設定する
- C++ ツールチェーンを構成する
cc_toolchainの追加構成を提供する Starlark ルールを作成して、Bazel がclangでアプリケーションをビルドできるようにします。- Linux マシンで
bazel build --config=clang_config //main:hello-worldを実行して、期待される結果を確認する - C++ アプリケーションをビルドする
始める前に
ビルド環境を設定する
このチュートリアルは、Linux を使用しており、C++ アプリケーションのビルドに成功し、適切なツールとライブラリをインストールしていることを前提としています。このチュートリアルでは、システムにインストールできる clang version 9.0.1 を使用します。
ビルド環境を次のように設定します。
まだ行っていない場合は、Bazel 0.23 以降をダウンロードしてインストールします。
GitHub からC++ プロジェクトの例をダウンロードし、ローカルマシンの空のディレクトリに配置します。
次の
cc_binaryターゲットをmain/BUILDファイルに追加します。cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )ワークスペース ディレクトリのルートに次の内容の
.bazelrcファイルを作成して、--configフラグを使用できるようにします。# Use our custom-configured c++ toolchain. build:clang_config --crosstool_top=//toolchain:clang_suite # Use --cpu as a differentiator. build:clang_config --cpu=k8 # Use the default Bazel C++ toolchain to build the tools used during the # build. build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
エントリ build:{config_name} --flag=value の場合、コマンドライン フラグ --config={config_name} はその特定のフラグに関連付けられます。使用されるフラグ（crosstool_top、cpu、host_crosstool_top）のドキュメントをご覧ください。
bazel build --config=clang_config //main:hello-world でターゲットをビルドすると、Bazel は cc_toolchain_suite
//toolchain:clang_suite からカスタム ツールチェーンを使用します。スイートでは、CPU ごとに異なるツールチェーンがリストされることがあります。そのため、フラグ --cpu=k8 で区別されています。
Bazel は、ビルド中にプロセス ラッパーなど、C++ で記述された多くの内部ツールを使用するため、ホスト プラットフォームに既存のデフォルトの C++ ツールチェーンが指定されます。これにより、これらのツールは、このチュートリアルで作成されたツールチェーンではなく、そのツールチェーンを使用してビルドされます。
C++ ツールチェーンの構成
C++ ツールチェーンを構成するには、以下のようにアプリケーションを繰り返しビルドし、エラーを 1 つずつ解消します。
次のコマンドでビルドを実行します。
bazel build --config=clang_config //main:hello-world.bazelrcファイルで--crosstool_top=//toolchain:clang_suiteを指定したため、Bazel は次のエラーをスローします。No such package `toolchain`: BUILD file not found on package path.ワークスペース ディレクトリに、パッケージ用の
toolchainディレクトリを作成し、toolchainディレクトリ内に空のBUILDファイルを作成します。ビルドを再度実行します。
toolchainパッケージでclang_suiteターゲットがまだ定義されていないため、Bazel は次のエラーをスローします。No such target '//toolchain:clang_suite': target 'clang_suite' not declared in package 'toolchain' defined by .../toolchain/BUILDtoolchain/BUILDファイルで、次のように空のファイルグループを定義します。package(default_visibility = ["//visibility:public"]) filegroup(name = "clang_suite")ビルドを再度実行します。Bazel は次のエラーをスローします。
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'Bazel は、
--crosstool_topフラグが、必要なToolchainInfoプロバイダを提供しないルールを指していることを検出しました。そのため、--crosstool_topをToolchainInfoを提供するルール（cc_toolchain_suiteルール）に指定する必要があります。toolchain/BUILDファイルで、空のファイルグループを次の内容に置き換えます。cc_toolchain_suite( name = "clang_suite", toolchains = { "k8": ":k8_toolchain", }, )toolchains属性は、--cpu（指定されている場合は--compilerも）の値をcc_toolchainに自動的にマッピングします。まだcc_toolchainターゲットを定義していないため、Bazel からすぐにエラーが返されます。ビルドを再度実行します。Bazel は次のエラーをスローします。
Rule '//toolchain:k8_toolchain' does not exist次に、
cc_toolchain_suite.toolchains属性のすべての値に対してcc_toolchainターゲットを定義する必要があります。toolchain/BUILDファイルに以下を追加します。filegroup(name = "empty") cc_toolchain( name = "k8_toolchain", toolchain_identifier = "k8-toolchain", toolchain_config = ":k8_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, )ビルドを再度実行します。Bazel は次のエラーをスローします。
Rule '//toolchain:k8_toolchain_config' does not exist次に、
toolchain/BUILDファイルに ":k8_toolchain_config" ターゲットを追加します。filegroup(name = "k8_toolchain_config")ビルドを再度実行します。Bazel は次のエラーをスローします。
'//toolchain:k8_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'CcToolchainConfigInfoは、C++ ツールチェーンの構成に使用するプロバイダです。このエラーを修正するには、次の内容のtoolchain/cc_toolchain_config.bzlファイルを作成して、Bazel にCcToolchainConfigInfoを提供する Starlark ルールを作成します。def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )cc_common.create_cc_toolchain_config_info()は必要なプロバイダCcToolchainConfigInfoを作成します。cc_toolchain_configルールを使用するには、パッケージ ステートメントの直下のtoolchain/BUILDに読み込みステートメントを追加します。load(":cc_toolchain_config.bzl", "cc_toolchain_config")また、「k8_toolchain_config」filegroup を
cc_toolchain_configルールの宣言に置き換えます。cc_toolchain_config(name = "k8_toolchain_config")ビルドを再度実行します。Bazel は次のエラーをスローします。
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`この時点で、Bazel はコードのビルドを試みるのに十分な情報を取得していますが、必要なビルド アクションを完了するために使用するツールはまだ認識していません。Starlark ルールの実装を変更して、使用するツールを Bazel に伝えます。そのためには、
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzlの tool_path() コンストラクタが必要です。# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )/usr/bin/clangと/usr/bin/ldがシステムの正しいパスであることを確認します。ビルドを再度実行します。Bazel は次のエラーをスローします。
..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world': this rule is missing dependency declarations for the following files included by 'main/hello-world.cc': '/usr/include/c++/9/ctime' '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h' ....Bazel は、インクルードされたヘッダーを検索する場所を把握する必要があります。この問題を解決する方法は複数あります（
cc_binaryのincludes属性を使用するなど）。ここでは、cc_common.create_cc_toolchain_config_infoのcxx_builtin_include_directoriesパラメータを使用して、ツールチェーン レベルで解決します。別のバージョンのclangを使用している場合は、インクルード パスが異なることに注意してください。これらのパスは、ディストリビューションによって異なる場合もあります。toolchain/cc_toolchain_config.bzlの戻り値を次のように変更します。return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )ビルドコマンドを再度実行すると、次のようなエラーが表示されます。
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'これは、リンカーに C++ 標準ライブラリがなく、そのシンボルが見つからないためです。この問題を解決する方法はたくさんあります。たとえば、
cc_binaryのlinkopts属性を使用する方法があります。ここでは、ツールチェーンを使用するターゲットがこのフラグを指定する必要がないようにすることで解決しています。次のコードを
cc_toolchain_config.bzlにコピーします。# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", "flag_group", "flag_set", "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )bazel build --config=clang_config //main:hello-worldを実行すると、最終的にビルドされます。
作業内容を確認する
このチュートリアルでは、基本的な C++ ツールチェーンを構成する方法を学びましたが、ツールチェーンはこれよりもはるかに強力です。
主なポイントは次のとおりです。
- コマンドラインで --crosstool_top フラグを指定する必要があります。このフラグは cc_toolchain_suite を指す必要があります。
- .bazelrc ファイルを使用して、特定の構成のショートカットを作成できます。
- cc_toolchain_suite には、さまざまな CPU とコンパイラの cc_toolchains がリストされている場合があります。--cpu などのコマンドライン フラグを使用して区別できます。- ツールチェーンにツールの場所を知らせる必要があります。このチュートリアルでは、システムからツールにアクセスする簡略版を使用します。より自己完結型の方法に関心がある場合は、ワークスペースについてこちらをご覧ください。ツールは別のワークスペースから取得される可能性があり、compiler_files などの属性に対するターゲット依存関係を持つ cc_toolchain でファイルを利用できるようにする必要があります。tool_paths も変更する必要があります。- リンクなどのさまざまなアクションに渡すフラグをカスタマイズする機能を作成できます。
関連情報
詳しくは、C++ ツールチェーンの構成をご覧ください。