Özellikler

file_count.bzl dosyası:

FileCountInfo = provider(
    fields = {
        'count' : 'number of files'
    }
)

def _file_count_aspect_impl(target, ctx):
    count = 0
    # Make sure the rule has a srcs attribute.
    if hasattr(ctx.rule.attr, 'srcs'):
        # Iterate through the sources counting files
        for src in ctx.rule.attr.srcs:
            for f in src.files.to_list():
                if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
                    count = count + 1
    # Get the counts from our dependencies.
    for dep in ctx.rule.attr.deps:
        count = count + dep[FileCountInfo].count
    return [FileCountInfo(count = count)]

file_count_aspect = aspect(
    implementation = _file_count_aspect_impl,
    attr_aspects = ['deps'],
    attrs = {
        'extension' : attr.string(values = ['*', 'h', 'cc']),
    }
)

def _file_count_rule_impl(ctx):
    for dep in ctx.attr.deps:
        print(dep[FileCountInfo].count)

file_count_rule = rule(
    implementation = _file_count_rule_impl,
    attrs = {
        'deps' : attr.label_list(aspects = [file_count_aspect]),
        'extension' : attr.string(default = '*'),
    },
)

BUILD.bazel dosyası:

load('//:file_count.bzl', 'file_count_rule')

cc_library(
    name = 'lib',
    srcs = [
        'lib.h',
        'lib.cc',
    ],
)

cc_binary(
    name = 'app',
    srcs = [
        'app.h',
        'app.cc',
        'main.cc',
    ],
    deps = ['lib'],
)

file_count_rule(
    name = 'file_count',
    deps = ['app'],
    extension = 'h',
)

Aspect tanımı

file_count_aspect = aspect(
    implementation = _file_count_aspect_impl,
    attr_aspects = ['deps'],
    attrs = {
        'extension' : attr.string(values = ['*', 'h', 'cc']),
    }
)

Bu örnekte, görünümün deps özelliği aracılığıyla nasıl dağıtıldığı gösterilmektedir.

attrs, bir yönle ilgili özellik grubunu tanımlar. Herkese açık yön özellikleri parametreleri tanımlar ve yalnızca bool, int veya string türünde olabilir. Kural tarafından dağıtılan özellikler için int ve string parametrelerinde values belirtilmelidir. Bu örnekte, değeri "*", "h" veya "cc" olan extension adlı bir parametre vardır.

Kural yayılımlı özellikler için parametre değerleri, istekte bulunan kuraldan alınır. kuralının aynı ada ve türe sahip özelliğini kullanarak en boy oranını girin. (file_count_rule kelimesinin tanımına bakın).

Komut satırı özellikleri için parametre değerleri, --aspects_parameters işareti kullanılarak iletilebilir. int ve string parametreleri için values kısıtlaması şu olabilir: atlandı.

En boyların label türünde gizli özelliklere de sahip olmasına izin verilir label_list. Özel etiket özellikleri, unsurlarla oluşturulan işlemler için gerekli araçlar veya kitaplıklar bulunur. Bu örnekte özel bir özellik tanımlanmamıştır ancak aşağıdaki kod snippet'inde bir aracı bir görünüme nasıl iletebileceğiniz gösterilmektedir:

...
    attrs = {
        '_protoc' : attr.label(
            default = Label('//tools:protoc'),
            executable = True,
            cfg = "exec"
        )
    }
...

Aspect uygulaması

FileCountInfo = provider(
    fields = {
        'count' : 'number of files'
    }
)

def _file_count_aspect_impl(target, ctx):
    count = 0
    # Make sure the rule has a srcs attribute.
    if hasattr(ctx.rule.attr, 'srcs'):
        # Iterate through the sources counting files
        for src in ctx.rule.attr.srcs:
            for f in src.files.to_list():
                if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
                    count = count + 1
    # Get the counts from our dependencies.
    for dep in ctx.rule.attr.deps:
        count = count + dep[FileCountInfo].count
    return [FileCountInfo(count = count)]

Tıpkı kural uygulama işlevi gibi, bir görünüm uygulama işlevi de bağımlılıkları tarafından erişilebilen bir sağlayıcı yapısını döndürür.

Bu örnekte FileCountInfo, benzersiz bir hizmet sağlayıcısı olarak tanımlanmış bir sağlayıcı count alanı. En iyi uygulama olarak, bir reklamverenin alanlarını açıkça tanımlamak fields özelliğini kullanan bir sağlayıcıdır.

A(X) en boy uygulaması için sağlayıcı grubu, sağlayıcıların birleşimidir hedefi X için bir kuralın uygulanmasından ve uygulanır. Bir kural uygulamasının yaydığı sağlayıcılar öğeler uygulanmadan önce oluşturulur ve dondurulamaz ve emin olun. Bir hedef ve ona uygulanan bir unsur varsa bu bir hatadır aynı türden bir sağlayıcı sağlayabilirsiniz, OutputGroupInfo (birleştirildiği takdirde, kuralı ve en boy oranı farklı çıkış gruplarını belirtir) ve InstrumentedFilesInfo (görüntüyü dikkate alın). Bu, yön uygulamalarının hiçbir zaman DefaultInfo döndürmeyeceği anlamına gelir.

Parametreler ve gizli özellikler, ctx öğesinin özelliklerinde iletilir. Bu örnekte extension parametresine referans verilerek hangi dosyaların sayılacağına karar verilir.

Geri dönen sağlayıcılar için, en boy oranı (attr_aspects listesinden) şununla değiştirilir: uygulamanın sonuçlarını tanımlamasına yardımcı olur. Örneğin, X'in noktalarında Y ve Z değerleri vardır. A(X) için ctx.rule.attr.deps değeri [A(Y), A(Z)] olur. Bu örnekte ctx.rule.attr.deps, en iyi performans gösteren ve “dep”lere uygulamanın sonuçları orijinal hedefin en boy oranı uygulandı.

Bu örnekte, özellik, FileCountInfo sağlayıcısına şuradan erişiyor: toplam geçişli dosya sayısını toplamak için bağımlılıklarını

Bir kuraldan özellik çağrılıyor

def _file_count_rule_impl(ctx):
    for dep in ctx.attr.deps:
        print(dep[FileCountInfo].count)

file_count_rule = rule(
    implementation = _file_count_rule_impl,
    attrs = {
        'deps' : attr.label_list(aspects = [file_count_aspect]),
        'extension' : attr.string(default = '*'),
    },
)

Kural uygulamasında, ctx.attr.deps üzerinden FileCountInfo'e nasıl erişileceği gösterilmektedir.

Kural tanımı, bir parametrenin (extension) nasıl tanımlanacağını gösterir. ve varsayılan bir değer (*) belirleyin. Projenin gidişatı boyunca 'cc', 'h' veya '*' değerlerinden biri değildi en boy tanımındaki parametreye uygulanan kısıtlamalar.

Hedef kural aracılığıyla bir yönü çağırma

load('//:file_count.bzl', 'file_count_rule')

cc_binary(
    name = 'app',
...
)

file_count_rule(
    name = 'file_count',
    deps = ['app'],
    extension = 'h',
)

Bu görselde, extension parametresinin özellik parametresine nasıl iletileceği gösterilmektedir aracılığıyla iletişim kurabilirsiniz. extension parametresi kural uygulamasında varsayılan bir değere sahip olduğundan extension isteğe bağlı bir parametre olarak kabul edilir.

file_count hedefi oluşturulduğunda, özelliğimiz şu yönde değerlendirilir: kendisi ve deps üzerinden yinelemeli olarak erişilebilen tüm hedefler.

Referanslar

• aspect API referansı