Bazel チュートリアル: Java プロジェクトをビルドする

このチュートリアルでは、Bazel を使用して Java アプリケーションをビルドする基本的な方法について説明します。ワークスペースを設定し、ターゲットや BUILD ファイルなどの Bazel の主要なコンセプトを示す簡単な Java プロジェクトをビルドします。

推定所要時間: 30 分。

学習内容

このチュートリアルでは、次の方法について学習します。

• ターゲットをビルドする
• プロジェクトの依存関係を可視化する
• プロジェクトを複数のターゲットとパッケージに分割する
• パッケージ間のターゲットの公開設定を制御する
• ラベルを使用してターゲットを参照する
• ターゲットをデプロイする

始める前に

Bazel をインストールする

チュートリアルの準備として、まだインストールしていない場合は、まず Bazel をインストールします。

JDK をインストールする

1. Java JDK をインストールします（推奨バージョンは 11 ですが、8 ～ 15 のバージョンがサポートされています）。

2. JAVA_HOME 環境変数を JDK を指すように設定します。

   • Linux/macOS の場合:

     export JAVA_HOME="$(dirname $(dirname $(realpath $(which javac))))"
     

   • Windows の場合:

     1. [コントロール パネル] を開きます。
     2. [システムとセキュリティ] > [システム] > [システムの詳細設定] > [詳細設定] タブ > [環境変数...] に移動します。.
     3. [ユーザー変数] リスト（上部にあるリスト）で [新規...] をクリックします。
     4. [変数名] フィールドに「JAVA_HOME」と入力します。
     5. [Browse Directory...] をクリックします。
     6. JDK ディレクトリ（C:\Program Files\Java\jdk1.8.0_152 など）に移動します。
     7. すべてのダイアログ ウィンドウで [OK] をクリックします。

サンプル プロジェクトを取得する

Bazel の GitHub リポジトリからサンプル プロジェクトを取得します。

git clone https://github.com/bazelbuild/examples

このチュートリアルのサンプル プロジェクトは examples/java-tutorial ディレクトリにあり、次のように構成されています。

java-tutorial
├── BUILD
├── src
│   └── main
│       └── java
│           └── com
│               └── example
│                   ├── cmdline
│                   │   ├── BUILD
│                   │   └── Runner.java
│                   ├── Greeting.java
│                   └── ProjectRunner.java
└── MODULE.bazel

Bazel を使用したビルド

ワークスペースを設定する

プロジェクトをビルドする前に、ワークスペースを設定する必要があります。ワークスペースは、プロジェクトのソースファイルと Bazel のビルド出力を保持するディレクトリです。また、Bazel が特別なファイルとして認識するファイルも含まれています。

• ディレクトリとそのコンテンツを Bazel ワークスペースとして識別し、プロジェクトのディレクトリ構造のルートに存在する MODULE.bazel ファイル。

• 1 つ以上の BUILD ファイル。プロジェクトのさまざまな部分をビルドする方法を Bazel に指示します。（BUILD ファイルを含むワークスペース内のディレクトリは、パッケージです。パッケージについては、このチュートリアルの後半で説明します）。

ディレクトリを Bazel ワークスペースとして指定するには、そのディレクトリに MODULE.bazel という名前の空のファイルを作成します。

Bazel がプロジェクトをビルドするとき、すべての入力と依存関係が同じワークスペースにある必要があります。異なるワークスペースにあるファイルは、リンクされていない限り互いに独立しています。リンクについては、このチュートリアルの範囲外です。

BUILD ファイルを理解する

BUILD ファイルには、Bazel のさまざまな種類の命令が含まれています。最も重要なタイプはビルドルールです。これは、実行可能バイナリやライブラリなど、必要な出力をビルドする方法を Bazel に指示します。BUILD ファイル内のビルドルールの各インスタンスはターゲットと呼ばれ、特定のソースファイルと依存関係のセットを指します。ターゲットは他のターゲットを指すこともできます。

