工具链

报告问题open_in_new 查看源代码open_in_new 每夜 build · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

本页介绍了工具链框架，规则作者可以通过该框架将规则逻辑与基于平台的工具选择解耦。建议您先阅读规则和平台页面，然后再继续。本页介绍了为何需要工具链、如何定义和使用工具链，以及 Bazel 如何根据平台限制条件选择适当的工具链。

设计初衷

我们先来看看工具链旨在解决的问题。假设您要编写规则来支持“bar”编程语言。您的 bar_binary 规则将使用 barc 编译器编译 *.bar 文件，该工具本身会在您的工作区中构建为另一个目标。由于编写 bar_binary 目标的用户不必指定对编译器的依赖项，因此您可以将其作为私有属性添加到规则定义中，使其成为隐式依赖项。

bar_binary = rule(
    implementation = _bar_binary_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = True),
        ...
        "_compiler": attr.label(
            default = "//bar_tools:barc_linux",  # the compiler running on linux
            providers = [BarcInfo],
        ),
    },
)

//bar_tools:barc_linux 现在是每个 bar_binary 目标的依赖项，因此它将在任何 bar_binary 目标之前构建。它可以像任何其他属性一样由规则的实现函数访问：

BarcInfo = provider(
    doc = "Information about how to invoke the barc compiler.",
    # In the real world, compiler_path and system_lib might hold File objects,
    # but for simplicity they are strings for this example. arch_flags is a list
    # of strings.
    fields = ["compiler_path", "system_lib", "arch_flags"],
)

def _bar_binary_impl(ctx):
    ...
    info = ctx.attr._compiler[BarcInfo]
    command = "%s -l %s %s" % (
        info.compiler_path,
        info.system_lib,
        " ".join(info.arch_flags),
    )
    ...

这里的问题是，编译器的标签会硬编码到 bar_binary 中，但不同的目标可能需要不同的编译器，具体取决于它们要针对哪个平台构建以及在哪个平台上构建（分别称为目标平台和执行平台）。此外，规则作者甚至不一定知道所有可用工具和平台，因此无法在规则定义中对其进行硬编码。

一个不太理想的解决方案是，将 _compiler 属性设为非私密属性，将负担转移给用户。然后，可以对各个目标进行硬编码，以便针对某个平台进行构建。

bar_binary(
    name = "myprog_on_linux",
    srcs = ["mysrc.bar"],
    compiler = "//bar_tools:barc_linux",
)

bar_binary(
    name = "myprog_on_windows",
    srcs = ["mysrc.bar"],
    compiler = "//bar_tools:barc_windows",
)

您可以使用 select 根据平台选择 compiler，从而改进此解决方案：

config_setting(
    name = "on_linux",
    constraint_values = [
        "@platforms//os:linux",
    ],
)

config_setting(
    name = "on_windows",
    constraint_values = [
        "@platforms//os:windows",
    ],
)

bar_binary(
    name = "myprog",
    srcs = ["mysrc.bar"],
    compiler = select({
        ":on_linux": "//bar_tools:barc_linux",
        ":on_windows": "//bar_tools:barc_windows",
    }),
)

但这很繁琐，而且要求每个 bar_binary 用户都执行此操作有点过分。如果在整个工作区中未一致使用此样式，则会导致 build 在单个平台上运行良好，但在扩展到多平台场景时失败。它也无法解决在不修改现有规则或目标的情况下添加对新平台和编译器的支持的问题。

工具链框架通过添加额外的间接层来解决此问题。本质上，您声明规则对目标系列（工具链类型）的某个成员具有抽象依赖项，然后 Bazel 会根据适用的平台约束条件自动将其解析为特定目标（工具链）。规则作者和目标作者都无需了解完整的平台和工具链。

编写使用工具链的规则

在工具链框架下，规则依赖于工具链类型，而不是直接依赖于工具。工具链类型是一种简单的目标，表示一类为不同平台提供相同角色的工具。例如，您可以声明一个表示 bar 编译器的类型：

# By convention, toolchain_type targets are named "toolchain_type" and
# distinguished by their package path. So the full path for this would be
# //bar_tools:toolchain_type.
toolchain_type(name = "toolchain_type")

修改了上一部分中的规则定义，使其声明使用 //bar_tools:toolchain_type 工具链，而不是将编译器作为属性纳入。

bar_binary = rule(
    implementation = _bar_binary_impl,
    attrs = {
        "srcs": attr.label_list(allow_files = True),
        ...
        # No `_compiler` attribute anymore.
    },
    toolchains = ["//bar_tools:toolchain_type"],
)

实现函数现在会使用工具链类型作为键，在 ctx.toolchains（而非 ctx.attr）下访问此依赖项。

