Genel Kurallar

Kurallar

• takma ad
• config_setting
• dosya grubu
• genel sorgu
• genrule
• starlark_doc_extract
• test_suite

takma ad

alias(name, actual, compatible_with, deprecation, features, restricted_to, tags, target_compatible_with, testonly, visibility)

alias kuralı, kurala ad verilebilecek başka bir ad oluşturur.

Takma ad oluşturma yalnızca "normal" hedefler için çalışır. Özellikle, package_group ve test_suite için diğer ad kullanılamaz.

Takma ad oluşturma, bir hedefi yeniden adlandırmak için çok sayıda dosya üzerinde değişiklik yapılmasının gerektiği büyük depolarda yardımcı olabilir. Takma ad kuralını birden fazla hedef için yeniden kullanmak istiyorsanız select işlev çağrısını depolamak için de kullanabilirsiniz.

Takma ad kuralının kendi görünürlük bildirimi vardır. Diğer tüm açılardan bakıldığında, bazı küçük istisnalarla birlikte, referansta bulunduğu kural gibi davranır (ör. takma adda test amaçlı yoksayılır; bunun yerine, referans verilen kuralın test amaçlı kullanımı kullanılır) ancak bazı küçük istisnalar söz konusudur:

• Komut satırında takma adından bahsedilirse testler çalıştırılmaz. Başvuruda bulunulan testi çalıştıran bir takma ad tanımlamak için tests özelliğinde tek hedef bulunan bir test_suite kuralı kullanın.
• Ortam grupları tanımlanırken environment kurallarının takma adları desteklenmez. Bunlar, --target_environment komut satırı seçeneğinde de desteklenmez.

Örnekler

filegroup(
    name = "data",
    srcs = ["data.txt"],
)

alias(
    name = "other",
    actual = ":data",
)

Bağımsız değişkenler

config_setting

config_setting(name, constraint_values, define_values, deprecation, distribs, features, flag_values, licenses, tags, testonly, values, visibility)

Yapılandırılabilir özelliklerin tetiklenmesi amacıyla, beklenen bir yapılandırma durumuyla (derleme işaretleri veya platform kısıtlamaları olarak ifade edilir) eşleşir. Bu kuralın nasıl kullanılacağı ile ilgili bilgi için select (Seçme) bölümüne ve genel özelliğe genel bakış için Yapılandırılabilir özellikler bölümüne bakın.

Örnekler

Aşağıdaki, --compilation_mode=opt veya -c opt değerini ayarlayan herhangi bir derlemeyle eşleşir (açıkça komut satırında veya dolaylı olarak .bazelrc dosyalarından):

  config_setting(
      name = "simple",
      values = {"compilation_mode": "opt"}
  )
  

Aşağıdaki, ARM'yi hedefleyen ve özel FOO=bar tanımlamasını uygulayan herhangi bir derlemeyle eşleşir (örneğin, bazel build --cpu=arm --define FOO=bar ...):

  config_setting(
      name = "two_conditions",
      values = {
          "cpu": "arm",
          "define": "FOO=bar"
      }
  )
  

Aşağıdaki, kullanıcı tanımlı işareti --//custom_flags:foo=1 (açıkça komut satırında veya dolaylı olarak .bazelrc dosyalarından) ayarlayan her derlemeyle eşleşir:

  config_setting(
      name = "my_custom_flag_is_set",
      flag_values = { "//custom_flags:foo": "1" },
  )
  

Aşağıdaki örnek, x86_64 mimarisine ve glibc sürüm 2.25'e sahip bir platformu hedefleyen tüm derlemelerle eşleşir ve //example:glibc_2_25 etiketine sahip bir constraint_value bulunduğu varsayılır. Bir platformun, bu iki kısıtlamanın dışında ek kısıtlama değerleri tanımladığı durumlarda da eşleştiğini unutmayın.

  config_setting(
      name = "64bit_glibc_2_25",
      constraint_values = [
          "@platforms//cpu:x86_64",
          "//example:glibc_2_25",
      ]
  )
  

Notlar

