BazelCon 2025 の登録と CFP が開始されました。

このページは Cloud Translation API によって翻訳されました。

プラットフォーム

問題を報告するソースを表示 Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

Bazel は、リンカーやコンパイラなどのさまざまなバージョンのビルドツールを使用して、さまざまなハードウェア、オペレーティングシステム、システム構成でコードをビルドしてテストできます。この複雑さを管理するために、Bazel には制約とプラットフォームの概念があります。制約とは、ビルド環境や本番環境が異なる可能性のあるディメンション（CPU アーキテクチャ、GPU の有無、システムにインストールされているコンパイラのバージョンなど）です。プラットフォームは、これらの制約の選択肢の名前付きコレクションであり、特定の環境で使用可能な特定のリソースを表します。

環境をプラットフォームとしてモデル化すると、Bazel はビルドアクションに適したツールチェーンを自動的に選択できます。プラットフォームは、config_setting ルールと組み合わせて使用して、構成可能な属性を記述することもできます。

Bazel は、プラットフォームが提供する 3 つのロールを認識します。

ホスト - Bazel 自体が実行されるプラットフォーム。
実行 - ビルドツールがビルドアクションを実行して中間出力と最終出力を生成するプラットフォーム。
ターゲット - 最終出力が存在し、実行されるプラットフォーム。

Bazel は、プラットフォームに関する次のビルドシナリオをサポートしています。

単一プラットフォームビルド（デフォルト）- ホスト、実行、ターゲットのプラットフォームが同じです。たとえば、Intel x64 CPU で実行されている Ubuntu で Linux 実行可能ファイルを作成する場合などです。
クロスコンパイルビルド - ホストプラットフォームと実行プラットフォームは同じですが、ターゲットプラットフォームが異なります。たとえば、MacBook Pro で実行されている macOS で iOS アプリをビルドする場合などです。
マルチプラットフォームビルド - ホスト、実行、ターゲットの各プラットフォームがすべて異なる。

制約とプラットフォームを定義する

プラットフォームの選択肢のスペースは、BUILD ファイル内の constraint_setting ルールと constraint_value ルールを使用して定義されます。constraint_setting は新しいディメンションを作成し、constraint_value は特定のディメンションの新しい値を作成します。これらを組み合わせることで、列挙型とその可能な値を効果的に定義できます。たとえば、次の BUILD ファイルのスニペットでは、2 つの可能な値を持つシステムの glibc バージョンの制約が導入されています。

constraint_setting(name = "glibc_version")

constraint_value(
    name = "glibc_2_25",
    constraint_setting = ":glibc_version",
)

constraint_value(
    name = "glibc_2_26",
    constraint_setting = ":glibc_version",
)

制約とその値は、ワークスペース内のさまざまなパッケージで定義できます。ラベルで参照され、通常の公開設定の制御が適用されます。可視性が許容される場合は、既存の制約設定に独自の値を定義して、その設定を拡張できます。

platform ルールは、特定の制約値の選択肢を持つ新しいプラットフォームを導入します。次の例では、linux_x86 という名前のプラットフォームを作成し、glibc バージョン 2.25 の x86_64 アーキテクチャで Linux オペレーティングシステムを実行する環境を記述しています。（Bazel の組み込み制約の詳細については、以下をご覧ください）。

platform(
    name = "linux_x86",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
        ":glibc_2_25",
    ],
)

一般的に有用な制約とプラットフォーム

エコシステムの一貫性を保つため、Bazel チームは、最も一般的な CPU アーキテクチャとオペレーティングシステムの制約定義を含むリポジトリを管理しています。これらはすべて https://github.com/bazelbuild/platforms にあります。

Bazel には、次の特別なプラットフォーム定義が付属しています。@platforms//host（@bazel_tools//tools:host_platform のエイリアス）。これは、自動検出されたホストプラットフォームの値です。Bazel が実行されているシステムの自動検出されたプラットフォームを表します。

ビルドのプラットフォームを指定する

ビルドのホストプラットフォームとターゲットプラットフォームは、次のコマンドラインフラグを使用して指定できます。

--host_platform - デフォルトは @bazel_tools//tools:host_platform です
- このターゲットは @platforms//host にエイリアス設定されています。これは、ホスト OS と CPU を検出し、プラットフォームターゲットを書き込むリポジトリルールによってサポートされています。
- @platforms//host:constraints.bzl もあります。これは、他の BUILD ファイルと Starlark ファイルで使用できる HOST_CONSTRAINTS という配列を公開します。
--platforms - デフォルトはホストプラットフォームです。
- つまり、他のフラグが設定されていない場合、@platforms//host がターゲットプラットフォームになります。
- --host_platform が設定されていて --platforms が設定されていない場合、--host_platform の値はホストプラットフォームとターゲットプラットフォームの両方になります。

