お見逃しなく: BazelCon 2023 は、Google ミュンヘンで 10 月 24 ～ 25 日に開催されます。登録受付を開始しました。 詳細

このページは Cloud Translation API によって翻訳されました。

構成可能なビルド属性

一般に select() と呼ばれる、構成可能な属性は、ユーザーがコマンドラインでビルドルール属性の値を切り替えることができる Bazel の機能です。

たとえば、アーキテクチャに適した実装を自動的に選択するマルチプラットフォームライブラリや、ビルド時にカスタマイズできる機能構成可能なバイナリで使用できます。

例

# myapp/BUILD

cc_binary(
    name = "mybinary",
    srcs = ["main.cc"],
    deps = select({
        ":arm_build": [":arm_lib"],
        ":x86_debug_build": [":x86_dev_lib"],
        "//conditions:default": [":generic_lib"],
    }),
)

config_setting(
    name = "arm_build",
    values = {"cpu": "arm"},
)

config_setting(
    name = "x86_debug_build",
    values = {
        "cpu": "x86",
        "compilation_mode": "dbg",
    },
)

これにより、コマンドラインのフラグに基づいて依存関係を「選択」する cc_binary が宣言されます。具体的には、deps は次のようになります。

コマンド	依存関係 =
`bazel build //myapp:mybinary --cpu=arm`	`[":arm_lib"]`
`bazel build //myapp:mybinary -c dbg --cpu=x86`	`[":x86_dev_lib"]`
`bazel build //myapp:mybinary --cpu=ppc`	`[":generic_lib"]`
`bazel build //myapp:mybinary -c dbg --cpu=ppc`	`[":generic_lib"]`

select() は、構成条件に基づいて選択される値のプレースホルダとして機能します。構成条件は、config_setting ターゲットを参照するラベルです。構成可能な属性で select() を使用すると、異なる条件が保留されている場合に、属性が異なる値を効果的に採用します。

一致は曖昧でなければなりません: 複数の条件が一致する場合、* それらはすべて同じ値に解決されます。たとえば、Linux x86 で実行した場合、どちらのブランチも「hello」に解決されるため、これは曖昧な {"@platforms//os:linux": "Hello", "@platforms//cpu:x86_64": "Hello"} です。* 1 つの values は、他のすべてのクラスの厳密なスーパーセットです。たとえば、values = {"cpu": "x86", "compilation_mode": "dbg"} は values = {"cpu": "x86"} の明確なスペシャライゼーションです。

他には何もない場合、組み込み条件 //conditions:default が自動的に一致します。

この例では deps を使用していますが、select() は、srcs、resources、cmd、その他のほとんどの属性でも同様に機能します。構成不可能な属性はごくわずかで、明確なアノテーションが付けられています。たとえば、config_setting の values 属性は構成できません。

`select()` と依存関係

一部の属性は、ターゲットの下にあるすべての推移的依存関係のビルドパラメータを変更します。たとえば、genrule のtoolsは、Bazel を実行しているマシンの CPU を--cpu変更します（クロスコンパイルのおかげで、ターゲットがビルドされている CPU と異なる場合があります）。これを構成遷移と呼びます。

指定の

#myapp/BUILD

config_setting(
    name = "arm_cpu",
    values = {"cpu": "arm"},
)

config_setting(
    name = "x86_cpu",
    values = {"cpu": "x86"},
)

genrule(
    name = "my_genrule",
    srcs = select({
        ":arm_cpu": ["g_arm.src"],
        ":x86_cpu": ["g_x86.src"],
    }),
    tools = select({
        ":arm_cpu": [":tool1"],
        ":x86_cpu": [":tool2"],
    }),
)

cc_binary(
    name = "tool1",
    srcs = select({
        ":arm_cpu": ["armtool.cc"],
        ":x86_cpu": ["x86tool.cc"],
    }),
)

実行中

$ bazel build //myapp:my_genrule --cpu=arm

x86 デベロッパーマシンにより、ビルドが g_arm.src、tool1、x86tool.cc にバインドされます。my_genrule に接続されている select はどちらも、--cpu=arm を含む my_genrule のビルドパラメータを使用します。tools 属性は、tool1 とその推移的依存関係について --cpu を x86 に変更します。tool1 の select は、tool1 のビルドパラメータ（--cpu=x86 を含む）を使用します。

