Chuỗi công cụ

Báo cáo vấn đề Xem nguồn Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

Trang này mô tả khung chuỗi công cụ, đây là cách để tác giả quy tắc tách rời logic quy tắc của họ khỏi việc lựa chọn công cụ dựa trên nền tảng. Bạn nên đọc trang quy tắc và nền tảng trước khi tiếp tục. Trang này trình bày lý do cần có chuỗi công cụ, cách xác định và sử dụng chuỗi công cụ, cũng như cách Bazel chọn một chuỗi công cụ phù hợp dựa trên các ràng buộc về nền tảng.

Động lực

Trước tiên, hãy xem xét vấn đề mà chuỗi công cụ được thiết kế để giải quyết. Giả sử bạn đang viết các quy tắc để hỗ trợ ngôn ngữ lập trình "bar". Quy tắc bar_binary của bạn sẽ biên dịch các tệp *.bar bằng trình biên dịch barc, bản thân công cụ này được tạo dưới dạng một mục tiêu khác trong không gian làm việc của bạn. Vì người dùng viết các mục tiêu bar_binary không cần phải chỉ định một phần phụ thuộc trên trình biên dịch, nên bạn sẽ biến phần phụ thuộc đó thành một phần phụ thuộc ngầm bằng cách thêm phần phụ thuộc đó vào định nghĩa quy tắc dưới dạng một thuộc tính riêng tư.

bar_binary = rule(
    implementation = _bar_binary_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = True),
        ...
        "_compiler": attr.label(
            default = "//bar_tools:barc_linux",  # the compiler running on linux
            providers = [BarcInfo],
        ),
    },
)

//bar_tools:barc_linux hiện là một phần phụ thuộc của mọi mục tiêu bar_binary, vì vậy, phần này sẽ được tạo trước mọi mục tiêu bar_binary. Hàm triển khai của quy tắc có thể truy cập vào thuộc tính này giống như mọi thuộc tính khác:

BarcInfo = provider(
    doc = "Information about how to invoke the barc compiler.",
    # In the real world, compiler_path and system_lib might hold File objects,
    # but for simplicity they are strings for this example. arch_flags is a list
    # of strings.
    fields = ["compiler_path", "system_lib", "arch_flags"],
)

def _bar_binary_impl(ctx):
    ...
    info = ctx.attr._compiler[BarcInfo]
    command = "%s -l %s %s" % (
        info.compiler_path,
        info.system_lib,
        " ".join(info.arch_flags),
    )
    ...

Vấn đề ở đây là nhãn của trình biên dịch được mã hoá cứng vào bar_binary, nhưng các mục tiêu khác nhau có thể cần các trình biên dịch khác nhau tuỳ thuộc vào nền tảng mà chúng đang được xây dựng và nền tảng mà chúng đang được xây dựng – lần lượt được gọi là nền tảng mục tiêu và nền tảng thực thi. Hơn nữa, tác giả quy tắc thậm chí không nhất thiết phải biết tất cả các công cụ và nền tảng có sẵn, vì vậy, không thể mã hoá cứng các công cụ và nền tảng đó trong định nghĩa của quy tắc.

Một giải pháp không lý tưởng là chuyển gánh nặng sang người dùng bằng cách đặt thuộc tính _compiler thành không riêng tư. Sau đó, các mục tiêu riêng lẻ có thể được mã hoá cứng để tạo cho nền tảng này hoặc nền tảng khác.

bar_binary(
    name = "myprog_on_linux",
    srcs = ["mysrc.bar"],
    compiler = "//bar_tools:barc_linux",
)

bar_binary(
    name = "myprog_on_windows",
    srcs = ["mysrc.bar"],
    compiler = "//bar_tools:barc_windows",
)

Bạn có thể cải thiện giải pháp này bằng cách sử dụng select để chọn compiler dựa trên nền tảng:

config_setting(
    name = "on_linux",
    constraint_values = [
        "@platforms//os:linux",
    ],
)

config_setting(
    name = "on_windows",
    constraint_values = [
        "@platforms//os:windows",
    ],
)

