Chương trình đăng ký tham gia sự kiện BazelCon 2024 đã bắt đầu!

Trang này được dịch bởi Cloud Translation API.

Khía cạnh

Báo cáo vấn đề Xem nguồn Hằng đêm · 7,4 của Google. 7.3 · 7,2 · 7.1 · 7 · 6,5

Trang này giải thích các kiến thức cơ bản và lợi ích của việc sử dụng phương diện, đồng thời cung cấp các ví dụ đơn giản và nâng cao.

Các khía cạnh cho phép bổ sung thông tin và hành động bổ sung vào biểu đồ phần phụ thuộc của bản dựng. Một số trường hợp điển hình khi các phương diện có thể hữu ích:

Các IDE có tích hợp Bazel có thể sử dụng các khía cạnh để thu thập thông tin về dự án.
Các công cụ tạo mã có thể tận dụng các khía cạnh để thực thi dữ liệu đầu vào của chúng trong không phân biệt mục tiêu. Ví dụ: tệp BUILD có thể chỉ định hệ phân cấp của các định nghĩa thư viện protobuf và các quy tắc dành riêng cho ngôn ngữ có thể sử dụng các khía cạnh để đính kèm các thao tác tạo mã hỗ trợ protobuf cho một ngôn ngữ cụ thể.

Kiến thức cơ bản về tỷ lệ khung hình

Tệp BUILD cung cấp nội dung mô tả về mã nguồn của dự án: những tệp nguồn nào thuộc dự án, những cấu phần phần mềm (mục tiêu) nào cần được tạo từ các tệp đó, phần phụ thuộc giữa các tệp đó là gì, v.v. Bazel sử dụng thông tin này để tạo bản dựng, tức là tìm ra tập hợp các hành động cần thiết để tạo cấu phần phần mềm (chẳng hạn như chạy trình biên dịch hoặc trình liên kết) và thực thi các hành động đó. Bazel hoàn thành điều này bằng cách xây dựng phần phụ thuộc biểu đồ giữa các mục tiêu và truy cập vào biểu đồ này để thu thập những hành động đó.

Hãy xem xét tệp BUILD sau:

java_library(name = 'W', ...)
java_library(name = 'Y', deps = [':W'], ...)
java_library(name = 'Z', deps = [':W'], ...)
java_library(name = 'Q', ...)
java_library(name = 'T', deps = [':Q'], ...)
java_library(name = 'X', deps = [':Y',':Z'], runtime_deps = [':T'], ...)

Tệp BUILD này xác định một biểu đồ phần phụ thuộc như trong hình sau:

Tạo biểu đồ

Hình 1. Biểu đồ phần phụ thuộc tệp BUILD.

Bazel phân tích biểu đồ phần phụ thuộc này bằng cách gọi một hàm triển khai của quy tắc tương ứng (trong trường hợp này là "java_library") cho mỗi mục tiêu trong ví dụ trên. Các hàm triển khai quy tắc tạo ra các hành động tạo cấu phần phần mềm, chẳng hạn như tệp .jar, và truyền thông tin, chẳng hạn như vị trí và tên của các cấu phần phần mềm đó, đến các phần phụ thuộc ngược của các mục tiêu đó trong nhà cung cấp.

Các khía cạnh tương tự với quy tắc ở chỗ chúng có chức năng triển khai tạo các thao tác và trả về trình cung cấp. Tuy nhiên, sức mạnh của chúng đến từ cách tạo biểu đồ phần phụ thuộc cho chúng. Một khía cạnh có triển khai và danh sách tất cả thuộc tính mà đoạn mã đó được lan truyền cùng. Hãy cân nhắc một khía cạnh A truyền dọc theo các thuộc tính có tên là "deps". Có thể áp dụng khía cạnh này cho một mục tiêu X, tạo ra một nút ứng dụng khung hình A(X). Trong quá trình áp dụng, khía cạnh A được áp dụng đệ quy cho tất cả các mục tiêu mà X tham chiếu đến trong thuộc tính "phần phụ thuộc" (tất cả các thuộc tính trong danh sách truyền tải của A).

Do đó, chỉ một hành động áp dụng khía cạnh A cho một mục tiêu X tạo ra "biểu đồ bóng đổ" trong số biểu đồ phần phụ thuộc ban đầu của các mục tiêu được minh hoạ trong hình sau:

