このページは Cloud Translation API によって翻訳されました。

Bazel で Android Native Development Kit を使用する

Bazel を初めて使用する場合は、まず Bazel を使用した Android のビルドのチュートリアルをご覧ください。

概要

Bazel は、Android Native Development Kit（NDK）ツールチェーンを使用するビルド構成を含め、さまざまなビルド構成で実行できます。つまり、通常の cc_library ルールと cc_binary ルールは、Bazel 内で直接 Android 向けにコンパイルできます。Bazel では、android_ndk_repository リポジトリルールを使用してこれを実現します。

前提条件

Android SDK と NDK がインストールされていることを確認してください。

SDK と NDK をセットアップするには、次のスニペットを WORKSPACE に追加します。

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

android_ndk_repository ルールの詳細については、Build Encyclopedia のエントリをご覧ください。

クイックスタート

cc_library 依存関係を android_binary ルールまたは android_library ルールに追加するだけで、C++ for Android をビルドすることができます。

たとえば、Android アプリの次の BUILD ファイルがあるとします。

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

この BUILD ファイルにより、次のターゲットグラフが生成されます。

検索結果の例

図 1. cc_library の依存関係を持つ Android プロジェクトのビルドグラフ。

アプリをビルドするには、次のコマンドを実行します。

bazel build //app/src/main:app

bazel build コマンドは、Java ファイル、Android リソースファイル、cc_library ルールをコンパイルし、すべてを APK にパッケージ化します。

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel は、デフォルトで armeabi-v7a ABI を対象に、すべての cc_libraries を単一の共有オブジェクト（.so）ファイルにコンパイルします。同時に複数の ABI の変更やビルドを行う方法については、ターゲット ABI の設定のセクションをご覧ください。

設定例

この例は、Bazel サンプルリポジトリで入手できます。

BUILD.bazel ファイルでは、android_binary、android_library、cc_library ルールを使用して 3 つのターゲットが定義されています。

android_binary トップレベルターゲットが APK をビルドします。

cc_library ターゲットには、JNI 関数実装を持つ単一の C++ ソースファイルが含まれています。

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library ターゲットには、Java ソース、リソースファイル、cc_library ターゲットへの依存関係を指定します。この例では、MainActivity.java が共有オブジェクトファイル libapp.so を読み込み、JNI 関数のメソッドシグネチャを定義します。

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

STL の設定

C++ STL を構成するには、--android_crosstool_top フラグを使用します。

bazel build //:app --android_crosstool_top=target label

@androidndk で利用可能な STL は次のとおりです。

STL	ターゲットラベル
STLport	`@androidndk//:toolchain-stlport`
libc++	`@androidndk//:toolchain-libcpp`
GNustl	`@androidndk//:toolchain-gnu-libstdcpp`

r16 以前では、デフォルトの STL は gnustl です。r17 以降の場合は libc++ です。便宜上、ターゲット @androidndk//:default_crosstool はそれぞれのデフォルト STL にエイリアスされます。

r18 以降では、STLport と gnustl が削除され、libc++ が NDK で唯一の STL になります。

これらの STL の詳細については、NDK のドキュメントをご覧ください。

ターゲット ABI を構成する

ターゲット ABI を構成するには、次のように --fat_apk_cpu フラグを使用します。

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

デフォルトでは、Bazel は armeabi-v7a のネイティブ Android コードをビルドします。x86 用のビルド（エミュレータ用など）には、--fat_apk_cpu=x86 を渡します。複数のアーキテクチャ用のファット APK を作成するには、複数の CPU（--fat_apk_cpu=armeabi-v7a,x86）を指定します。

複数の ABI が指定されている場合、Bazel は各 ABI の共有オブジェクトを含む APK をビルドします。

NDK のリビジョンと Android API レベルに応じて、次の ABI を使用できます。

NDK リビジョン	ABI
16 以下	armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64
17 歳以上	armeabi-v7a、arm64-v8a、x86、x86_64

これらの ABI の詳細については、NDK のドキュメントをご覧ください。

マルチ ABI Fat APK は APK のサイズを大きくするため、リリースビルドにはおすすめしませんが、開発および QA ビルドには有用です。

C++ 標準の選択

C++ 標準に従ってビルドするには、次のフラグを使用します。

