Performansı Optimize Etme

Sorun bildirme Kaynağı görüntüleme Nightly · 7.4 . 7.3 · 7,2 · 7,1 · 7,0 · 6,5

Kural yazarken en yaygın performans sorunu, bağımlılıklardan toplanan verileri taramak veya kopyalamaktır. Bu işlemler, derleme işleminin tamamında toplandığında kolayca O(N^2) zaman veya alan alabilir. Bu sorunu önlemek için depo setlerini etkili bir şekilde nasıl kullanacağınızı anlamanız çok önemlidir.

Bunu doğru şekilde yapmak zor olabilir. Bu nedenle Bazel, hata yapmış olabileceğiniz noktaları bulmanıza yardımcı olan bir bellek profilleyici de sağlar. Aşağıdaki durumlarda uyar: Verimsiz bir kural yazmanın maliyeti, kural tam olarak yaygın bir şekilde kullanılıyor.

Depo kümelerini kullanma

Kural bağımlılıklarıyla ilgili bilgileri toplarken depsets belirtin. Bilgi yayınlamak için yalnızca düz listeleri veya diktleri kullanın yerel olarak ayarlayın.

Desset, bilgileri paylaşmaya olanak tanıyan iç içe yerleştirilmiş bir grafik olarak temsil eder.

Aşağıdaki grafiği inceleyin:

C -> B -> A
D ---^

Her düğüm tek bir dize yayınlar. Veriler, veri kümeleriyle şu şekilde görünür:

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

Her öğeden yalnızca bir kez bahsedildiğini unutmayın. Listeler sayesinde şunları yapabilirsiniz:

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

Bu örnekte 'a' dört kez kullanılmıştır. Daha büyük grafiklerde sorun daha da kötü hale gelir.

Aşağıda, geçişli bilgileri yayınlamak için depset'leri doğru şekilde kullanan bir kural uygulaması örneği verilmiştir. Yerel kural yayınlamanın kabul edilebilir olduğunu unutmayın isterseniz listeleri kullanabilirsiniz, çünkü bu O(N^2) değildir.

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

Daha fazla bilgi için cihaza genel bakış sayfasını ziyaret edin.

depset.to_list() numarasını aramaktan kaçının

Bir geliştirmeyi düz listeye dönüştürmek için to_list(). Ancak bu genellikle O(N^2) ile sonuçlanır maliyet. Mümkünse hata ayıklama dışında hataları düzleştirmekten kaçının. amaçlar.

Yaygın bir yanlış inanış, sadece bir şey yaparak duyguları özgürce düzeltebileceğinizdir. <xx>_binary kuralı gibi üst düzey hedeflere uygulanır. Çünkü bu durumda maliyet, seviye boyunca toplanan verileri gösterir. Ancak bu, sorun yaşanırken hâlâ O(N^2) bağımlılıkları çakışan bir dizi hedef oluşturursunuz. Bu, testlerinizi oluştururken //foo/tests/... veya bir IDE projesini içe aktarırken.

Arama sayısını depset'e düşürme

depset işlevinin bir döngü içinde çağrılması genellikle hatadır. Potansiyel riskler nedeniyle iç içe geçmiş olabilir. Bu da kötü performans gösterir. Örneğin:

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

Bu kod kolayca değiştirilebilir. İlk olarak, geçişli verileri toplayın ve hepsini aynı anda birleştirmek için:

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

Bu, bazen liste kapsamı kullanılarak azaltılabilir:

x = depset(transitive = [i.deps for i in inputs])

Komut satırları için ctx.actions.args() kullanma

Komut satırları oluştururken ctx.actions.args() işlevini kullanmanız gerekir. Bu, tüm depsetlerin genişletilmesini yürütme aşamasına erteler.

Bu, kesinlikle daha hızlı olmanın yanı sıra kurallarınızın hafıza tüketimini bazen %90 veya daha fazla azaltır.

Aşağıda bazı ipuçları verilmiştir:

  • Depset'leri ve listeleri birleştirmek yerine doğrudan bağımsız değişken olarak iletin kendiniz. Bu veriler sizin için ctx.actions.args() tarafından genişletilecektir. Depset içeriklerinde dönüştürme işlemi yapmanız gerekiyorsa ctx.actions.args#add değerine bakarak ihtiyacınız olan işlevi bulup bulamayacağınızı kontrol edin.

  • File#path bağımsız değişkenini mi ilerliyorsunuz? Gerek yok. Tüm dosyalar, otomatik olarak yoluna dönüştürülür ve genişletme zamanına ertelenir.

  • Dize oluşturmak için bunları birbirine bağlamaktan kaçının. En iyi dize bağımsız değişkeni, belleği kuralınızın tüm örnekleri arasında paylaşılacağı için sabit bir değerdir.

  • Bağımsız değişkenler komut satırı için çok uzunsa ctx.actions.args() nesnesi Parametre değeri, ctx.actions.args#use_param_file Bu sahne arkasında yapılır. Params dosyasını açıkça kontrol etmeniz gerekiyorsa ctx.actions.write kullanarak manuel olarak yazabilirsiniz.

Örnek:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

Geçişli işlem girişleri depset olmalıdır

ctx.actions.run işlevini kullanarak bir işlem oluştururken inputs alanının öğeleri kabul ettiğini unutmayın. Bu seçeneği, geçişli olarak toplanır.

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

Asılı

Bazel asılı görünüyorsa Ctrl-\ tuşlarına basabilir veya Bazel'i İleti dizisi almak için bir SIGQUIT sinyali (kill -3 $(bazel info server_pid)) oluşturun $(bazel info output_base)/server/jvm.out dosyasının dökümünü alın.

Bazel kilitlenirse bazel info'ü çalıştıramayabilirsiniz. Bu nedenle, output_base dizini genellikle Workspace dizininizdeki bazel-<workspace> simge bağlantısının üst dizinidir.

Performans profilleme

JSON izleme profili, Bazel'in çağrı sırasında ne kadar zaman harcadığını hızlıca anlamak için çok yararlı olabilir.

Bellek kullanımının profilini çıkarma

Bazel, kuralınızın verilerini kontrol etmenize yardımcı olabilecek yerleşik bir bellek profil oluşturucusuyla birlikte gelir. bazı işaretler vardır. Sorun varsa soruna neden olan tam kod satırını bulmak için yığını dökebilirsiniz.

Bellek izlemeyi etkinleştirme

Şu iki başlangıç işaretini her Bazel çağrısına iletmeniz gerekir:

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.0.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

Bu komutlar, sunucuyu bellek izleme modunda başlatır. Bunları bir Bazel çağrısında bile unutursanız sunucu yeniden başlatılır ve baştan başlamanız gerekir.

Bellek İzleyici'yi kullanma

Örneğin, foo hedefine bakın ve ne işe yaradığını öğrenin. Yalnızca alıcı çalıştırma aşamasını çalıştırmadan analizi çalıştırıyorsanız --nobuild işareti.

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

Daha sonra, tüm Bazel örneğinin tükettiği bellek miktarına bakın:

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

bazel dump --rules simgesini kullanarak verileri kural sınıfına göre ayırın:

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

bazel dump --skylark_memory kullanarak bir pprof dosyası oluşturarak belleğin nereye gittiğine bakın:

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

Yığını incelemek için pprof aracını kullanın. İyi bir başlangıç noktası pprof -flame $HOME/prof.gz kullanarak flame grafiği alınıyor.

pprof'yi https://github.com/google/pprof adresinden indirin.

En popüler telefon araması sitelerinin satırlarla ek açıklamalı metin dökümünü alın:

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)