플랫폼 및 도구 모음 규칙

이 규칙 집합은 빌드하려는 특정 하드웨어 플랫폼을 모델링하고 이러한 플랫폼의 코드를 컴파일하는 데 필요한 특정 도구를 지정할 수 있도록 하기 위해 존재합니다. 사용자는 여기에 설명된 개념에 익숙해야 합니다.

규칙

• constraint_setting
• constraint_value
• 플랫폼
• toolchain
• toolchain_type

constraint_setting

constraint_setting(name, default_constraint_value, deprecation, distribs, features, licenses, tags, testonly, visibility)

이 규칙은 플랫폼에서 값을 지정할 수 있는 새로운 제약 조건 유형을 도입하는 데 사용됩니다. 예를 들어 플랫폼에 설치된 glibc 라이브러리의 버전이 서로 다를 수 있는 기능을 나타내기 위해 'glibc_version'이라는 constraint_setting를 정의할 수 있습니다. 자세한 내용은 플랫폼 페이지를 참고하세요.

각 constraint_setting에는 확장 가능한 연결된 constraint_value 집합이 있습니다. 일반적으로 이러한 설정은 동일한 패키지에 정의되지만, 때로는 다른 패키지에서 기존 설정에 새로운 값을 도입하기도 합니다. 예를 들어 사전 정의된 설정 @platforms//cpu:cpu는 잘 알려지지 않은 CPU 아키텍처를 타겟팅하는 플랫폼을 정의하기 위해 맞춤 값으로 확장할 수 있습니다.

인수

constraint_value

constraint_value(name, constraint_setting, deprecation, distribs, features, licenses, tags, testonly, visibility)

예

다음은 CPU 아키텍처를 나타내는 사전 정의된 constraint_value의 새로운 가능한 값을 만듭니다.

constraint_value(
    name = "mips",
    constraint_setting = "@platforms//cpu:cpu",
)

인수

platform

platform(name, constraint_values, deprecation, distribs, exec_properties, features, licenses, parents, remote_execution_properties, tags, testonly, visibility)

이 규칙은 빌드의 일부가 실행될 수 있는 환경을 설명하는 제약 조건 선택사항(예: CPU 아키텍처 또는 컴파일러 버전)의 명명된 컬렉션인 새 플랫폼을 정의합니다. 자세한 내용은 플랫폼 페이지를 참고하세요.

예

이는 ARM에서 Linux를 실행하는 환경을 설명하는 플랫폼을 정의합니다.

platform(
    name = "linux_arm",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:arm",
    ],
)

플랫폼 상속

플랫폼은 parents 속성을 사용하여 제약 조건 값을 상속할 다른 플랫폼을 지정할 수 있습니다. parents 속성은 목록을 사용하지만 현재는 단일 값만 지원되며 여러 상위 요소를 지정하면 오류가 발생합니다.

플랫폼에서 제약 조건 설정 값을 확인할 때는 먼저 직접 설정된 값(constraint_values 속성을 통해)을 확인하고, 그런 다음 상위 항목의 제약 조건 값을 확인합니다. 이 과정은 상위 플랫폼 체인에서 재귀적으로 계속됩니다. 이러한 방식으로 플랫폼에 직접 설정된 값은 상위에 설정된 값을 재정의합니다.

플랫폼은 상위 플랫폼에서 exec_properties 속성을 상속합니다. 상위 및 하위 플랫폼의 exec_properties에 있는 사전 항목이 결합됩니다. 상위 요소와 하위 요소의 exec_properties에 동일한 키가 표시되면 하위 요소의 값이 사용됩니다. 하위 플랫폼에서 빈 문자열을 값으로 지정하면 해당 속성이 설정 해제됩니다.

플랫폼은 상위 플랫폼에서 (지원 중단된) remote_execution_properties 속성을 상속할 수도 있습니다. 참고: 새 코드에서는 exec_properties를 대신 사용해야 합니다. 아래에 설명된 로직은 기존 동작과 호환되도록 유지되지만 향후 삭제될 예정입니다. 상위 플랫폼이 있는 경우 remote_execution_platform 설정 로직은 다음과 같습니다.