C++ 標準	フラグ
C++98	デフォルト。フラグは不要
C++11	`--cxxopt=-std=c++11`
C++14	`--cxxopt=-std=c++14`

次に例を示します。

bazel build //:app --cxxopt=-std=c++11

--cxxopt、--copt、--linkopt を使用してコンパイラフラグとリンカーフラグを渡す方法について詳しくは、ユーザーマニュアルをご覧ください。

コンパイラフラグとリンカーフラグは、copts と linkopts を使用して、cc_library で属性として指定することもできます。次に例を示します。

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

プラットフォームとツールチェーンとの統合

Bazel の構成モデルは、プラットフォームとツールチェーンに移行しています。ビルドで --platforms フラグを使用してビルド対象のアーキテクチャまたはオペレーティングシステムを選択する場合、NDK を使用するには、--extra_toolchains フラグを Bazel に渡す必要があります。

たとえば、Go ルールで提供される android_arm64_cgo ツールチェーンと統合するには、--platforms フラグに加えて --extra_toolchains=@androidndk//:all を渡します。

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

WORKSPACE ファイルで直接登録することもできます。

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

これらのツールチェーンを登録すると、アーキテクチャとオペレーティングシステムの制約を解決する際に、NDK の BUILD ファイル（NDK 20 の場合）でツールチェーンを検索するよう Bazel に指示します。

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

仕組み: Android 構成の移行の概要

android_binary ルールは、Android 互換構成で依存関係をビルドするよう Bazel に明示的に指示できます。これにより、ABI と STL の構成の --fat_apk_cpu と --android_crosstool_top を除き、特別なフラグなしで Bazel ビルドが正常に動作します。

この自動構成は、バックグラウンドで Android の構成の移行を使用します。

互換性のあるルール（android_binary など）は、依存関係の構成を Android 構成に自動的に変更するため、ビルドの Android 固有のサブツリーのみが影響を受けます。ビルドグラフの他の部分は、トップレベルのターゲット構成を使用して処理されます。ビルドグラフにそれをサポートするパスがある場合は、両方の構成で単一のターゲットを処理することさえ可能です。

Bazel が Android 互換構成（トップレベルで指定されているか、上位レベルの遷移ポイント）になると、追加の遷移ポイントが発生しても、構成はそれ以上変更されません。

Android 構成への移行をトリガーする組み込みの場所は、android_binary の deps 属性のみです。

たとえば、フラグを指定せずに cc_library 依存関係を持つ android_library ターゲットをビルドしようとすると、JNI ヘッダーが見つからないというエラーが発生することがあります。

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

理想的には、このような自動移行により、ほとんどのケースで Bazel が正しく動作するはずです。ただし、C++ デベロッパーが特定の cc_library をテストする場合など、Bazel コマンドラインのターゲットがすでにこれらの移行ルールのいずれかを下回っている場合は、カスタム --crosstool_top を使用する必要があります。

`android_binary` を使用せずに Android 用の `cc_library` をビルドする

android_binary を使用せずに Android 用のスタンドアロンの cc_binary または cc_library をビルドするには、--crosstool_top フラグ、--cpu フラグ、--host_crosstool_top フラグを使用します。

次に例を示します。

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

この例では、トップレベルの cc_library ターゲットと cc_binary ターゲットは NDK ツールチェーンを使用してビルドされています。ただし、ホストツールチェーンがターゲットツールチェーンからコピーされるため、Bazel 独自のホストツールは NDK ツールチェーンを使用してビルドされます（Android の場合は）。この問題を回避するには、--host_crosstool_top の値を @bazel_tools//tools/cpp:toolchain に指定して、ホストの C++ ツールチェーンを明示的に設定します。

この方法では、ビルドツリー全体が影響を受けます。

これらのフラグは、project/.bazelrc の bazelrc 構成（ABI ごとに 1 つ）に含めることができます。

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

次に、たとえば x86 の cc_library をビルドするには、次のコマンドを実行します。

bazel build //my/cc/jni:target --config=android_x86

一般に、この方法は低レベルのターゲット（cc_library など）や、ビルド内容が正確にわかっている場合に使用します。制御できない多数のターゲットをビルドすることが予想される高レベルのターゲットについては、android_binary からの自動構成移行をご活用ください。