• Birden fazla config_setting mevcut yapılandırma durumuyla eşleştiğinde ne olacağını öğrenmek için seçim bölümüne bakın.
• Kısaltılmış biçimleri (ör. --compilation_mode - -c) destekleyen flag'ler için values tanımları tam formu kullanmalıdır. Bunlar, iki formdan birini kullanarak çağrıları otomatik olarak eşleştirir.
• Bir işaret birden fazla değer alırsa (--copt=-Da --copt=-Db veya liste türünde Starlark işareti gibi) "a" değerinin gerçek listenin herhangi bir yerinde bulunması halinde values = { "flag": "a" } eşleşir.

  values = { "myflag": "a,b" } aynı şekilde çalışır: Bu, --myflag=a --myflag=b, --myflag=a --myflag=b --myflag=c, --myflag=a,b ve --myflag=c,b,a ile eşleşir. Tam anlamlar işaretler arasında değişiklik gösterir. Örneğin, --copt aynı örnekte birden fazla değeri desteklemez: --copt=a,b, ["a,b"] değerini üretirken --copt=a --copt=b, ["a", "b"] değerini üretir (yani values = { "copt": "a,b" }, ilkiyle eşleşir ancak ikincisiyle eşleşmez). Ancak --ios_multi_cpus (Apple kuralları için) şunları yapar: -ios_multi_cpus=a,b ve ios_multi_cpus=a --ios_multi_cpus=b ikisi de ["a", "b"] oluşturur. Tam beklentileri doğrulamak için işaret tanımlarını kontrol edin ve koşullarınızı dikkatlice test edin.

• Yerleşik derleme işaretleri tarafından modellenmeyen koşullar tanımlamanız gerekiyorsa Starlark tarafından tanımlanan işaretleri kullanın. --define öğesini de kullanabilirsiniz, ancak bu daha zayıf destek sağlar ve önerilmez. Daha fazla tartışma için buraya bakın.
• Farklı paketlerde aynı config_setting tanımlarını tekrarlamaktan kaçının. Bunun yerine, standart pakette tanımlanan ortak bir config_setting öğesine başvurun.
• values, define_values ve constraint_values aynı config_setting içinde herhangi bir kombinasyonda kullanılabilir ancak belirli bir config_setting için en az bir kombinasyon ayarlanmalıdır.

Bağımsız değişkenler

            config_setting(
                name = "a_and_b",
                values = {
                    "define": "a=1",
                    "define": "b=2",
                })
          

            config_setting(
                name = "a_and_b",
                define_values = {
                    "a": "1",
                    "b": "2",
                })
          

dosya grubu

filegroup(name, srcs, data, compatible_with, deprecation, distribs, features, licenses, output_group, restricted_to, tags, target_compatible_with, testonly, visibility)

Hedef koleksiyonuna kolay bir ad vermek için filegroup kullanın. Daha sonra bunlara diğer kurallardan referans verilebilir.

Dizinlere doğrudan referans vermek yerine filegroup kullanılması önerilir. Derleme sistemi dizin altındaki tüm dosyalar hakkında tam bilgiye sahip olmadığı için derleme sistemi sessizdir. Bu nedenle, bu dosyalar değiştiğinde yeniden oluşturma yapmayabilir. filegroup, glob ile birleştirildiğinde tüm dosyaların derleme sistemi tarafından açıkça bilinmesini sağlayabilir.

Örnekler

İki kaynak dosyadan oluşan bir filegroup oluşturmak için

filegroup(
    name = "mygroup",
    srcs = [
        "a_file.txt",
        "some/subdirectory/another_file.txt",
    ],
)

Veya bir test verisi dizini oluşturmak için bir glob kullanın:

filegroup(
    name = "exported_testdata",
    srcs = glob([
        "testdata/*.dat",
        "testdata/logs/**/*.log",
    ]),
)

Bu tanımlardan yararlanmak için filegroup öğesine herhangi bir kuraldan etiket ekleyin:

cc_library(
    name = "my_library",
    srcs = ["foo.cc"],
    data = [
        "//my_package:exported_testdata",
        "//my_package:mygroup",
    ],
)

Bağımsız değişkenler

Genquery

genquery(name, deps, data, compatible_with, compressed_output, deprecation, distribs, exec_compatible_with, exec_properties, expression, features, licenses, opts, restricted_to, scope, strict, tags, target_compatible_with, testonly, visibility)

genquery(), Blaze sorgu dilinde belirtilen bir sorguyu çalıştırır ve sonucu bir dosyaya döküm.

Derlemenin tutarlılığını sağlamak için sorgunun yalnızca scope özelliğinde belirtilen hedeflerin geçişli kapanışını ziyaret etmesine izin verilir. strict belirtilmemişse veya doğru değerine ayarlanırsa bu kuralı ihlal eden sorgular yürütme sırasında başarısız olur (strict yanlış değerine ayarlanırsa kapsam dışı hedefler bir uyarıyla atlanır). Bunun olmamasını sağlamanın en kolay yolu, sorgu ifadesinde belirtilenle aynı etiketleri kapsam içinde belirtmektir.

