การกำหนดค่าเชนเครื่องมือ C++

ภาพรวม

Bazel ต้องมีความรู้เกี่ยวกับส่วนประกอบภายในของคอมไพเลอร์ เช่น ไดเรกทอรีรวมและแฟล็กสำคัญ เพื่อเรียกใช้คอมไพเลอร์ด้วยตัวเลือกที่ถูกต้อง กล่าวอีกนัยหนึ่งคือ Bazel ต้องการโมเดลคอมไพเลอร์ที่เรียบง่ายเพื่อทำความเข้าใจการทำงานของคอมไพเลอร์

Bazel ต้องทราบข้อมูลต่อไปนี้

• คอมไพเลอร์รองรับ thinLTO, โมดูล, การลิงก์แบบไดนามิก หรือ PIC (โค้ดที่ไม่ขึ้นกับตำแหน่ง) หรือไม่
• เส้นทางไปยังเครื่องมือที่จำเป็น เช่น gcc, ld, ar, objcopy และอื่นๆ
• ระบบในตัวมีไดเรกทอรี Bazel ต้องใช้ไฟล์เหล่านี้เพื่อตรวจสอบว่าส่วนหัวทั้งหมดที่รวมอยู่ในไฟล์ต้นฉบับได้รับการประกาศอย่างถูกต้องในไฟล์ BUILD
• Sysroot เริ่มต้น
• แฟล็กที่จะใช้สำหรับการคอมไพล์ การลิงก์ การเก็บถาวร
• แฟล็กที่จะใช้สำหรับโหมดการคอมไพล์ที่รองรับ (opt, dbg, fastbuild)
• สร้างตัวแปรที่คอมไพเลอร์ต้องการโดยเฉพาะ

หากคอมไพเลอร์รองรับสถาปัตยกรรมหลายแบบ Bazel จะต้องกำหนดค่า แยกกัน

CcToolchainConfigInfo เป็นผู้ให้บริการที่ให้ระดับความละเอียดที่จำเป็นสำหรับการกำหนดค่าลักษณะการทำงานของกฎ C++ ของ Bazel โดยค่าเริ่มต้น Bazel จะกำหนดค่า CcToolchainConfigInfo สำหรับบิลด์โดยอัตโนมัติ แต่คุณมีตัวเลือกในการกำหนดค่าด้วยตนเอง โดยคุณต้องมีกฎ Starlark ที่ระบุ CcToolchainConfigInfo และต้องชี้แอตทริบิวต์ toolchain_config ของ cc_toolchain ไปยังกฎของคุณ คุณสร้าง CcToolchainConfigInfo ได้โดยโทรไปที่ cc_common.create_cc_toolchain_config_info() คุณดูตัวสร้าง Starlark สำหรับโครงสร้างทั้งหมดที่จำเป็นในกระบวนการได้ที่ @rules_cc//cc:cc_toolchain_config_lib.bzl

เมื่อเป้าหมาย C++ เข้าสู่ระยะการวิเคราะห์ Bazel จะเลือกcc_toolchainเป้าหมายที่เหมาะสมตามไฟล์ BUILD และรับCcToolchainConfigInfoผู้ให้บริการจากเป้าหมายที่ระบุในแอตทริบิวต์ cc_toolchain.toolchain_config cc_toolchain เป้าหมาย จะส่งข้อมูลนี้ไปยังเป้าหมาย C++ ผ่าน CcToolchainProvider

ตัวอย่างเช่น การดำเนินการคอมไพล์หรือลิงก์ที่สร้างขึ้นโดยกฎ เช่น cc_binary หรือ cc_library ต้องมีข้อมูลต่อไปนี้

• คอมไพเลอร์หรือลิงเกอร์ที่จะใช้
• Flag บรรทัดคำสั่งสำหรับคอมไพเลอร์/ลิงเกอร์
• แฟล็กการกำหนดค่าที่ส่งผ่าน--copt/--linkopt options
• ตัวแปรสภาพแวดล้อม
• อาร์ติแฟกต์ที่จำเป็นในแซนด์บ็อกซ์ซึ่งการดำเนินการจะทำงาน

ข้อมูลข้างต้นทั้งหมด ยกเว้นอาร์ติแฟกต์ที่จำเป็นในแซนด์บ็อกซ์ จะระบุไว้ในเป้าหมาย Starlark ที่ cc_toolchain ชี้ไป

