関数

目次

• package
• package_group
• exports_files
• glob
• 選択
• サブパッケージ

パッケージ

package(default_deprecation, default_package_metadata, default_testonly, default_visibility, features)

この関数は、パッケージ内のすべてのルールに適用されるメタデータを宣言します。パッケージ（BUILD ファイル）内で最大 1 回使用されます。

リポジトリ全体のすべてのルールに適用されるメタデータを宣言する対応する部分については、リポジトリのルートにある REPO.bazel ファイルの repo() 関数を使用します。repo() 関数は、package() とまったく同じ引数を取得します。

package() 関数は、ファイルの先頭にあるすべての load() ステートメントの直後、ルールの前に呼び出す必要があります。

引数

例

package(default_visibility = ["//foo:target"])

package_group

package_group(name, packages, includes)

この関数は、パッケージのセットを定義し、ラベルをそのセットに関連付けます。ラベルは visibility 属性で参照できます。

パッケージ グループは主に可視性制御に使用されます。一般公開されているターゲットは、ソースツリー内のすべてのパッケージから参照できます。非公開のターゲットは、独自のパッケージ内でのみ参照できます（サブパッケージは不可）。これらの極端なケースの中間では、ターゲットは自身のパッケージと、1 つ以上のパッケージ グループで記述されたパッケージのいずれかへのアクセスを許可する場合があります。可視性システムの詳細については、visibility 属性をご覧ください。

指定されたパッケージは、packages 属性に一致するか、includes 属性で言及されている他のパッケージ グループのいずれかにすでに含まれている場合、そのグループに含まれていると見なされます。

パッケージ グループは技術的にはターゲットですが、ルールによって作成されることはなく、可視性保護もありません。

引数

例

次の package_group 宣言は、熱帯フルーツを含む「tropical」というパッケージ グループを指定します。

package_group(
    name = "tropical",
    packages = [
        "//fruits/mango",
        "//fruits/orange",
        "//fruits/papaya/...",
    ],
)

次の宣言は、架空のアプリケーションのパッケージ グループを指定しています。

package_group(
    name = "fooapp",
    includes = [
        ":controller",
        ":model",
        ":view",
    ],
)

package_group(
    name = "model",
    packages = ["//fooapp/database"],
)

package_group(
    name = "view",
    packages = [
        "//fooapp/swingui",
        "//fooapp/webui",
    ],
)

package_group(
    name = "controller",
    packages = ["//fooapp/algorithm"],
)

exports_files

exports_files([label, ...], visibility, licenses)

exports_files() は、このパッケージに属し、他のパッケージにエクスポートされるファイルのリストを指定します。

パッケージの BUILD ファイルは、exports_files() ステートメントで明示的にエクスポートされている場合にのみ、別のパッケージに属するソースファイルを直接参照できます。詳しくは、ファイルの公開設定をご覧ください。

以前の動作として、ルールへの入力として言及されたファイルも、フラグ --incompatible_no_implicit_file_export が反転されるまで、デフォルトの可視性でエクスポートされます。ただし、この動作に依存することは避けるべきであり、積極的に移行する必要があります。

引数

引数は、現在のパッケージ内のファイル名のリストです。公開設定の宣言を指定することもできます。この場合、ファイルは指定されたターゲットに対して公開されます。公開設定が指定されていない場合、package 関数でパッケージのデフォルトの公開設定が指定されていても、ファイルはすべてのパッケージから参照できます。ライセンスを指定することもできます。

例

次の例では、他のパッケージが使用できるように、test_data パッケージのテキスト ファイル golden.txt をエクスポートします。たとえば、テストの data 属性で使用できます。

# from //test_data/BUILD

exports_files(["golden.txt"])

glob

glob(include, exclude=[], exclude_directories=1, allow_empty=True)

Glob は、特定のパスパターンに一致するすべてのファイルを検索し、それらのパスの新しい可変のソート済みリストを返すヘルパー関数です。Glob は、自身のパッケージ内のファイルのみを検索し、ソースファイルのみを検索します（生成されたファイルやその他のターゲットは検索しません）。

