パフォーマンスの最適化

問題を報告する ソースを表示 Nightly · 8.4 · 8.3 · 8.2 · 8.1 · 8.0 · 7.6

ルールを作成する際に最も一般的なパフォーマンスの落とし穴は、依存関係から蓄積されたデータをトラバースまたはコピーすることです。ビルド全体で集計すると、これらのオペレーションは簡単に O(N^2) の時間または空間を消費する可能性があります。これを回避するには、depsset を効果的に使用する方法を理解することが重要です。

これを正しく行うのは難しい場合があるため、Bazel には、間違いを犯した可能性のある場所を見つけるのに役立つメモリ プロファイラも用意されています。警告: 非効率的なルールを作成した場合、そのコストはルールが広く使用されるまで明らかにならないことがあります。

depset を使用する

ルール依存関係から情報をロールアップする場合は、常に depset を使用する必要があります。現在のルールにローカルな情報を公開するには、プレーン リストまたは辞書のみを使用します。

depsset は、情報をネストされたグラフとして表し、共有を可能にします。

次のグラフについて考えてみましょう。

C -> B -> A
D ---^

各ノードは単一の文字列を公開します。depsets を使用すると、データは次のようになります。

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

各項目は 1 回のみ言及されています。リストを使用すると、次のようになります。

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

この例では、'a' が 4 回言及されています。グラフが大きくなると、この問題はさらに悪化します。

以下に、depsets を正しく使用して推移的情報を公開するルール実装の例を示します。これは O(N^2) ではないため、必要に応じてリストを使用してルールローカル情報を公開してもかまいません。

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

詳細については、depset の概要ページをご覧ください。

depset.to_list() を呼び出さないようにする

to_list() を使用して depset をフラット リストに強制変換できますが、通常は O(N^2) のコストが発生します。デバッグ目的以外で depsets をフラット化することは、できるだけ避けてください。

よくある誤解は、<xx>_binary ルールなどのトップレベル ターゲットでのみ実行する場合、ビルドグラフの各レベルでコストが累積されないため、depsets を自由にフラット化できるというものです。ただし、依存関係が重複するターゲットのセットをビルドする場合は、依然として O(N^2) になります。このエラーは、テスト //foo/tests/... をビルドするとき、または IDE プロジェクトをインポートするときに発生します。

depset の呼び出し回数を減らす

ループ内で depset を呼び出すのは、多くの場合間違いです。これにより、ネストが非常に深い depsets が作成され、パフォーマンスが低下する可能性があります。次に例を示します。

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

このコードは簡単に置き換えることができます。まず、推移的 depsets を収集し、すべてを一度にマージします。

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

リスト内包表記を使用すると、この処理を短縮できる場合があります。

x = depset(transitive = [i.deps for i in inputs])

コマンドラインには ctx.actions.args() を使用する

コマンドラインを作成する場合は、ctx.actions.args() を使用する必要があります。これにより、depsets の展開が実行フェーズに延期されます。

厳密に高速であるだけでなく、ルールのメモリ消費量も削減されます（90% 以上削減されることもあります）。

以下にいくつかの方法をご紹介します。

  • 自分でフラット化するのではなく、depsets とリストを引数として直接渡します。ctx.actions.args() によって展開されます。depset の内容に変換が必要な場合は、ctx.actions.args#add を確認して、適切なものがあるかどうかを確認します。

  • File#path を引数として渡していますか？必要ありません。ファイルはすべて自動的にパスに変換され、展開時に延期されます。

  • 文字列を連結して文字列を構築することは避けてください。文字列引数には定数を使用することをおすすめします。定数のメモリはルールのすべてのインスタンス間で共有されます。

  • コマンドラインで引数が長すぎる場合は、ctx.actions.args#use_param_file を使用して、ctx.actions.args() オブジェクトを条件付きまたは無条件でパラメータ ファイルに書き込むことができます。これは、アクションの実行時にバックグラウンドで行われます。パラメータ ファイルを明示的に制御する必要がある場合は、ctx.actions.write を使用して手動で書き込むことができます。

例:

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

推移的なアクション入力は depsets である必要があります

ctx.actions.run を使用してアクションをビルドする場合、inputs フィールドは depset を受け入れることを忘れないでください。依存関係から推移的に入力が収集される場合は常に使用します。

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

吊り下げ

Bazel がハングしているように見える場合は、Ctrl-\ を押すか、Bazel に SIGQUIT シグナル（kill -3 $(bazel info server_pid)）を送信して、ファイル $(bazel info output_base)/server/jvm.out にスレッド ダンプを取得できます。

bazel がハングアップしている場合は bazel info を実行できない可能性があるため、通常、output_base ディレクトリはワークスペース ディレクトリ内の bazel-<workspace> シンボリック リンクの親ディレクトリになります。

パフォーマンス プロファイリング

JSON トレース プロファイルは、呼び出し中に Bazel が何に時間を費やしたかをすばやく把握するのに非常に役立ちます。

--experimental_command_profile フラグを使用すると、さまざまな種類の Java Flight Recorder プロファイル（CPU 時間、実時間、メモリ割り当て、ロック競合）をキャプチャできます。

--starlark_cpu_profile フラグを使用すると、すべての Starlark スレッドによる CPU 使用率の pprof プロファイルを書き込むことができます。

メモリ プロファイリング

Bazel には、ルールのメモリ使用量を確認するのに役立つメモリ プロファイラが組み込まれています。問題が発生した場合は、ヒープをダンプして、問題の原因となっているコード行を特定できます。

メモリ トラッキングを有効にする

次の 2 つの起動フラグは、Bazel のすべての呼び出しに渡す必要があります。

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.4.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

これらは、メモリ トラッキング モードでサーバーを起動します。これらの値を 1 回でも忘れると、サーバーが再起動し、最初からやり直す必要があります。

メモリ トラッカーの使用

たとえば、ターゲット foo を見て、その動作を確認します。分析のみを実行し、ビルド実行フェーズを実行しないようにするには、--nobuild フラグを追加します。

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

次に、Bazel インスタンス全体のメモリ使用量を確認します。

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

bazel dump --rules を使用してルールクラスごとに分類します。

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

bazel dump --skylark_memory を使用して pprof ファイルを生成し、メモリの使用状況を確認します。

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

pprof ツールを使用してヒープを調べます。まず、pprof -flame $HOME/prof.gz を使用してフレームグラフを取得します。

https://github.com/google/pprof から pprof を取得します。

最もホットなコールサイトのテキスト ダンプを取得し、行で注釈を付けます。

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)