互換性のないターゲットをスキップする

特定のターゲットプラットフォーム向けにビルドする場合、そのプラットフォームで動作しないターゲットをスキップすることが望ましいことがよくあります。たとえば、//... を使用して Linux マシンでビルドする場合、Windows デバイスドライバでコンパイラエラーが多数発生する可能性があります。target_compatible_with 属性を使用して、コードのターゲットプラットフォームの制約を Bazel に伝えます。

この属性の最も簡単な使用方法は、ターゲットを単一のプラットフォームに制限することです。制約をすべて満たしていないプラットフォームでは、ターゲットはビルドされません。次の例では、win_driver_lib.cc を 64 ビット Windows に制限しています。

cc_library(
    name = "win_driver_lib",
    srcs = ["win_driver_lib.cc"],
    target_compatible_with = [
        "@platforms//cpu:x86_64",
        ";@platforms//os:windows",
    ],
)

:win_driver_lib は 64 ビット Windows でのビルドにのみ互換性があり、それ以外では互換性がありません。非互換性は推移的です。互換性のないターゲットに推移的に依存するターゲットは、それ自体が互換性がないと見なされます。

ターゲットがスキップされるのはいつですか？

ターゲットが互換性がないと見なされ、ターゲットパターン展開の一部としてビルドに含まれている場合、ターゲットはスキップされます。たとえば、次の 2 つの呼び出しは、ターゲットパターンの展開で見つかった互換性のないターゲットをスキップします。

$ bazel build --platforms=//:myplatform //...

$ bazel build --platforms=//:myplatform //:all

--expand_test_suites を指定してコマンドラインで test_suite が指定されている場合、test_suite 内の互換性のないテストも同様にスキップされます。つまり、コマンドラインの test_suite ターゲットは :all や ... のように動作します。--noexpand_test_suites を使用すると、拡張が防止され、互換性のないテストを含む test_suite ターゲットも互換性がなくなります。

コマンドラインで互換性のないターゲットを明示的に指定すると、エラーメッセージが表示され、ビルドが失敗します。

$ bazel build --platforms=//:myplatform //:target_incompatible_with_myplatform
...
ERROR: Target //:target_incompatible_with_myplatform is incompatible and cannot be built, but was explicitly requested.
...
FAILED: Build did NOT complete successfully

--skip_incompatible_explicit_targets が有効になっている場合、互換性のない明示的なターゲットはサイレントにスキップされます。

より表現力の高い制約

制約をより柔軟に表現するには、どのプラットフォームも満たさない @platforms//:incompatible constraint_value を使用します。

select() を @platforms//:incompatible と組み合わせて使用すると、より複雑な制限を表現できます。たとえば、基本的な OR ロジックを実装するために使用します。次のマークは、macOS と Linux に対応しているが、他のプラットフォームには対応していないライブラリを示します。

cc_library(
    name = "unixish_lib",
    srcs = ["unixish_lib.cc"],
    target_compatible_with = select({
        "@platforms//os:osx": [],
        "@platforms//os:linux": [],
        "//conditions:default": ["@platforms//:incompatible"],
    }),
)

上記は次のように解釈できます。

macOS をターゲットにしている場合、ターゲットには制約がありません。
Linux をターゲットに設定する場合、ターゲットに制約はありません。
それ以外の場合、ターゲットには @platforms//:incompatible 制約があります。@platforms//:incompatible はどのプラットフォームにも含まれていないため、ターゲットは互換性がないと見なされます。

制約を読みやすくするには、skylib の selects.with_or() を使用します。

逆互換性も同様に表現できます。次の例は、ARM 以外のすべてと互換性のあるライブラリを示しています。

cc_library(
    name = "non_arm_lib",
    srcs = ["non_arm_lib.cc"],
    target_compatible_with = select({
        "@platforms//cpu:arm": ["@platforms//:incompatible"],
        "//conditions:default": [],
    }),
)

`bazel cquery` を使用して互換性のないターゲットを検出する

bazel cquery の Starlark 出力形式で IncompatiblePlatformProvider を使用すると、互換性のないターゲットと互換性のあるターゲットを区別できます。

これは、互換性のないターゲットを除外するために使用できます。次の例では、互換性のあるターゲットのラベルのみが出力されます。互換性のないターゲットは出力されません。

$ cat example.cquery

def format(target):
  if "IncompatiblePlatformProvider" not in providers(target):
    return target.label
  return ""


$ bazel cquery //... --output=starlark --starlark:file=example.cquery

既知の問題

互換性のないターゲットは可視性の制限を無視します。