bar_binary(
    name = "myprog",
    srcs = ["mysrc.bar"],
    compiler = select({
        ":on_linux": "//bar_tools:barc_linux",
        ":on_windows": "//bar_tools:barc_windows",
    }),
)

Nhưng việc này khá tẻ nhạt và có phần quá đáng khi yêu cầu mọi người dùng bar_binary làm như vậy. Nếu bạn không sử dụng nhất quán kiểu này trong toàn bộ không gian làm việc, thì điều này sẽ dẫn đến các bản dựng hoạt động bình thường trên một nền tảng duy nhất nhưng không thành công khi mở rộng sang các trường hợp đa nền tảng. Nó cũng không giải quyết vấn đề thêm hỗ trợ cho các nền tảng và trình biên dịch mới mà không sửa đổi các quy tắc hoặc mục tiêu hiện có.

Khung chuỗi công cụ giải quyết vấn đề này bằng cách thêm một cấp độ gián tiếp bổ sung. Về cơ bản, bạn khai báo rằng quy tắc của bạn có một phần phụ thuộc trừu tượng vào một số thành phần của một họ mục tiêu (một loại chuỗi công cụ) và Bazel sẽ tự động phân giải phần phụ thuộc này thành một mục tiêu cụ thể (một chuỗi công cụ) dựa trên các ràng buộc nền tảng có thể áp dụng. Cả tác giả quy tắc và tác giả mục tiêu đều không cần biết toàn bộ các nền tảng và chuỗi công cụ có sẵn.

Viết các quy tắc sử dụng chuỗi công cụ

Trong khuôn khổ chuỗi công cụ, thay vì có các quy tắc phụ thuộc trực tiếp vào các công cụ, chúng sẽ phụ thuộc vào các loại chuỗi công cụ. Loại chuỗi công cụ là một mục tiêu đơn giản, đại diện cho một lớp công cụ đóng vai trò tương tự đối với nhiều nền tảng. Ví dụ: bạn có thể khai báo một loại đại diện cho trình biên dịch thanh:

# By convention, toolchain_type targets are named "toolchain_type" and
# distinguished by their package path. So the full path for this would be
# //bar_tools:toolchain_type.
toolchain_type(name = "toolchain_type")

Định nghĩa quy tắc ở phần trước được sửa đổi để thay vì lấy trình biên dịch làm thuộc tính, quy tắc này khai báo rằng quy tắc đó sử dụng một chuỗi công cụ //bar_tools:toolchain_type.

bar_binary = rule(
    implementation = _bar_binary_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = True),
        ...
        # No `_compiler` attribute anymore.
    },
    toolchains = ["//bar_tools:toolchain_type"],
)

Giờ đây, hàm triển khai sẽ truy cập vào phần phụ thuộc này trong ctx.toolchains thay vì ctx.attr, bằng cách sử dụng loại chuỗi công cụ làm khoá.

def _bar_binary_impl(ctx):
    ...
    info = ctx.toolchains["//bar_tools:toolchain_type"].barcinfo
    # The rest is unchanged.
    command = "%s -l %s %s" % (
        info.compiler_path,
        info.system_lib,
        " ".join(info.arch_flags),
    )
    ...

ctx.toolchains["//bar_tools:toolchain_type"] trả về trình cung cấp ToolchainInfo của bất kỳ mục tiêu nào mà Bazel đã phân giải phần phụ thuộc chuỗi công cụ. Các trường của đối tượng ToolchainInfo được đặt theo quy tắc của công cụ cơ bản; trong phần tiếp theo, quy tắc này được xác định sao cho có một trường barcinfo bao bọc một đối tượng BarcInfo.

Quy trình của Bazel để phân giải chuỗi công cụ thành các mục tiêu được mô tả bên dưới. Trên thực tế, chỉ mục tiêu chuỗi công cụ đã phân giải mới trở thành một phần phụ thuộc của mục tiêu bar_binary, chứ không phải toàn bộ không gian của các chuỗi công cụ đề xuất.