def _bar_binary_impl(ctx):
    ...
    info = ctx.toolchains["//bar_tools:toolchain_type"].barcinfo
    # The rest is unchanged.
    command = "%s -l %s %s" % (
        info.compiler_path,
        info.system_lib,
        " ".join(info.arch_flags),
    )
    ...

ctx.toolchains["//bar_tools:toolchain_type"] 会返回 Bazel 将工具链依赖项解析到的任何目标的 ToolchainInfo 提供程序。ToolchainInfo 对象的字段由底层工具的规则设置；在下一部分中，我们将定义此规则，使其包含一个封装 BarcInfo 对象的 barcinfo 字段。

下文介绍了 Bazel 将工具链解析为目标的过程。只有已解析的工具链目标才会实际成为 bar_binary 目标的依赖项，而不是候选工具链的整个空间。

必需和可选工具链

默认情况下，当规则使用裸标签（如上所示）表达工具链类型依赖项时，工具链类型会被视为必需。如果 Bazel 无法为强制性工具链类型找到匹配的工具链（请参阅下文中的工具链解析），则会出现错误，并且分析会停止。

您也可以声明可选的工具链类型依赖项，如下所示：

bar_binary = rule(
    ...
    toolchains = [
        config_common.toolchain_type("//bar_tools:toolchain_type", mandatory = False),
    ],
)

如果无法解析可选的工具链类型，分析会继续，并且 ctx.toolchains["//bar_tools:toolchain_type"] 的结果为 None。

config_common.toolchain_type 函数默认设为必需。

您可以使用以下表单：

• 强制性工具链类型：
  • toolchains = ["//bar_tools:toolchain_type"]
  • toolchains = [config_common.toolchain_type("//bar_tools:toolchain_type")]
  • toolchains = [config_common.toolchain_type("//bar_tools:toolchain_type", mandatory = True)]
• 可选的工具链类型：
  • toolchains = [config_common.toolchain_type("//bar_tools:toolchain_type", mandatory = False)]

bar_binary = rule(
    ...
    toolchains = [
        "//foo_tools:toolchain_type",
        config_common.toolchain_type("//bar_tools:toolchain_type", mandatory = False),
    ],
)

您还可以在同一规则中混合使用这些形式。不过，如果同一工具链类型被列出多次，则系统会采用最严格的版本，其中必需的版本比可选的版本更严格。

使用工具链编写方面的内容

与规则一样，方面可以访问相同的工具链 API：您可以定义所需的工具链类型、通过上下文访问工具链，并使用这些工具链生成新的操作。

bar_aspect = aspect(
    implementation = _bar_aspect_impl,
    attrs = {},
    toolchains = ['//bar_tools:toolchain_type'],
)

def _bar_aspect_impl(target, ctx):
  toolchain = ctx.toolchains['//bar_tools:toolchain_type']
  # Use the toolchain provider like in a rule.
  return []

定义工具链

如需为给定工具链类型定义一些工具链，您需要满足以下三个条件：

1. 一种特定于语言的规则，表示工具或工具套件的类型。按照惯例，此规则的名称以“_toolchain”结尾。

   1. 注意：\_toolchain 规则无法创建任何 build 操作。而是会从其他规则收集工件，并将其转发给使用该工具链的规则。该规则负责创建所有 build 操作。

2. 此规则类型的多个目标，表示适用于不同平台的工具或工具套件的版本。

3. 对于每个此类目标，通用 toolchain 规则的关联目标，用于提供工具链框架使用的元数据。此 toolchain 目标还指与此工具链关联的 toolchain_type。这意味着，给定的 _toolchain 规则可以与任何 toolchain_type 相关联，并且只有在使用此 _toolchain 规则的 toolchain 实例中，该规则才与 toolchain_type 相关联。

下面是运行示例的 bar_toolchain 规则定义。我们的示例只有一个编译器，但也可以在其下方分组其他工具，例如链接器。

def _bar_toolchain_impl(ctx):
    toolchain_info = platform_common.ToolchainInfo(
        barcinfo = BarcInfo(
            compiler_path = ctx.attr.compiler_path,
            system_lib = ctx.attr.system_lib,
            arch_flags = ctx.attr.arch_flags,
        ),
    )
    return [toolchain_info]

bar_toolchain = rule(
    implementation = _bar_toolchain_impl,
    attrs = {
        "compiler_path": attr.string(),
        "system_lib": attr.string(),
        "arch_flags": attr.string_list(),
    },
)

该规则必须返回一个 ToolchainInfo 提供程序，该提供程序将成为使用 ctx.toolchains 和工具链类型的标签检索的对象。与 struct 一样，ToolchainInfo 可以包含任意字段-值对。应在工具链类型中明确记录要向 ToolchainInfo 添加的确切字段。在此示例中，返回的值封装在 BarcInfo 对象中，以重复使用上面定义的架构；这种样式可能对验证和代码重用很有用。