ソースファイルのパッケージ相対パスが include パターンのいずれかに一致し、exclude パターンのいずれにも一致しない場合、ソースファイルのラベルが結果に含まれます。

include リストと exclude リストには、現在のパッケージを基準とするパスパターンが含まれています。すべてのパターンは 1 つ以上のパスセグメントで構成できます。Unix パスと同様に、これらのセグメントは / で区切られます。セグメントには * ワイルドカードを含めることができます。これは、ディレクトリ区切り文字 / を除く、パスセグメント内の任意のサブ文字列（空のサブ文字列も含む）と一致します。このワイルドカードは、1 つのパス セグメント内で複数回使用できます。また、** ワイルドカードは 0 個以上の完全なパス セグメントに一致しますが、スタンドアロンのパス セグメントとして宣言する必要があります。

• foo/bar.txt がこのパッケージの foo/bar.txt ファイルと完全に一致する
• foo/*.txt は、ファイルが .txt で終わる場合、foo/ ディレクトリ内のすべてのファイルと一致します（foo/ がサブパッケージの場合を除く）。
• foo/a*.htm* は、foo/ ディレクトリ内のすべてのファイルに一致します。これらのファイルは、a で始まり、任意の文字列（空の場合もあります）が続き、.htm が続き、別の任意の文字列で終わります（foo/axx.htm や foo/a.html、foo/axxx.html など）。
• **/a.txt は、このパッケージのすべてのサブディレクトリにあるすべての a.txt ファイルと一致します。
• **/bar/**/*.txt は、結果のパスの少なくとも 1 つのディレクトリが bar（xxx/bar/yyy/zzz/a.txt や bar/a.txt など。** は 0 個のセグメントにも一致します）または bar/zzz/a.txt と呼ばれる場合、このパッケージのすべてのサブディレクトリ内のすべての .txt ファイルに一致します。
• ** は、このパッケージのすべてのサブディレクトリ内のすべてのファイルと一致します。
• foo**/a.txt は無効なパターンです。** はセグメントとして単独で存在する必要があるためです。

exclude_directories 引数が有効（1 に設定）の場合、ディレクトリ タイプのファイルは結果から除外されます（デフォルトは 1）。

allow_empty 引数が False に設定されている場合、結果が空のリストになる場合は glob 関数がエラーを返します。

重要な制限事項と注意事項がいくつかあります。

1. glob() は BUILD ファイルの評価中に実行されるため、glob() はソースツリー内のファイルのみに一致し、生成されたファイルには一致しません。ソースファイルと生成ファイルの両方を必要とするターゲットをビルドする場合は、生成ファイルの明示的なリストを glob に追加する必要があります。:mylib と :gen_java_srcs を使用した例をご覧ください。

2. ルールが一致したソースファイルと同じ名前の場合、ルールはファイルを「シャドーイング」します。

   これを理解するには、glob() がパスのリストを返すことを思い出してください。したがって、他のルールの属性（srcs = glob(["*.cc"]) など）で glob() を使用すると、一致するパスを明示的にリストするのと同じ効果が得られます。たとえば、glob() が ["Foo.java", "bar/Baz.java"] を生成するが、パッケージに「Foo.java」というルールもある場合（Bazel は警告しますが、許可されています）、glob() のコンシューマーは「Foo.java」ファイルではなく「Foo.java」ルール（その出力）を使用します。詳しくは、GitHub の問題 #10395 をご覧ください。

3. グロブはサブディレクトリ内のファイルと一致する場合があります。サブディレクトリ名にはワイルドカードを使用できます。ただし、