構成条件

構成可能な属性の各キーは、config_setting または constraint_value への参照ラベルです。

config_setting は、想定されるコマンドラインフラグの設定のコレクションです。ターゲットにカプセル化することで、ユーザーが複数の場所から参照できる「標準的な」条件を維持しやすくなります。

constraint_value は、マルチプラットフォームの動作をサポートしています。

組み込みフラグ

--cpu のようなフラグは Bazel に組み込まれています。ビルドツールは、すべてのプロジェクト内のすべてのビルドについてネイティブに認識します。これらは config_setting の values 属性で指定されます。

config_setting(
    name = "meaningful_condition_name",
    values = {
        "flag1": "value1",
        "flag2": "value2",
        ...
    },
)

flagN はフラグ名です（-- がないため、"--cpu" ではなく "cpu"）。valueN は、そのフラグの想定値です。:meaningful_condition_name は、values のすべてのエントリが一致する場合に一致します。順序が関係ありません。

valueN は、コマンドラインで設定された場合と同様に解析されます。これは次のことを意味します。

bazel build -c opt に一致する values = { "compilation_mode": "opt" }
bazel build --force_pic=1 に一致する values = { "force_pic": "true" }
bazel build --noforce_pic に一致する values = { "force_pic": "0" }

config_setting は、ターゲットの動作に影響するフラグのみをサポートします。たとえば、--show_progress は、Bazel がユーザーに進行状況を報告する方法にのみ影響するため、許可されません。ターゲットは、そのフラグを使用して結果を作成できません。サポートされているフラグの正確なセットは文書化されていません。実際には、「意味がある」というフラグのほとんどは機能します。

カスタムフラグ

Starlark ビルド設定を使用して、独自のプロジェクト固有のフラグをモデル化できます。組み込みフラグとは異なり、これらはビルドターゲットとして定義されるため、Bazel はターゲットラベルで参照します。

これらは config_setting の flag_values 属性でトリガーされます。

config_setting(
    name = "meaningful_condition_name",
    flag_values = {
        "//myflags:flag1": "value1",
        "//myflags:flag2": "value2",
        ...
    },
)

動作は組み込みフラグと同じです。動作例については、こちらをご覧ください。

--define は、カスタムフラグの代替のレガシー構文です（例: --define foo=bar）。これは、values 属性（values = {"define": "foo=bar"}）または define_values 属性（define_values = {"foo": "bar"}）で表現できます。--define は、下位互換性のためにのみサポートされます。可能な限り Starlark ビルド設定を優先する。

values、flag_values、define_values はそれぞれ独立して評価します。config_setting はすべての値に一致する場合に一致します。

デフォルトの条件

他の条件が一致しない場合、組み込み条件 //conditions:default が一致します。

「完全一致」ルールのため、一致がなくデフォルトの条件がない構成可能な属性は "no matching conditions" エラーを出力します。これにより、予期しない設定で発生するサイレント障害から保護できます。

# myapp/BUILD

config_setting(
    name = "x86_cpu",
    values = {"cpu": "x86"},
)

cc_library(
    name = "x86_only_lib",
    srcs = select({
        ":x86_cpu": ["lib.cc"],
    }),
)

$ bazel build //myapp:x86_only_lib --cpu=arm
ERROR: Configurable attribute "srcs" doesn't match this configuration (would
a default condition help?).
Conditions checked:
  //myapp:x86_cpu

より明確なエラーを表示するには、select() の no_match_error 属性を使用してカスタムメッセージを設定します。

プラットフォーム

コマンドラインで複数のフラグを指定すると柔軟性が向上しますが、ターゲットをビルドするたびに個別にフラグを設定するのが手間のかかる場合もあります。プラットフォームを使用すると、これらをシンプルなバンドルに統合できます。

# myapp/BUILD

sh_binary(
    name = "my_rocks",
    srcs = select({
        ":basalt": ["pyroxene.sh"],
        ":marble": ["calcite.sh"],
        "//conditions:default": ["feldspar.sh"],
    }),
)