java-tutorial/BUILD ファイルを確認します。

java_binary(
    name = "ProjectRunner",
    srcs = glob(["src/main/java/com/example/*.java"]),
)

この例では、ProjectRunner ターゲットは Bazel の組み込みの java_binary ルールをインスタンス化します。このルールは、Bazel に .jar ファイルとラッパー シェル スクリプト（両方ともターゲットにちなんだ名前）をビルドするように指示します。

ターゲットの属性には、依存関係とオプションが明示的に記述されています。name 属性は必須ですが、多くの属性は省略可能です。たとえば、ProjectRunner ルール ターゲットでは、name はターゲットの名前、srcs は Bazel がターゲットのビルドに使用するソースファイルを指定し、main_class は main メソッドを含むクラスを指定します。（この例では、ソースファイルを 1 つずつリストするのではなく、glob を使用してソースファイルのセットを Bazel に渡しています）。

プロジェクトをビルドする

サンプル プロジェクトをビルドするには、java-tutorial ディレクトリに移動して次のコマンドを実行します。

bazel build //:ProjectRunner

ターゲット ラベルの // 部分は、ワークスペースのルート（この場合はルート自体）に対する BUILD ファイルの場所であり、ProjectRunner は BUILD ファイル内のターゲット名です。（ターゲット ラベルの詳細については、このチュートリアルの最後で説明します）。

Bazel は次のような出力を生成します。

   INFO: Found 1 target...
   Target //:ProjectRunner up-to-date:
      bazel-bin/ProjectRunner.jar
      bazel-bin/ProjectRunner
   INFO: Elapsed time: 1.021s, Critical Path: 0.83s

これで、最初の Bazel ターゲットがビルドされました。Bazel は、ビルド出力をワークスペースのルートにある bazel-bin ディレクトリに配置します。その内容を参照して、Bazel の出力構造の概要を把握します。

ビルドしたばかりのバイナリをテストします。

bazel-bin/ProjectRunner

依存関係グラフを確認する

Bazel では、ビルドの依存関係を BUILD ファイルで明示的に宣言する必要があります。Bazel はこれらのステートメントを使用してプロジェクトの依存関係グラフを作成し、正確な増分ビルドを可能にします。

サンプル プロジェクトの依存関係を可視化するには、ワークスペースのルートで次のコマンドを実行して、依存関係グラフのテキスト表現を生成します。

bazel query  --notool_deps --noimplicit_deps "deps(//:ProjectRunner)" --output graph

上記のコマンドは、ターゲット //:ProjectRunner のすべての依存関係（ホストと暗黙的な依存関係を除く）を探し、出力をグラフとしてフォーマットするよう Bazel に指示します。

次に、テキストを GraphViz に貼り付けます。

ご覧のとおり、このプロジェクトには、追加の依存関係なしで 2 つのソースファイルをビルドする単一のターゲットがあります。

ワークスペースを設定し、プロジェクトをビルドして、その依存関係を調べたら、複雑さを追加できます。

Bazel ビルドを調整する

小規模なプロジェクトでは 1 つのターゲットで十分ですが、大規模なプロジェクトでは、複数のターゲットとパッケージに分割して、高速な増分ビルド（変更された部分のみを再ビルド）を可能にし、プロジェクトの複数の部分を同時にビルドしてビルドを高速化することをおすすめします。

複数のビルド ターゲットを指定する

サンプル プロジェクトのビルドを 2 つのターゲットに分割できます。java-tutorial/BUILD ファイルの内容を次のように置き換えます。

java_binary(
    name = "ProjectRunner",
    srcs = ["src/main/java/com/example/ProjectRunner.java"],
    main_class = "com.example.ProjectRunner",
    deps = [":greeter"],
)

java_library(
    name = "greeter",
    srcs = ["src/main/java/com/example/Greeting.java"],
)

