Platformlar ve Araç Zinciri Kuralları

Bu kural grubu, oluşturduğunuz belirli donanım platformlarını modellemenize ve bu platformlar için kodu derlemek üzere ihtiyaç duyabileceğiniz belirli araçları belirtmenize olanak tanımak için vardır. Kullanıcı, burada açıklanan kavramlar hakkında bilgi sahibi olmalıdır.

Kurallar

• constraint_setting
• constraint_value
• platform
• toolchain
• toolchain_type

constraint_setting

constraint_setting(name, default_constraint_value, deprecation, distribs, features, licenses, tags, testonly, visibility)

Bu kural, bir platformun değer belirleyebileceği yeni bir kısıtlama türü sunmak için kullanılır. Örneğin, platformların glibc kitaplığının farklı sürümlerini yükleme özelliğini temsil etmek için "glibc_version" adlı bir constraint_setting tanımlayabilirsiniz. Daha fazla bilgi için Platformlar sayfasına bakın.

Her constraint_setting, genişletilebilir bir ilişkili constraint_value grubu içerir. Bunlar genellikle aynı pakette tanımlanır ancak bazen farklı bir paket, mevcut bir ayar için yeni değerler sunar. Örneğin, önceden tanımlanmış @platforms//cpu:cpu ayarı, belirsiz bir CPU mimarisini hedefleyen bir platformu tanımlamak için özel bir değerle genişletilebilir.

Bağımsız değişkenler

constraint_value

constraint_value(name, constraint_setting, deprecation, distribs, features, licenses, tags, testonly, visibility)

Örnek

Aşağıdaki kod, önceden tanımlanmış constraint_value için yeni bir olası değer oluşturur. Bu değer, CPU mimarisini temsil eder.

constraint_value(
    name = "mips",
    constraint_setting = "@platforms//cpu:cpu",
)

Bağımsız değişkenler

platform

platform(name, constraint_values, deprecation, distribs, exec_properties, features, flags, licenses, parents, remote_execution_properties, required_settings, tags, testonly, visibility)

Bu kural, derlemenin bir bölümünün çalışabileceği bir ortamı tanımlayan, kısıtlama seçeneklerinin (ör. CPU mimarisi veya derleyici sürümü) adlandırılmış bir koleksiyonu olan yeni bir platform tanımlar. Daha fazla bilgi için Platformlar sayfasına bakın.

Örnek

Bu, ARM'de Linux çalıştıran herhangi bir ortamı tanımlayan bir platformu tanımlar.

platform(
    name = "linux_arm",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:arm",
    ],
)

Platform Bayrakları

Platformlar, platform hedef platform olarak kullanıldığında (ör. --platforms işaretinin değeri olarak) yapılandırmaya eklenecek işaretlerin listesini belirtmek için flags özelliğini kullanabilir.

Platformdan ayarlanan işaretler, en yüksek önceliğe sahiptir ve komut satırı, rc dosyası veya geçişten gelen bu işaretin önceki değerlerinin üzerine yazar.

Örnek

platform(
    name = "foo",
    flags = [
        "--dynamic_mode=fully",
        "--//bool_flag",
        "--no//package:other_bool_flag",
    ],
)