Chuỗi công cụ bắt buộc và không bắt buộc

Theo mặc định, khi một quy tắc biểu thị phần phụ thuộc loại chuỗi công cụ bằng nhãn trần (như minh hoạ ở trên), loại chuỗi công cụ sẽ được coi là bắt buộc. Nếu Bazel không tìm thấy chuỗi công cụ phù hợp (xem phần Phân giải chuỗi công cụ bên dưới) cho một loại chuỗi công cụ bắt buộc, thì đây là một lỗi và quá trình phân tích sẽ dừng lại.

Thay vào đó, bạn có thể khai báo một phần phụ thuộc loại chuỗi công cụ không bắt buộc, như sau:

bar_binary = rule(
    ...
    toolchains = [
        config_common.toolchain_type("//bar_tools:toolchain_type", mandatory = False),
    ],
)

Khi không thể phân giải một loại chuỗi công cụ không bắt buộc, quá trình phân tích sẽ tiếp tục và kết quả của ctx.toolchains["//bar_tools:toolchain_type"] là None.

Hàm config_common.toolchain_type mặc định là bắt buộc.

Bạn có thể sử dụng các biểu mẫu sau:

  • Các loại chuỗi công cụ bắt buộc:
    • toolchains = ["//bar_tools:toolchain_type"]
    • toolchains = [config_common.toolchain_type("//bar_tools:toolchain_type")]
    • toolchains = [config_common.toolchain_type("//bar_tools:toolchain_type", mandatory = True)]
  • Các loại chuỗi công cụ không bắt buộc:
    • toolchains = [config_common.toolchain_type("//bar_tools:toolchain_type", mandatory = False)]
bar_binary = rule(
    ...
    toolchains = [
        "//foo_tools:toolchain_type",
        config_common.toolchain_type("//bar_tools:toolchain_type", mandatory = False),
    ],
)

Bạn cũng có thể kết hợp các biểu mẫu trong cùng một quy tắc. Tuy nhiên, nếu cùng một loại chuỗi công cụ được liệt kê nhiều lần, thì hệ thống sẽ lấy phiên bản nghiêm ngặt nhất, trong đó bắt buộc sẽ nghiêm ngặt hơn không bắt buộc.

Các khía cạnh viết sử dụng chuỗi công cụ

Các khía cạnh có quyền truy cập vào cùng một API chuỗi công cụ như các quy tắc: bạn có thể xác định các loại chuỗi công cụ bắt buộc, truy cập vào chuỗi công cụ thông qua ngữ cảnh và sử dụng chúng để tạo các thao tác mới bằng chuỗi công cụ.

bar_aspect = aspect(
    implementation = _bar_aspect_impl,
    attrs = {},
    toolchains = ['//bar_tools:toolchain_type'],
)

def _bar_aspect_impl(target, ctx):
  toolchain = ctx.toolchains['//bar_tools:toolchain_type']
  # Use the toolchain provider like in a rule.
  return []

Xác định chuỗi công cụ

Để xác định một số chuỗi công cụ cho một loại chuỗi công cụ nhất định, bạn cần có 3 thứ:

  1. Một quy tắc theo ngôn ngữ cụ thể, thể hiện loại công cụ hoặc bộ công cụ. Theo quy ước, tên của quy tắc này có hậu tố "_toolchain".

    1. Lưu ý: Quy tắc \_toolchain không thể tạo bất kỳ thao tác nào trong bản dựng. Thay vào đó, nó thu thập các cấu phần phần mềm từ các quy tắc khác và chuyển tiếp chúng đến quy tắc sử dụng chuỗi công cụ. Quy tắc đó chịu trách nhiệm tạo tất cả các thao tác xây dựng.

  2. Một số mục tiêu của loại quy tắc này, đại diện cho các phiên bản của công cụ hoặc bộ công cụ cho các nền tảng khác nhau.

  3. Đối với mỗi mục tiêu như vậy, một mục tiêu liên kết của quy tắc toolchain chung, để cung cấp siêu dữ liệu mà khung chuỗi công cụ sử dụng. Mục tiêu toolchain này cũng đề cập đến toolchain_type được liên kết với chuỗi công cụ này. Điều này có nghĩa là một quy tắc _toolchain nhất định có thể được liên kết với bất kỳ toolchain_type nào và chỉ trong một phiên bản toolchain sử dụng quy tắc _toolchain này thì quy tắc đó mới được liên kết với một toolchain_type.