この構成では、Bazel はまず greeter ライブラリをビルドし、次に ProjectRunner バイナリをビルドします。java_binary の deps 属性は、ProjectRunner バイナリをビルドするために greeter ライブラリが必要であることを Bazel に伝えます。

この新しいバージョンのプロジェクトをビルドするには、次のコマンドを実行します。

bazel build //:ProjectRunner

Bazel は次のような出力を生成します。

INFO: Found 1 target...
Target //:ProjectRunner up-to-date:
  bazel-bin/ProjectRunner.jar
  bazel-bin/ProjectRunner
INFO: Elapsed time: 2.454s, Critical Path: 1.58s

ビルドしたばかりのバイナリをテストします。

bazel-bin/ProjectRunner

ここで ProjectRunner.java を変更してプロジェクトを再ビルドすると、Bazel はそのファイルのみを再コンパイルします。

依存関係グラフを見ると、ProjectRunner は以前と同じ入力に依存していますが、ビルドの構造が異なっていることがわかります。

これで、2 つのターゲットを含むプロジェクトが作成されました。ProjectRunner ターゲットは 1 つのソースファイルをビルドし、1 つの追加のソースファイルをビルドする別のターゲット（:greeter）に依存します。

複数のパッケージを使用する

それでは、プロジェクトを複数のパッケージに分割しましょう。src/main/java/com/example/cmdline ディレクトリを見ると、BUILD ファイルといくつかのソースファイルも含まれていることがわかります。そのため、Bazel から見ると、ワークスペースには //src/main/java/com/example/cmdline と // の 2 つのパッケージが含まれています（ワークスペースのルートに BUILD ファイルがあるため）。

src/main/java/com/example/cmdline/BUILD ファイルを確認します。

java_binary(
    name = "runner",
    srcs = ["Runner.java"],
    main_class = "com.example.cmdline.Runner",
    deps = ["//:greeter"],
)

runner ターゲットは // パッケージの greeter ターゲットに依存しています（ターゲット ラベル //:greeter）。Bazel は deps 属性を通じてこれを認識しています。依存関係グラフを見てみましょう。

ただし、ビルドを成功させるには、visibility 属性を使用して、//src/main/java/com/example/cmdline/BUILD の runner ターゲットに //BUILD のターゲットに対する可視性を明示的に付与する必要があります。これは、デフォルトではターゲットは同じ BUILD ファイル内の他のターゲットにのみ表示されるためです。（Bazel は、ターゲットの可視性を使用して、実装の詳細を含むライブラリが公開 API に漏洩するなどの問題を回避します）。

そのためには、以下に示すように、java-tutorial/BUILD の greeter ターゲットに visibility 属性を追加します。

java_library(
    name = "greeter",
    srcs = ["src/main/java/com/example/Greeting.java"],
    visibility = ["//src/main/java/com/example/cmdline:__pkg__"],
)

ワークスペースのルートで次のコマンドを実行して、新しいパッケージをビルドできるようになりました。

bazel build //src/main/java/com/example/cmdline:runner

Bazel は次のような出力を生成します。

INFO: Found 1 target...
Target //src/main/java/com/example/cmdline:runner up-to-date:
  bazel-bin/src/main/java/com/example/cmdline/runner.jar
  bazel-bin/src/main/java/com/example/cmdline/runner
  INFO: Elapsed time: 1.576s, Critical Path: 0.81s

ビルドしたばかりのバイナリをテストします。

./bazel-bin/src/main/java/com/example/cmdline/runner

これで、プロジェクトを 2 つのパッケージとしてビルドするように変更し、各パッケージに 1 つのターゲットを含め、それらの間の依存関係を理解しました。

ラベルを使用してターゲットを参照する

BUILD ファイルとコマンドラインで、Bazel はターゲット ラベルを使用してターゲット（//:ProjectRunner や //src/main/java/com/example/cmdline:runner など）を参照します。構文は次のとおりです。