โดยจะประกาศอาร์ติแฟกต์ที่จะจัดส่งไปยังแซนด์บ็อกซ์ในcc_toolchain เป้าหมาย เช่น คุณสามารถใช้แอตทริบิวต์ cc_toolchain.linker_files เพื่อ ระบุไบนารีของ Linker และไลบรารี Toolchain ที่จะจัดส่งไปยังแซนด์บ็อกซ์

การเลือก Toolchain

ตรรกะการเลือกเชนเครื่องมือทำงานดังนี้

1. ผู้ใช้ระบุcc_toolchain_suiteเป้าหมายในไฟล์ BUILD และชี้ Bazel ไปยังเป้าหมายโดยใช้--crosstool_top ตัวเลือก

2. cc_toolchain_suite เป้าหมายอ้างอิงเชนเครื่องมือหลายรายการ ค่าของแฟล็ก --cpu และ --compiler จะกำหนดว่าระบบจะเลือก Toolchain ใด โดยอิงตามค่าของแฟล็ก --cpu เพียงอย่างเดียว หรือ อิงตามค่า --cpu | --compiler ร่วม กระบวนการเลือกมีดังนี้

   • หากระบุตัวเลือก --compiler Bazel จะเลือกรายการที่เกี่ยวข้องจากแอตทริบิวต์ cc_toolchain_suite.toolchains ที่มี --cpu | --compiler หาก Bazel ไม่พบ รายการที่ตรงกัน ระบบจะแสดงข้อผิดพลาด

   • หากไม่ได้ระบุ--compiler Bazel จะเลือกรายการที่เกี่ยวข้องจากแอตทริบิวต์ cc_toolchain_suite.toolchains ที่มีเพียง --cpu

   • หากไม่ได้ระบุแฟล็ก Bazel จะตรวจสอบระบบโฮสต์และเลือกค่า --cpu ตามสิ่งที่พบ ดูโค้ดกลไกการตรวจสอบ

เมื่อเลือก Toolchain แล้ว ออบเจ็กต์ feature และ action_config ที่เกี่ยวข้องในกฎ Starlark จะควบคุมการกำหนดค่าของการสร้าง (นั่นคือ รายการที่อธิบายในภายหลัง) ข้อความเหล่านี้ช่วยให้สามารถใช้ฟีเจอร์ C++ ที่สมบูรณ์ใน Bazel โดยไม่ต้องแก้ไขไบนารีของ Bazel กฎ C++ รองรับการดำเนินการที่ไม่ซ้ำกันหลายรายการซึ่งมีรายละเอียดอยู่ใน ซอร์สโค้ดของ Bazel

ฟีเจอร์

ฟีเจอร์คือเอนทิตีที่ต้องใช้ Flag บรรทัดคำสั่ง การดำเนินการ ข้อจำกัดในสภาพแวดล้อมการดำเนินการ หรือการเปลี่ยนแปลงการอ้างอิง ฟีเจอร์ อาจเป็นอะไรที่เรียบง่าย เช่น การอนุญาตให้ไฟล์ BUILD เลือกการกำหนดค่าของ แฟล็ก เช่น treat_warnings_as_errors หรือโต้ตอบกับกฎ C++ และ รวมการดำเนินการคอมไพล์ใหม่และอินพุตในการคอมไพล์ เช่น header_modules หรือ thin_lto

ในอุดมคติ CcToolchainConfigInfo จะมีรายการฟีเจอร์ โดยแต่ละฟีเจอร์ ประกอบด้วยกลุ่ม Flag อย่างน้อย 1 กลุ่ม ซึ่งแต่ละกลุ่มจะกำหนดรายการ Flag ที่ใช้กับการดำเนินการ Bazel ที่เฉพาะเจาะจง

ฟีเจอร์จะระบุตามชื่อ ซึ่งช่วยให้แยกการกำหนดค่ากฎ Starlark ออกจากการเผยแพร่ Bazel ได้อย่างสมบูรณ์ กล่าวคือ การเผยแพร่ Bazel จะไม่ส่งผลต่อลักษณะการทำงานของการกำหนดค่า CcToolchainConfigInfo ตราบใดที่การกำหนดค่าเหล่านั้นไม่จำเป็นต้องใช้ฟีเจอร์ใหม่

ฟีเจอร์จะเปิดใช้ได้ด้วยวิธีใดวิธีหนึ่งต่อไปนี้