Đối với ví dụ đang chạy của chúng ta, sau đây là định nghĩa cho quy tắc bar_toolchain. Ví dụ của chúng ta chỉ có một trình biên dịch, nhưng các công cụ khác như trình liên kết cũng có thể được nhóm bên dưới trình biên dịch.

def _bar_toolchain_impl(ctx):
    toolchain_info = platform_common.ToolchainInfo(
        barcinfo = BarcInfo(
            compiler_path = ctx.attr.compiler_path,
            system_lib = ctx.attr.system_lib,
            arch_flags = ctx.attr.arch_flags,
        ),
    )
    return [toolchain_info]

bar_toolchain = rule(
    implementation = _bar_toolchain_impl,
    attrs = {
        "compiler_path": attr.string(),
        "system_lib": attr.string(),
        "arch_flags": attr.string_list(),
    },
)

Quy tắc này phải trả về một trình cung cấp ToolchainInfo. Trình cung cấp này sẽ trở thành đối tượng mà quy tắc sử dụng truy xuất bằng ctx.toolchains và nhãn của loại chuỗi công cụ. ToolchainInfo, chẳng hạn như struct, có thể chứa các cặp giá trị trường tuỳ ý. Thông số về chính xác những trường nào được thêm vào ToolchainInfo phải được ghi lại rõ ràng ở loại chuỗi công cụ. Trong ví dụ này, các giá trị trả về được bao bọc trong một đối tượng BarcInfo để sử dụng lại giản đồ đã xác định ở trên; kiểu này có thể hữu ích cho việc xác thực và sử dụng lại mã.

Giờ đây, bạn có thể xác định các mục tiêu cho những trình biên dịch barc cụ thể.

bar_toolchain(
    name = "barc_linux",
    arch_flags = [
        "--arch=Linux",
        "--debug_everything",
    ],
    compiler_path = "/path/to/barc/on/linux",
    system_lib = "/usr/lib/libbarc.so",
)

bar_toolchain(
    name = "barc_windows",
    arch_flags = [
        "--arch=Windows",
        # Different flags, no debug support on windows.
    ],
    compiler_path = "C:\\path\\on\\windows\\barc.exe",
    system_lib = "C:\\path\\on\\windows\\barclib.dll",
)

Cuối cùng, bạn tạo toolchain định nghĩa cho 2 bar_toolchain mục tiêu. Các định nghĩa này liên kết các mục tiêu theo ngôn ngữ cụ thể với loại chuỗi công cụ và cung cấp thông tin về các ràng buộc cho Bazel biết khi nào chuỗi công cụ phù hợp với một nền tảng nhất định.

toolchain(
    name = "barc_linux_toolchain",
    exec_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    target_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":barc_linux",
    toolchain_type = ":toolchain_type",
)