config_setting(
    name = "basalt",
    constraint_values = [
        ":black",
        ":igneous",
    ],
)

config_setting(
    name = "marble",
    constraint_values = [
        ":white",
        ":metamorphic",
    ],
)

# constraint_setting acts as an enum type, and constraint_value as an enum value.
constraint_setting(name = "color")
constraint_value(name = "black", constraint_setting = "color")
constraint_value(name = "white", constraint_setting = "color")
constraint_setting(name = "texture")
constraint_value(name = "smooth", constraint_setting = "texture")
constraint_setting(name = "type")
constraint_value(name = "igneous", constraint_setting = "type")
constraint_value(name = "metamorphic", constraint_setting = "type")

platform(
    name = "basalt_platform",
    constraint_values = [
        ":black",
        ":igneous",
    ],
)

platform(
    name = "marble_platform",
    constraint_values = [
        ":white",
        ":smooth",
        ":metamorphic",
    ],
)

プラットフォームは、コマンドラインで指定できます。プラットフォームの constraint_values のサブセットを含む config_setting を有効にし、それらの config_setting を select() 式で照合できるようにします。

たとえば、my_rocks の srcs 属性を calcite.sh に設定するには、次のコマンドを実行します。

bazel build //my_app:my_rocks --platforms=//myapp:marble_platform

プラットフォームがない場合は、次のようになります。

bazel build //my_app:my_rocks --define color=white --define texture=smooth --define type=metamorphic

select() は constraint_value を直接読み取ることもできます。

constraint_setting(name = "type")
constraint_value(name = "igneous", constraint_setting = "type")
constraint_value(name = "metamorphic", constraint_setting = "type")
sh_binary(
    name = "my_rocks",
    srcs = select({
        ":igneous": ["igneous.sh"],
        ":metamorphic" ["metamorphic.sh"],
    }),
)

これにより、単一の値のみをチェックするだけでよいため、ボイラープレート config_setting が不要になります。

プラットフォームはまだ開発中です。詳しくは、ドキュメントをご覧ください。

`select()` の組み合わせ

select は同じ属性に複数回指定することができます。

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"] +
           select({
               ":armeabi_mode": ["armeabi_src.sh"],
               ":x86_mode": ["x86_src.sh"],
           }) +
           select({
               ":opt_mode": ["opt_extras.sh"],
               ":dbg_mode": ["dbg_extras.sh"],
           }),
)

select を別の select に含めることはできません。selects をネストする必要があり、属性が他のターゲットを値として受け取る場合は、中間ターゲットを使用します。

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":armeabi_mode": [":armeabi_lib"],
        ...
    }),
)

sh_library(
    name = "armeabi_lib",
    srcs = select({
        ":opt_mode": ["armeabi_with_opt.sh"],
        ...
    }),
)

複数の条件が一致した場合に select を一致させる必要がある場合は、AND 連結の使用を検討してください。

OR チェーン

次の点にご注意ください。

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":config1": [":standard_lib"],
        ":config2": [":standard_lib"],
        ":config3": [":standard_lib"],
        ":config4": [":special_lib"],
    }),
)

ほとんどの条件は同じ依存関係に評価されますが、この構文は読みにくく、メンテナンスが困難です。繰り返しを [":standard_lib"] にしないことをおすすめします。

選択肢の一つは、値を BUILD 変数として事前に定義することです。

STANDARD_DEP = [":standard_lib"]

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":config1": STANDARD_DEP,
        ":config2": STANDARD_DEP,
        ":config3": STANDARD_DEP,
        ":config4": [":special_lib"],
    }),
)

これにより、依存関係を簡単に管理できます。ただし、それでも不要な重複が生じます。

より直接的にサポートするには、次のいずれかを使用します。

`selects.with_or`

Skylib の selects モジュールの with_or マクロは、OR 内で OR 条件を直接サポートしています。

load("@bazel_skylib//lib:selects.bzl", "selects")

sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = selects.with_or({
        (":config1", ":config2", ":config3"): [":standard_lib"],
        ":config4": [":special_lib"],
    }),
)

`selects.config_setting_group`