• ตั้งค่าฟิลด์ enabled ของฟีเจอร์เป็น true
• Bazel หรือเจ้าของกฎเปิดใช้ฟีเจอร์นี้อย่างชัดเจน
• ผู้ใช้เปิดใช้ผ่าน--featureตัวเลือก Bazel หรือแอตทริบิวต์featuresกฎ

ฟีเจอร์อาจมีความสัมพันธ์กัน ขึ้นอยู่กับแฟล็กบรรทัดคำสั่ง BUILD การตั้งค่าไฟล์ และตัวแปรอื่นๆ

ความสัมพันธ์ของฟีเจอร์

โดยปกติแล้วจะมีการจัดการการขึ้นต่อกันโดยตรงด้วย Bazel ซึ่งจะบังคับใช้ ข้อกำหนดและจัดการความขัดแย้งที่เกิดขึ้นตามลักษณะของฟีเจอร์ ที่กำหนดไว้ในการบิลด์ ข้อกำหนดของ Toolchain ช่วยให้มีข้อจำกัดที่ละเอียดยิ่งขึ้น สำหรับการใช้งานโดยตรงภายในกฎ Starlark ที่ควบคุมการรองรับ และการขยายฟีเจอร์ ได้แก่

requires = [
   feature_set (features = [
       'feature-name-1',
       'feature-name-2'
   ]),
]

implies = ['feature']

provides = ['feature']

with_features = [
  with_feature_set(
    features = ['feature-1'],
    not_features = ['feature-2'],
  ),
]

การดำเนินการ

การดำเนินการช่วยให้คุณมีความยืดหยุ่นในการแก้ไขสถานการณ์ภายใต้ การดำเนินการโดยไม่ต้องสันนิษฐานว่าการดำเนินการจะทำงานอย่างไร action_config ระบุไบนารีของเครื่องมือที่การดำเนินการเรียกใช้ ส่วน feature ระบุการกำหนดค่า (แฟล็ก) ที่กำหนดลักษณะการทำงานของเครื่องมือนั้น เมื่อมีการเรียกใช้การดำเนินการ

ฟีเจอร์อ้างอิงการดำเนินการเพื่อส่งสัญญาณว่าการดำเนินการใดของ Bazel ที่ฟีเจอร์ส่งผลต่อ เนื่องจากสามารถแก้ไขกราฟการดำเนินการของ Bazel ได้ CcToolchainConfigInfoผู้ให้บริการมีเครื่องมือและการดำเนินการที่มีการติดแฟล็ก ซึ่งเชื่อมโยงกับเครื่องมือและการดำเนินการเหล่านั้น เช่น c++-compile ระบบจะกำหนด Flag ให้กับการดำเนินการแต่ละอย่าง โดยเชื่อมโยงกับการดำเนินการนั้นกับฟีเจอร์

ชื่อการดำเนินการแต่ละชื่อแสดงถึงการดำเนินการประเภทเดียวที่ Bazel ดำเนินการ เช่น การคอมไพล์หรือการลิงก์ อย่างไรก็ตาม การดำเนินการและประเภทการดำเนินการของ Bazel มีความสัมพันธ์แบบกลุ่มต่อหนึ่ง ซึ่งประเภทการดำเนินการของ Bazel หมายถึงคลาส Java ที่ใช้การดำเนินการ (เช่น CppCompileAction) โดยเฉพาะอย่างยิ่ง "การดำเนินการของแอสเซมเบลอร์" และ "การดำเนินการของคอมไพเลอร์" ในตารางด้านล่างคือ CppCompileAction ส่วนการดำเนินการลิงก์คือ CppLinkAction

การดำเนินการของ Assembler

การดำเนินการของคอมไพเลอร์

การดำเนินของการลิงก์

การดำเนินการ AR

การดำเนินการ AR จะรวบรวมไฟล์ออบเจ็กต์ไว้ในไลบรารีที่เก็บถาวร (ไฟล์ .a) ผ่าน ar และเข้ารหัสความหมายบางอย่างลงในชื่อ

การดำเนินการ LTO

การใช้ action_config

action_config คือโครงสร้าง Starlark ที่อธิบายการดำเนินการของ Bazel โดยการระบุเครื่องมือ (ไบนารี) ที่จะเรียกใช้ระหว่างการดำเนินการและชุด ของแฟล็กที่กำหนดโดยฟีเจอร์ โดยการแจ้งเตือนเหล่านี้จะใช้ข้อจำกัดกับการดำเนินการ

