บทแนะนำ Bazel: กำหนดค่าเชนเครื่องมือ C++

Nightly · 9.1 · 9.0 · 8.7 · 8.6 · 8.5 · 8.4 · 8.3 · 8.2 · 8.1

บทแนะนำนี้ใช้สถานการณ์ตัวอย่างเพื่ออธิบายวิธีกำหนดค่า Toolchain ของ C++ สำหรับโปรเจ็กต์ โดยอิงตาม โปรเจ็กต์ C++ ตัวอย่าง ที่สร้างโดยไม่มีข้อผิดพลาดโดยใช้ clang

สิ่งที่คุณจะได้เรียนรู้

ในบทแนะนำนี้ คุณจะได้เรียนรู้วิธีการต่อไปนี้

  • ตั้งค่าสภาพแวดล้อมของบิลด์
  • กำหนดค่า Toolchain ของ C++
  • สร้างกฎ Starlark ที่ให้การกำหนดค่าเพิ่มเติมสำหรับ cc_toolchain เพื่อให้ Bazel สร้างแอปพลิเคชันด้วย clang ได้
  • ยืนยันผลลัพธ์ที่คาดไว้โดยเรียกใช้ bazel build --config=clang_config //main:hello-world ในเครื่อง Linux
  • สร้างแอปพลิเคชัน C++

ก่อนเริ่มต้น

ตั้งค่าสภาพแวดล้อมของบิลด์

บทแนะนำนี้ถือว่าคุณใช้ Linux และสร้างแอปพลิเคชัน C++ รวมถึงติดตั้งเครื่องมือและไลบรารีที่เหมาะสมเรียบร้อยแล้ว บทแนะนำนี้ใช้ clang version 9.0.1 ซึ่งคุณสามารถติดตั้งในระบบได้

ตั้งค่าสภาพแวดล้อมของบิลด์ดังนี้

  1. ดาวน์โหลดและติดตั้ง Bazel 0.23 ขึ้นไป หากยังไม่ได้ทำ

  2. ดาวน์โหลด โปรเจ็กต์ C++ ตัวอย่าง จาก GitHub แล้ววางไว้ในไดเรกทอรีว่างในเครื่องของคุณ

  3. เพิ่มเป้าหมาย cc_binary ต่อไปนี้ลงในไฟล์ main/BUILD

    cc_binary(
    name = "hello-world",
    srcs = ["hello-world.cc"],
)

  4. สร้างไฟล์ .bazelrc ที่รูทของไดเรกทอรีพื้นที่ทำงานโดยมีเนื้อหาต่อไปนี้เพื่อเปิดใช้แฟล็ก --config

    # Use our custom-configured c++ toolchain.

build:clang_config --crosstool_top=//toolchain:clang_suite

# Use --cpu as a differentiator.

build:clang_config --cpu=k8

# Use the default Bazel C++ toolchain to build the tools used during the
# build.

build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

สำหรับรายการ build:{config_name} --flag=value Flag บรรทัดคำสั่ง --config={config_name} จะเชื่อมโยงกับแฟล็กนั้น ดู เอกสารประกอบสำหรับแฟล็กที่ใช้ ได้แก่ crosstool_top, cpu และ host_crosstool_top

เมื่อสร้าง เป้าหมาย ด้วย bazel build --config=clang_config //main:hello-world Bazel จะใช้ Toolchain ที่กำหนดเองจาก cc_toolchain_suite //toolchain:clang_suite ชุดเครื่องมืออาจแสดง Toolchain ที่แตกต่างกันสำหรับ CPU ที่แตกต่างกัน และนั่นคือเหตุผลที่ต้องแยกความแตกต่างด้วยแฟล็ก --cpu=k8

เนื่องจาก Bazel ใช้เครื่องมือภายในหลายรายการที่เขียนด้วย C++ ระหว่างการบิลด์ ระบบจึงระบุ Toolchain ของ C++ เริ่มต้นที่มีอยู่แล้วสำหรับแพลตฟอร์มโฮสต์ เพื่อให้เครื่องมือเหล่านี้สร้างขึ้นโดยใช้ Toolchain นั้นแทนที่จะใช้ Toolchain ที่สร้างขึ้นในบทแนะนำนี้

การกำหนดค่า Toolchain ของ C++