Skylib の selects モジュールの config_setting_group マクロは、複数の config_setting の OR をサポートします。

load("@bazel_skylib//lib:selects.bzl", "selects")

config_setting(
    name = "config1",
    values = {"cpu": "arm"},
)
config_setting(
    name = "config2",
    values = {"compilation_mode": "dbg"},
)
selects.config_setting_group(
    name = "config1_or_2",
    match_any = [":config1", ":config2"],
)
sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":config1_or_2": [":standard_lib"],
        "//conditions:default": [":other_lib"],
    }),
)

selects.with_or とは異なり、さまざまなターゲットがさまざまな属性で :config1_or_2 を共有できます。

1 つの条件が他と異なるものである場合、またはすべてが同じ値に解決される場合を除いて、複数の条件が一致するのはエラーになります。詳しくは、こちらをご覧ください。

AND 連結

複数の条件が一致した場合に select 分岐が一致する必要がある場合は、Skylib マクロ config_setting_group を使用します。

config_setting(
    name = "config1",
    values = {"cpu": "arm"},
)
config_setting(
    name = "config2",
    values = {"compilation_mode": "dbg"},
)
selects.config_setting_group(
    name = "config1_and_2",
    match_all = [":config1", ":config2"],
)
sh_binary(
    name = "my_target",
    srcs = ["always_include.sh"],
    deps = select({
        ":config1_and_2": [":standard_lib"],
        "//conditions:default": [":other_lib"],
    }),
)

OR チェーンとは異なり、既存の config_setting を select 内で直接 AND にすることはできません。明示的に config_setting_group でラップする必要があります。

カスタムエラーメッセージ

デフォルトでは、条件が一致しない場合、select() がアタッチされているターゲットはエラーで失敗します。

ERROR: Configurable attribute "deps" doesn't match this configuration (would
a default condition help?).
Conditions checked:
  //tools/cc_target_os:darwin
  //tools/cc_target_os:android

これは no_match_error 属性を使用してカスタマイズできます。

cc_library(
    name = "my_lib",
    deps = select(
        {
            "//tools/cc_target_os:android": [":android_deps"],
            "//tools/cc_target_os:windows": [":windows_deps"],
        },
        no_match_error = "Please build with an Android or Windows toolchain",
    ),
)

$ bazel build //myapp:my_lib
ERROR: Configurable attribute "deps" doesn't match this configuration: Please
build with an Android or Windows toolchain

ルールの互換性

ルールの実装では、構成可能な属性の解決値を受け取ります。次に例を示します。

# myapp/BUILD

some_rule(
    name = "my_target",
    some_attr = select({
        ":foo_mode": [":foo"],
        ":bar_mode": [":bar"],
    }),
)

$ bazel build //myapp/my_target --define mode=foo

ルールの実装コードでは、ctx.attr.some_attr が [":foo"] として表示されます。

マクロは、select() 句を受け取ってネイティブルールに渡すことができます。ユーザーが直接操作することはできません。たとえばマクロを変換する手段が

select({"foo": "val"}, ...)

強化する、

select({"foo": "val_with_suffix"}, ...)

これには 2 つの理由があります。

1 つ目は、select がどのパスを選択するのか把握する必要があるマクロは、フラグ値が認識される前に発生する Bazel の読み込みフェーズで評価されるため、機能しません。これは Bazel の設計上の主な制限であり、すぐには変更されない可能性があります。

次に、マクロはすべての select パスを反復処理するだけで済みますが、技術的には可能ですが、一貫性のある UI がありません。これを変更するにはさらに設計が必要です。

Bazel クエリと cquery

Bazel query は Bazel の読み込みフェーズで動作します。つまり、ビルドの後半（分析フェーズ）まで、ターゲットが使用するコマンドラインフラグは認識されません。そのため、どの select() ブランチが選択されているかは判断できません。

Bazel cquery は、Bazel の分析フェーズの後に動作するため、この情報がすべて含まれており、select() を正確に解決できます。

次の点を検討します。

load("@bazel_skylib//rules:common_settings.bzl", "string_flag")

# myapp/BUILD

string_flag(
    name = "dog_type",
    build_setting_default = "cat"
)

