Halaman ini menjelaskan dasar-dasar dan manfaat penggunaan aspek serta memberikan contoh sederhana dan lanjutan contoh.
Aspek memungkinkan penambahan informasi dan tindakan ke grafik dependensi build. Beberapa skenario umum saat aspek dapat berguna:
- IDE yang mengintegrasikan Bazel dapat menggunakan aspek untuk mengumpulkan informasi tentang project.
- Alat pembuatan kode dapat memanfaatkan aspek untuk dieksekusi pada inputnya dengan cara agnostik target. Sebagai contoh, file
BUILDdapat menentukan hierarki definisi library protobuf, dan aturan khusus bahasa dapat menggunakan aspek untuk melampirkan tindakan yang menghasilkan kode dukungan protobuf untuk bahasa tertentu.
Dasar-dasar aspek
File BUILD memberikan deskripsi kode sumber project: file sumber mana yang merupakan bagian dari project, artefak (target) mana yang harus dibuat dari file tersebut, apa dependensi antara file tersebut, dll. Bazel menggunakan informasi ini untuk melakukan build, yaitu, Bazel menentukan kumpulan tindakan yang diperlukan untuk menghasilkan artefak (seperti menjalankan compiler atau linker) dan menjalankan tindakan tersebut. Bazel mencapai hal ini dengan membuat grafik dependensi antar-target dan mengunjungi grafik ini untuk mengumpulkan tindakan tersebut.
Pertimbangkan file BUILD berikut:
java_library(name = 'W', ...)
java_library(name = 'Y', deps = [':W'], ...)
java_library(name = 'Z', deps = [':W'], ...)
java_library(name = 'Q', ...)
java_library(name = 'T', deps = [':Q'], ...)
java_library(name = 'X', deps = [':Y',':Z'], runtime_deps = [':T'], ...)
File BUILD ini menentukan grafik dependensi yang ditampilkan pada gambar berikut:
Gambar 1. Grafik dependensi file BUILD.
Bazel menganalisis grafik dependensi ini dengan memanggil fungsi implementasi dari
aturan yang sesuai (dalam hal ini "java_library") untuk setiap
target dalam contoh di atas. Fungsi implementasi aturan menghasilkan tindakan yang
membuat artefak, seperti file .jar, dan meneruskan informasi, seperti lokasi
dan nama artefak tersebut, ke dependensi terbalik dari target tersebut di
penyedia.
Aspek mirip dengan aturan karena memiliki fungsi implementasi yang menghasilkan tindakan dan menampilkan penyedia. Namun, kemampuannya berasal dari cara grafik dependensi dibuat untuknya. Aspek memiliki implementasi dan daftar semua atribut yang disebarkannya. Pertimbangkan aspek A yang disebarkan bersama atribut bernama "deps". Aspek ini dapat diterapkan ke target X, yang menghasilkan node aplikasi aspek A(X). Selama penerapannya, aspek A diterapkan secara rekursif ke semua target yang dirujuk X dalam atribut "deps" (semua atribut dalam daftar penyebaran A).
Dengan demikian, satu tindakan penerapan aspek A ke target X menghasilkan "grafik bayangan" dari grafik dependensi asli target yang ditampilkan pada gambar berikut:
Gambar 2. Grafik build dengan aspek.
Satu-satunya tepi yang dibayangi adalah tepi di sepanjang atribut dalam kumpulan penyebaran, sehingga tepi runtime_deps tidak dibayangi dalam contoh ini. Fungsi implementasi aspek kemudian dipanggil di semua node dalam grafik bayangan, mirip dengan cara implementasi aturan dipanggil di node grafik asli.
Contoh sederhana
Contoh ini menunjukkan cara mencetak file sumber secara rekursif untuk aturan dan semua dependensinya yang memiliki atribut deps. Contoh ini menunjukkan implementasi aspek, definisi aspek, dan cara memanggil aspek dari command line Bazel.
def _print_aspect_impl(target, ctx):
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the files that make up the sources and
# print their paths.
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
print(f.path)
return []
print_aspect = aspect(
implementation = _print_aspect_impl,
attr_aspects = ['deps'],
)
Mari kita bagi contoh ini menjadi beberapa bagian dan periksa setiap bagian satu per satu.
Definisi aspek
print_aspect = aspect(
implementation = _print_aspect_impl,
attr_aspects = ['deps'],
)
Definisi aspek mirip dengan definisi aturan, dan ditentukan menggunakan
fungsi aspect.
Sama seperti aturan, aspek memiliki fungsi implementasi yang dalam hal ini adalah _print_aspect_impl.
attr_aspects adalah daftar atribut aturan yang digunakan untuk menyebarkan aspek.
Dalam hal ini, aspek akan disebarkan bersama atribut deps dari aturan yang diterapkan.
Argumen umum lainnya untuk attr_aspects adalah ['*'] yang akan menyebarkan
aspek ke semua atribut aturan.
Implementasi aspek
def _print_aspect_impl(target, ctx):
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the files that make up the sources and
# print their paths.
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
print(f.path)
return []
Fungsi implementasi aspek mirip dengan fungsi implementasi aturan. Fungsi ini menampilkan penyedia, dapat menghasilkan tindakan, dan menggunakan dua argumen:
target: target yang diterapkan aspek.ctx: objekctxyang dapat digunakan untuk mengakses atribut dan menghasilkan output serta tindakan.
Fungsi implementasi dapat mengakses atribut aturan target melalui
ctx.rule.attr. Fungsi ini dapat memeriksa penyedia yang disediakan oleh target yang diterapkan (melalui argumen target).
Aspek harus menampilkan daftar penyedia. Dalam contoh ini, aspek tidak menyediakan apa pun, sehingga menampilkan daftar kosong.
Memanggil aspek menggunakan command line
Cara paling sederhana untuk menerapkan aspek adalah dari command line menggunakan argumen
--aspects. Dengan asumsi aspek di atas ditentukan dalam file bernama print.bzl ini:
bazel build //MyExample:example --aspects print.bzl%print_aspect
akan menerapkan print_aspect ke target example dan semua aturan target yang dapat diakses secara rekursif melalui atribut deps.
Flag --aspects menggunakan satu argumen, yang merupakan spesifikasi aspek
dalam format <extension file label>%<aspect top-level name>.
Contoh lanjutan
Contoh berikut menunjukkan penggunaan aspek dari aturan target yang menghitung file dalam target, yang berpotensi memfilternya berdasarkan ekstensi. Contoh ini menunjukkan cara menggunakan penyedia untuk menampilkan nilai, cara menggunakan parameter untuk meneruskan argumen ke implementasi aspek, dan cara memanggil aspek dari aturan.
File file_count.bzl:
FileCountInfo = provider(
fields = {
'count' : 'number of files'
}
)
def _file_count_aspect_impl(target, ctx):
count = 0
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the sources counting files
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
count = count + 1
# Get the counts from our dependencies.
for dep in ctx.rule.attr.deps:
count = count + dep[FileCountInfo].count
return [FileCountInfo(count = count)]
file_count_aspect = aspect(
implementation = _file_count_aspect_impl,
attr_aspects = ['deps'],
attrs = {
'extension' : attr.string(values = ['*', 'h', 'cc']),
}
)
def _file_count_rule_impl(ctx):
for dep in ctx.attr.deps:
print(dep[FileCountInfo].count)
file_count_rule = rule(
implementation = _file_count_rule_impl,
attrs = {
'deps' : attr.label_list(aspects = [file_count_aspect]),
'extension' : attr.string(default = '*'),
},
)
File BUILD.bazel:
load('//:file_count.bzl', 'file_count_rule')
cc_library(
name = 'lib',
srcs = [
'lib.h',
'lib.cc',
],
)
cc_binary(
name = 'app',
srcs = [
'app.h',
'app.cc',
'main.cc',
],
deps = ['lib'],
)
file_count_rule(
name = 'file_count',
deps = ['app'],
extension = 'h',
)
Definisi aspek
file_count_aspect = aspect(
implementation = _file_count_aspect_impl,
attr_aspects = ['deps'],
attrs = {
'extension' : attr.string(values = ['*', 'h', 'cc']),
}
)
Contoh ini menunjukkan cara aspek disebarkan melalui atribut deps.
attrs menentukan kumpulan atribut untuk aspek. Atribut aspek publik menentukan parameter dan hanya dapat berjenis bool, int, atau string.
Untuk aspek yang disebarkan aturan, parameter int dan string harus memiliki values yang ditentukan. Contoh ini memiliki parameter bernama extension yang diizinkan memiliki '*', 'h', atau 'cc' sebagai nilai.
Untuk aspek yang disebarkan aturan, nilai parameter diambil dari aturan yang meminta aspek, menggunakan atribut aturan yang memiliki nama dan jenis yang sama.
(lihat definisi file_count_rule).
Untuk aspek command line, nilai parameter dapat diteruskan menggunakan
--aspects_parameters
flag. Pembatasan values parameter int dan string dapat dihilangkan.
Aspek juga diizinkan memiliki atribut pribadi berjenis label atau
label_list. Atribut label pribadi dapat digunakan untuk menentukan dependensi pada alat atau library yang diperlukan untuk tindakan yang dihasilkan oleh aspek. Tidak ada atribut pribadi yang ditentukan dalam contoh ini, tetapi cuplikan kode berikut menunjukkan cara meneruskan alat ke aspek:
...
attrs = {
'_protoc' : attr.label(
default = Label('//tools:protoc'),
executable = True,
cfg = "exec"
)
}
...
Implementasi aspek
FileCountInfo = provider(
fields = {
'count' : 'number of files'
}
)
def _file_count_aspect_impl(target, ctx):
count = 0
# Make sure the rule has a srcs attribute.
if hasattr(ctx.rule.attr, 'srcs'):
# Iterate through the sources counting files
for src in ctx.rule.attr.srcs:
for f in src.files.to_list():
if ctx.attr.extension == '*' or ctx.attr.extension == f.extension:
count = count + 1
# Get the counts from our dependencies.
for dep in ctx.rule.attr.deps:
count = count + dep[FileCountInfo].count
return [FileCountInfo(count = count)]
Sama seperti fungsi implementasi aturan, fungsi implementasi aspek menampilkan struct penyedia yang dapat diakses oleh dependensinya.
Dalam contoh ini, FileCountInfo ditentukan sebagai penyedia yang memiliki satu kolom count. Praktik terbaiknya adalah menentukan kolom penyedia secara eksplisit menggunakan atribut fields.
Kumpulan penyedia untuk aplikasi aspek A(X) adalah gabungan penyedia yang berasal dari implementasi aturan untuk target X dan dari implementasi aspek A. Penyedia yang disebarkan implementasi aturan dibuat dan dibekukan sebelum aspek diterapkan dan tidak dapat diubah dari aspek. Terjadi error jika target dan aspek yang diterapkan ke target tersebut masing-masing
menyediakan penyedia dengan jenis yang sama, dengan pengecualian
OutputGroupInfo
(yang digabungkan, selama
aturan dan aspek menentukan grup output yang berbeda) dan
InstrumentedFilesInfo
(yang diambil dari aspek). Artinya, implementasi aspek tidak boleh
menampilkan DefaultInfo.
Parameter dan atribut pribadi diteruskan dalam atribut ctx. Contoh ini mereferensikan parameter extension dan menentukan file yang akan dihitung.
Untuk penyedia yang ditampilkan, nilai atribut yang digunakan untuk menyebarkan aspek (dari daftar attr_aspects) diganti dengan hasil penerapan aspek ke atribut tersebut. Misalnya, jika target X memiliki Y dan Z dalam dependensinya, ctx.rule.attr.deps untuk A(X) akan menjadi [A(Y), A(Z)].
Dalam contoh ini, ctx.rule.attr.deps adalah objek Target yang merupakan hasil penerapan aspek ke 'deps' dari target asli yang diterapkan aspek.
Dalam contoh ini, aspek mengakses penyedia FileCountInfo dari dependensi target untuk mengakumulasikan jumlah file transitif total.
Memanggil aspek dari aturan
def _file_count_rule_impl(ctx):
for dep in ctx.attr.deps:
print(dep[FileCountInfo].count)
file_count_rule = rule(
implementation = _file_count_rule_impl,
attrs = {
'deps' : attr.label_list(aspects = [file_count_aspect]),
'extension' : attr.string(default = '*'),
},
)
Implementasi aturan menunjukkan cara mengakses FileCountInfo melalui ctx.attr.deps.
Definisi aturan menunjukkan cara menentukan parameter (extension) dan memberikan nilai default (*). Perhatikan bahwa memiliki nilai default yang bukan salah satu dari 'cc', 'h', atau '*' akan menjadi error karena batasan yang ditempatkan pada parameter dalam definisi aspek.
Memanggil aspek melalui aturan target
load('//:file_count.bzl', 'file_count_rule')
cc_binary(
name = 'app',
...
)
file_count_rule(
name = 'file_count',
deps = ['app'],
extension = 'h',
)
Contoh ini menunjukkan cara meneruskan parameter extension ke aspek melalui aturan. Karena parameter extension memiliki nilai default dalam implementasi aturan, extension akan dianggap sebagai parameter opsional.
Saat target file_count dibuat, aspek kita akan dievaluasi untuk dirinya sendiri, dan semua target yang dapat diakses secara rekursif melalui deps.