หากต้องการกำหนดค่า Toolchain ของ C++ ให้สร้างแอปพลิเคชันซ้ำๆ และกำจัดข้อผิดพลาดทีละรายการตามที่อธิบายไว้ด้านล่าง

  1. เรียกใช้บิลด์ด้วยคำสั่งต่อไปนี้

    bazel build --config=clang_config //main:hello-world

    เนื่องจากคุณระบุ --crosstool_top=//toolchain:clang_suite ในไฟล์ .bazelrc Bazel จึงแสดงข้อผิดพลาดต่อไปนี้

    No such package `toolchain`: BUILD file not found on package path.

    ในไดเรกทอรีพื้นที่ทำงาน ให้สร้างไดเรกทอรี toolchain สำหรับแพ็กเกจและไฟล์ BUILD ว่างเปล่าภายในไดเรกทอรี toolchain

  2. เรียกใช้การสร้างอีกครั้ง เนื่องจากแพ็กเกจ toolchain ยังไม่ได้กำหนดเป้าหมาย clang_suite Bazel จึงแสดงข้อผิดพลาดต่อไปนี้

    No such target '//toolchain:clang_suite': target 'clang_suite' not declared
in package 'toolchain' defined by .../toolchain/BUILD

    ในไฟล์ toolchain/BUILD ให้กำหนด filegroup ว่างเปล่าดังนี้

    package(default_visibility = ["//visibility:public"])

filegroup(name = "clang_suite")

  3. เรียกใช้การสร้างอีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

    '//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'

    Bazel พบว่าแฟล็ก --crosstool_top ชี้ไปที่กฎที่ ไม่ได้ระบุผู้ให้บริการ ToolchainInfo ที่จำเป็น ดังนั้นคุณจึงต้องชี้ --crosstool_top ไปที่กฎที่ระบุ ToolchainInfo ซึ่งก็คือกฎ cc_toolchain_suite ในไฟล์ toolchain/BUILD ให้แทนที่ filegroup ว่างเปล่าด้วยข้อมูลต่อไปนี้

    cc_toolchain_suite(
    name = "clang_suite",
    toolchains = {
        "k8": ":k8_toolchain",
    },
)

    แอตทริบิวต์ toolchains จะแมปค่า --cpu (และ --compiler ด้วยเมื่อระบุ) กับ cc_toolchain โดยอัตโนมัติ คุณยังไม่ได้กำหนดเป้าหมาย cc_toolchain ใดๆ และ Bazel จะแสดงข้อผิดพลาดเกี่ยวกับเรื่องนี้ในเร็วๆ นี้

  4. เรียกใช้การสร้างอีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

    Rule '//toolchain:k8_toolchain' does not exist

    ตอนนี้คุณต้องกำหนดเป้าหมาย cc_toolchain สำหรับทุกค่าในแอตทริบิวต์ cc_toolchain_suite.toolchains เพิ่มข้อมูลต่อไปนี้ลงในไฟล์ toolchain/BUILD

    filegroup(name = "empty")

cc_toolchain(
    name = "k8_toolchain",
    toolchain_identifier = "k8-toolchain",
    toolchain_config = ":k8_toolchain_config",
    all_files = ":empty",
    compiler_files = ":empty",
    dwp_files = ":empty",
    linker_files = ":empty",
    objcopy_files = ":empty",
    strip_files = ":empty",
    supports_param_files = 0,
)

  5. เรียกใช้การสร้างอีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

    Rule '//toolchain:k8_toolchain_config' does not exist

    จากนั้นเพิ่มเป้าหมาย ":k8_toolchain_config" ลงในไฟล์ toolchain/BUILD

    filegroup(name = "k8_toolchain_config")

  6. เรียกใช้การสร้างอีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

    '//toolchain:k8_toolchain_config' does not have mandatory providers:
'CcToolchainConfigInfo'

    CcToolchainConfigInfo เป็นผู้ให้บริการที่คุณใช้กำหนดค่า Toolchain ของ C++ หากต้องการแก้ไขข้อผิดพลาดนี้ ให้สร้างกฎ Starlark ที่ระบุ CcToolchainConfigInfo ให้ Bazel โดยสร้างไฟล์ toolchain/cc_toolchain_config.bzl ที่มีเนื้อหาต่อไปนี้

    def _impl(ctx):
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "k8-toolchain",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
    )

cc_toolchain_config = rule(
    implementation = _impl,
    attrs = {},
    provides = [CcToolchainConfigInfo],
)

    cc_common.create_cc_toolchain_config_info() จะสร้างผู้ให้บริการ CcToolchainConfigInfo ที่จำเป็น หากต้องการใช้กฎ cc_toolchain_config ให้เพิ่มคำสั่งโหลดลงใน toolchain/BUILD ใต้คำสั่งแพ็กเกจ

    load(":cc_toolchain_config.bzl", "cc_toolchain_config")

    และแทนที่ filegroup "k8_toolchain_config" ด้วยการประกาศกฎ cc_toolchain_config

    cc_toolchain_config(name = "k8_toolchain_config")

  7. เรียกใช้การสร้างอีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

    .../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1)