现在，您可以为特定 barc 编译器定义目标。

bar_toolchain(
    name = "barc_linux",
    arch_flags = [
        "--arch=Linux",
        "--debug_everything",
    ],
    compiler_path = "/path/to/barc/on/linux",
    system_lib = "/usr/lib/libbarc.so",
)

bar_toolchain(
    name = "barc_windows",
    arch_flags = [
        "--arch=Windows",
        # Different flags, no debug support on windows.
    ],
    compiler_path = "C:\\path\\on\\windows\\barc.exe",
    system_lib = "C:\\path\\on\\windows\\barclib.dll",
)

最后，您需要为两个 bar_toolchain 目标创建 toolchain 定义。这些定义会将特定于语言的目标与工具链类型相关联，并提供约束条件信息，以告知 Bazel 何时工具链适用于给定平台。

toolchain(
    name = "barc_linux_toolchain",
    exec_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    target_compatible_with = [
        "@platforms//os:linux",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":barc_linux",
    toolchain_type = ":toolchain_type",
)

toolchain(
    name = "barc_windows_toolchain",
    exec_compatible_with = [
        "@platforms//os:windows",
        "@platforms//cpu:x86_64",
    ],
    target_compatible_with = [
        "@platforms//os:windows",
        "@platforms//cpu:x86_64",
    ],
    toolchain = ":barc_windows",
    toolchain_type = ":toolchain_type",
)

上述使用相对路径语法表明这些定义都位于同一软件包中，但没有理由不能将工具链类型、特定于语言的工具链目标和 toolchain 定义目标都放在单独的软件包中。

如需查看实际示例，请参阅 go_toolchain。

工具链和配置

规则作者面临的一个重要问题是，在分析 bar_toolchain 目标时，它会看到哪些配置，以及应对依赖项使用哪些转换？上面的示例使用了字符串属性，但对于依赖于 Bazel 代码库中的其他目标的更复杂的工具链，会发生什么情况？

我们来看看更复杂的 bar_toolchain 版本：

def _bar_toolchain_impl(ctx):
    # The implementation is mostly the same as above, so skipping.
    pass

bar_toolchain = rule(
    implementation = _bar_toolchain_impl,
    attrs = {
        "compiler": attr.label(
            executable = True,
            mandatory = True,
            cfg = "exec",
        ),
        "system_lib": attr.label(
            mandatory = True,
            cfg = "target",
        ),
        "arch_flags": attr.string_list(),
    },
)

attr.label 的使用方式与标准规则相同，但 cfg 参数的含义略有不同。

通过工具链解析将目标（称为“父级”）与工具链相关联的依赖项使用了一种称为“工具链转换”的特殊配置转换。工具链转换会保持配置不变，但会强制工具链的执行平台与父级相同（否则，工具链的工具链解析可能会选择任何执行平台，而不会一定与父级相同）。这样一来，toolchain 的任何 exec 依赖项也可以针对父级的 build 操作执行。工具链中使用 cfg = "target" 的任何依赖项（或未指定 cfg，因为“target”是默认值）都将针对与父级相同的目标平台构建。这样一来，工具链规则就可以向需要它们的 build 规则提供库（上面的 system_lib 属性）和工具（compiler 属性）。系统库会链接到最终工件，因此需要针对同一平台进行构建，而编译器是构建期间调用的工具，需要能够在执行平台上运行。

使用工具链进行注册和构建

至此，所有构建块都已组装完毕，您只需将工具链提供给 Bazel 的解析过程即可。为此，您可以使用 register_toolchains() 在 MODULE.bazel 文件中注册工具链，也可以使用 --extra_toolchains 标志在命令行上传递工具链的标签。

register_toolchains(
    "//bar_tools:barc_linux_toolchain",
    "//bar_tools:barc_windows_toolchain",
    # Target patterns are also permitted, so you could have also written:
    # "//bar_tools:all",
    # or even
    # "//bar_tools/...",
)

使用目标模式注册工具链时，各个工具链的注册顺序由以下规则决定：

• 在软件包的子软件包中定义的工具链会在软件包本身中定义的工具链之前注册。
• 在软件包中，工具链会按其名称的字典顺序注册。

现在，当您构建依赖于工具链类型的目标时，系统会根据目标平台和执行平台选择适当的工具链。

# my_pkg/BUILD

platform(
    name = "my_target_platform",
    constraint_values = [
        "@platforms//os:linux",
    ],
)

bar_binary(
    name = "my_bar_binary",
    ...
)

bazel build //my_pkg:my_bar_binary --platforms=//my_pkg:my_target_platform

Bazel 会看到 //my_pkg:my_bar_binary 是使用具有 @platforms//os:linux 的平台构建的，因此会将 //bar_tools:toolchain_type 引用解析为 //bar_tools:barc_linux_toolchain。这最终会构建 //bar_tools:barc_linux，但不会构建 //bar_tools:barc_windows。

工具链解析

对于使用工具链的每个目标，Bazel 的工具链解析过程都会确定目标的具体工具链依赖项。该过程将一组必需的工具链类型、目标平台、可用执行平台列表和可用工具链列表作为输入。其输出是每个工具链类型的所选工具链，以及当前目标的所选执行平台。

可用的执行平台和工具链是通过 MODULE.bazel 文件中的 register_execution_platforms 和 register_toolchains 调用从外部依赖项图中收集的。您还可以在命令行中通过 --extra_execution_platforms 和 --extra_toolchains 指定其他执行平台和工具链。宿主平台会自动作为可用执行平台包含在内。可用平台和工具链会以有序列表的形式进行跟踪，以实现确定性，并优先考虑列表中的前几项。

系统会根据 --extra_toolchains 和 register_toolchains 创建一组可用工具链（按优先级排序）：

1. 系统会先添加使用 --extra_toolchains 注册的工具链。（其中，最后的工具链具有最高优先级。）
2. 在传递的外部依赖项图中使用 register_toolchains 注册的工具链，按以下顺序排列：（其中，首先提及的工具链具有最高优先级。）
   1. 由根模块注册的工具链（例如，工作区根目录中的 MODULE.bazel）；
   2. 在用户的 WORKSPACE 文件中注册的工具链，包括从中调用的任何宏；
   3. 由非根模块注册的工具链（例如，根模块指定的依赖项及其依赖项等）；
   4. 在“WORKSPACE 后缀”中注册的工具链；这仅供与 Bazel 安装捆绑的某些原生规则使用。

注意：:all、:* 和 /... 等伪目标的排序由 Bazel 的软件包加载机制决定，该机制使用字典顺序。

解决步骤如下。

1. 如果平台也具有列表中的每个 constraint_value（显式或默认），则 target_compatible_with 或 exec_compatible_with 子句与该平台匹配。constraint_value

   如果平台具有来自 constraint_setting 的 constraint_value，而该子句未引用这些 constraint_setting，则这些 constraint_value 不会影响匹配。

2. 如果要构建的目标指定了 exec_compatible_with 属性（或其规则定义指定了 exec_compatible_with 参数），系统会过滤可用执行平台列表，以移除不符合执行限制条件的平台。

3. 系统会过滤可用工具链列表，以移除与当前配置不匹配的所有指定 target_settings 的工具链。

4. 对于每个可用的执行平台，您可以将每种工具链类型与第一个与此执行平台和目标平台兼容的可用工具链（如果有）相关联。

5. 如果任何执行平台都未能为其某种工具链类型找到兼容的强制性工具链，则会被排除。在剩余的平台中，第一个平台会成为当前目标的执行平台，其关联的工具链（如果有）会成为目标的依赖项。

所选的执行平台用于运行目标生成的所有操作。

如果同一目标可以在同一 build 中采用多种配置（例如针对不同的 CPU）进行构建，则解析过程会独立应用于目标的每个版本。

如果规则使用执行组，则每个执行组都会单独执行工具链解析，并且每个执行组都有自己的执行平台和工具链。

调试工具链

如果您要为现有规则添加工具链支持，请使用 --toolchain_resolution_debug=regex 标志。在工具链解析期间，该标志会针对与正则表达式变量匹配的工具链类型或目标名称提供详细输出。您可以使用 .* 输出所有信息。Bazel 会输出在解析过程中检查和跳过的工具链的名称。

如果您想查看哪些 cquery 依赖项来自工具链解析，请使用 cquery 的 --transitions 标志：

# Find all direct dependencies of //cc:my_cc_lib. This includes explicitly
# declared dependencies, implicit dependencies, and toolchain dependencies.
$ bazel cquery 'deps(//cc:my_cc_lib, 1)'
//cc:my_cc_lib (96d6638)
@bazel_tools//tools/cpp:toolchain (96d6638)
@bazel_tools//tools/def_parser:def_parser (HOST)
//cc:my_cc_dep (96d6638)
@local_config_platform//:host (96d6638)
@bazel_tools//tools/cpp:toolchain_type (96d6638)
//:default_host_platform (96d6638)
@local_config_cc//:cc-compiler-k8 (HOST)
//cc:my_cc_lib.cc (null)
@bazel_tools//tools/cpp:grep-includes (HOST)

# Which of these are from toolchain resolution?
$ bazel cquery 'deps(//cc:my_cc_lib, 1)' --transitions=lite | grep "toolchain dependency"
  [toolchain dependency]#@local_config_cc//:cc-compiler-k8#HostTransition -> b6df211