Tạo biểu đồ có Aspect

Hình 2. Tạo biểu đồ bằng các khía cạnh.

Các cạnh duy nhất bị đổ bóng là các cạnh dọc theo các thuộc tính trong tập hợp truyền lan, do đó cạnh runtime_deps không bị đổ bóng trong ví dụ: Sau đó, hàm triển khai khung hình được gọi trên tất cả các nút trong biểu đồ bóng tương tự như cách gọi phương thức triển khai quy tắc trên các nút của đồ thị ban đầu.

Ví dụ đơn giản

Ví dụ này minh hoạ cách in đệ quy các tệp nguồn cho một và tất cả các phần phụ thuộc của quy tắc đó có thuộc tính deps. Trang này cho thấy cách triển khai một khía cạnh, định nghĩa một khía cạnh và cách gọi khía cạnh đó từ dòng lệnh Bazel.

def _print_aspect_impl(target, ctx):
    # Make sure the rule has a srcs attribute.
    if hasattr(ctx.rule.attr, 'srcs'):
        # Iterate through the files that make up the sources and
        # print their paths.
        for src in ctx.rule.attr.srcs:
            for f in src.files.to_list():
                print(f.path)
    return []

print_aspect = aspect(
    implementation = _print_aspect_impl,
    attr_aspects = ['deps'],
)

Hãy chia nhỏ ví dụ này thành nhiều phần rồi kiểm tra riêng từng phần.

Định nghĩa về tỷ lệ khung hình

print_aspect = aspect(
    implementation = _print_aspect_impl,
    attr_aspects = ['deps'],
)

Định nghĩa về khía cạnh tương tự như định nghĩa về quy tắc và được xác định bằng hàm aspect.

Giống như quy tắc, một khía cạnh có hàm triển khai mà trong trường hợp này là _print_aspect_impl.

attr_aspects là danh sách các thuộc tính quy tắc mà khung hình sẽ được phổ biến theo đó. Trong trường hợp này, phương diện sẽ được truyền dọc theo thuộc tính deps của các quy tắc mà phương diện đó được áp dụng.

Một đối số phổ biến khác cho attr_aspects là ['*']. Đối số này sẽ truyền tải khía cạnh đến tất cả các thuộc tính của một quy tắc.

Cách triển khai Aspect

def _print_aspect_impl(target, ctx):
    # Make sure the rule has a srcs attribute.
    if hasattr(ctx.rule.attr, 'srcs'):
        # Iterate through the files that make up the sources and
        # print their paths.
        for src in ctx.rule.attr.srcs:
            for f in src.files.to_list():
                print(f.path)
    return []

Các hàm triển khai Aspect tương tự như triển khai quy tắc . Các tham số này trả về nhà cung cấp, có thể tạo hành động và dùng 2 đối số:

target: Mục tiêu mà phương diện đang được áp dụng.
ctx: Đối tượng ctx có thể được dùng để truy cập vào các thuộc tính, đồng thời tạo ra đầu ra và hành động.

Hàm triển khai có thể truy cập vào các thuộc tính của quy tắc mục tiêu thông qua ctx.rule.attr. Công cụ này có thể kiểm tra các nhà cung cấp do mục tiêu áp dụng (thông qua đối số target).

Cần có các phương diện để trả về danh sách nhà cung cấp. Trong ví dụ này, phương diện không cung cấp bất kỳ giá trị nào, do đó sẽ trả về một danh sách trống.

Gọi phương diện bằng dòng lệnh

Cách đơn giản nhất để áp dụng một khía cạnh là từ dòng lệnh bằng cách sử dụng đối số --aspects. Giả sử khía cạnh ở trên đã được xác định trong một tệp có tên print.bzl sau:

bazel build //MyExample:example --aspects print.bzl%print_aspect

sẽ áp dụng print_aspect cho example mục tiêu và tất cả các quy tắc mục tiêu có thể truy cập đệ quy thông qua thuộc tính deps.

Cờ --aspects nhận một đối số, là thông số kỹ thuật của tỷ lệ khung hình ở định dạng <extension file label>%<aspect top-level name>.

Ví dụ nâng cao

