Maven から Bazel への移行

問題を報告するソースを表示 Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

このページでは、前提条件やインストール手順など、Maven から Bazel に移行する方法について説明します。Maven と Bazel の違いについて説明し、Guava プロジェクトを使用した移行の例を示します。

ビルドツールから Bazel に移行する場合は、開発チーム、CI システム、その他の関連システムを完全に移行するまで、両方のビルドツールを並行して実行することをおすすめします。Maven と Bazel は同じリポジトリで実行できます。

始める前に

Bazel がまだインストールされていない場合は、インストールします。
Bazel を初めて使用する場合は、移行を開始する前に、Bazel の概要: Java のビルドのチュートリアルをご覧ください。このチュートリアルでは、Bazel のコンセプト、構造、ラベル構文について説明します。

Maven と Bazel の違い

Maven は最上位の pom.xml ファイルを使用します。Bazel は、複数のビルドファイルと BUILD ファイルごとの複数のターゲットをサポートしているため、Maven よりも増分ビルドが可能です。
Maven は、デプロイプロセスの手順を担当します。Bazel はデプロイを自動化しません。
Bazel を使用すると、言語間の依存関係を表現できます。
プロジェクトに新しいセクションを追加する際に、Bazel では新しい BUILD ファイルを追加する必要がある場合があります。ベストプラクティスは、新しい Java パッケージごとに BUILD ファイルを追加することです。

Maven から Bazel に移行する

以下に、プロジェクトを Bazel に移行する手順を示します。

WORKSPACE ファイルを作成する
1 つの BUILD ファイルを作成する
BUILD ファイルをさらに作成する
Bazel を使用してビルドする

以下の例は、Maven から Bazel への Guava プロジェクトの移行によるものです。使用される Guava プロジェクトはリリース v31.1 です。Guava を使用する例では、移行の各手順は説明していませんが、移行用に生成または手動で追加されるファイルとその内容を示しています。

$ git clone https://github.com/google/guava.git && cd guava
$ git checkout v31.1

1. WORKSPACE ファイルを作成する

プロジェクトのルートに WORKSPACE という名前のファイルを作成します。プロジェクトに外部依存関係がない場合、ワークスペースファイルは空にできます。

プロジェクトがプロジェクトのディレクトリにないファイルまたはパッケージに依存している場合は、ワークスペースファイルでこれらの外部依存関係を指定します。ワークスペースファイルの外部依存関係のリストを自動化するには、rules_jvm_external を使用します。このルールセットの使用手順については、README をご覧ください。

Guava プロジェクトの例: 外部依存関係

rules_jvm_external ルールセットを使用して、Guava プロジェクトの外部依存関係を一覧表示できます。

WORKSPACE ファイルに次のスニペットを追加します。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

RULES_JVM_EXTERNAL_TAG = "4.3"
RULES_JVM_EXTERNAL_SHA = "6274687f6fc5783b589f56a2f1ed60de3ce1f99bc4e8f9edef3de43bdf7c6e74"

http_archive(
    name = "rules_jvm_external",
    sha256 = RULES_JVM_EXTERNAL_SHA,
    strip_prefix = "rules_jvm_external-%s" % RULES_JVM_EXTERNAL_TAG,
    url = "https://github.com/bazelbuild/rules_jvm_external/archive/%s.zip" % RULES_JVM_EXTERNAL_TAG,
)

load("@rules_jvm_external//:defs.bzl", "maven_install")

maven_install(
    artifacts = [
        "com.google.code.findbugs:jsr305:3.0.2",
        "com.google.errorprone:error_prone_annotations:2.11.0",
        "com.google.j2objc:j2objc-annotations:1.3",
        "org.codehaus.mojo:animal-sniffer-annotations:1.20",
        "org.checkerframework:checker-qual:3.12.0",
    ],
    repositories = [
        "https://repo1.maven.org/maven2",
    ],
)

2. BUILD ファイルを 1 つ作成する

ワークスペースを定義し、外部依存関係（該当する場合）をリストアップしたら、プロジェクトのビルド方法を記述する BUILD ファイルを作成する必要があります。1 つの pom.xml ファイルを使用する Maven とは異なり、Bazel は多くの BUILD ファイルを使用してプロジェクトをビルドできます。これらのファイルは複数のビルドターゲットを指定し、Bazel が増分ビルドを生成できるようにします。

BUILD ファイルを段階的に追加します。まず、プロジェクトのルートに 1 つの BUILD ファイルを追加し、それを使用して Bazel で初期ビルドを行います。次に、より詳細なターゲットを含む BUILD ファイルを追加して、ビルドを調整します。

WORKSPACE ファイルと同じディレクトリに、BUILD という名前のテキストファイルを作成します。
この BUILD ファイルで、適切なルールを使用して、プロジェクトをビルドするターゲットを 1 つ作成します。次のヒントを参考にしてください。
- 適切なルールを使用します。
  - 単一の Maven モジュールを含むプロジェクトをビルドするには、次のように java_library ルールを使用します。
