ビルドの一環としてツールを実行する必要があるとします。たとえば、ソースファイルを生成または前処理したり、バイナリを圧縮したりできます。このチュートリアルでは、画像のサイズを変更するマクロを作成します。
マクロはシンプルなタスクに適しています。新しいプログラミング言語のサポートを追加するなど、より複雑な作業を行う場合は、ルールの作成を検討してください。ルールを使用すると、詳細に管理して柔軟性を高めることができます。
画像のサイズを変更するマクロを作成する最も簡単な方法は、genrule
を使用することです。
genrule(
name = "logo_miniature",
srcs = ["logo.png"],
outs = ["small_logo.png"],
cmd = "convert $< -resize 100x100 $@",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)
他の画像のサイズを変更する必要がある場合は、コードを再利用することをおすすめします。これを行うには、別の .bzl
ファイルで関数を定義し、miniature.bzl
ファイルを呼び出します。
def miniature(name, src, size="100x100", **kwargs):
"""Create a miniature of the src image.
The generated file is prefixed with 'small_'.
"""
native.genrule(
name = name,
srcs = [src],
outs = ["small_" + src],
cmd = "convert $< -resize " + size + " $@",
**kwargs
)
注意点:
規則と同様に、マクロにはルールと同じように
name
引数があります。マクロの動作をドキュメント化するには、Python と同様に docstring を使用します。
genrule
またはその他のネイティブ ルールを呼び出すには、native.
を使用します。**kwargs
を使用して、追加の引数を基盤となるgenrule
に転送します(Python と同様です)。これは、ユーザーがvisibility
やtags
などの標準属性を使用できる場合に便利です。
次に、BUILD
ファイルのマクロを使用します。
load("//path/to:miniature.bzl", "miniature")
miniature(
name = "logo_miniature",
src = "image.png",
)
cc_binary(
name = "my_app",
srcs = ["my_app.cc"],
data = [":logo_miniature"],
)