ตัวสร้าง action_config() มีพารามิเตอร์ต่อไปนี้

action_config สามารถกำหนดและสื่อถึงฟีเจอร์อื่นๆ และ action_config ตามที่ระบุไว้ใน ความสัมพันธ์ของฟีเจอร์ที่อธิบายไว้ก่อนหน้านี้ ลักษณะการทำงานนี้ คล้ายกับลักษณะการทำงานของฟีเจอร์

แอตทริบิวต์ 2 รายการสุดท้ายซ้ำซ้อนกับแอตทริบิวต์ที่เกี่ยวข้องใน ฟีเจอร์ และรวมไว้เนื่องจากการดำเนินการ Bazel บางอย่างต้องใช้แฟล็กหรือ ตัวแปรสภาพแวดล้อมบางอย่าง และเป้าหมายคือหลีกเลี่ยงaction_config+feature คู่ที่ไม่จำเป็น โดยปกติแล้ว การแชร์ฟีเจอร์เดียวใน action_config หลายรายการเป็นสิ่งที่แนะนำ

คุณกำหนด action_config ที่มี action_name เดียวกันมากกว่า 1 รายการไม่ได้ ภายในเครื่องมือเดียวกัน ซึ่งจะช่วยป้องกันความคลุมเครือในเส้นทางเครื่องมือ และบังคับใช้เจตนาเบื้องหลัง action_config นั่นคืออธิบายพร็อพเพอร์ตี้ของการดำเนินการ อย่างชัดเจนในที่เดียวในเครื่องมือ

การใช้ตัวสร้างเครื่องมือ

action_config สามารถระบุชุดเครื่องมือผ่านพารามิเตอร์ tools ได้ ตัวสร้าง tool() จะใช้พารามิเตอร์ต่อไปนี้

สำหรับ action_config ที่กำหนด จะมีเพียง tool เดียวที่ใช้ เส้นทางเครื่องมือและข้อกำหนดในการดำเนินการกับ Bazel Action ระบบจะเลือกเครื่องมือโดยการวนซ้ำแอตทริบิวต์ tools ใน action_config จนกว่าจะพบเครื่องมือที่มีชุด with_feature ที่ตรงกับการกำหนดค่าฟีเจอร์ (ดูข้อมูลเพิ่มเติมในความสัมพันธ์ของฟีเจอร์ที่ส่วนต้นของหน้านี้ ) คุณควรปิดท้ายรายการเครื่องมือด้วยเครื่องมือเริ่มต้น ที่สอดคล้องกับการกำหนดค่าฟีเจอร์ที่ว่างเปล่า

ตัวอย่างการใช้

ฟีเจอร์และการดำเนินการสามารถใช้ร่วมกันเพื่อใช้การดำเนินการของ Bazel กับความหมายข้ามแพลตฟอร์มที่หลากหลาย ตัวอย่างเช่น การสร้างสัญลักษณ์การแก้ไขข้อบกพร่องใน macOS ต้องสร้างสัญลักษณ์ในการดำเนินการคอมไพล์ จากนั้นเรียกใช้เครื่องมือเฉพาะในระหว่างการดำเนินการลิงก์เพื่อสร้างที่เก็บถาวร dsym ที่บีบอัด แล้วจึงคลายการบีบอัดที่เก็บถาวรนั้นเพื่อสร้างชุดแอปพลิเคชันและไฟล์ .plist ที่ Xcode ใช้ได้

ใน Bazel คุณสามารถใช้กระบวนการนี้แทนได้ดังนี้ โดยที่ unbundle-debuginfo คือการดำเนินการของ Bazel

load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")

action_configs = [
    action_config (
        action_name = ACTION_NAMES.cpp_link_executable,
        tools = [
            tool(
                with_features = [
                    with_feature(features=["generate-debug-symbols"]),
                ],
                path = "toolchain/mac/ld-with-dsym-packaging",
            ),
            tool (path = "toolchain/mac/ld"),
        ],
    ),
]

features = [
    feature(
        name = "generate-debug-symbols",
        flag_sets = [
            flag_set (
                actions = [
                    ACTION_NAMES.c_compile,
                    ACTION_NAMES.cpp_compile
                ],
                flag_groups = [
                    flag_group(
                        flags = ["-g"],
                    ),
                ],
            )
        ],
        implies = ["unbundle-debuginfo"],
   ),
]