cc_library(
    name = "my_lib",
    deps = select({
        ":long": [":foo_dep"],
        ":short": [":bar_dep"],
    }),
)

config_setting(
    name = "long",
    flag_values = {":dog_type": "dachshund"},
)

config_setting(
    name = "short",
    flag_values = {":dog_type": "pug"},
)

query は、:my_lib の依存関係を過大評価します。

$ bazel query 'deps(//myapp:my_lib)'
//myapp:my_lib
//myapp:foo_dep
//myapp:bar_dep

cquery は正確な依存関係を表示します。

$ bazel cquery 'deps(//myapp:my_lib)' --//myapp:dog_type=pug
//myapp:my_lib
//myapp:bar_dep

よくある質問

select() がマクロで機能しないのはなぜですか。

select() はルールで機能します。詳細については、ルールの互換性をご覧ください。

この質問は通常、select() がマクロで機能しないことを主な問題にします。これらはルールとは異なります。違いについては、ルールとマクロのドキュメントをご覧ください。エンドツーエンドの例を以下に示します。

ルールとマクロの定義:

# myapp/defs.bzl

# Rule implementation: when an attribute is read, all select()s have already
# been resolved. So it looks like a plain old attribute just like any other.
def _impl(ctx):
    name = ctx.attr.name
    allcaps = ctx.attr.my_config_string.upper()  # This works fine on all values.
    print("My name is " + name + " with custom message: " + allcaps)

# Rule declaration:
my_custom_bazel_rule = rule(
    implementation = _impl,
    attrs = {"my_config_string": attr.string()},
)

# Macro declaration:
def my_custom_bazel_macro(name, my_config_string):
    allcaps = my_config_string.upper()  # This line won't work with select(s).
    print("My name is " + name + " with custom message: " + allcaps)

ルールとマクロをインスタンス化します。

# myapp/BUILD

load("//myapp:defs.bzl", "my_custom_bazel_rule")
load("//myapp:defs.bzl", "my_custom_bazel_macro")

my_custom_bazel_rule(
    name = "happy_rule",
    my_config_string = select({
        "//tools/target_cpu:x86": "first string",
        "//third_party/bazel_platforms/cpu:ppc": "second string",
    }),
)

my_custom_bazel_macro(
    name = "happy_macro",
    my_config_string = "fixed string",
)

my_custom_bazel_macro(
    name = "sad_macro",
    my_config_string = select({
        "//tools/target_cpu:x86": "first string",
        "//third_party/bazel_platforms/cpu:ppc": "other string",
    }),
)

sad_macro は select() を処理できないため、ビルドは失敗します。

$ bazel build //myapp:all
ERROR: /myworkspace/myapp/BUILD:17:1: Traceback
  (most recent call last):