```
java_library(
    name = "everything",
    srcs = glob(["src/main/java/**/*.java"]),
    resources = glob(["src/main/resources/**"]),
    deps = ["//:all-external-targets"],
)
```
  - 複数の Maven モジュールを含むプロジェクトをビルドするには、次のように java_library ルールを使用します。
```
java_library(
    name = "everything",
    srcs = glob([
        "Module1/src/main/java/**/*.java",
        "Module2/src/main/java/**/*.java",
        ...
    ]),
    resources = glob([
        "Module1/src/main/resources/**",
        "Module2/src/main/resources/**",
        ...
    ]),
    deps = ["//:all-external-targets"],
)
```
  - バイナリをビルドするには、java_binary ルールを使用します。
```
java_binary(
    name = "everything",
    srcs = glob(["src/main/java/**/*.java"]),
    resources = glob(["src/main/resources/**"]),
    deps = ["//:all-external-targets"],
    main_class = "com.example.Main"
)
```
- 属性を指定します。
  - name: ターゲットにわかりやすい名前を付けます。上記の例では、ターゲットは「everything」と呼ばれます。
  - srcs: グロブを使用して、プロジェクト内のすべての .java ファイルを一覧表示します。
  - resources: グロブを使用して、プロジェクト内のすべてのリソースを一覧表示します。
  - deps: プロジェクトに必要な外部依存関係を特定する必要があります。たとえば、ツール generate_workspace を使用して外部依存関係のリストを生成した場合、java_library の依存関係は generated_java_libraries マクロにリストされているライブラリです。
- Guava プロジェクトの移行におけるこの最上位レベルの BUILD ファイルの例をご覧ください。
プロジェクトのルートに BUILD ファイルが作成されたので、プロジェクトをビルドして動作することを確認します。コマンドラインで、ワークスペースディレクトリから bazel build //:everything を使用して、Bazel でプロジェクトをビルドします。

これで、Bazel でプロジェクトが正常にビルドされました。プロジェクトの増分ビルドを許可するには、さらに BUILD ファイルを追加する必要があります。

Guava プロジェクトの例: 1 つの BUILD ファイルから始める

Guava プロジェクトを Bazel に移行するとき、最初は 1 つの BUILD ファイルを使用してプロジェクト全体をビルドします。ワークスペースディレクトリにあるこの初期 BUILD ファイルの内容は次のとおりです。

java_library(
    name = "everything",
    srcs = glob([
        "guava/src/**/*.java",
        "futures/failureaccess/src/**/*.java",
    ]),
    deps = [
        "@maven//:com_google_code_findbugs_jsr305",
        "@maven//:com_google_errorprone_error_prone_annotations",
        "@maven//:com_google_j2objc_j2objc_annotations",
        "@maven//:org_checkerframework_checker_qual",
        "@maven//:org_codehaus_mojo_animal_sniffer_annotations",
    ],
)

3. BUILD ファイルをさらに作成する（省略可）

最初のビルドを完了した後に確認したように、Bazel は 1 つの BUILD file で動作します。ただし、詳細なターゲットを含む BUILD ファイルを追加して、ビルドをより小さなチャンクに分割することを検討する必要があります。

複数のターゲットを含む複数の BUILD ファイルを使用すると、ビルドの粒度が上がり、次のことが可能になります。

プロジェクトの増分ビルドの増加、
ビルドの並列実行の増加、
将来のユーザーのためにビルドの保守性を向上させる。
パッケージ間のターゲットの可視性を制御し、実装の詳細を含むライブラリが公開 API に漏洩するなどの問題を回避できます。

BUILD ファイルを追加する際のヒント:

まず、各 Java パッケージに BUILD ファイルを追加します。依存関係が最も少ない Java パッケージから始め、依存関係が最も多いパッケージまで順に処理します。
BUILD ファイルを追加してターゲットを指定したら、これらの新しいターゲットを、それらに依存するターゲットの deps セクションに追加します。glob() 関数はパッケージの境界を越えないため、パッケージの数が増えるにつれて、glob() で一致するファイルは減少します。
main ディレクトリに BUILD ファイルを追加するたびに、対応する test ディレクトリに BUILD ファイルを追加してください。
パッケージ間の可視性を適切に制限するように注意してください。
BUILD ファイルの設定でエラーのトラブルシューティングを簡単に行うには、各ビルドファイルを追加するたびに、Bazel でプロジェクトがビルドされることを確認します。bazel build //... を実行して、すべてのターゲットが引き続きビルドされることを確認します。

4. Bazel を使用してビルドする

Bazel を使用してビルドを行い、BUILD ファイルを追加してビルドの設定を検証します。

必要な粒度の BUILD ファイルがある場合は、Bazel を使用してすべてのビルドを生成できます。