บทแนะนำ Bazel: สร้างโปรเจ็กต์ Java

รายงานปัญหา ดูแหล่งที่มา รุ่น Nightly · 7.4 7.3 · 7.2 · 7.1 · 7.0 · 6.5

บทแนะนํานี้จะอธิบายพื้นฐานการสร้างแอปพลิเคชัน Java ด้วย Bazel คุณจะตั้งค่าพื้นที่ทำงานและสร้างโปรเจ็กต์ Java แบบง่ายๆ ที่ แสดงแนวคิดหลักของ Bazel เช่น เป้าหมายและไฟล์ BUILD

เวลาโดยประมาณในการดำเนินการเสร็จสมบูรณ์: 30 นาที

สิ่งที่คุณจะได้เรียนรู้

ในบทแนะนำนี้ คุณจะได้เรียนรู้วิธีทำสิ่งต่อไปนี้

  • สร้างเป้าหมาย
  • แสดงภาพทรัพยากร Dependency ของโปรเจ็กต์
  • แยกโปรเจ็กต์ออกเป็นหลายเป้าหมายและแพ็กเกจ
  • ควบคุมระดับการเข้าถึงเป้าหมายในแพ็กเกจต่างๆ
  • อ้างอิงเป้าหมายผ่านป้ายกํากับ
  • ติดตั้งใช้งานเป้าหมาย

ก่อนเริ่มต้น

ติดตั้ง Bazel

ในการเตรียมตัวสำหรับบทแนะนำ ให้ติดตั้ง Bazel ก่อน หากยังไม่ได้ติดตั้ง

ติดตั้ง JDK

  1. ติดตั้ง Java JDK (เวอร์ชันที่ต้องการคือ 11 แต่รองรับเวอร์ชัน 8 ถึง 15)

  2. ตั้งค่าตัวแปรสภาพแวดล้อม JAVA_HOME ให้ชี้ไปยัง JDK

    • ใน Linux/macOS:

      export JAVA_HOME="$(dirname $(dirname $(realpath $(which javac))))"

    • บน Windows:

      1. เปิดแผงควบคุม
      2. ไปที่ "ระบบและความปลอดภัย" "ระบบ" "การตั้งค่าระบบขั้นสูง" "ขั้นสูง" แท็บ > "ตัวแปรสภาพแวดล้อม..."
      3. คลิก "ใหม่..." ในรายการ "ตัวแปรของผู้ใช้" (รายการที่ด้านบน)
      4. ป้อน JAVA_HOME ในช่อง "ชื่อตัวแปร"
      5. คลิก "เรียกดูไดเรกทอรี..."
      6. ไปที่ไดเรกทอรี JDK (เช่น C:\Program Files\Java\jdk1.8.0_152)
      7. คลิก "ตกลง" ในหน้าต่างกล่องโต้ตอบทั้งหมด

รับโปรเจ็กต์ตัวอย่าง

เรียกข้อมูลโปรเจ็กต์ตัวอย่างจากที่เก็บ GitHub ของ Bazel

git clone https://github.com/bazelbuild/examples

โปรเจ็กต์ตัวอย่างสําหรับบทแนะนํานี้จะอยู่ในไดเรกทอรี examples/java-tutorial และมีลักษณะดังนี้

java-tutorial
├── BUILD
├── src
│   └── main
│       └── java
│           └── com
│               └── example
│                   ├── cmdline
│                   │   ├── BUILD
│                   │   └── Runner.java
│                   ├── Greeting.java
│                   └── ProjectRunner.java
└── WORKSPACE

สร้างด้วย Bazel

ตั้งค่าพื้นที่ทํางาน