4. ラベルはパッケージ境界を越えることができず、glob はサブパッケージ内のファイルと一致しません。

   たとえば、パッケージ x の glob 式 **/*.cc は、x/y がパッケージとして（x/y/BUILD として、または package-path の他の場所で）存在する場合、x/y/z.cc を含みません。つまり、glob 式の結果は実際には BUILD ファイルの存在に依存します。つまり、x/y という名前のパッケージが存在しない場合、または --deleted_packages フラグを使用して削除済みとしてマークされている場合、同じ glob 式に x/y/z.cc が含まれます。

5. 上記の制限は、使用するワイルドカードに関係なく、すべての glob 式に適用されます。
6. ファイル名が . で始まる隠しファイルは、** と * の両方のワイルドカードで完全に一致します。複合パターンで隠しファイルを照合する場合は、パターンを . で始める必要があります。たとえば、* と .*.txt は .foo.txt と一致しますが、*.txt は一致しません。非表示ディレクトリも同様に照合されます。非表示ディレクトリには、入力として必要のないファイルが含まれている可能性があり、不要な glob ファイルの数とメモリ消費量が増加する可能性があります。非表示ディレクトリを除外するには、それらを「exclude」リスト引数に追加します。
7. 「**」ワイルドカードには 1 つのコーナーケースがあります。パターン "**" はパッケージのディレクトリ パスと一致しません。つまり、glob(["**"], exclude_directories = 0) は現在のパッケージのディレクトリの直下にあるすべてのファイルとディレクトリを推移的に照合します（ただし、サブパッケージのディレクトリには入りません。これについては前の注をご覧ください）。

一般に、グロブ パターンには、単なる「*」ではなく、適切な拡張子（*.html など）を指定するようにしてください。より明示的な名前は、自己文書化されており、バックアップ ファイルや emacs/vi/... の自動保存ファイルと誤って一致しないようにします。

ビルドルールを記述するときに、glob の要素を列挙できます。これにより、入力ごとに個別のルールを生成できます。下記の展開された glob の例をご覧ください。

glob の例

このディレクトリ内のすべての Java ファイルと、:gen_java_srcs ルールによって生成されたすべてのファイルから構築された Java ライブラリを作成します。

java_library(
    name = "mylib",
    srcs = glob(["*.java"]) + [":gen_java_srcs"],
    deps = "...",
)

genrule(
    name = "gen_java_srcs",
    outs = [
        "Foo.java",
        "Bar.java",
    ],
    ...
)

testdata ディレクトリ内のすべての txt ファイル（experimental.txt を除く）を含めます。testdata のサブディレクトリにあるファイルは含まれません。これらのファイルを含める場合は、再帰的グロブ（**）を使用します。

sh_test(
    name = "mytest",
    srcs = ["mytest.sh"],
    data = glob(
        ["testdata/*.txt"],
        exclude = ["testdata/experimental.txt"],
    ),
)

再帰的 glob の例

テストが testdata ディレクトリとそのサブディレクトリ（さらにそのサブディレクトリなど）内のすべての txt ファイルに依存するようにします。BUILD ファイルを含むサブディレクトリは無視されます。（上記の制限事項と注意事項をご覧ください）。

sh_test(
    name = "mytest",
    srcs = ["mytest.sh"],
    data = glob(["testdata/**/*.txt"]),
)

このディレクトリとすべてのサブディレクトリ（パスに testing という名前のディレクトリが含まれるものを除く）にあるすべての java ファイルからビルドされたライブラリを作成します。このパターンは、ビルドの増分性を低下させ、ビルド時間を長くする可能性があるため、可能な限り避けるべきです。

java_library(
    name = "mylib",
    srcs = glob(
        ["**/*.java"],
        exclude = ["**/testing/**"],
    ),
)

拡張された Glob の例

現在のディレクトリに *_test.cc の個々の genrule を作成し、ファイル内の行数をカウントします。

# Conveniently, the build language supports list comprehensions.
[genrule(
    name = "count_lines_" + f[:-3],  # strip ".cc"
    srcs = [f],
    outs = ["%s-linecount.txt" % f[:-3]],
    cmd = "wc -l $< >$@",
 ) for f in glob(["*_test.cc"])]