ฟีเจอร์เดียวกันนี้อาจมีการใช้งานที่แตกต่างกันโดยสิ้นเชิงสำหรับ Linux ซึ่งใช้ fission หรือสำหรับ Windows ซึ่งสร้างไฟล์ .pdb ตัวอย่างเช่น การติดตั้งใช้งานสำหรับการสร้างสัญลักษณ์สำหรับแก้ไขข้อบกพร่องที่อิงตาม fission อาจมีลักษณะดังนี้

load("@rules_cc//cc:defs.bzl", "ACTION_NAMES")

action_configs = [
    action_config (
        name = ACTION_NAMES.cpp_compile,
        tools = [
            tool(
                path = "toolchain/bin/gcc",
            ),
        ],
    ),
]

features = [
    feature (
        name = "generate-debug-symbols",
        requires = [with_feature_set(features = ["dbg"])],
        flag_sets = [
            flag_set(
                actions = [ACTION_NAMES.cpp_compile],
                flag_groups = [
                    flag_group(
                        flags = ["-gsplit-dwarf"],
                    ),
                ],
            ),
            flag_set(
                actions = [ACTION_NAMES.cpp_link_executable],
                flag_groups = [
                    flag_group(
                        flags = ["-Wl", "--gdb-index"],
                    ),
                ],
            ),
      ],
    ),
]

กลุ่มฟีเจอร์ทดลอง

CcToolchainConfigInfo ช่วยให้คุณจัดกลุ่มแฟล็กเป็นกลุ่มที่ทำหน้าที่ตาม วัตถุประสงค์ที่เฉพาะเจาะจง คุณสามารถระบุแฟล็กภายในโดยใช้ตัวแปรที่กำหนดไว้ล่วงหน้า ภายในค่าแฟล็ก ซึ่งคอมไพเลอร์จะขยายเมื่อเพิ่มแฟล็กไปยัง คำสั่งบิลด์ เช่น

flag_group (
    flags = ["%{output_execpath}"],
)

ในกรณีนี้ เนื้อหาของแฟล็กจะถูกแทนที่ด้วยเส้นทางไฟล์เอาต์พุต ของการดำเนินการ

ระบบจะขยายกลุ่มแฟล็กไปยังคำสั่งบิลด์ตามลำดับที่ปรากฏ ในรายการจากบนลงล่างและจากซ้ายไปขวา

สําหรับแฟล็กที่ต้องทําซ้ำโดยมีค่าต่างกันเมื่อเพิ่มลงในคําสั่งบิลด์ กลุ่มแฟล็กจะวนซ้ำตัวแปรประเภท list ได้ เช่น ตัวแปร include_path ประเภท list

flag_group (
    iterate_over = "include_paths",
    flags = ["-I%{include_paths}"],
)

จะขยายเป็น -I<path> สำหรับองค์ประกอบเส้นทางแต่ละรายการในรายการ include_paths ระบบจะขยายแฟล็ก (หรือ flag_group) ทั้งหมดในส่วนเนื้อหาของการประกาศกลุ่มแฟล็กเป็นหน่วยเดียว เช่น

flag_group (
    iterate_over = "include_paths",
    flags = ["-I", "%{include_paths}"],
)

จะขยายเป็น -I <path> สำหรับองค์ประกอบเส้นทางแต่ละรายการในรายการ include_paths

ตัวแปรสามารถทำซ้ำได้หลายครั้ง เช่น

flag_group (
    iterate_over = "include_paths",
    flags = ["-iprefix=%{include_paths}", "-isystem=%{include_paths}"],
)

ขยายเป็น

-iprefix=<inc0> -isystem=<inc0> -iprefix=<inc1> -isystem=<inc1>

ตัวแปรอาจสอดคล้องกับโครงสร้างที่เข้าถึงได้โดยใช้รูปแบบจุด เช่น

flag_group (
    flags = ["-l%{libraries_to_link.name}"],
)

คุณสามารถซ้อนโครงสร้างและอาจมีลำดับด้วย คุณต้องระบุเส้นทางแบบเต็มผ่านฟิลด์เพื่อป้องกันการตั้งชื่อซ้ำ และเพื่อให้ชัดเจน เช่น

flag_group (
    iterate_over = "libraries_to_link",
    flag_groups = [
        flag_group (
            iterate_over = "libraries_to_link.shared_libraries",
            flags = ["-l%{libraries_to_link.shared_libraries.name}"],
        ),
    ],
)