src/main/tools/linux-sandbox-pid1.cc:421:
"execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory
Target //:hello-world failed to build`

    ณ จุดนี้ Bazel มีข้อมูลเพียงพอที่จะพยายามสร้างโค้ด แต่ยังไม่ทราบว่าจะใช้เครื่องมือใดในการดำเนินการบิลด์ที่จำเป็นให้เสร็จสมบูรณ์ คุณจะแก้ไขการใช้งานกฎ Starlark เพื่อบอก Bazel ว่าจะใช้เครื่องมือใด โดยคุณต้องใช้ตัวสร้าง tool_path() จาก @bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl

    # toolchain/cc_toolchain_config.bzl:
# NEW
load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path")

def _impl(ctx):
    tool_paths = [ # NEW
        tool_path(
            name = "gcc",
            path = "/usr/bin/clang",
        ),
        tool_path(
            name = "ld",
            path = "/usr/bin/ld",
        ),
        tool_path(
            name = "ar",
            path = "/usr/bin/ar",
        ),
        tool_path(
            name = "cpp",
            path = "/bin/false",
        ),
        tool_path(
            name = "gcov",
            path = "/bin/false",
        ),
        tool_path(
            name = "nm",
            path = "/bin/false",
        ),
        tool_path(
            name = "objdump",
            path = "/bin/false",
        ),
        tool_path(
            name = "strip",
            path = "/bin/false",
        ),
    ]
    return cc_common.create_cc_toolchain_config_info(
        ctx = ctx,
        toolchain_identifier = "local",
        host_system_name = "local",
        target_system_name = "local",
        target_cpu = "k8",
        target_libc = "unknown",
        compiler = "clang",
        abi_version = "unknown",
        abi_libc_version = "unknown",
        tool_paths = tool_paths, # NEW
    )

    ตรวจสอบว่า /usr/bin/clang และ /usr/bin/ld เป็นเส้นทางที่ถูกต้องสำหรับระบบของคุณ

  8. เรียกใช้การสร้างอีกครั้ง Bazel แสดงข้อผิดพลาดต่อไปนี้

     ..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world':
 this rule is missing dependency declarations for the following files included by 'main/hello-world.cc':
 '/usr/include/c++/9/ctime'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h'
 '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h'
 ....

    Bazel ต้องทราบว่าจะค้นหาส่วนหัวที่รวมไว้จากที่ใด คุณสามารถแก้ปัญหานี้ได้หลายวิธี เช่น ใช้แอตทริบิวต์ includes ของ cc_binary แต่ในที่นี้เราจะแก้ปัญหาที่ระดับ Toolchain ด้วย พารามิเตอร์ cxx_builtin_include_directories ของ cc_common.create_cc_toolchain_config_info โปรดทราบว่าหาก คุณใช้ clang เวอร์ชันอื่น เส้นทางรวมจะ แตกต่างกัน เส้นทางเหล่านี้อาจแตกต่างกันไปตามการเผยแพร่ด้วย

    แก้ไขค่าที่แสดงใน toolchain/cc_toolchain_config.bzl ให้มีลักษณะดังนี้

     return cc_common.create_cc_toolchain_config_info(
      ctx = ctx,
      cxx_builtin_include_directories = [ # NEW
        "/usr/lib/llvm-9/lib/clang/9.0.1/include",
        "/usr/include",
      ],
      toolchain_identifier = "local",
      host_system_name = "local",
      target_system_name = "local",
      target_cpu = "k8",
      target_libc = "unknown",
      compiler = "clang",
      abi_version = "unknown",
      abi_libc_version = "unknown",
      tool_paths = tool_paths,
 )

  9. เรียกใช้คำสั่งสร้างอีกครั้ง คุณจะเห็นข้อผิดพลาดดังนี้

    /usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()':