คุณต้องตั้งค่าพื้นที่ทํางานก่อนจึงจะสร้างโปรเจ็กต์ได้ เวิร์กช็อปคือไดเรกทอรีที่มีไฟล์ต้นฉบับของโปรเจ็กต์และเอาต์พุตการสร้างของ Bazel ทั้งนี้ ยังมีไฟล์ที่ Bazel เห็นว่าพิเศษด้วย ดังนี้

  • ไฟล์ WORKSPACE ซึ่งระบุไดเรกทอรีและเนื้อหาในไดเรกทอรีเป็น Bazel Workspace และอยู่ที่รูทของโครงสร้างไดเรกทอรีของโปรเจ็กต์

  • ไฟล์ BUILD อย่างน้อย 1 ไฟล์ ซึ่งบอก Bazel ถึงวิธีสร้างส่วนต่างๆ ของ สำหรับโครงการ (ไดเรกทอรีภายในพื้นที่ทำงานที่มีไฟล์ BUILD จะเป็นแพ็กเกจ คุณจะได้เรียนรู้เกี่ยวกับแพ็กเกจในบทแนะนำนี้ในภายหลัง)

หากต้องการกำหนดไดเรกทอรีเป็นพื้นที่ทำงาน Bazel ให้สร้างไฟล์เปล่าชื่อ WORKSPACE ในไดเรกทอรีนั้น

เมื่อ Bazel สร้างโปรเจ็กต์ อินพุตและการอ้างอิงทั้งหมดต้องเหมือนกัน Google Workspace ได้อย่างเต็มประสิทธิภาพ ไฟล์ที่อยู่ในพื้นที่ทำงานที่ต่างกันจะแยกออกจากกันเป็น 1 ไฟล์ วิดีโออื่นยกเว้นที่ลิงก์อยู่ ซึ่งอยู่นอกเหนือขอบเขตของบทแนะนำนี้

ทำความเข้าใจไฟล์ BUILD

ไฟล์ BUILD มีวิธีการหลายประเภทสำหรับ Bazel ประเภทที่สำคัญที่สุดคือกฎการสร้าง ซึ่งบอก Bazel ว่าจะสร้างเอาต์พุตที่ต้องการอย่างไร เช่น ไฟล์ไบนารีหรือไลบรารีที่เรียกใช้ได้ อินสแตนซ์แต่ละรายการของกฎการสร้างในไฟล์ BUILD เรียกว่าเป้าหมายและชี้ไปยังชุดไฟล์ต้นทางและชุดข้อมูลที่พึ่งพาที่เฉพาะเจาะจง เป้าหมายยังสามารถชี้ไปยัง เป้าหมาย

โปรดดูไฟล์ java-tutorial/BUILD

java_binary(
    name = "ProjectRunner",
    srcs = glob(["src/main/java/com/example/*.java"]),
)

ในตัวอย่างของเรา เป้าหมาย ProjectRunner จะสร้างอินสแตนซ์กฎ java_binary ในตัวของ Bazel กฎบอก Bazel สร้างไฟล์ .jar และสคริปต์ Shell Wrapper (ซึ่งทั้งคู่ตั้งชื่อตามเป้าหมาย)

แอตทริบิวต์ในเป้าหมายจะระบุการพึ่งพาและตัวเลือกอย่างชัดเจน แม้ว่าแอตทริบิวต์ name จะเป็นสิ่งที่ต้องระบุ แต่แอตทริบิวต์อื่นๆ หลายรายการเป็นค่าที่ไม่บังคับ ตัวอย่างเช่น ใน เป้าหมายกฎ ProjectRunner, name คือชื่อของเป้าหมาย, srcs ระบุ ไฟล์ต้นฉบับที่ Bazel ใช้ในการสร้างเป้าหมาย และ main_class ระบุ ที่มีเมธอดหลัก (คุณอาจสังเกตเห็นว่าตัวอย่างของเราใช้ glob เพื่อส่งชุดไฟล์ต้นฉบับไปยัง Bazel แทนที่จะแสดงรายการทีละรายการ)

สร้างโปรเจ็กต์