1. 자식 플랫폼에 remote_execution_property이 설정되지 않은 경우 부모의 remote_execution_properties가 사용됩니다.
2. remote_execution_property이 하위 플랫폼에 설정되어 있고 리터럴 문자열 {PARENT_REMOTE_EXECUTION_PROPERTIES}가 포함되어 있으면 해당 매크로는 상위 remote_execution_property 속성의 콘텐츠로 대체됩니다.
3. remote_execution_property이 하위 플랫폼에 설정되어 있고 매크로를 포함하지 않는 경우 하위의 remote_execution_property이 변경되지 않고 사용됩니다.

remote_execution_properties는 지원 중단되고 단계적으로 폐지되므로 동일한 상속 체인에서 remote_execution_properties와 exec_properties를 혼합할 수 없습니다. 지원 중단된 remote_execution_properties보다 exec_properties을 사용하는 것이 좋습니다.

예: 제약 조건 값

platform(
    name = "parent",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:arm",
    ],
)
platform(
    name = "child_a",
    parents = [":parent"],
    constraint_values = [
        "@platforms//cpu:x86_64",
    ],
)
platform(
    name = "child_b",
    parents = [":parent"],
)

이 예에서 하위 플랫폼에는 다음과 같은 속성이 있습니다.

• child_a에는 제약 조건 값 @platforms//os:linux (상위 항목에서 상속됨)과 @platforms//cpu:x86_64 (플랫폼에서 직접 설정됨)이 있습니다.
• child_b는 상위 항목에서 모든 제약 조건 값을 상속하며 자체 값을 설정하지 않습니다.

예: 실행 속성

platform(
    name = "parent",
    exec_properties = {
      "k1": "v1",
      "k2": "v2",
    },
)
platform(
    name = "child_a",
    parents = [":parent"],
)
platform(
    name = "child_b",
    parents = [":parent"],
    exec_properties = {
      "k1": "child"
    }
)
platform(
    name = "child_c",
    parents = [":parent"],
    exec_properties = {
      "k1": ""
    }
)
platform(
    name = "child_d",
    parents = [":parent"],
    exec_properties = {
      "k3": "v3"
    }
)

이 예에서 하위 플랫폼에는 다음과 같은 속성이 있습니다.

• child_a는 상위 요소의 'exec_properties'를 상속하고 자체적으로 설정하지 않습니다.
• child_b은 상위의 exec_properties을 상속하고 k1 값을 재정의합니다. exec_properties은 { "k1": "child", "k2": "v2" }입니다.
• child_c은 상위 항목의 exec_properties을 상속하고 k1을 설정 해제합니다. exec_properties은 { "k2": "v2" }입니다.
• child_d는 상위 요소의 exec_properties를 상속하고 새 속성을 추가합니다. exec_properties은 { "k1": "v1", "k2": "v2", "k3": "v3" }입니다.

인수

도구 모음

toolchain(name, deprecation, distribs, exec_compatible_with, features, licenses, tags, target_compatible_with, target_settings, testonly, toolchain, toolchain_type, visibility)

이 규칙은 도구 모음 확인 중에 선택할 수 있도록 특정 도구 모음의 유형과 제약 조건을 선언합니다. 자세한 내용은 도구 모음 페이지를 참고하세요.

인수

toolchain_type

toolchain_type(name, compatible_with, deprecation, features, restricted_to, tags, target_compatible_with, testonly, visibility)

이 규칙은 새로운 유형의 도구 모음, 즉 다양한 플랫폼에서 동일한 역할을 하는 도구 클래스를 나타내는 간단한 타겟을 정의합니다.

자세한 내용은 도구 모음 페이지를 참고하세요.

예

이는 맞춤 규칙의 도구 모음 유형을 정의합니다.

toolchain_type(
    name = "bar_toolchain_type",
)

이는 bzl 파일에서 사용할 수 있습니다.

bar_binary = rule(
    implementation = _bar_binary_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = True),
        ...
        # No `_compiler` attribute anymore.
    },
    toolchains = ["//bar_tools:toolchain_type"]
)

인수