BazelCon 2025 の登録と CFP が開始されました。

このページは Cloud Translation API によって翻訳されました。

従来のマクロ

問題を報告するソースを表示 Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

以前のマクロは、BUILD ファイルから呼び出される非構造化関数で、ターゲットを作成できます。読み込みフェーズの終了までに、以前のマクロは存在しなくなり、Bazel はインスタンス化されたルールの具体的なセットのみを認識します。

以前のマクロを使用すべきでない理由（代わりにシンボリックマクロを使用すべき理由）

可能な場合は、シンボリックマクロを使用する必要があります。

シンボリックマクロ

遠隔操作を防止する
きめ細かい可視性により、実装の詳細を非表示にできるようにする
型付き属性を取得します。つまり、ラベルと選択の自動変換が行われます。
読みやすくなる
遅延評価がまもなく導入されます

用途

マクロの一般的なユースケースは、ルールを再利用する場合です。

たとえば、BUILD ファイルの genrule は、コマンドにハードコードされた some_arg 引数を使用して //:generator でファイルを生成します。

genrule(
    name = "file",
    outs = ["file.txt"],
    cmd = "$(location //:generator) some_arg > $@",
    tools = ["//:generator"],
)

異なる引数で複数のファイルを生成する場合は、このコードをマクロ関数に抽出することをおすすめします。name パラメータと arg パラメータを持つ file_generator というマクロを作成するには、genrule を次のように置き換えます。

load("//path:generator.bzl", "file_generator")

file_generator(
    name = "file",
    arg = "some_arg",
)

file_generator(
    name = "file-two",
    arg = "some_arg_two",
)

file_generator(
    name = "file-three",
    arg = "some_arg_three",
)

ここでは、//path パッケージにある .bzl ファイルから file_generator シンボルを読み込みます。マクロ関数定義を別の .bzl ファイルに配置することで、BUILD ファイルをクリーンで宣言的に保つことができます。.bzl ファイルは、ワークスペース内の任意のパッケージから読み込むことができます。

最後に、path/generator.bzl で、元の genrule 定義をカプセル化してパラメータ化するマクロの定義を記述します。

def file_generator(name, arg, visibility=None):
  native.genrule(
    name = name,
    outs = [name + ".txt"],
    cmd = "$(location //:generator) %s > $@" % arg,
    tools = ["//:generator"],
    visibility = visibility,
  )

マクロを使用してルールを連結することもできます。この例は、前の genrule の出力を入力として使用する genrule を示す、連鎖した genrule を示しています。

def chained_genrules(name, visibility=None):
  native.genrule(
    name = name + "-one",
    outs = [name + ".one"],
    cmd = "$(location :tool-one) $@",
    tools = [":tool-one"],
    visibility = ["//visibility:private"],
  )

  native.genrule(
    name = name + "-two",
    srcs = [name + ".one"],
    outs = [name + ".two"],
    cmd = "$(location :tool-two) $< $@",
    tools = [":tool-two"],
    visibility = visibility,
  )

この例では、2 つ目の genrule にのみ可視性の値を割り当てています。これにより、マクロ作成者は、中間ルールの出力をワークスペース内の他のターゲットから依存されないように非表示にできます。

マクロの展開

マクロの動作を調べるには、--output=build を指定して query コマンドを使用し、展開された形式を確認します。

$ bazel query --output=build :file
# /absolute/path/test/ext.bzl:42:3
genrule(
  name = "file",
  tools = ["//:generator"],
  outs = ["//test:file.txt"],
  cmd = "$(location //:generator) some_arg > $@",
)

ネイティブルールのインスタンス化

ネイティブルール（load() ステートメントを必要としないルール）は、ネイティブモジュールからインスタンス化できます。

def my_macro(name, visibility=None):
  native.cc_library(
    name = name,
    srcs = ["main.cc"],
    visibility = visibility,
  )