หากต้องการสร้างโปรเจ็กต์ตัวอย่าง ให้ไปที่ไดเรกทอรี java-tutorial และเรียกใช้

bazel build //:ProjectRunner

ในป้ายกำกับเป้าหมาย ส่วน // คือตำแหน่งของไฟล์ BUILD สัมพัทธ์กับรูทของพื้นที่ทำงาน (ในกรณีนี้คือรูทเอง) และ ProjectRunner คือชื่อเป้าหมายในไฟล์ BUILD (คุณจะได้ดูรายละเอียดเพิ่มเติมเกี่ยวกับป้ายกํากับเป้าหมายที่ส่วนท้ายของบทแนะนํานี้)

Bazel จะสร้างเอาต์พุตที่คล้ายกับตัวอย่างต่อไปนี้

   INFO: Found 1 target...
   Target //:ProjectRunner up-to-date:
      bazel-bin/ProjectRunner.jar
      bazel-bin/ProjectRunner
   INFO: Elapsed time: 1.021s, Critical Path: 0.83s

ยินดีด้วย คุณเพิ่งสร้างเป้าหมาย Bazel รายการแรก Bazel จะวางเอาต์พุตการสร้างในไดเรกทอรี bazel-bin ที่รูทของพื้นที่ทํางาน เรียกดูเนื้อหาเพื่อดูตัวอย่างโครงสร้างเอาต์พุตของ Bazel

ตอนนี้ให้ทดสอบไบนารีที่เพิ่งสร้างขึ้นใหม่โดยทำดังนี้

bazel-bin/ProjectRunner

ตรวจสอบกราฟทรัพยากร Dependency

Bazel กําหนดให้ต้องประกาศการพึ่งพาการบิลด์อย่างชัดแจ้งในไฟล์ BUILD Bazel จะใช้ข้อความเหล่านั้นเพื่อสร้างกราฟทรัพยากร Dependency ของโครงการ ช่วยให้มีบิลด์เพิ่มขึ้นที่แม่นยำ

คุณสามารถสร้างข้อความเพื่อดูทรัพยากร Dependency ของโปรเจ็กต์ตัวอย่างได้ การแสดงกราฟทรัพยากร Dependency ด้วยการเรียกใช้คำสั่งนี้ที่ รูทของพื้นที่ทำงาน:

bazel query  --notool_deps --noimplicit_deps "deps(//:ProjectRunner)" --output graph

คำสั่งข้างต้นบอกให้ Bazel ค้นหาไลบรารีทั้งหมดของเป้าหมาย //:ProjectRunner (ยกเว้นไลบรารีของโฮสต์และไลบรารีโดยนัย) และจัดรูปแบบเอาต์พุตเป็นกราฟ

จากนั้นวางข้อความลงใน GraphViz

คุณจะเห็นได้ว่า โปรเจ็กต์นี้มีเป้าหมายเดียวที่สร้างไฟล์ต้นฉบับ 2 ไฟล์ด้วย ไม่มีการอ้างอิงเพิ่มเติม:

กราฟการขึ้นต่อกันของเป้าหมาย "ProjectRunner"

หลังจากตั้งค่าพื้นที่ทำงานแล้ว ให้สร้างโปรเจ็กต์และตรวจสอบ ทรัพยากร Dependency เพิ่มเติม คุณก็จะเพิ่มความซับซ้อนได้

ปรับแต่งงานสร้าง Bazel

แม้ว่าเป้าหมายเดียวจะเพียงพอสําหรับโปรเจ็กต์ขนาดเล็ก แต่คุณอาจต้องแยกโปรเจ็กต์ขนาดใหญ่ออกเป็นเป้าหมายและแพ็กเกจหลายรายการเพื่อให้บิลด์ได้อย่างรวดเร็ว (กล่าวคือ บิลด์เฉพาะสิ่งที่เปลี่ยนแปลง) และเพื่อเร่งความเร็วในการสร้างโดยการสร้างหลายส่วนของโปรเจ็กต์พร้อมกัน