上記の BUILD ファイルがパッケージ //foo にあり、パッケージに一致するファイル a_test.cc、b_test.cc、c_test.cc が 3 つ含まれている場合、bazel query '//foo:all' を実行すると、生成されたすべてのルールが一覧表示されます。

$ bazel query '//foo:all' | sort
//foo:count_lines_a_test
//foo:count_lines_b_test
//foo:count_lines_c_test

選択

select(
    {conditionA: valuesA, conditionB: valuesB, ...},
    no_match_error = "custom message"
)

select() は、ルール属性を構成可能にするヘルパー関数です。ほぼすべての属性割り当ての右辺を置き換えることができるため、その値はコマンドラインの Bazel フラグに依存します。たとえば、プラットフォーム固有の依存関係を定義したり、ルールが「developer」モードと「release」モードのどちらでビルドされたかに応じて異なるリソースを埋め込んだりするために使用できます。

基本的な使い方は次のとおりです。

sh_binary(
    name = "mytarget",
    srcs = select({
        ":conditionA": ["mytarget_a.sh"],
        ":conditionB": ["mytarget_b.sh"],
        "//conditions:default": ["mytarget_default.sh"]
    })
)

これにより、通常のラベルリストの割り当てを、構成条件を一致する値にマッピングする select 呼び出しに置き換えることで、sh_binary の srcs 属性を構成可能にします。各条件は、config_setting または constraint_value へのラベル参照です。ターゲットの構成が想定される値のセットと一致する場合、「一致」します。mytarget#srcs の値は、現在の呼び出しに一致するラベルリストになります。

注:

• 呼び出しごとに 1 つの条件が選択されます。
• 複数の条件が一致し、そのうちの 1 つが他の条件の特殊化である場合、特殊化が優先されます。B に A と同じフラグと制約値がすべて含まれ、さらに追加のフラグまたは制約値が含まれている場合、条件 B は条件 A の特殊化と見なされます。これは、以下の例 2 に示すように、特殊化の解決は順序付けを行うようには設計されていないことも意味します。
• 複数の条件が一致し、そのうちの 1 つが他のすべての条件の特殊化でない場合、すべての条件が同じ値に解決されない限り、Bazel はエラーで失敗します。
• 他の条件が一致しない場合、特別な疑似ラベル //conditions:default が一致すると見なされます。この条件が省略されている場合は、エラーを回避するために他のルールが一致する必要があります。
• select は、より大きな属性割り当ての内部に埋め込むことができます。したがって、srcs = ["common.sh"] + select({ ":conditionA": ["myrule_a.sh"], ...}) と srcs = select({ ":conditionA": ["a.sh"]}) + select({ ":conditionB": ["b.sh"]}) は有効な式です。
• select はほとんどの属性で機能しますが、一部の属性では機能しません。互換性のない属性は、ドキュメントで nonconfigurable とマークされています。

  サブパッケージ

  subpackages(include, exclude=[], allow_empty=True)

  subpackages() は、glob() と同様のヘルパー関数で、ファイルやディレクトリではなくサブパッケージを一覧表示します。glob() と同じパスパターンを使用し、現在読み込まれている BUILD ファイルの直接の子孫であるサブパッケージと一致させることができます。一致パターンと除外パターンの詳細な説明と例については、glob をご覧ください。

  返されるサブパッケージのリストはソートされ、include のパターンに一致し、exclude のパターンに一致しない、現在の読み込みパッケージからの相対パスが含まれます。

  例

  次の例では、パッケージ foo/BUILD のすべての直接サブパッケージを一覧表示します。

  # The following BUILD files exist:
  # foo/BUILD
  # foo/bar/baz/BUILD
  # foo/sub/BUILD
  # foo/sub/deeper/BUILD
  #
  # In foo/BUILD a call to
  subs = subpackages(include = ["**"])
  
  # results in subs == ["sub", "bar/baz"]
  #
  # 'sub/deeper' is not included because it is a subpackage of 'foo/sub' not of
  # 'foo'
  

  一般に、この関数を直接呼び出すのではなく、skylib の「サブパッケージ」モジュールを使用することが推奨されます。