toolchain(
    name = "barc_windows_toolchain",
    exec_compatible_with = [
        "@platforms//os:windows",
        "@platforms//cpu:x86_64",
    ],
    target_compatible_with = [
        "@platforms//os:windows",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":barc_windows",
    toolchain_type = ":toolchain_type",
)

Việc sử dụng cú pháp đường dẫn tương đối ở trên cho thấy tất cả các định nghĩa này đều nằm trong cùng một gói, nhưng không có lý do gì khiến loại chuỗi công cụ, các mục tiêu chuỗi công cụ dành riêng cho ngôn ngữ và các mục tiêu định nghĩa toolchain không thể nằm trong các gói riêng biệt.

Hãy xem go_toolchain để biết ví dụ thực tế.

Chuỗi công cụ và cấu hình

Một câu hỏi quan trọng đối với tác giả quy tắc là khi một mục tiêu bar_toolchain được phân tích, mục tiêu đó sẽ thấy cấu hình nào và những quá trình chuyển đổi nào nên được dùng cho các phần phụ thuộc? Ví dụ trên sử dụng các thuộc tính chuỗi, nhưng điều gì sẽ xảy ra đối với một chuỗi công cụ phức tạp hơn phụ thuộc vào các mục tiêu khác trong kho lưu trữ Bazel?

Hãy xem một phiên bản phức tạp hơn của bar_toolchain:

def _bar_toolchain_impl(ctx):
    # The implementation is mostly the same as above, so skipping.
    pass

bar_toolchain = rule(
    implementation = _bar_toolchain_impl,
    attrs = {
        "compiler": attr.label(
            executable = True,
            mandatory = True,
            cfg = "exec",
        ),
        "system_lib": attr.label(
            mandatory = True,
            cfg = "target",
        ),
        "arch_flags": attr.string_list(),
    },
)

Việc sử dụng attr.label cũng giống như đối với một quy tắc tiêu chuẩn, nhưng ý nghĩa của tham số cfg có chút khác biệt.

Phần phụ thuộc từ một mục tiêu (gọi là "mục tiêu mẹ") đến một chuỗi công cụ thông qua quá trình phân giải chuỗi công cụ sẽ sử dụng một quá trình chuyển đổi cấu hình đặc biệt, gọi là "quá trình chuyển đổi chuỗi công cụ". Quá trình chuyển đổi chuỗi công cụ vẫn giữ nguyên cấu hình, ngoại trừ việc quá trình này buộc nền tảng thực thi phải giống nhau cho chuỗi công cụ như đối với thành phần mẹ (nếu không, quá trình phân giải chuỗi công cụ cho chuỗi công cụ có thể chọn bất kỳ nền tảng thực thi nào và không nhất thiết phải giống như đối với thành phần mẹ). Điều này cho phép mọi phần phụ thuộc exec của chuỗi công cụ cũng có thể thực thi cho các thao tác tạo của thành phần mẹ. Mọi phần phụ thuộc của chuỗi công cụ sử dụng cfg = "target" (hoặc không chỉ định cfg, vì "target" là giá trị mặc định) đều được tạo cho cùng một nền tảng mục tiêu như nền tảng mẹ. Điều này cho phép các quy tắc chuỗi công cụ đóng góp cả thư viện (thuộc tính system_lib ở trên) và công cụ (thuộc tính compiler) cho các quy tắc xây dựng cần chúng. Các thư viện hệ thống được liên kết vào cấu phần phần mềm cuối cùng, vì vậy cần được tạo cho cùng một nền tảng, trong khi trình biên dịch là một công cụ được gọi trong quá trình tạo và cần có khả năng chạy trên nền tảng thực thi.

Đăng ký và tạo bằng chuỗi công cụ

Đến đây, tất cả các khối xây dựng đã được lắp ráp và bạn chỉ cần cung cấp các chuỗi công cụ cho quy trình phân giải của Bazel. Việc này được thực hiện bằng cách đăng ký chuỗi công cụ, trong tệp MODULE.bazel bằng cách sử dụng register_toolchains() hoặc bằng cách truyền nhãn của chuỗi công cụ trên dòng lệnh bằng cách sử dụng cờ --extra_toolchains.

register_toolchains(
    "//bar_tools:barc_linux_toolchain",
    "//bar_tools:barc_windows_toolchain",
    # Target patterns are also permitted, so you could have also written:
    # "//bar_tools:all",
    # or even
    # "//bar_tools/...",
)

Khi sử dụng các mẫu mục tiêu để đăng ký chuỗi công cụ, thứ tự đăng ký từng chuỗi công cụ sẽ được xác định theo các quy tắc sau:

  • Các chuỗi công cụ được xác định trong một gói con của một gói sẽ được đăng ký trước các chuỗi công cụ được xác định trong chính gói đó.
  • Trong một gói, chuỗi công cụ được đăng ký theo thứ tự từ vựng của tên.

Giờ đây, khi bạn tạo một mục tiêu phụ thuộc vào một loại chuỗi công cụ, một chuỗi công cụ thích hợp sẽ được chọn dựa trên mục tiêu và nền tảng thực thi.

# my_pkg/BUILD

platform(
    name = "my_target_platform",
    constraint_values = [
        "@platforms//os:linux",
    ],
)

bar_binary(
    name = "my_bar_binary",
    ...
)

bazel build //my_pkg:my_bar_binary --platforms=//my_pkg:my_target_platform

Bazel sẽ thấy rằng //my_pkg:my_bar_binary đang được tạo bằng một nền tảng có @platforms//os:linux và do đó, giải quyết tham chiếu //bar_tools:toolchain_type đến //bar_tools:barc_linux_toolchain. Thao tác này sẽ tạo ra //bar_tools:barc_linux nhưng không tạo ra //bar_tools:barc_windows.

Độ phân giải chuỗi công cụ

Đối với mỗi mục tiêu sử dụng chuỗi công cụ, quy trình phân giải chuỗi công cụ của Bazel sẽ xác định các phần phụ thuộc cụ thể của chuỗi công cụ của mục tiêu. Quy trình này lấy đầu vào là một tập hợp các loại chuỗi công cụ bắt buộc, nền tảng mục tiêu, danh sách các nền tảng thực thi có sẵn và danh sách các chuỗi công cụ có sẵn. Đầu ra của nó là một chuỗi công cụ đã chọn cho mỗi loại chuỗi công cụ cũng như một nền tảng thực thi đã chọn cho mục tiêu hiện tại.

Các nền tảng thực thi và chuỗi công cụ có sẵn được thu thập từ biểu đồ phần phụ thuộc bên ngoài thông qua các lệnh gọi register_execution_platforms và register_toolchains trong MODULE.bazelfiles. Additional execution platforms and toolchains may also be specified on the command line via [--extra_execution_platforms](/versions/7.6.0/reference/command-line-reference#flag--extra_execution_platforms) and [--extra_toolchains`](/versions/7.6.0/reference/command-line-reference#flag--extra_toolchains). Nền tảng lưu trữ sẽ tự động được thêm vào làm nền tảng thực thi có sẵn. Các nền tảng và chuỗi công cụ có sẵn được theo dõi dưới dạng danh sách có thứ tự để xác định, ưu tiên các mục trước đó trong danh sách.

Tập hợp các chuỗi công cụ có sẵn (theo thứ tự ưu tiên) được tạo từ --extra_toolchains và register_toolchains:

  1. Các chuỗi công cụ được đăng ký bằng --extra_toolchains sẽ được thêm trước. (Trong số này, chuỗi công cụ cuối cùng có mức độ ưu tiên cao nhất.)
  2. Các chuỗi công cụ được đăng ký bằng register_toolchains trong biểu đồ phần phụ thuộc bên ngoài bắc cầu, theo thứ tự sau: (Trong số này, chuỗi công cụ đầu tiên được đề cập có mức độ ưu tiên cao nhất.)
    1. Toolchain do mô-đun gốc đăng ký (tức là MODULE.bazel tại gốc không gian làm việc);
    2. Các chuỗi công cụ được đăng ký trong tệp WORKSPACE của người dùng, kể cả trong mọi macro được gọi từ đó;
    3. Toolchain do các mô-đun không phải là mô-đun gốc đăng ký (chẳng hạn như các phần phụ thuộc do mô-đun gốc chỉ định và các phần phụ thuộc của chúng, v.v.);
    4. Chuỗi công cụ được đăng ký trong "hậu tố WORKSPACE"; chỉ một số quy tắc gốc nhất định đi kèm với bản cài đặt Bazel mới sử dụng hậu tố này.

LƯU Ý: Các mục tiêu giả như :all, :* và /... được sắp xếp theo cơ chế tải gói của Bazel, cơ chế này sử dụng thứ tự từ điển.

Sau đây là các bước giải quyết.

  1. Mệnh đề target_compatible_with hoặc exec_compatible_with khớp với một nền tảng nếu, đối với mỗi constraint_value trong danh sách, nền tảng đó cũng có constraint_value (một cách rõ ràng hoặc theo mặc định).

    Nếu nền tảng có constraint_value từ constraint_setting không được mệnh đề tham chiếu, thì những constraint_value này sẽ không ảnh hưởng đến việc so khớp.

  2. Nếu đích đến đang được tạo chỉ định thuộc tính exec_compatible_with (hoặc định nghĩa quy tắc của thuộc tính đó chỉ định đối số exec_compatible_with), thì danh sách các nền tảng thực thi có sẵn sẽ được lọc để loại bỏ mọi nền tảng không khớp với các ràng buộc thực thi.

  3. Đối với mỗi nền tảng thực thi có sẵn, bạn sẽ liên kết từng loại chuỗi công cụ với chuỗi công cụ có sẵn đầu tiên (nếu có) tương thích với nền tảng thực thi này và nền tảng mục tiêu.

  4. Mọi nền tảng thực thi không tìm thấy chuỗi công cụ bắt buộc tương thích cho một trong các loại chuỗi công cụ đều bị loại trừ. Trong số các nền tảng còn lại, nền tảng đầu tiên sẽ trở thành nền tảng thực thi của mục tiêu hiện tại và các chuỗi công cụ được liên kết (nếu có) sẽ trở thành các phần phụ thuộc của mục tiêu.

Nền tảng thực thi đã chọn được dùng để chạy tất cả các thao tác mà đích tạo ra.

Trong trường hợp cùng một mục tiêu có thể được tạo trong nhiều cấu hình (chẳng hạn như cho các CPU khác nhau) trong cùng một bản dựng, quy trình phân giải sẽ được áp dụng độc lập cho từng phiên bản của mục tiêu.

Nếu quy tắc sử dụng nhóm thực thi, mỗi nhóm thực thi sẽ thực hiện riêng quá trình phân giải chuỗi công cụ và mỗi nhóm có nền tảng thực thi và chuỗi công cụ riêng.

Gỡ lỗi chuỗi công cụ

Nếu bạn đang thêm chế độ hỗ trợ chuỗi công cụ vào một quy tắc hiện có, hãy sử dụng cờ --toolchain_resolution_debug=regex. Trong quá trình phân giải chuỗi công cụ, cờ này sẽ cung cấp đầu ra chi tiết cho các loại chuỗi công cụ hoặc tên mục tiêu khớp với biến biểu thức chính quy. Bạn có thể dùng .* để xuất tất cả thông tin. Bazel sẽ xuất tên của các chuỗi công cụ mà nó kiểm tra và bỏ qua trong quá trình phân giải.

Nếu bạn muốn xem những phần phụ thuộc cquery nào đến từ quá trình phân giải chuỗi công cụ, hãy sử dụng cờ --transitions của cquery:

# Find all direct dependencies of //cc:my_cc_lib. This includes explicitly
# declared dependencies, implicit dependencies, and toolchain dependencies.
$ bazel cquery 'deps(//cc:my_cc_lib, 1)'
//cc:my_cc_lib (96d6638)
@bazel_tools//tools/cpp:toolchain (96d6638)
@bazel_tools//tools/def_parser:def_parser (HOST)
//cc:my_cc_dep (96d6638)
@local_config_platform//:host (96d6638)
@bazel_tools//tools/cpp:toolchain_type (96d6638)
//:default_host_platform (96d6638)
@local_config_cc//:cc-compiler-k8 (HOST)
//cc:my_cc_lib.cc (null)
@bazel_tools//tools/cpp:grep-includes (HOST)

# Which of these are from toolchain resolution?
$ bazel cquery 'deps(//cc:my_cc_lib, 1)' --transitions=lite | grep "toolchain dependency"
  [toolchain dependency]#@local_config_cc//:cc-compiler-k8#HostTransition -> b6df211