Ví dụ sau đây minh hoạ việc sử dụng một khía cạnh từ quy tắc mục tiêu để đếm các tệp trong mục tiêu, có thể lọc các tệp đó theo đuôi tệp. Bài viết này cho biết cách sử dụng trình cung cấp để trả về các giá trị, cách sử dụng các thông số để truyền một đối số vào quá trình triển khai khía cạnh và cách gọi một khía cạnh từ một quy tắc.

Tệp file_count.bzl:

FileCountInfo = provider(
    fields = {
        'count' : 'number of files'
    }
)

def _file_count_aspect_impl(target, ctx):
    count = 0
    # Make sure the rule has a srcs attribute.
    if hasattr(ctx.rule.attr, 'srcs'):
        # Iterate through the sources counting files
        for src in ctx.rule.attr.srcs:
            for f in src.files.to_list():
                if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
                    count = count + 1
    # Get the counts from our dependencies.
    for dep in ctx.rule.attr.deps:
        count = count + dep[FileCountInfo].count
    return [FileCountInfo(count = count)]

file_count_aspect = aspect(
    implementation = _file_count_aspect_impl,
    attr_aspects = ['deps'],
    attrs = {
        'extension' : attr.string(values = ['*', 'h', 'cc']),
    }
)

def _file_count_rule_impl(ctx):
    for dep in ctx.attr.deps:
        print(dep[FileCountInfo].count)

file_count_rule = rule(
    implementation = _file_count_rule_impl,
    attrs = {
        'deps' : attr.label_list(aspects = [file_count_aspect]),
        'extension' : attr.string(default = '*'),
    },
)

Tệp BUILD.bazel:

load('//:file_count.bzl', 'file_count_rule')

cc_library(
    name = 'lib',
    srcs = [
        'lib.h',
        'lib.cc',
    ],
)

cc_binary(
    name = 'app',
    srcs = [
        'app.h',
        'app.cc',
        'main.cc',
    ],
    deps = ['lib'],
)

file_count_rule(
    name = 'file_count',
    deps = ['app'],
    extension = 'h',
)

Định nghĩa về tỷ lệ khung hình

file_count_aspect = aspect(
    implementation = _file_count_aspect_impl,
    attr_aspects = ['deps'],
    attrs = {
        'extension' : attr.string(values = ['*', 'h', 'cc']),
    }
)

Ví dụ này cho thấy cách phương diện truyền tải thông qua thuộc tính deps.

attrs xác định một tập hợp các thuộc tính của một khung hình. Thuộc tính khung hình công khai định nghĩa tham số và chỉ có thể thuộc kiểu bool, int hoặc string. Đối với các khía cạnh được truyền theo quy tắc, tham số int và string phải có values được chỉ định trên đó. Ví dụ này có một tham số có tên là extension được phép có giá trị là "*", "h" hoặc "cc".

Đối với các khía cạnh được truyền theo quy tắc, giá trị tham số được lấy từ quy tắc yêu cầu khía cạnh, sử dụng thuộc tính của quy tắc có cùng tên và loại. (xem định nghĩa của file_count_rule).

Đối với các khía cạnh dòng lệnh, bạn có thể truyền giá trị tham số bằng cờ --aspects_parameters. Quy định hạn chế values đối với tham số int và string có thể là đã bỏ qua.

Các khía cạnh cũng được phép có các thuộc tính riêng tư thuộc loại label hoặc label_list. Bạn có thể sử dụng các thuộc tính nhãn riêng tư để chỉ định các phần phụ thuộc trên các công cụ hoặc thư viện cần thiết cho các hành động do các khía cạnh tạo ra. Không có thuộc tính riêng tư nào được xác định trong ví dụ này, nhưng đoạn mã sau đây minh hoạ cách bạn có thể truyền một công cụ vào một khía cạnh:

...
    attrs = {
        '_protoc' : attr.label(
            default = Label('//tools:protoc'),
            executable = True,
            cfg = "exec"
        )
    }
...

Triển khai tỷ lệ khung hình

FileCountInfo = provider(
    fields = {
        'count' : 'number of files'
    }
)