ระบุเป้าหมายของบิลด์หลายรายการ

คุณแบ่งโปรเจ็กต์ตัวอย่างที่สร้างออกเป็น 2 เป้าหมายได้ แทนที่เนื้อหาของ ไฟล์ java-tutorial/BUILD ที่มีข้อมูลดังต่อไปนี้

java_binary(
    name = "ProjectRunner",
    srcs = ["src/main/java/com/example/ProjectRunner.java"],
    main_class = "com.example.ProjectRunner",
    deps = [":greeter"],
)

java_library(
    name = "greeter",
    srcs = ["src/main/java/com/example/Greeting.java"],
)

ด้วยการกำหนดค่านี้ Bazel จะสร้างไลบรารี greeter ก่อน จากนั้น เลขฐานสอง ProjectRunner แอตทริบิวต์ deps ใน java_binary บอก Bazel ว่าต้องใช้ไลบรารี greeter เพื่อสร้างไบนารี ProjectRunner

หากต้องการสร้างโปรเจ็กต์เวอร์ชันใหม่นี้ ให้เรียกใช้คำสั่งต่อไปนี้

bazel build //:ProjectRunner

Bazel จะสร้างเอาต์พุตที่คล้ายกับตัวอย่างต่อไปนี้

INFO: Found 1 target...
Target //:ProjectRunner up-to-date:
  bazel-bin/ProjectRunner.jar
  bazel-bin/ProjectRunner
INFO: Elapsed time: 2.454s, Critical Path: 1.58s

ตอนนี้ให้ทดสอบไบนารีที่เพิ่งสร้างขึ้นใหม่โดยทำดังนี้

bazel-bin/ProjectRunner

หากตอนนี้คุณแก้ไข ProjectRunner.java และสร้างโปรเจ็กต์ใหม่ Bazel เท่านั้น คอมไพล์ไฟล์นั้นซ้ำ

เมื่อดูกราฟทรัพยากร Dependency แล้ว คุณจะเห็นได้ว่า ProjectRunner ขึ้นอยู่กับ ป้อนข้อมูลเหมือนเดิม แต่โครงสร้างของบิลด์จะแตกต่างออกไป

กราฟทรัพยากร Dependency ของเป้าหมาย "ProjectRunner" หลังจากเพิ่ม Dependency

ตอนนี้คุณได้สร้างโปรเจ็กต์ที่มีเป้าหมาย 2 รายการแล้ว เป้าหมาย ProjectRunner จะสร้างไฟล์ต้นฉบับ 2 ไฟล์และขึ้นอยู่กับเป้าหมายอื่น 1 รายการ (:greeter) ซึ่งจะสร้างไฟล์ต้นฉบับอีก 1 ไฟล์

ใช้หลายแพ็กเกจ

ตอนนี้เราจะมาแบ่งโปรเจ็กต์ออกเป็นหลายๆ แพ็กเกจ เมื่อดูที่ไดเรกทอรี src/main/java/com/example/cmdline คุณจะเห็นว่ามีไฟล์ BUILD และไฟล์ต้นฉบับบางไฟล์ด้วย ดังนั้น ตอนนี้พื้นที่ทํางานของ Bazel จะมีแพ็กเกจ 2 รายการ ได้แก่ //src/main/java/com/example/cmdline และ // (เนื่องจากมีไฟล์ BUILD ที่รูทของพื้นที่ทํางาน)

ดูไฟล์ src/main/java/com/example/cmdline/BUILD:

java_binary(
    name = "runner",
    srcs = ["Runner.java"],
    main_class = "com.example.cmdline.Runner",
    deps = ["//:greeter"],
)

เป้าหมาย runner ขึ้นอยู่กับเป้าหมาย greeter ในแพ็กเกจ // (ดังนั้น ป้ายกำกับเป้าหมาย //:greeter) - Bazel ทราบเรื่องนี้ผ่านแอตทริบิวต์ deps ดูกราฟทรัพยากร Dependency ต่อไปนี้