File "/myworkspace/myapp/BUILD", line 17
my_custom_bazel_macro(name = "sad_macro", my_config_stri..."}))
File "/myworkspace/myapp/defs.bzl", line 4, in
  my_custom_bazel_macro
my_config_string.upper()
type 'select' has no method upper().
ERROR: error loading package 'myapp': Package 'myapp' contains errors.

sad_macro をコメントアウトすると、ビルドが成功します。

# Comment out sad_macro so it doesn't mess up the build.
$ bazel build //myapp:all
DEBUG: /myworkspace/myapp/defs.bzl:5:3: My name is happy_macro with custom message: FIXED STRING.
DEBUG: /myworkspace/myapp/hi.bzl:15:3: My name is happy_rule with custom message: FIRST STRING.

定義によるマクロは、Bazel がビルドのコマンドラインフラグを読み取る前に評価されるため、これを変更することはできません。つまり、select() を評価するのに十分な情報がありません。

ただし、マクロは不透明な blob として select() をルールに渡すことができます。

# myapp/defs.bzl

def my_custom_bazel_macro(name, my_config_string):
    print("Invoking macro " + name)
    my_custom_bazel_rule(
        name = name + "_as_target",
        my_config_string = my_config_string,
    )

$ bazel build //myapp:sad_macro_less_sad
DEBUG: /myworkspace/myapp/defs.bzl:23:3: Invoking macro sad_macro_less_sad.
DEBUG: /myworkspace/myapp/defs.bzl:15:3: My name is sad_macro_less_sad with custom message: FIRST STRING.

select() が常に true を返すのはなぜですか？

定義により（マクロではなく）マクロが select() を評価できないため、評価しようとすると通常エラーになります。

ERROR: /myworkspace/myapp/BUILD:17:1: Traceback
  (most recent call last):
File "/myworkspace/myapp/BUILD", line 17
my_custom_bazel_macro(name = "sad_macro", my_config_stri..."}))
File "/myworkspace/myapp/defs.bzl", line 4, in
  my_custom_bazel_macro
my_config_string.upper()
type 'select' has no method upper().

ブール値は、通知なく失敗する特殊なケースであるため、特に注意する必要があります。

$ cat myapp/defs.bzl
def my_boolean_macro(boolval):
  print("TRUE" if boolval else "FALSE")

$ cat myapp/BUILD
load("//myapp:defs.bzl", "my_boolean_macro")
my_boolean_macro(
    boolval = select({
        "//tools/target_cpu:x86": True,
        "//third_party/bazel_platforms/cpu:ppc": False,
    }),
)

$ bazel build //myapp:all --cpu=x86
DEBUG: /myworkspace/myapp/defs.bzl:4:3: TRUE.
$ bazel build //mypro:all --cpu=ppc
DEBUG: /myworkspace/myapp/defs.bzl:4:3: TRUE.

これは、マクロが select() の内容を認識しないためです。評価するのは select() オブジェクト自体です。Pythonic 設計標準によると、ごく一部の例外を除くすべてのオブジェクトは自動的に true を返します。

select() を辞書のように読み取ることはできますか？

Bazel はビルドのコマンドラインパラメータを認識する前にマクロを評価するため、選択内容は評価できません。たとえば、少なくとも select() の辞書を読み取り、それぞれの値に接尾辞を追加できますか。

概念的には可能ですが、Bazel 機能にはまだ対応していません。今すぐできることは、直線辞書を作成して select() にフィードすることです。

$ cat myapp/defs.bzl
def selecty_genrule(name, select_cmd):
  for key in select_cmd.keys():
    select_cmd[key] += " WITH SUFFIX"
  native.genrule(
      name = name,
      outs = [name + ".out"],
      srcs = [],
      cmd = "echo " + select(select_cmd + {"//conditions:default": "default"})
        + " > $@"
  )

$ cat myapp/BUILD
selecty_genrule(
    name = "selecty",
    select_cmd = {
        "//tools/target_cpu:x86": "x86 mode",
    },
)

$ bazel build //testapp:selecty --cpu=x86 && cat bazel-genfiles/testapp/selecty.out
x86 mode WITH SUFFIX

select() とネイティブタイプの両方をサポートする場合は、次の操作を行います。

$ cat myapp/defs.bzl
def selecty_genrule(name, select_cmd):
    cmd_suffix = ""
    if type(select_cmd) == "string":
        cmd_suffix = select_cmd + " WITH SUFFIX"
    elif type(select_cmd) == "dict":
        for key in select_cmd.keys():
            select_cmd[key] += " WITH SUFFIX"
        cmd_suffix = select(select_cmd + {"//conditions:default": "default"})

    native.genrule(
        name = name,
        outs = [name + ".out"],
        srcs = [],
        cmd = "echo " + cmd_suffix + "> $@",
    )

select() が bind() で動作しないのはなぜですか？

bind() は WORKSPACE ルールであるため、BUILD ルールではありません。

Workspace ルールに特定の構成はなく、BUILD ルールと同じように評価されません。そのため、bind() 内の select() は、実際に特定のブランチに対して評価することはできません。

このタイプのランタイム決定を行うには、alias() を使用して、actual 属性で select() を指定する必要があります。alias() は BUILD ルールであり、特定の構成で評価されるため、これは正しく機能します。

必要に応じて、bind() ターゲットポイントに alias() を指定することもできます。

$ cat WORKSPACE
workspace(name = "myapp")
bind(name = "openssl", actual = "//:ssl")
http_archive(name = "alternative", ...)
http_archive(name = "boringssl", ...)

$ cat BUILD
config_setting(
    name = "alt_ssl",
    define_values = {
        "ssl_library": "alternative",
    },
)

alias(
    name = "ssl",
    actual = select({
        "//:alt_ssl": "@alternative//:ssl",
        "//conditions:default": "@boringssl//:ssl",
    }),
)

この設定では、--define ssl_library=alternative を渡すことができます。//:ssl または //external:ssl に依存するターゲットは、@alternative//:ssl にあるものを確認できます。

select() が期待どおりに選択しないのはなぜですか？

//myapp:foo の select() で想定する条件を選択していない場合は、cquery と bazel config を使用してデバッグします。

ビルドの最上位のターゲットが //myapp:foo の場合は、次のコマンドを実行します。

$ bazel cquery //myapp:foo <desired build flags>
//myapp:foo (12e23b9a2b534a)

サブグラフ内の任意の場所で //myapp:foo に依存する他の //bar をビルドする場合は、次のコマンドを実行します。

$ bazel cquery 'somepath(//bar, //myapp:foo)' <desired build flags>
//bar:bar   (3ag3193fee94a2)
//bar:intermediate_dep (12e23b9a2b534a)
//myapp:foo (12e23b9a2b534a)

//myapp:foo の横にある (12e23b9a2b534a) は、//myapp:foo の select() を解決する構成のハッシュです。値は bazel config で確認できます。

$ bazel config 12e23b9a2b534a
BuildConfigurationValue 12e23b9a2b534a
Fragment com.google.devtools.build.lib.analysis.config.CoreOptions {
  cpu: darwin
  compilation_mode: fastbuild
  ...
}
Fragment com.google.devtools.build.lib.rules.cpp.CppOptions {
  linkopt: [-Dfoo=bar]
  ...
}
...

この出力を、各 config_setting で想定される設定と比較します。

//myapp:foo は、同じビルドの異なる構成に存在する場合があります。somepath を使用して適切なものを取得する方法については、cquery docs をご覧ください。

`select()` がプラットフォームと連携しないのはなぜですか？

セマンティクスが不明であるため、Bazel は、特定のプラットフォームがターゲットプラットフォームであるかどうかをチェックする構成可能な属性をサポートしていません。

例:

platform(
    name = "x86_linux_platform",
    constraint_values = [
        "@platforms//cpu:x86",
        "@platforms//os:linux",
    ],
)

cc_library(
    name = "lib",
    srcs = [...],
    linkopts = select({
        ":x86_linux_platform": ["--enable_x86_optimizations"],
        "//conditions:default": [],
    }),
)

この BUILD ファイルで、ターゲットプラットフォームに @platforms//cpu:x86 と @platforms//os:linux の両方の制約があり、ここで :x86_linux_platform が定義されていない場合、どの select() を使用する必要がありますか？BUILD ファイルの作成者と個別のプラットフォームを定義したユーザーのアイデアは異なる場合があります。

別の方法があれば教えてください。

代わりに、次の制約のある任意のプラットフォームに一致する config_setting を定義します。

config_setting(
    name = "is_x86_linux",
    constraint_values = [
        "@platforms//cpu:x86",
        "@platforms//os:linux",
    ],
)

cc_library(
    name = "lib",
    srcs = [...],
    linkopts = select({
        ":is_x86_linux": ["--enable_x86_optimizations"],
        "//conditions:default": [],
    }),
)

このプロセスは特定のセマンティクスを定義して、どのプラットフォームが目的の条件を満たしているかを明確にします。

プラットフォームで YouTube を`select`したい場合は、

ビルド要件でプラットフォームの確認が特に必要な場合は、config_setting で --platforms フラグの値を反転できます。

config_setting(
    name = "is_specific_x86_linux_platform",
    values = {
        "platforms": ["//package:x86_linux_platform"],
    },
)

cc_library(
    name = "lib",
    srcs = [...],
    linkopts = select({
        ":is_specific_x86_linux_platform": ["--enable_x86_optimizations"],
        "//conditions:default": [],
    }),
)

Bazel チームは、このような作業を推奨していません。ビルドが過度に制限され、期待される条件が一致しない場合、ユーザーを混乱させます。