การสร้างมาโคร

สมมติว่าคุณต้องเรียกใช้เครื่องมือเป็นส่วนหนึ่งของการสร้าง ตัวอย่างเช่น คุณอาจต้องการสร้างหรือประมวลผลล่วงหน้าไฟล์ต้นฉบับ หรือบีบอัดไบนารี ในบทแนะนำนี้ คุณจะได้สร้างมาโครที่ปรับขนาดรูปภาพ

มาโครเหมาะสำหรับงานง่ายๆ หากต้องการทำสิ่งที่ซับซ้อนกว่านี้ เช่น เพิ่มการรองรับภาษาโปรแกรมใหม่ ให้พิจารณาสร้างกฎ กฎช่วยให้คุณควบคุมและมีความยืดหยุ่นมากขึ้น

วิธีที่ง่ายที่สุดในการสร้างมาโครที่ปรับขนาดรูปภาพคือการใช้genrule

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

หากต้องการปรับขนาดรูปภาพเพิ่มเติม คุณอาจต้องใช้โค้ดซ้ำ โดยทำดังนี้ กำหนดฟังก์ชันในไฟล์ .bzl แยกต่างหาก แล้วเรียกใช้ไฟล์ miniature.bzl

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

ข้อควรทราบ

• ตามธรรมเนียมแล้ว มาโครจะมีอาร์กิวเมนต์ name เช่นเดียวกับกฎ

• หากต้องการบันทึกพฤติกรรมของมาโคร ให้ใช้สตริงเอกสารเหมือนใน Python

• หากต้องการเรียกใช้ genrule หรือกฎเนทีฟอื่นๆ ให้ใช้ native.

• ใช้ **kwargs เพื่อส่งต่ออาร์กิวเมนต์เพิ่มเติมไปยัง genrule (ทำงานเหมือนใน Python) ซึ่งจะเป็นประโยชน์เพื่อให้ผู้ใช้ใช้แอตทริบิวต์มาตรฐาน เช่น visibility, หรือ tags ได้

ตอนนี้ให้ใช้มาโครจากไฟล์ BUILD ดังนี้

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)