กราฟทรัพยากร Dependency ของ "Runner" เป้าหมาย

อย่างไรก็ตาม คุณต้องให้เป้าหมาย runner อย่างชัดเจนเพื่อให้บิลด์ประสบความสำเร็จ การแสดงผล //src/main/java/com/example/cmdline/BUILD เป้าหมายไปยังเป้าหมายใน //BUILD โดยใช้แอตทริบิวต์ visibility เนื่องจากโดยค่าเริ่มต้น เฉพาะเป้าหมายอื่นๆ ในไฟล์ BUILD เดียวกันเท่านั้นที่จะเห็นเป้าหมาย (Bazel ใช้เป้าหมาย การมองเห็นเพื่อป้องกันปัญหาต่างๆ เช่น ไลบรารีที่มีรายละเอียดการใช้งาน รั่วไหลไปยัง API สาธารณะ)

โดยเพิ่มแอตทริบิวต์ visibility ลงในเป้าหมาย greeter ใน java-tutorial/BUILD ตามที่แสดงด้านล่าง:

java_library(
    name = "greeter",
    srcs = ["src/main/java/com/example/Greeting.java"],
    visibility = ["//src/main/java/com/example/cmdline:__pkg__"],
)

ตอนนี้คุณสามารถสร้างแพ็กเกจใหม่โดยเรียกใช้คำสั่งต่อไปนี้ที่รูท ในพื้นที่ทำงาน

bazel build //src/main/java/com/example/cmdline:runner

Bazel จะสร้างเอาต์พุตที่คล้ายกับตัวอย่างต่อไปนี้

INFO: Found 1 target...
Target //src/main/java/com/example/cmdline:runner up-to-date:
  bazel-bin/src/main/java/com/example/cmdline/runner.jar
  bazel-bin/src/main/java/com/example/cmdline/runner
  INFO: Elapsed time: 1.576s, Critical Path: 0.81s

ตอนนี้ให้ทดสอบไบนารีที่เพิ่งสร้างขึ้นใหม่โดยทำดังนี้

./bazel-bin/src/main/java/com/example/cmdline/runner

ตอนนี้คุณแก้ไขโปรเจ็กต์เพื่อสร้างเป็น 2 แพ็กเกจแล้ว โดยแต่ละแพ็กเกจจะมี 1 แพ็กเกจ กำหนดเป้าหมายและทำความเข้าใจการพึ่งพากันระหว่างกัน

ใช้ป้ายกำกับเพื่ออ้างอิงเป้าหมาย

ในไฟล์ BUILD และที่บรรทัดคำสั่ง Bazel จะใช้ป้ายกำกับเป้าหมายเพื่ออ้างอิงเป้าหมาย เช่น //:ProjectRunner หรือ //src/main/java/com/example/cmdline:runner ไวยากรณ์ของคำสั่งมีดังนี้

//path/to/package:target-name

หากเป้าหมายคือเป้าหมายของกฎ path/to/package คือเส้นทางไปยังไดเรกทอรีที่มีไฟล์ BUILD และ target-name คือชื่อที่คุณตั้งให้กับเป้าหมายในไฟล์ BUILD (แอตทริบิวต์ name) หากเป้าหมายเป็นไฟล์ path/to/package คือเส้นทางไปยังรูทของแพ็กเกจ และ target-name คือชื่อไฟล์เป้าหมาย รวมถึงเส้นทางแบบเต็ม

เมื่ออ้างอิงเป้าหมายที่รูทของที่เก็บข้อมูล เส้นทางของแพ็กเกจจะว่างเปล่า ให้ใช้ //:target-name เมื่ออ้างอิงเป้าหมายภายใน BUILD เดียวกัน คุณสามารถข้ามตัวระบุรูทของพื้นที่ทำงาน // และใช้ :target-name