パッケージ名（たとえば、どの BUILD ファイルがマクロを呼び出しているか）を知る必要がある場合は、関数 native.package_name() を使用します。native は .bzl ファイルでのみ使用でき、BUILD ファイルでは使用できません。

マクロでのラベル解決

以前のマクロは読み込みフェーズで評価されるため、以前のマクロで使用されている "//foo:bar" などのラベル文字列は、定義されている .bzl ファイルではなく、マクロが使用されている BUILD ファイルを基準に解釈されます。この動作は、公開された Starlark ルールセットの一部であるなど、他のリポジトリで使用されるマクロでは一般的に望ましくありません。

Starlark ルールと同じ動作にするには、ラベル文字列を Label コンストラクタでラップします。

# @my_ruleset//rules:defs.bzl
def my_cc_wrapper(name, deps = [], **kwargs):
  native.cc_library(
    name = name,
    deps = deps + select({
      # Due to the use of Label, this label is resolved within @my_ruleset,
      # regardless of its site of use.
      Label("//config:needs_foo"): [
        # Due to the use of Label, this label will resolve to the correct target
        # even if the canonical name of @dep_of_my_ruleset should be different
        # in the main repo, such as due to repo mappings.
        Label("@dep_of_my_ruleset//tools:foo"),
      ],
      "//conditions:default": [],
    }),
    **kwargs,
  )

デバッグ

bazel query --output=build //my/path:all は、評価後の BUILD ファイルの形式を示します。以前のマクロ、glob、ループはすべて展開されます。既知の制限事項: select 式は出力に表示されません。
generator_function（ルールを生成した関数）または generator_name（マクロの name 属性）に基づいて出力をフィルタできます。 bash $ bazel query --output=build 'attr(generator_function, my_macro, //my/path:all)'
BUILD ファイルでルール foo が生成される場所を正確に特定するには、次の方法を試してください。BUILD ファイルの先頭付近に cc_library(name = "foo") という行を挿入します。Bazel を実行します。ルール foo が作成されると（名前の競合が原因で）例外が発生し、完全なスタックトレースが表示されます。
デバッグに print を使用することもできます。読み込みフェーズ中に、メッセージが DEBUG ログ行として表示されます。まれなケースを除き、デポにコードを送信する前に、print 呼び出しを削除するか、False をデフォルトとする debugging パラメータの下で条件付きにします。

エラー

エラーをスローする場合は、fail 関数を使用します。何が問題だったのか、BUILD ファイルを修正する方法をユーザーに明確に説明します。エラーをキャッチすることはできません。

def my_macro(name, deps, visibility=None):
  if len(deps) < 2:
    fail("Expected at least two values in deps")
  # ...

規則

ルールをインスタンス化するすべてのパブリック関数（アンダースコアで始まらない関数）には、name 引数が必要です。この引数は省略可能にしないでください（デフォルト値を指定しないでください）。
公開関数は、Python の慣例に従った docstring を使用する必要があります。
BUILD ファイルでは、マクロの name 引数はキーワード引数（位置引数ではない）である必要があります。
マクロによって生成されたルールの name 属性には、名前引数を接頭辞として含める必要があります。たとえば、macro(name = "foo") は cc_library foo と genrule foo_gen を生成できます。
ほとんどの場合、省略可能なパラメータのデフォルト値は None にする必要があります。None はネイティブルールに直接渡すことができます。ネイティブルールでは、引数を渡さなかった場合と同じように扱われます。そのため、この目的で 0、False、[] に置き換える必要はありません。マクロは、作成するルールに委任する必要があります。ルールのデフォルトは複雑であるか、時間の経過とともに変化する可能性があるためです。また、クエリ言語またはビルドシステムの内部からアクセスすると、デフォルト値に明示的に設定されたパラメータは、設定されていない（または None に設定されている）パラメータとは異なるように見えます。
マクロには省略可能な visibility 引数が必要です。