Burada ve komut satırında izin verilen sorgular arasındaki tek fark, joker karakter hedef özellikleri (ör. //pkg:* veya //pkg:all) içeren sorgulara burada izin verilmemesidir. Bunun iki nedeni vardır. Birincisi, genquery ürününün, çıkışını etkilemesi için sorgunun geçişli olarak kapatılması dışındaki hedeflerin önlenmesi için bir kapsam belirtmesi gerekir. İkinci olarak, BUILD dosyaları joker karakter bağımlılıklarını desteklemediğinden (ör. deps=["//a/..."]'ye izin verilmez).

--output=graph|minrank|maxrank hariç olmak üzere veya üst düzey işlev olarak somepath kullanıldığında, sorgu çıkışı deterministik çıktıyı uygulamak için sözlüksel olarak sıralanır.

Çıkış dosyasının adı kuralın adıdır.

Örnekler

Bu örnekte, belirtilen hedefin geçişli kapatma işlemindeki etiketlerin listesi bir dosyaya yazılmaktadır.

genquery(
    name = "kiwi-deps",
    expression = "deps(//kiwi:kiwi_lib)",
    scope = ["//kiwi:kiwi_lib"],
)

Bağımsız değişkenler

Genrule

genrule(name, srcs, outs, cmd, cmd_bash, cmd_bat, cmd_ps, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, executable, features, licenses, local, message, output_licenses, output_to_bindir, restricted_to, tags, target_compatible_with, testonly, toolchains, tools, visibility)

genrule, kullanıcı tanımlı Bash komutunu kullanarak bir veya daha fazla dosya oluşturur.

Genrule, görev için belirli bir kural yoksa kullanabileceğiniz genel derleme kurallarıdır. Örneğin, Bash tek satırlık bir hazırlayabilirsiniz. Yine de C++ dosyalarını derlemeniz gerekiyorsa mevcut cc_* kurallarına bağlı kalın. Tüm ağır işlemler sizin yerinize zaten yapılmıştır.

Genrule öğesinin, komut bağımsız değişkenini yorumlamak için kabuk gerektirdiğini unutmayın. PATH üzerinde bulunan rastgele programlara başvurmak da kolaydır. Ancak bu, komutu hermetik hale getirir ve yeniden üretemeyebilir. Yalnızca tek bir araç çalıştırmanız gerekiyorsa bunun yerine run_binary'yi kullanabilirsiniz.

Testleri çalıştırmak için genrule kullanmayın. Testler ve test sonuçları için önbelleğe alma politikaları ve ortam değişkenleri de dahil olmak üzere özel dağıtımlar vardır. Testlerin genellikle derleme tamamlandıktan sonra ve hedef mimari üzerinde çalıştırılması gerekir. Öte yandan, genel kurallar derleme sırasında ve yönetici mimarisi üzerinde yürütülür (ikisi farklı olabilir). Genel amaçlı bir test kuralına ihtiyacınız varsa sh_test kullanın.

Çapraz derlemede dikkat edilmesi gereken noktalar

Çapraz derleme hakkında daha fazla bilgi için kullanıcı kılavuzunu inceleyin.

Genrule'lar derleme sırasında çalışır ancak çıkışları genellikle derlemeden sonra dağıtım veya test için kullanılır. Mikrodenetleyici için C kodu derleme örneğini düşünün: Derleyici, C kaynak dosyalarını kabul eder ve bir mikrodenetleyicide çalışan kod oluşturur. Oluşturulan kodun, kendisini oluşturmak için kullanılan CPU'da çalıştırılamayacağı açık şekilde, ancak C derleyicisinin (kaynaktan derlenmişse) kendisinin çalışması gerekir.

Derleme sistemi, derlemenin çalıştığı makineleri tanımlamak için yönetici yapılandırmasını ve derleme çıkışının çalışması gereken makineleri açıklamak için hedef yapılandırmayı kullanır. Bunların her birini yapılandırma seçenekleri sunar ve çakışmaları önlemek için karşılık gelen dosyaları ayrı dizinlere ayırır.

Genrule'lar için derleme sistemi, bağımlılıkların uygun şekilde oluşturulmasını sağlar: target yapılandırması için srcs oluşturulur, tools exec yapılandırması için oluşturulur ve çıkışın hedef yapılandırması için olduğu kabul edilir. Ayrıca, Genrule komutların ilgili araçlara iletebileceği "Make" değişkenleri de sağlar.

Genel kuralların herhangi bir deps özelliği tanımlamaması kasıtlıdır. Diğer yerleşik kurallar, bağımlı kuralların nasıl ele alınacağını otomatik olarak belirlemek için kurallar arasında iletilen dile bağlı meta bilgileri kullanır ancak genel kurallar için bu düzeyde otomasyon mümkün değildir. Genrule'lar yalnızca dosya ve çalıştırma dosyaları düzeyinde çalışır.

Özel Durumlar

Exec-exec derlemesi: Bazı durumlarda derleme sisteminin, çıkışın derleme sırasında da yürütülebilmesi için genrule çalıştırması gerekir. Örneğin, bir genrule, daha sonra başka bir Genrule tarafından kullanılacak bir özel derleyici derlerse ilkinin, yürütme yapılandırması için çıktısını oluşturması gerekir. Çünkü derleyici bu aşamada diğer genel kuralda da çalışır. Bu durumda, derleme sistemi otomatik olarak doğru şeyi yapar: hedef yapılandırma yerine yönetici yapılandırması için ilk genel kuralın srcs ve outs öğesini oluşturur. Daha fazla bilgi için kullanım kılavuzuna bakın.

JDK ve C++ Araçları: JDK veya C++ derleyici paketindeki bir aracı kullanmak için derleme sistemi, kullanılacak bir dizi değişken sağlar. Ayrıntılar için "Yap" değişkeni bölümüne bakın.

Genel ortam

Genrule komutu, bir komut veya ardışık düzen başarısız olduğunda başarısız olacak şekilde yapılandırılan Bash kabuğu tarafından set -e -o pipefail kullanılarak yürütülür.

Derleme aracı; Bash komutunu yalnızca PATH, PWD, TMPDIR ve birkaç diğer temel değişkenleri tanımlayan temiz bir işlem ortamında yürütür. Derlemelerin tekrarlanabilir olmasını sağlamak için kullanıcının kabuk ortamında tanımlanan çoğu değişken, Genrule (Genrule) komutuna iletilmez. Bununla birlikte, Bazel (Blaze değil) kullanıcının PATH ortam değişkeninin değerinden geçer. PATH değerinde yapılan herhangi bir değişiklik, Bazel'in bir sonraki derlemede komutu yeniden yürütmesine neden olur.

Genrule komutu, şu anda zorunlu olmasa da komutun alt öğeleri olan işlemleri bağlamak dışında ağa erişmemelidir.

Derleme sistemi mevcut çıkış dosyalarını otomatik olarak siler, ancak bir genrule çalıştırmadan önce gerekli tüm üst dizinleri oluşturur. Ayrıca, hata durumunda çıkış dosyalarını da kaldırır.

Genel Tavsiye

• Bir genel kural tarafından çalıştırılan araçların deterministik ve hermetik olduğundan emin olun. Çıkışlarına zaman damgaları yazmamalı, kümeler ve haritalar için sabit sıralama kullanmalı, mutlak yollar kullanmamalı, çıkışa yalnızca göreli dosya yolları yazmalıdır. Bu kurala uyulmaması, beklenmeyen derleme davranışlarına (Bazel'in beklediğiniz bir genel kuralı yeniden oluşturmamasına) ve önbellek performansının düşmesine neden olur.
• $(location) öğesini çıkışlar, araçlar ve kaynaklar için yoğun bir şekilde kullanın. Çıkış dosyalarının farklı yapılandırmalara göre ayrılması nedeniyle, genruller sabit kodlu ve/veya mutlak yollara dayanamaz.
• Aynı veya çok benzer kişilerin birden fazla yerde kullanılması ihtimaline karşı ortak bir Starlark makrosu yazın. Genel kural karmaşıksa bir komut dosyasında veya Starlark kuralı olarak uygulamayı düşünebilirsiniz. Bu sayede okunabilirliği ve test edilebilirliği iyileştirebilirsiniz.
• Çıkış kodunun, kuralın başarılı veya başarısız olduğunu doğru şekilde gösterdiğinden emin olun.
• stdout veya stderr'e bilgilendirme amaçlı iletiler yazmayın. Hata ayıklama için faydalı olsa da bu, kolayca gürültüye dönüşebilir. Başarılı bir oluşturucu sessiz olmalıdır. Diğer yandan, başarısız bir genel kural iyi hata mesajları vermelidir.
• $$ evaluates to a $, a literal dollar-sign, so in order to invoke a shell command containing dollar-signs such as ls $(dirname $x), one must escape it thus: ls $$(dirname $$x).
• Sembol bağlantılar ve dizinler oluşturmaktan kaçının. Bazel, Genrule'lar tarafından oluşturulan dizin/simgesel bağlantı yapısını kopyalamaz ve dizinler için bağımlılık kontrolü düzgün değildir.
• Diğer kurallarda genel kurala referans verirken genel kuralın etiketini veya ayrı ayrı çıkış dosyalarının etiketlerini kullanabilirsiniz. Bazen bir yaklaşım daha okunabilir olur, bazen diğeri: tüketici kuralının srcs öğesinde çıkışlara isme göre referans vermek, istemeden genrule'ın diğer çıktılarını toplamaktan kaçınır ancak genel kural çok sayıda çıktı üretiyorsa yorucu olabilir.

Örnekler

Bu örnek, foo.h oluşturur. Komut giriş almadığı için kaynak yok. Komut tarafından çalıştırılan "ikili", genrule ile aynı pakette bulunan bir perl komut dosyasıdır.

genrule(
    name = "foo",
    srcs = [],
    outs = ["foo.h"],
    cmd = "./$(location create_foo.pl) > \"$@\"",
    tools = ["create_foo.pl"],
)

Aşağıdaki örnekte filegroup özelliğinin nasıl kullanılacağı ve başka bir genrule öğesinin çıkışları gösterilmektedir. Açık $(location) yönergeleri yerine $(SRCS) kullanıldığında da işe yarayacağını unutmayın. Bu örnekte, örneği göstermek amacıyla ikinci kural kullanılmaktadır.

genrule(
    name = "concat_all_files",
    srcs = [
        "//some:files",  # a filegroup with multiple files in it ==> $(locations)
        "//other:gen",   # a genrule with a single output ==> $(location)
    ],
    outs = ["concatenated.txt"],
    cmd = "cat $(locations //some:files) $(location //other:gen) > $@",
)

Bağımsız değişkenler

starlark_doc_extract

starlark_doc_extract(name, deps, src, data, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, features, licenses, render_main_repo_name, restricted_to, symbol_names, tags, target_compatible_with, testonly, visibility)

starlark_doc_extract(), belirli bir .bzl veya .scl dosyasında tanımlanan veya yeniden dışa aktarılan kurallar, işlevler (makrolar dahil), özellikler ve sağlayıcılarla ilgili dokümanları ayıklar. Bu kuralın sonucu, Bazel kaynak ağacındaki stardoc_output.proto bölümünde tanımlandığı gibi bir ModuleInfo ikili programıdır.

Dolaylı çıkış hedefleri

• name.binaryproto (varsayılan çıkış): ModuleInfo ikili programı.
• name.textproto (yalnızca açıkça talep edildiğinde oluşturulur): name.binaryproto metin protokolü sürümü.

Uyarı: Bu kuralın çıkış biçiminin kararlı olacağı garanti edilmez. Esas olarak Stardoc tarafından dahili kullanım için tasarlanmıştır.

Bağımsız değişkenler

test_suite

test_suite(name, compatible_with, deprecation, distribs, features, licenses, restricted_to, tags, target_compatible_with, testonly, tests, visibility)

test_suite, kullanıcılar için "faydalı" olarak kabul edilen bir dizi testi tanımlar. Bu sayede projeler, "kontrol etmeden önce çalıştırmanız gereken testler", "projemizin stres testleri" veya "tüm küçük testler" gibi test setleri tanımlayabilir. blaze test komutu şu organizasyona uyar: blaze test //some/test:suite gibi bir çağrı için Blaze önce //some/test:suite hedefi tarafından geçişli olarak dahil edilen tüm test hedeflerini numaralandırır (buna "test_suite genişletmesi" denir), ardından Blaze bu hedefleri oluşturup test eder.

Örnekler

Mevcut paketteki tüm küçük testleri çalıştıracak bir test paketi.

test_suite(
    name = "small_tests",
    tags = ["small"],
)

Belirli bir test grubunu çalıştıran bir test paketi:

test_suite(
    name = "smoke_tests",
    tests = [
        "system_unittest",
        "public_api_unittest",
    ],
)

Mevcut pakette stabil olmayan tüm testleri çalıştırmak için kullanılan bir test paketi.

test_suite(
    name = "non_flaky_test",
    tags = ["-flaky"],
)

Bağımsız değişkenler