Grupos de ejecución automática (AEG)

Los grupos de ejecución automática seleccionan una plataforma de ejecución para cada tipo de cadena de herramientas. En otras palabras, un objetivo puede tener varias plataformas de ejecución sin definir grupos de ejecución.

Resumen breve

Los grupos de ejecución automática están estrechamente conectados a las cadenas de herramientas. Si usas cadenas de herramientas, debes configurarlas en las acciones afectadas (acciones que usan un ejecutable o una herramienta de una cadena de herramientas) agregando el parámetro toolchain. Por ejemplo:

ctx.actions.run(
    ...,
    executable = ctx.toolchain['@bazel_tools//tools/jdk:toolchain_type'].tool,
    ...,
    toolchain = '@bazel_tools//tools/jdk:toolchain_type',
)

Si la acción no usa una herramienta o un ejecutable de una cadena de herramientas, y Blaze no lo detecta (se genera el error), puedes configurar toolchain = None.

Si necesitas usar varias cadenas de herramientas en una sola plataforma de ejecución (una acción usa ejecutables o herramientas de dos o más cadenas de herramientas), debes definir manualmente exec_groups (consulta la sección ¿Cuándo debo usar un exec_group personalizado?).

Historial

Antes de los AEG, la plataforma de ejecución se seleccionaba a nivel de la regla. Por ejemplo:

my_rule = rule(
    _impl,
    toolchains = ['//tools:toolchain_type_1', '//tools:toolchain_type_2'],
)

La regla my_rule registra dos tipos de cadenas de herramientas. Esto significa que la resolución de cadena de herramientas se usó para encontrar una plataforma de ejecución que admita ambos tipos de cadenas de herramientas. Se usó la plataforma de ejecución seleccionada para cada acción registrada dentro de la regla, a menos que se especifique de otra manera con exec_groups. En otras palabras, todas las acciones dentro de la regla solían tener una sola plataforma de ejecución, incluso si usaban herramientas de diferentes cadenas de herramientas (la plataforma de ejecución se selecciona para cada destino). Esto generaba fallas cuando no había una plataforma de ejecución compatible con todas las cadenas de herramientas.

Estado actual

Con los AEG, se selecciona la plataforma de ejecución para cada tipo de cadena de herramientas. La función de implementación del ejemplo anterior, my_rule, se vería de la siguiente manera:

def _impl(ctx):
    ctx.actions.run(
      mnemonic = "First action",
      executable = ctx.toolchain['//tools:toolchain_type_1'].tool,
      toolchain = '//tools:toolchain_type_1',
    )

    ctx.actions.run(
      mnemonic = "Second action",
      executable = ctx.toolchain['//tools:toolchain_type_2'].tool,
      toolchain = '//tools:toolchain_type_2',
    )

Esta regla crea dos acciones: First action, que usa un ejecutable de un //tools:toolchain_type_1, y Second action, que usa un ejecutable de un //tools:toolchain_type_2. Antes de los AEG, ambas acciones se ejecutaban en una sola plataforma de ejecución que admitía ambos tipos de cadena de herramientas. Con los AEG, cuando se agrega el parámetro toolchain dentro de las acciones, cada acción se ejecuta en la plataforma de ejecución que proporciona la cadena de herramientas. Las acciones se pueden ejecutar en diferentes plataformas de ejecución.

Lo mismo sucede con ctx.actions.run_shell, en el que se debe agregar el parámetro toolchain cuando tools proviene de una cadena de herramientas.

Diferencia entre los grupos de ejecución personalizados y los grupos de ejecución automáticos

Como su nombre lo indica, los AEG son grupos de ejecución que se crean automáticamente para cada tipo de cadena de herramientas registrada en una regla. No es necesario especificarlos de forma manual, a diferencia de los grupos de ejecución "clásicos".

¿Cuándo debo usar un exec_group personalizado?

Los exec_groups personalizados solo son necesarios en el caso de que varias cadenas de herramientas deban ejecutarse en una sola plataforma de ejecución. En todos los demás casos, no es necesario definir exec_groups personalizados. Por ejemplo:

def _impl(ctx):
    ctx.actions.run(
      ...,
      executable = ctx.toolchain['//tools:toolchain_type_1'].tool,
      tools = [ctx.toolchain['//tools:toolchain_type_2'].tool],
      exec_group = 'two_toolchains',
    )

my_rule = rule(
    _impl,
    exec_groups = {
        "two_toolchains": exec_group(
            toolchains = ['//tools:toolchain_type_1', '//tools:toolchain_type_2'],
        ),
    }
)

Migración de AEG

De forma interna, en google3, Blaze ya usa AEG. Externamente para Bazel, la migración está en proceso. Algunas reglas ya usan esta función (p.ej., las reglas de Java y C++).

¿Qué versiones de Bazel admiten esta migración?

Los AEG son totalmente compatibles con Bazel 7.

¿Cómo habilitar los AEG?

Establecer --incompatible_auto_exec_groups como verdadero. Obtén más información sobre la marca en el problema de GitHub.

¿Cómo habilitar los AEG dentro de una regla en particular?

Establece el atributo _use_auto_exec_groups en una regla.

my_rule = rule(
    _impl,
    attrs = {
      "_use_auto_exec_groups": attr.bool(default = True),
    }
)

Esto habilita los AEG solo en my_rule, y sus acciones comienzan a usar la nueva lógica cuando se selecciona la plataforma de ejecución. La marca incompatible se anula con este atributo.

¿Cómo inhabilito los AEG en caso de error?

Establece --incompatible_auto_exec_groups como "false" para inhabilitar por completo los AEG en tu proyecto (problema de GitHub de la marca) o inhabilita una regla particular configurando el atributo _use_auto_exec_groups como False (más detalles sobre el atributo).

Mensajes de error durante la migración a AEG

No se pudo identificar si las herramientas provienen de dependencias implícitas o de una cadena de herramientas. Establece el parámetro de cadena de herramientas. Si no usas una cadena de herramientas, configúrala como "None".

• En este caso, obtienes una pila de llamadas antes de que se produzca el error y puedes ver con claridad qué acción exacta necesita el parámetro de cadena de herramientas. Verifica qué cadena de herramientas se usa para la acción y configúrala con el parámetro de cadena de herramientas. Si no se usa ninguna cadena de herramientas dentro de la acción para herramientas o ejecutables, configúrala como None.

Se declaró una acción para una cadena de herramientas inexistente '[toolchain_type]'.

• Esto significa que configuraste el parámetro de cadena de herramientas en la acción, pero no lo registraste en la regla. Registra la cadena de herramientas o establece None dentro de la acción.

Material adicional

Para obtener más información, consulta el documento de diseño Grupos de ejecución automática para cadenas de herramientas.