ตัวอย่างเช่น สำหรับเป้าหมายในไฟล์ java-tutorial/BUILD คุณไม่จำเป็นต้องระบุเส้นทางของแพ็กเกจ เนื่องจากรูทของพื้นที่ทำงานเป็นแพ็กเกจอยู่แล้ว (//) และป้ายกำกับเป้าหมาย 2 รายการของคุณก็คือ //:ProjectRunner และ //:greeter

แต่สำหรับเป้าหมายในไฟล์ //src/main/java/com/example/cmdline/BUILD คุณต้องระบุเส้นทางแบบเต็มของแพ็กเกจ //src/main/java/com/example/cmdline และป้ายกำกับเป้าหมายคือ //src/main/java/com/example/cmdline:runner

สร้างแพ็กเกจเป้าหมาย Java สำหรับการทำให้ใช้งานได้

ตอนนี้เรามาทำแพ็กเกจเป้าหมาย Java สำหรับการทำให้ใช้งานได้ด้วยการสร้างไบนารีที่มี ของทรัพยากร Dependency รันไทม์ ซึ่งจะช่วยให้คุณเรียกใช้ไบนารีนอกสภาพแวดล้อมการพัฒนาได้

ดังที่คุณจำได้ กฎการสร้าง java_binary จะสร้าง .jar และสคริปต์เชลล์ของ Wrapper ดูเนื้อหาของ runner.jar โดยใช้คำสั่งนี้

jar tf bazel-bin/src/main/java/com/example/cmdline/runner.jar

คอนเทนต์มีดังนี้

META-INF/
META-INF/MANIFEST.MF
com/
com/example/
com/example/cmdline/
com/example/cmdline/Runner.class

คุณจะเห็นว่า runner.jar มี Runner.class แต่ไม่มี Dependency Greeting.class สคริปต์ runner ที่ Bazel สร้างจะเพิ่ม greeter.jar ไปยังคลาสพาธ ดังนั้นหากคุณปล่อยไว้แบบนี้ รายการก็จะทำงานภายใน แต่ จะไม่ทำงานแบบสแตนด์อโลนในเครื่องอื่น โชคดีที่กฎ java_binary จะช่วยให้คุณสร้างไบนารีแบบ ในตัวที่นำไปใช้ได้ ต่อท้ายด้วย _deploy.jar เป็นชื่อเป้าหมาย:

bazel build //src/main/java/com/example/cmdline:runner_deploy.jar

Bazel จะสร้างเอาต์พุตที่คล้ายกับตัวอย่างต่อไปนี้

INFO: Found 1 target...
Target //src/main/java/com/example/cmdline:runner_deploy.jar up-to-date:
  bazel-bin/src/main/java/com/example/cmdline/runner_deploy.jar
INFO: Elapsed time: 1.700s, Critical Path: 0.23s

คุณเพิ่งสร้าง runner_deploy.jar ซึ่งสามารถเรียกใช้ได้แบบสแตนด์อโลนจากสภาพแวดล้อมการพัฒนา เนื่องจากมีไลบรารีรันไทม์ที่จำเป็น ดูเนื้อหาของ JAR แบบสแตนด์อโลนนี้โดยใช้คำสั่งเดียวกันกับก่อนหน้านี้

jar tf bazel-bin/src/main/java/com/example/cmdline/runner_deploy.jar

เนื้อหาประกอบด้วยคลาสที่จำเป็นทั้งหมดในการเรียกใช้

META-INF/
META-INF/MANIFEST.MF
build-data.properties
com/
com/example/
com/example/cmdline/
com/example/cmdline/Runner.class
com/example/Greeting.class

อ่านเพิ่มเติม

โปรดดูรายละเอียดเพิ่มเติมที่หัวข้อต่อไปนี้

ขอให้สนุกกับการสร้าง