การสร้างมาโครเดิม

สำคัญ: บทแนะนำนี้มีไว้สำหรับ มาโครเดิม หาก คุณต้องการรองรับเฉพาะ Bazel 8 ขึ้นไป เราขอแนะนำให้ใช้ มาโคร สัญลักษณ์แทน โปรดดูที่ การสร้างมาโคร สัญลักษณ์

สมมติว่าคุณต้องเรียกใช้เครื่องมือเป็นส่วนหนึ่งของการสร้าง เช่น คุณ อาจต้องการสร้างหรือประมวลผลไฟล์ต้นฉบับล่วงหน้า หรือบีบอัดไบนารี ในบทแนะนำนี้ คุณจะได้สร้างมาโครเดิมที่ปรับขนาดรูปภาพ

มาโครเหมาะสำหรับงานง่ายๆ หากต้องการทำสิ่งที่ซับซ้อนกว่านี้ เช่น เพิ่มการรองรับภาษาโปรแกรมใหม่ ให้ลอง สร้างกฎ กฎช่วยให้คุณควบคุมและมีความยืดหยุ่นมากขึ้น

วิธีที่ง่ายที่สุดในการสร้างมาโครที่ปรับขนาดรูปภาพคือการใช้ genrule ดังนี้

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

หากต้องการปรับขนาดรูปภาพเพิ่มเติม คุณอาจต้องการนำโค้ดกลับมาใช้ซ้ำ โดยกำหนดฟังก์ชันในไฟล์ .bzl แยกต่างหาก และเรียกไฟล์ว่า miniature.bzl ดังนี้

def miniature(name, src, size = "100x100", **kwargs):
    """Create a miniature of the src image.

    The generated file is prefixed with 'small_'.
    """
    native.genrule(
        name = name,
        srcs = [src],
        # Note that the line below will fail if `src` is not a filename string
        outs = ["small_" + src],
        cmd = "convert $< -resize " + size + " $@",
        **kwargs
    )

ข้อควรทราบบางประการมีดังนี้

• โดยทั่วไปแล้ว มาโครเดิมจะมีอาร์กิวเมนต์ name เหมือนกับกฎ

• หากต้องการบันทึกพฤติกรรมของมาโครเดิม ให้ใช้ docstring เหมือนใน Python

• หากต้องการเรียก genrule หรือกฎดั้งเดิมอื่นๆ ให้ใส่คำนำหน้า native.

• ใช้ **kwargs เพื่อส่งต่ออาร์กิวเมนต์เพิ่มเติมไปยัง genrule ที่อยู่เบื้องหลัง(ทำงานเหมือนใน Python) ซึ่งจะเป็นประโยชน์เพื่อให้ผู้ใช้สามารถใช้แอตทริบิวต์มาตรฐาน เช่น visibility หรือ tags

ตอนนี้ให้ใช้มาโครจากไฟล์ BUILD ดังนี้

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

และสุดท้ายคือหมายเหตุคำเตือน: มาโครจะถือว่า src เป็นสตริงชื่อไฟล์ (มิเช่นนั้น outs = ["small_" + src] จะล้มเหลว) ดังนั้น src = "image.png" จึงใช้งานได้ แต่จะเกิดอะไรขึ้นหากไฟล์ BUILD ใช้ src = "/versions/8.0.0//other/package:image.png" หรือแม้แต่ src = select(...) แทน

คุณควรประกาศข้อสันนิษฐานดังกล่าวในเอกสารประกอบของมาโคร น่าเสียดายที่มาโครเดิม โดยเฉพาะมาโครขนาดใหญ่ มักจะเปราะบาง เนื่องจาก อาจสังเกตและบันทึกข้อสันนิษฐานดังกล่าวทั้งหมดในโค้ดได้ยาก และ แน่นอนว่าผู้ใช้มาโครบางรายจะไม่อ่านเอกสารประกอบ เราขอแนะนำ, หากเป็นไปได้ ให้ใช้ มาโครสัญลักษณ์แทน ซึ่งมีการ ตรวจสอบประเภทแอตทริบิวต์ในตัว