一般的な C++ ビルドのユースケース

ここでは、Bazel で C++ プロジェクトをビルドするための最も一般的なユースケースをいくつか紹介します。まだ行っていない場合は、チュートリアル Bazel の概要: C++ プロジェクトの構築を完了して、Bazel で C++ プロジェクトを構築します。

cc_library と hdrs のヘッダーファイルについて詳しくは、cc_library をご覧ください。

ターゲットに複数のファイルを含める

glob では、1 つのターゲットに複数のファイルを含めることができます。例:

cc_library(
    name = "build-all-the-files",
    srcs = glob(["*.cc"]),
    hdrs = glob(["*.h"]),
)

このターゲットを使用すると、Bazel は、このターゲットを含む BUILD ファイルと同じディレクトリ（サブディレクトリを除く）にある .cc ファイルと .h ファイルをすべてビルドします。

推移的インクルードの使用

ファイルにヘッダーが含まれている場合、そのファイルがソースである（つまり、srcs、hdrs、または textual_hdrs 属性にそのファイルがある）ルールは、含まれるヘッダーのライブラリルールによって異なります。逆に、依存関係として直接依存関係のみを指定する必要があります。たとえば、sandwich.h に bread.h が含まれ、bread.h に flour.h が含まれているとします。sandwich.h には flour.h（サンドイッチに入れる小麦粉が必要な人）が含まれていないため、BUILD ファイルは次のようになります。

cc_library(
    name = "sandwich",
    srcs = ["sandwich.cc"],
    hdrs = ["sandwich.h"],
    deps = [":bread"],
)

cc_library(
    name = "bread",
    srcs = ["bread.cc"],
    hdrs = ["bread.h"],
    deps = [":flour"],
)

cc_library(
    name = "flour",
    srcs = ["flour.cc"],
    hdrs = ["flour.h"],
)

ここでは、sandwich ライブラリは flour ライブラリに依存する bread ライブラリに依存しています。

インクルードパスの追加

場合によっては、ワークスペースのルートにルートを含めることができない（またはしたくない）ことがあります。既存のライブラリには、ワークスペースのパスと一致しないインクルードディレクトリがすでに存在している場合があります。たとえば、次のディレクトリ構造があるとします。

└── my-project
    ├── legacy
    │   └── some_lib
    │       ├── BUILD
    │       ├── include
    │       │   └── some_lib.h
    │       └── some_lib.cc
    └── WORKSPACE

Bazel は some_lib.h を legacy/some_lib/include/some_lib.h として想定しますが、some_lib.cc に "some_lib.h" が含まれているとします。インクルードパスを有効にするには、legacy/some_lib/BUILD で some_lib/include ディレクトリがインクルードディレクトリであることを指定する必要があります。

cc_library(
    name = "some_lib",
    srcs = ["some_lib.cc"],
    hdrs = ["include/some_lib.h"],
    copts = ["-Ilegacy/some_lib/include"],
)

特に、外部依存関係の場合、ヘッダーファイルに / 接頭辞を付ける必要があるため、これが便利です。

外部ライブラリのインクルード

Google Test を使用しているとします。WORKSPACE ファイル内のリポジトリ関数のいずれかを使用して Google Test をダウンロードし、リポジトリで利用できるようにすることができます。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
)

次に、Google Test のコンパイルに使用する BUILD ファイル gtest.BUILD を作成します。Google Test には、次のような cc_library ルールを複雑にする「特別な」要件があります。

googletest-release-1.10.0/src/ 内の googletest-release-1.10.0/src/gtest-all.cc #include の他のすべてのファイル: 重複シンボルのリンクエラーを防ぐために、コンパイルから除外します。
googletest-release-1.10.0/include/ ディレクトリからの相対ヘッダーファイル（"gtest/gtest.h"）を使用するため、そのディレクトリをインクルードパスに追加する必要があります。
pthread でリンクする必要があるため、linkopt として追加します。

最終的なルールは以下のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["googletest-release-1.10.0/src/*.cc"],
        exclude = ["googletest-release-1.10.0/src/gtest-all.cc"]
    ),
    hdrs = glob([
        "googletest-release-1.10.0/include/**/*.h",
        "googletest-release-1.10.0/src/*.h"
    ]),
    copts = [
        "-Iexternal/gtest/googletest-release-1.10.0/include",
        "-Iexternal/gtest/googletest-release-1.10.0"
    ],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

これは多少わかりにくい点です。アーカイブ構造の副産物として、すべてに googletest-release-1.10.0 という接頭辞が付加されます。strip_prefix 属性を追加して、この接頭辞を http_archive から削除できます。

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

http_archive(
    name = "gtest",
    url = "https://github.com/google/googletest/archive/release-1.10.0.zip",
    sha256 = "94c634d499558a76fa649edb13721dce6e98fb1e7018dfaeba3cd7a083945e91",
    build_file = "@//:gtest.BUILD",
    strip_prefix = "googletest-release-1.10.0",
)

gtest.BUILD は次のようになります。

cc_library(
    name = "main",
    srcs = glob(
        ["src/*.cc"],
        exclude = ["src/gtest-all.cc"]
    ),
    hdrs = glob([
        "include/**/*.h",
        "src/*.h"
    ]),
    copts = ["-Iexternal/gtest/include"],
    linkopts = ["-pthread"],
    visibility = ["//visibility:public"],
)

cc_ ルールが @gtest//:main に依存するようになりました。

C++ テストを作成して実行する

たとえば、次のようにテスト ./test/hello-test.cc を作成します。

#include "gtest/gtest.h"
#include "main/hello-greet.h"

TEST(HelloTest, GetGreet) {
  EXPECT_EQ(get_greet("Bazel"), "Hello Bazel");
}

テスト用の ./test/BUILD ファイルを作成します。

cc_test(
    name = "hello-test",
    srcs = ["hello-test.cc"],
    copts = ["-Iexternal/gtest/include"],
    deps = [
        "@gtest//:main",
        "//main:hello-greet",
    ],
)

hello-greet を hello-test に表示するには、"//test:__pkg__", を ./main/BUILD の visibility 属性に追加する必要があります。

これで、bazel test を使用してテストを実行できます。

bazel test test:hello-test

これにより、次の出力が生成されます。

INFO: Found 1 test target...
Target //test:hello-test up-to-date:
  bazel-bin/test/hello-test
INFO: Elapsed time: 4.497s, Critical Path: 2.53s
//test:hello-test PASSED in 0.3s

Executed 1 out of 1 tests: 1 test passes.

プリコンパイル済みライブラリへの依存関係の追加

コンパイル済みバージョン（ヘッダーや .so ファイルなど）しかないライブラリを使用する場合は、cc_library ルールでラップします。

cc_library(
    name = "mylib",
    srcs = ["mylib.so"],
    hdrs = ["mylib.h"],
)

このようにして、ワークスペース内の他の C++ ターゲットはこのルールに依存できます。