Bu, foo adlı bir platformu tanımlar. Hedef platform bu olduğunda (kullanıcı --platforms//:foo belirttiği, bir geçiş //command_line_option:platforms işaretini ["//:foo"] olarak ayarladığı veya //:foo yürütme platformu olarak kullanıldığı için) belirtilen işaretler yapılandırmada ayarlanır.

Platformlar ve Tekrarlanabilir İşaretler

Bazı işaretler tekrarlandığında değerleri biriktirir. Örneğin, --features, --copt, config.string(repeatable = True) olarak oluşturulan tüm Starlark işaretleri. Bu işaretler, platformdan işaret ayarlamayla uyumlu değildir. Bunun yerine, önceki tüm değerler kaldırılır ve platformdaki değerlerle üzerine yazılır.

Örneğin, aşağıdaki platformda build --platforms=//:repeat_demo --features feature_a --features feature_b çağrısı, komut satırında ayarlanan özellikleri kaldırarak --feature işaretinin değerinin ["feature_c", "feature_d"] olmasına neden olur.

platform(
    name = "repeat_demo",
    flags = [
        "--features=feature_c",
        "--features=feature_d",
    ],
)

Bu nedenle, flags özelliğinde tekrarlanabilir işaretlerin kullanılması önerilmez.

Platform Devralma

Platformlar, kısıtlama değerlerini devralacakları başka bir platformu belirtmek için parents özelliğini kullanabilir. parents özelliği bir liste alsa da şu anda birden fazla değer desteklenmemektedir ve birden fazla üst öğe belirtmek hataya neden olur.

Bir platformda kısıtlama ayarının değeri kontrol edilirken önce doğrudan ayarlanan değerler (constraint_values özelliği aracılığıyla) ve ardından üst öğedeki kısıtlama değerleri kontrol edilir. Bu işlem, üst platformlar zincirinde yinelemeli olarak devam eder. Bu şekilde, doğrudan bir platformda ayarlanan tüm değerler, üst öğede ayarlanan değerleri geçersiz kılar.

Platformlar, exec_properties özelliğini üst platformdan devralır. Üst ve alt platformların exec_properties sözlük girişleri birleştirilir. Aynı anahtar hem üst öğenin hem de alt öğenin exec_properties içinde görünüyorsa alt öğenin değeri kullanılır. Alt platform değer olarak boş bir dize belirtirse ilgili özellik ayarlanmaz.

Platformlar, (kullanımdan kaldırılan) remote_execution_properties özelliğini üst platformdan da devralabilir. Not: Yeni kodda bunun yerine exec_properties kullanılmalıdır. Aşağıda açıklanan mantık, eski davranışlarla uyumlu olması için korunur ancak gelecekte kaldırılacaktır. Bir üst platform olduğunda remote_execution_platform ayarlanmasıyla ilgili mantık aşağıdaki gibidir:

1. Çocuk platformunda remote_execution_property ayarlanmamışsa üst öğenin remote_execution_properties kullanılır.
2. Çocuk platformunda remote_execution_property ayarlanmışsa ve {PARENT_REMOTE_EXECUTION_PROPERTIES} hazır dizesini içeriyorsa bu makro, üst öğenin remote_execution_property özelliğinin içeriğiyle değiştirilir.
3. Alt platformda remote_execution_property ayarlanmışsa ve makroyu içermiyorsa alt öğenin remote_execution_property değeri değiştirilmeden kullanılır.

remote_execution_properties kullanımdan kaldırılacağı için aynı devralma zincirinde remote_execution_properties ve exec_properties karıştırılamaz. Kullanımdan kaldırılan remote_execution_properties yerine exec_properties kullanmayı tercih edin.

Örnek: Kısıtlama Değerleri

platform(
    name = "parent",
    constraint_values = [
        "@platforms//os:linux",
        "@platforms//cpu:arm",
    ],
)
platform(
    name = "child_a",
    parents = [":parent"],
    constraint_values = [
        "@platforms//cpu:x86_64",
    ],
)
platform(
    name = "child_b",
    parents = [":parent"],
)

Bu örnekte, alt platformlar aşağıdaki özelliklere sahiptir:

• child_a, @platforms//os:linux (üst öğeden devralınan) ve @platforms//cpu:x86_64 (doğrudan platformda ayarlanan) kısıtlama değerlerine sahip.
• child_b, tüm kısıtlama değerlerini üst öğeden devralır ve kendi değerlerini ayarlamaz.

Örnek: Yürütme özellikleri

platform(
    name = "parent",
    exec_properties = {
      "k1": "v1",
      "k2": "v2",
    },
)
platform(
    name = "child_a",
    parents = [":parent"],
)
platform(
    name = "child_b",
    parents = [":parent"],
    exec_properties = {
      "k1": "child"
    }
)
platform(
    name = "child_c",
    parents = [":parent"],
    exec_properties = {
      "k1": ""
    }
)
platform(
    name = "child_d",
    parents = [":parent"],
    exec_properties = {
      "k3": "v3"
    }
)

Bu örnekte, alt platformlar aşağıdaki özelliklere sahiptir:

• child_a, üst öğenin "exec_properties" özelliğini devralır ve kendi özelliğini ayarlamaz.
• child_b, üst öğenin exec_properties değerini devralır ve k1 değerini geçersiz kılar. exec_properties değeri: { "k1": "child", "k2": "v2" }.
• child_c, üst öğenin exec_properties özelliğini devralır ve k1 özelliğini ayarlanmamış hale getirir. exec_properties değeri: { "k2": "v2" }.
• child_d, üst öğenin exec_properties özelliğini devralır ve yeni bir özellik ekler. exec_properties değeri: { "k1": "v1", "k2": "v2", "k3": "v3" }.

Bağımsız değişkenler

araç zinciri

toolchain(name, deprecation, distribs, exec_compatible_with, features, licenses, tags, target_compatible_with, target_settings, testonly, toolchain, toolchain_type, visibility)

Bu kural, araç zinciri çözümlemesi sırasında seçilebilmesi için belirli bir araç zincirinin türünü ve kısıtlamalarını bildirir. Daha fazla bilgi için Toolchains (Araç Zincirleri) sayfasına bakın.

Bağımsız değişkenler

toolchain_type

toolchain_type(name, compatible_with, deprecation, features, restricted_to, tags, target_compatible_with, testonly, visibility)

Bu kural, yeni bir araç zinciri türünü tanımlar: Farklı platformlarda aynı rolü üstlenen bir araç sınıfını temsil eden basit bir hedef.

Daha fazla bilgi için Toolchains (Araç Zincirleri) sayfasına bakın.

Örnek

Bu, özel bir kural için araç zinciri türünü tanımlar.

toolchain_type(
    name = "bar_toolchain_type",
)

Bu, bir bzl dosyasında kullanılabilir.

bar_binary = rule(
    implementation = _bar_binary_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = True),
        ...
        # No `_compiler` attribute anymore.
    },
    toolchains = ["//bar_tools:toolchain_type"]
)

Bağımsız değişkenler