การขยายแบบมีเงื่อนไข

กลุ่ม Flag รองรับการขยายแบบมีเงื่อนไขตามการมีตัวแปรหรือฟิลด์ใดฟิลด์หนึ่งโดยใช้แอตทริบิวต์ expand_if_available, expand_if_not_available, expand_if_true, expand_if_false หรือ expand_if_equal เช่น

flag_group (
    iterate_over = "libraries_to_link",
    flag_groups = [
        flag_group (
            iterate_over = "libraries_to_link.shared_libraries",
            flag_groups = [
                flag_group (
                    expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
                    flags = ["--whole_archive"],
                ),
                flag_group (
                    flags = ["-l%{libraries_to_link.shared_libraries.name}"],
                ),
                flag_group (
                    expand_if_available = "libraries_to_link.shared_libraries.is_whole_archive",
                    flags = ["--no_whole_archive"],
                ),
            ],
        ),
    ],
)

การอ้างอิง CcToolchainConfigInfo

ส่วนนี้มีข้อมูลอ้างอิงเกี่ยวกับตัวแปรบิลด์ ฟีเจอร์ และข้อมูลอื่นๆ ที่จำเป็นต่อการกำหนดค่ากฎ C++ ให้สำเร็จ

ตัวแปรบิลด์ CcToolchainConfigInfo

ต่อไปนี้คือข้อมูลอ้างอิงของCcToolchainConfigInfoตัวแปรบิลด์

ฟีเจอร์ที่รู้จักกันดี

ต่อไปนี้คือข้อมูลอ้างอิงเกี่ยวกับฟีเจอร์และเงื่อนไขการเปิดใช้งาน

ตรรกะการแก้ไขฟีเจอร์เดิม

Bazel จะทำการเปลี่ยนแปลงต่อไปนี้กับฟีเจอร์ของ Toolchain เพื่อให้เข้ากันได้แบบย้อนหลัง

• ย้ายฟีเจอร์ legacy_compile_flags ไปไว้ที่ด้านบนของเชนเครื่องมือ
• ย้ายฟีเจอร์ default_compile_flags ไปไว้ที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ dependency_file (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ pic (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ per_object_debug_info (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ preprocessor_defines (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ includes (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ include_paths (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ fdo_instrument (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ fdo_optimize (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ cs_fdo_instrument (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ cs_fdo_optimize (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ fdo_prefetch_hints (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ autofdo (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ build_interface_libraries (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ dynamic_library_linker_tool (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ shared_flag (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ linkstamps (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ output_execpath_flags (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ runtime_library_search_directories (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ library_search_directories (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ archiver_flags (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ libraries_to_link (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ force_pic_flags (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ user_link_flags (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ legacy_link_flags (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ static_libgcc (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ fission_support (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ strip_debug_symbols (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ coverage (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ llvm_coverage_map_format (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ gcc_coverage_map_format (หากไม่มี) ไปที่ด้านบนของเชนเครื่องมือ
• เพิ่มฟีเจอร์ fully_static_link (หากไม่มี) ที่ด้านล่างของเครื่องมือ
• เพิ่มฟีเจอร์ user_compile_flags (หากไม่มี) ที่ด้านล่างของเครื่องมือ
• เพิ่มฟีเจอร์ sysroot (หากไม่มี) ที่ด้านล่างของเครื่องมือ
• เพิ่มฟีเจอร์ unfiltered_compile_flags (หากไม่มี) ที่ด้านล่างของเครื่องมือ
• เพิ่มฟีเจอร์ linker_param_file (หากไม่มี) ที่ด้านล่างของเครื่องมือ
• เพิ่มฟีเจอร์ compiler_input_flags (หากไม่มี) ที่ด้านล่างของเครื่องมือ
• เพิ่มฟีเจอร์ compiler_output_flags (หากไม่มี) ที่ด้านล่างของเครื่องมือ

นี่เป็นรายการฟีเจอร์ที่ยาว เรามีแผนที่จะนำออกเมื่อCrosstool ใน Starlark เสร็จสมบูรณ์ สำหรับผู้อ่านที่สนใจ โปรดดูการใช้งานใน CppActionConfigs และสำหรับเครื่องมือในขั้นตอนการผลิต ให้พิจารณาเพิ่ม no_legacy_features เพื่อให้ เครื่องมือในขั้นตอนการผลิตทำงานแบบสแตนด์อโลนมากขึ้น