hello-world.cc:(.text+0x68): undefined reference to `std::cout'

    สาเหตุของข้อผิดพลาดนี้คือตัวลิงก์ไม่มีไลบรารีมาตรฐานของ C++ และค้นหาสัญลักษณ์ของไลบรารีไม่ได้ คุณสามารถแก้ปัญหานี้ได้หลายวิธี เช่น ใช้แอตทริบิวต์ linkopts ของ cc_binary ในที่นี้เราจะแก้ปัญหาโดยตรวจสอบว่าเป้าหมายใดก็ตามที่ใช้ Toolchain ไม่จำเป็นต้องระบุแฟล็กนี้

    คัดลอกโค้ดต่อไปนี้ลงใน cc_toolchain_config.bzl

      # NEW
  load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES")
  # NEW
  load(
      "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl",
      "feature",
      "flag_group",
      "flag_set",
      "tool_path",
  )

  all_link_actions = [ # NEW
      ACTION_NAMES.cpp_link_executable,
      ACTION_NAMES.cpp_link_dynamic_library,
      ACTION_NAMES.cpp_link_nodeps_dynamic_library,
  ]

  def _impl(ctx):
      tool_paths = [
          tool_path(
              name = "gcc",
              path = "/usr/bin/clang",
          ),
          tool_path(
              name = "ld",
              path = "/usr/bin/ld",
          ),
          tool_path(
              name = "ar",
              path = "/bin/false",
          ),
          tool_path(
              name = "cpp",
              path = "/bin/false",
          ),
          tool_path(
              name = "gcov",
              path = "/bin/false",
          ),
          tool_path(
              name = "nm",
              path = "/bin/false",
          ),
          tool_path(
              name = "objdump",
              path = "/bin/false",
          ),
          tool_path(
              name = "strip",
              path = "/bin/false",
          ),
      ]

      features = [ # NEW
          feature(
              name = "default_linker_flags",
              enabled = True,
              flag_sets = [
                  flag_set(
                      actions = all_link_actions,
                      flag_groups = ([
                          flag_group(
                              flags = [
                                  "-lstdc++",
                              ],
                          ),
                      ]),
                  ),
              ],
          ),
      ]

      return cc_common.create_cc_toolchain_config_info(
          ctx = ctx,
          features = features, # NEW
          cxx_builtin_include_directories = [
              "/usr/lib/llvm-9/lib/clang/9.0.1/include",
              "/usr/include",
          ],
          toolchain_identifier = "local",
          host_system_name = "local",
          target_system_name = "local",
          target_cpu = "k8",
          target_libc = "unknown",
          compiler = "clang",
          abi_version = "unknown",
          abi_libc_version = "unknown",
          tool_paths = tool_paths,
      )

  cc_toolchain_config = rule(
      implementation = _impl,
      attrs = {},
      provides = [CcToolchainConfigInfo],
  )

  10. หากเรียกใช้ bazel build --config=clang_config //main:hello-world ระบบควรสร้างได้ในที่สุด

ตรวจสอบงาน

ในบทแนะนำนี้ คุณได้เรียนรู้วิธีกำหนดค่า Toolchain ของ C++ พื้นฐาน แต่ Toolchain มีประสิทธิภาพมากกว่าตัวอย่างง่ายๆ นี้

ข้อควรจำที่สำคัญมีดังนี้: - คุณต้องระบุแฟล็ก --crosstool_top ในบรรทัดคำสั่งซึ่งควร ชี้ไปที่ cc_toolchain_suite - คุณสามารถสร้างแป้นพิมพ์ลัดสำหรับการกำหนดค่าที่เฉพาะเจาะจงได้โดยใช้ไฟล์ .bazelrc - cc_toolchain_suite อาจแสดง cc_toolchains สำหรับ CPU และ คอมไพเลอร์ที่แตกต่างกัน คุณสามารถใช้แฟล็กบรรทัดคำสั่ง เช่น --cpu เพื่อแยกความแตกต่าง - คุณต้องแจ้งให้ Toolchain ทราบตำแหน่งที่เครื่องมืออยู่ ในบทแนะนำนี้ มีเวอร์ชันที่ง่ายขึ้นซึ่งคุณเข้าถึงเครื่องมือจากระบบ หาก สนใจแนวทางที่ครอบคลุมมากขึ้น คุณสามารถอ่านข้อมูลเกี่ยวกับ พื้นที่ทำงาน ได้ที่นี่ เครื่องมือของคุณอาจมาจากพื้นที่ทำงานอื่น และคุณจะต้องทำให้ไฟล์ของเครื่องมือพร้อมใช้งานสำหรับ cc_toolchain โดยมีการพึ่งพาเป้าหมายในแอตทริบิวต์ เช่น compiler_files นอกจากนี้ คุณจะต้องเปลี่ยน tool_paths ด้วย - คุณสามารถสร้างฟีเจอร์เพื่อปรับแต่งแฟล็กที่จะส่งไปยัง การดำเนินการต่างๆ ไม่ว่าจะเป็นการลิงก์หรือการดำเนินการประเภทอื่นๆ

อ่านเพิ่มเติม

ดูรายละเอียดเพิ่มเติมได้ที่ การกำหนดค่า Toolchain ของ C++