परफ़ॉर्मेंस को ऑप्टिमाइज़ करना

नियम लिखते समय, परफ़ॉर्मेंस से जुड़ी सबसे आम समस्या, डिपेंडेंसी से इकट्ठा किए गए डेटा को ट्रैवर्स या कॉपी करना है. पूरे बिल्ड में इकट्ठा किए जाने पर, इन कार्रवाइयों में O(N^2) समय या जगह लग सकती है. इससे बचने के लिए, यह समझना ज़रूरी है कि depsets का असरदार तरीके से इस्तेमाल कैसे किया जाए.

इसे सही तरीके से करना मुश्किल हो सकता है. इसलिए, Bazel में मेमोरी प्रोफ़ाइलर की सुविधा भी मिलती है. इससे आपको उन जगहों का पता लगाने में मदद मिलती है जहां आपसे गलती हो सकती है. चेतावनी: किसी ऐसे नियम को लिखने की लागत का पता तब तक नहीं चलता जब तक उसका बड़े पैमाने पर इस्तेमाल न किया जाए.

depsets का इस्तेमाल करना

नियम की डिपेंडेंसी से जानकारी इकट्ठा करते समय, आपको depsets का इस्तेमाल करना चाहिए. मौजूदा नियम के लिए, स्थानीय जानकारी पब्लिश करने के लिए सिर्फ़ सामान्य सूचियों या डिक्शनरी का इस्तेमाल करें.

कोई depset, जानकारी को नेस्ट किए गए ग्राफ़ के तौर पर दिखाता है. इससे जानकारी शेयर की जा सकती है.

यहां दिया गया ग्राफ़ देखें:

C -> B -> A
D ---^

हर नोड, एक स्ट्रिंग पब्लिश करता है. depsets की मदद से, डेटा इस तरह दिखता है:

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

ध्यान दें कि हर आइटम का ज़िक्र सिर्फ़ एक बार किया गया है. सूचियों की मदद से, आपको यह जानकारी मिलेगी:

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

ध्यान दें कि इस मामले में 'a' का ज़िक्र चार बार किया गया है! बड़े ग्राफ़ के साथ, यह समस्या और भी बढ़ जाएगी.

यहां नियम को लागू करने का एक उदाहरण दिया गया है. इसमें, ट्रांज़िटिव जानकारी पब्लिश करने के लिए, depsets का सही तरीके से इस्तेमाल किया गया है. ध्यान दें कि अगर आपको नियम से जुड़ी स्थानीय जानकारी, सूचियों का इस्तेमाल करके पब्लिश करनी है, तो ऐसा किया जा सकता है. ऐसा इसलिए, क्योंकि यह O(N^2) नहीं है.

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

ज़्यादा जानकारी के लिए, depset की खास जानकारी वाला पेज देखें.

depset.to_list() को कॉल करने से बचें

`to_list()` का इस्तेमाल करके, किसी depset को फ़्लैट सूची में बदला जा सकता है. हालांकि, ऐसा करने पर आम तौर पर O(N^2) लागत लगती है.to_list() अगर मुमकिन हो, तो डीबग करने के मकसद के अलावा, depsets को फ़्लैट करने से बचें.

आम तौर पर यह माना जाता है कि अगर depsets को सिर्फ़ टॉप-लेवल टारगेट पर फ़्लैट किया जाता है, तो उन्हें आसानी से फ़्लैट किया जा सकता है. जैसे, <xx>_binary नियम. ऐसा इसलिए, क्योंकि तब लागत, बिल्ड ग्राफ़ के हर लेवल पर इकट्ठा नहीं होती. हालांकि, ओवरलैप होने वाली डिपेंडेंसी वाले टारगेट का सेट बनाने पर, यह अब भी O(N^2) है. ऐसा तब होता है, जब आपके टेस्ट //foo/tests/... बनाए जाते हैं या जब किसी IDE प्रोजेक्ट को इंपोर्ट किया जाता है.

depset को कॉल करने की संख्या कम करना

लूप के अंदर depset को कॉल करना अक्सर एक गलती होती है. इससे, depsets को बहुत ज़्यादा नेस्ट किया जा सकता है. इससे परफ़ॉर्मेंस खराब हो सकती है. उदाहरण के लिए:

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

इस कोड को आसानी से बदला जा सकता है. सबसे पहले, ट्रांज़िटिव depsets इकट्ठा करें और उन्हें एक साथ मर्ज करें:

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

कभी-कभी इसे सूची की समझ का इस्तेमाल करके कम किया जा सकता है:

x = depset(transitive = [i.deps for i in inputs])

कमांड लाइन के लिए, ctx.actions.args() का इस्तेमाल करना

कमांड लाइन बनाते समय, आपको ctx.actions.args() का इस्तेमाल करना चाहिए. इससे, किसी भी depset का एक्सपैंशन, एक्ज़ीक्यूशन फ़ेज़ तक टल जाता है.

यह न सिर्फ़ ज़्यादा तेज़ है, बल्कि इससे आपके नियमों की मेमोरी की खपत भी कम होगी. कभी-कभी यह 90% या उससे ज़्यादा भी हो सकती है.

यहां कुछ तरीके दिए गए हैं:

• depsets और सूचियों को सीधे तौर पर आर्ग्युमेंट के तौर पर पास करें. इन्हें खुद फ़्लैट न करें. ctx.actions.args() आपके लिए इन्हें एक्सपैंड करेगा. अगर आपको depset के कॉन्टेंट में कोई बदलाव करना है, तो ctx.actions.args#add देखें. इससे आपको पता चलेगा कि कोई चीज़ काम की है या नहीं.