//path/to/package:target-name

ターゲットがルール ターゲットの場合、path/to/package は BUILD ファイルを含むディレクトリのパスで、target-name は BUILD ファイルでターゲットに付けた名前（name 属性）です。ターゲットがファイル ターゲットの場合、path/to/package はパッケージのルートへのパスで、target-name はターゲット ファイルの名前（フルパスを含む）です。

リポジトリ ルートでターゲットを参照する場合、パッケージ パスは空です。//:target-name のみを使用します。同じ BUILD ファイル内のターゲットを参照する場合は、// ワークスペース ルート ID を省略して :target-name のみを使用することもできます。

たとえば、java-tutorial/BUILD ファイルのターゲットの場合、ワークスペースのルート自体がパッケージ（//）であり、2 つのターゲット ラベルは単に //:ProjectRunner と //:greeter であったため、パッケージ パスを指定する必要はありませんでした。

ただし、//src/main/java/com/example/cmdline/BUILD ファイルのターゲットでは、//src/main/java/com/example/cmdline の完全なパッケージ パスを指定する必要があり、ターゲット ラベルは //src/main/java/com/example/cmdline:runner でした。

デプロイ用に Java ターゲットをパッケージ化する

次に、すべてのランタイム依存関係を含むバイナリをビルドして、デプロイ用の Java ターゲットをパッケージ化します。これにより、開発環境外でバイナリを実行できます。

java_binary ビルドルールは、.jar とラッパー シェル スクリプトを生成します。次のコマンドを使用して、runner.jar の内容を確認します。

jar tf bazel-bin/src/main/java/com/example/cmdline/runner.jar

内容は次のとおりです。

META-INF/
META-INF/MANIFEST.MF
com/
com/example/
com/example/cmdline/
com/example/cmdline/Runner.class

ご覧のとおり、runner.jar には Runner.class が含まれていますが、依存関係である Greeting.class は含まれていません。Bazel が生成する runner スクリプトは、クラスパスに greeter.jar を追加します。このままにしておくと、ローカルでは実行されますが、別のマシンでスタンドアロンで実行されません。幸いなことに、java_binary ルールを使用すると、自己完結型のデプロイ可能なバイナリをビルドできます。ビルドするには、ターゲット名に _deploy.jar を追加します。

bazel build //src/main/java/com/example/cmdline:runner_deploy.jar

Bazel は次のような出力を生成します。

INFO: Found 1 target...
Target //src/main/java/com/example/cmdline:runner_deploy.jar up-to-date:
  bazel-bin/src/main/java/com/example/cmdline/runner_deploy.jar
INFO: Elapsed time: 1.700s, Critical Path: 0.23s

これで runner_deploy.jar がビルドされました。これには必要なランタイム依存関係が含まれているため、開発環境から離れてスタンドアロンで実行できます。以前と同じコマンドを使用して、このスタンドアロン JAR の内容を確認します。

jar tf bazel-bin/src/main/java/com/example/cmdline/runner_deploy.jar

コンテンツには、実行に必要なすべてのクラスが含まれています。

META-INF/
META-INF/MANIFEST.MF
build-data.properties
com/
com/example/
com/example/cmdline/
com/example/cmdline/Runner.class
com/example/Greeting.class

関連情報

詳しくは、以下をご覧ください。

• 推移的な Maven 依存関係を管理するルールの rules_jvm_external。

• ローカル リポジトリとリモート リポジトリの操作について詳しくは、外部依存関係をご覧ください。

• Bazel の詳細については、その他のルールをご覧ください。

• Bazel で C++ プロジェクトのビルドを開始するための C++ ビルドのチュートリアル。

• Android アプリケーションのチュートリアルと iOS アプリケーションのチュートリアル）で、Bazel を使用して Android と iOS 向けのモバイル アプリケーションのビルドを開始します。

Happy building!