def _file_count_aspect_impl(target, ctx):
    count = 0
    # Make sure the rule has a srcs attribute.
    if hasattr(ctx.rule.attr, 'srcs'):
        # Iterate through the sources counting files
        for src in ctx.rule.attr.srcs:
            for f in src.files.to_list():
                if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
                    count = count + 1
    # Get the counts from our dependencies.
    for dep in ctx.rule.attr.deps:
        count = count + dep[FileCountInfo].count
    return [FileCountInfo(count = count)]

Giống như hàm triển khai quy tắc, hàm triển khai khía cạnh sẽ trả về một cấu trúc gồm các trình cung cấp có thể truy cập được đối với các phần phụ thuộc của nó.

Trong ví dụ này, FileCountInfo được định nghĩa là một trình cung cấp có một trường count. Tốt nhất là bạn nên xác định rõ ràng các trường của nhà cung cấp bằng cách sử dụng thuộc tính fields.

Tập hợp các nhà cung cấp cho một ứng dụng khía cạnh A(X) là tập hợp hợp nhất các nhà cung cấp đến từ việc triển khai một quy tắc cho mục tiêu X và từ việc triển khai khía cạnh A. Các trình cung cấp mà quá trình triển khai quy tắc sẽ áp dụng được tạo và cố định trước khi các thành phần được áp dụng và không thể sửa đổi được trên khía cạnh. Sẽ xảy ra lỗi nếu một mục tiêu và một khía cạnh được áp dụng cho mục tiêu đó cung cấp cho nhà cung cấp cùng một loại, ngoại trừ OutputGroupInfo (được hợp nhất, miễn là quy tắc và khía cạnh chỉ định các nhóm đầu ra khác nhau) và InstrumentedFilesInfo (được lấy từ khía cạnh). Điều này có nghĩa là việc triển khai khung hình có thể không bao giờ trả lại DefaultInfo.

Các tham số và thuộc tính riêng tư được chuyển vào các thuộc tính của ctx. Ví dụ này tham chiếu đến tham số extension và xác định những tệp cần tính.

Đối với nhà cung cấp cũ, giá trị của các thuộc tính mà theo đó khía cạnh được truyền tải (từ danh sách attr_aspects) được thay thế bằng kết quả của việc áp dụng khía cạnh đó vào chúng. Ví dụ: nếu mục tiêu X có Y và Z trong phần phụ thuộc, thì ctx.rule.attr.deps cho A(X) sẽ là [A(Y), A(Z)]. Trong ví dụ này, ctx.rule.attr.deps là các đối tượng Mục tiêu là kết quả của việc áp dụng khung hình cho các "deps" của mục tiêu ban đầu mà đã được áp dụng khung hình.

Trong ví dụ này, phương diện truy cập vào trình cung cấp FileCountInfo từ các phần phụ thuộc của mục tiêu để tích luỹ tổng số tệp bắc cầu.

Gọi phương diện từ một quy tắc

def _file_count_rule_impl(ctx):
    for dep in ctx.attr.deps:
        print(dep[FileCountInfo].count)

file_count_rule = rule(
    implementation = _file_count_rule_impl,
    attrs = {
        'deps' : attr.label_list(aspects = [file_count_aspect]),
        'extension' : attr.string(default = '*'),
    },
)

Quá trình triển khai quy tắc minh hoạ cách truy cập vào FileCountInfo thông qua ctx.attr.deps.

Định nghĩa quy tắc minh hoạ cách xác định một thông số (extension) và cung cấp giá trị mặc định (*). Lưu ý rằng việc có giá trị mặc định không phải là một trong các giá trị 'cc', 'h' hoặc '*' sẽ là lỗi do các hạn chế được đặt đối với tham số trong định nghĩa khung hình.

Gọi một khía cạnh thông qua quy tắc mục tiêu

load('//:file_count.bzl', 'file_count_rule')

cc_binary(
    name = 'app',
...
)

file_count_rule(
    name = 'file_count',
    deps = ['app'],
    extension = 'h',
)

Điều này minh hoạ cách truyền tham số extension vào phương diện thông qua quy tắc. Vì tham số extension có giá trị mặc định trong mã triển khai quy tắc, extension sẽ được coi là tham số không bắt buộc.

Khi mục tiêu file_count được tạo, khía cạnh của chúng ta sẽ được đánh giá để và tất cả các mục tiêu có thể truy cập theo cách đệ quy thông qua deps.

Tài liệu tham khảo

Tài liệu tham khảo API aspect