• क्या आप File#path को आर्ग्युमेंट के तौर पर पास कर रहे हैं? ऐसा करने की ज़रूरत नहीं है. किसी भी फ़ाइल को अपने-आप उसके पाथ में बदल दिया जाता है. इसे एक्सपैंशन के समय तक टाला जा सकता है.

• स्ट्रिंग को एक साथ जोड़कर बनाने से बचें. स्ट्रिंग आर्ग्युमेंट के तौर पर, कॉन्स्टैंट सबसे अच्छा होता है. ऐसा इसलिए, क्योंकि इसकी मेमोरी, आपके नियम के सभी इंस्टेंस के बीच शेयर की जाएगी.

• अगर आर्ग्युमेंट, कमांड लाइन के लिए बहुत ज़्यादा लंबे हैं, तो एक ctx.actions.args() ऑब्जेक्ट को किसी पैरामीटर फ़ाइल में शर्त के हिसाब से या बिना शर्त के लिखा जा सकता है. इसके लिए, ctx.actions.args#use_param_file का इस्तेमाल करें. जब कार्रवाई की जाती है, तो यह बैकग्राउंड में होता है. अगर आपको पैरामीटर फ़ाइल को साफ़ तौर पर कंट्रोल करना है, तो इसे मैन्युअल तरीके से लिखा जा सकता है. इसके लिए, ctx.actions.write का इस्तेमाल करें.

उदाहरण:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "-<-foo=file> path" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # I<t will ho>wever pass ["--foo", file path] to the acti<on comman>d line,
  # instead of ["--foo=file_path"]
  args.add(&qu<ot;--foo&>quot;, file)

  <# Use for>mat if you prefer ["--foo=file path"] to ["--foo", file path]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each=";-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

ट्रांज़िटिव ऐक्शन इनपुट, depsets होने चाहिए

ctx.actions.run का इस्तेमाल करके कोई कार्रवाई करते समय, यह न भूलें कि inputs फ़ील्ड, depset स्वीकार करता है. इसका इस्तेमाल तब करें, जब इनपुट को ट्रांज़िटिव तरीके से डिपेंडेंसी से इकट्ठा किया जाता है.

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

हैंग होना

अगर Bazel हैंग हो गया है, तो Ctrl-\ दबाएं या Bazel को SIGQUIT सिग्नल भेजें (kill -3 $(bazel info server_pid)). इससे, $(bazel info output_base)/server/jvm.out फ़ाइल में थ्रेड डंप मिलेगा.

Bazel के हैंग होने पर, हो सकता है कि bazel info न चलाया जा सके. इसलिए, output_base डायरेक्ट्री आम तौर पर, आपके वर्कस्पेस डायरेक्ट्री में मौजूद bazel-<workspace> सिमलंक की पैरंट डायरेक्ट्री होती है.

परफ़ॉर्मेंस की प्रोफ़ाइलिंग

JSON ट्रेस प्रोफ़ाइल, यह समझने में बहुत काम आ सकती है कि Bazel ने इनवोकेशन के दौरान किस काम में कितना समय लगाया.

मेमोरी की प्रोफ़ाइलिंग

Bazel में, मेमोरी प्रोफ़ाइलर की सुविधा पहले से मौजूद होती है. इससे, आपके नियम के मेमोरी इस्तेमाल की जांच की जा सकती है. अगर कोई समस्या है, तो समस्या पैदा करने वाले कोड की सटीक लाइन ढूंढने के लिए, हीप को डंप किया जा सकता है.

मेमोरी ट्रैकिंग चालू करना

आपको Bazel के हर इनवोकेशन में, ये दो स्टार्टअप फ़्लैग पास करने होंगे:

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.4.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

इनसे, सर्वर मेमोरी ट्रैकिंग मोड में शुरू होता है. अगर आपने Bazel के किसी भी इनवोकेशन के लिए इन्हें पास नहीं किया, तो सर्वर रीस्टार्ट हो जाएगा और आपको फिर से शुरू करना होगा.

मेमोरी ट्रैकर का इस्तेमाल करना

उदाहरण के लिए, टारगेट foo देखें और जानें कि यह क्या करता है. सिर्फ़ विश्लेषण करने और बिल्ड एक्ज़ीक्यूशन फ़ेज़ को न चलाने के लिए, --nobuild फ़्लैग जोड़ें.

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

इसके बाद, देखें कि Bazel का पूरा इंस्टेंस कितनी मेमोरी इस्तेमाल करता है:

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

bazel dump --rules का इस्तेमाल करके, इसे नियम क्लास के हिसाब से ब्रेकडाउन करें:

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

bazel dump --skylark_memory का इस्तेमाल करके, pprof फ़ाइल जनरेट करें और देखें कि मेमोरी कहां जा रही है:

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

हीप की जांच करने के लिए, pprof टूल का इस्तेमाल करें. pprof -flame $HOME/prof.gz का इस्तेमाल करके, फ़्लेम ग्राफ़ पाना एक अच्छा शुरुआती पॉइंट है.

pprof को https://github.com/google/pprof से डाउनलोड करें.

सबसे ज़्यादा कॉल वाली साइटों का टेक्स्ट डंप पाएं. इसमें लाइनें भी शामिल होंगी:

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)