一般ルール

ルール

• エイリアス
• config_setting
• ファイル グループ
• genquery
• genrule
• starlark_doc_extract
• test_suite

エイリアス

alias(name, actual, compatible_with, deprecation, features, restricted_to, tags, target_compatible_with, testonly, visibility)

alias ルールは、ルールの別名を作成します。

エイリアス設定は「標準」のターゲットに対してのみ機能します。特に、package_group と test_suite にエイリアスを設定することはできません。

エイリアスの設定は、ターゲットの名前を変更するために大量のファイルを変更する必要がある大規模なリポジトリで役立ちます。また、ロジックを複数のターゲットで再利用したい場合は、エイリアス ルールを使用して select 関数呼び出しを格納することもできます。

エイリアス ルールには独自の公開設定宣言があります。その他の点では、参照するルールと同様に動作します（たとえば、エイリアスの testonly は無視され、代わりに参照されるルールの testonly-ness が使用されます）。ただし、いくつかの例外があります。

• コマンドラインにエイリアスが指定されている場合、テストは実行されません。参照先テストを実行するエイリアスを定義するには、tests 属性で単一のターゲットを持つ test_suite ルールを使用します。
• 環境グループを定義する場合、environment ルールのエイリアスはサポートされません。--target_environment コマンドライン オプションでもサポートされていません。

例

filegroup(
    name = "data",
    srcs = ["data.txt"],
)

alias(
    name = "other",
    actual = ":data",
)

引数

config_setting

config_setting(name, constraint_values, define_values, deprecation, distribs, features, flag_values, licenses, tags, testonly, values, visibility)

構成可能な属性をトリガーするために、想定される構成状態（ビルドフラグまたはプラットフォームの制約として表される）と一致すること。このルールの使用方法については、select をご覧ください。一般的な機能の概要については、 構成可能な属性をご覧ください。

例

以下は、--compilation_mode=opt または -c opt を（コマンドラインで明示的に、または .bazelrc ファイルから暗黙的に）設定しているすべてのビルドに一致します。

  config_setting(
      name = "simple",
      values = {"compilation_mode": "opt"}
  )
  

以下は、ARM をターゲットとし、カスタム定義 FOO=bar（bazel build --cpu=arm --define FOO=bar ... など）を適用するビルドに一致します。

  config_setting(
      name = "two_conditions",
      values = {
          "cpu": "arm",
          "define": "FOO=bar"
      }
  )
  

以下は、ユーザー定義フラグ --//custom_flags:foo=1 を（コマンドラインで明示的に、または .bazelrc ファイルから暗黙的に）設定するビルドと一致します。

  config_setting(
      name = "my_custom_flag_is_set",
      flag_values = { "//custom_flags:foo": "1" },
  )
  

以下は、//example:glibc_2_25 というラベルの constraint_value が存在すると仮定して、x86_64 アーキテクチャのプラットフォームと glibc バージョン 2.25 をターゲットとするすべてのビルドと一致します。なお、この 2 つを超える追加の制約値を定義している場合は、プラットフォームが一致します。

  config_setting(
      name = "64bit_glibc_2_25",
      constraint_values = [
          "@platforms//cpu:x86_64",
          "//example:glibc_2_25",
      ]
  )
  

メモ

• 複数の config_setting が現在の構成状態と一致した場合の動作については、select をご覧ください。
• 省略形をサポートするフラグ（--compilation_mode と -c など）では、values 定義で完全な形式を使用する必要があります。これらは、どちらの形式を使用した呼び出しとも自動的に一致します。
• フラグが複数の値を取る場合（--copt=-Da --copt=-Db やリスト型の Starlark フラグなど）、values = { "flag": "a" } は実際のリストの任意の場所に "a" が存在するときに一致します。

  values = { "myflag": "a,b" } も同じように動作します。これは --myflag=a --myflag=b、--myflag=a --myflag=b --myflag=c、--myflag=a,b、--myflag=c,b,a と一致します。正確なセマンティクスは、フラグによって異なります。たとえば、--copt は同じインスタンス内の複数の値をサポートしていません。--copt=a,b は ["a,b"] を生成し、--copt=a --copt=b は ["a", "b"] を生成します（values = { "copt": "a,b" } は前者と一致しますが後者には一致しません）。ただし、--ios_multi_cpus（Apple のルールの場合）は行います。-ios_multi_cpus=a,b と ios_multi_cpus=a --ios_multi_cpus=b はどちらも ["a", "b"] を生成します。フラグの定義を確認し、条件を慎重にテストして、期待どおりの結果が得られていることを確認します。

• 組み込みのビルドフラグでモデル化されない条件を定義する必要がある場合は、 Starlark 定義のフラグを使用します。--define も使用できますが、サポートが弱いため、おすすめしません。詳しくは、こちらをご覧ください。
• 異なるパッケージで同じ config_setting 定義を繰り返さないでください。代わりに、正規パッケージで定義された共通の config_setting を参照してください。
• values、define_values、constraint_values は、同じ config_setting で任意の組み合わせで使用できますが、特定の config_setting には少なくとも 1 つを設定する必要があります。

引数

            config_setting(
                name = "a_and_b",
                values = {
                    "define": "a=1",
                    "define": "b=2",
                })
          

            config_setting(
                name = "a_and_b",
                define_values = {
                    "a": "1",
                    "b": "2",
                })
          

filegroup

filegroup(name, srcs, data, compatible_with, deprecation, distribs, features, licenses, output_group, restricted_to, tags, target_compatible_with, testonly, visibility)

filegroup を使用して、ターゲットのコレクションにわかりやすい名前を付けます。これらは他のルールから参照できます。

ディレクトリを直接参照するのではなく、filegroup を使用することをおすすめします。後者は、ビルドシステムがディレクトリの下のすべてのファイルを完全に把握しているわけではないため、問題はありません。そのため、これらのファイルが変更されても再ビルドされない可能性があります。filegroup を glob と組み合わせると、すべてのファイルがビルドシステムに対して明示的に認識されるようになります。

例

2 つのソースファイルで構成される filegroup を作成する手順は次のとおりです。

filegroup(
    name = "mygroup",
    srcs = [
        "a_file.txt",
        "some/subdirectory/another_file.txt",
    ],
)

または、glob を使用して testdata ディレクトリを掘り下げます。

filegroup(
    name = "exported_testdata",
    srcs = glob([
        "testdata/*.dat",
        "testdata/logs/**/*.log",
    ]),
)

これらの定義を利用するには、任意のルールのラベルで filegroup を参照します。

cc_library(
    name = "my_library",
    srcs = ["foo.cc"],
    data = [
        "//my_package:exported_testdata",
        "//my_package:mygroup",
    ],
)

引数

genquery

genquery(name, deps, data, compatible_with, compressed_output, deprecation, distribs, exec_compatible_with, exec_properties, expression, features, licenses, opts, restricted_to, scope, strict, tags, target_compatible_with, testonly, visibility)

genquery() は、Blaze クエリ言語で指定されたクエリを実行し、結果をファイルにダンプします。

ビルドの整合性を保つため、クエリでは scope 属性で指定されたターゲットの推移的クロージャへのアクセスのみが許可されます。strict が未指定または true の場合、このルールに違反するクエリは実行中に失敗します（strict が false の場合、スコープ外のターゲットは単にスキップされ、警告が表示されます）。これを防ぐ最も簡単な方法は、クエリ式と同じラベルをスコープ内で指定することです。

ここで許可されるクエリとコマンドラインで許可される唯一の違いは、ワイルドカード ターゲット指定を含むクエリ（//pkg:* や //pkg:all など）は許可されないことです。これには 2 つの理由があります。1 つ目は、genquery がクエリの推移的クロージャ以外のターゲットが出力に影響しないようにスコープを指定する必要がある、2 つ目は、BUILD ファイルがワイルドカード依存関係をサポートしていない（例: deps=["//a/..."] は許可されない）ことです。

genquery の出力は、決定論的な出力を適用するために辞書順に並べられます。ただし、--output=graph|minrank|maxrank の場合、または somepath がトップレベル関数として使用されている場合は除きます。

出力ファイルの名前はルールの名前です。

例

この例では、指定されたターゲットの推移的クロージャ内のラベルのリストをファイルに書き込みます。

genquery(
    name = "kiwi-deps",
    expression = "deps(//kiwi:kiwi_lib)",
    scope = ["//kiwi:kiwi_lib"],
)

引数

genrule

genrule(name, srcs, outs, cmd, cmd_bash, cmd_bat, cmd_ps, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, executable, features, licenses, local, message, output_licenses, output_to_bindir, restricted_to, tags, target_compatible_with, testonly, toolchains, tools, visibility)

genrule は、ユーザー定義の Bash コマンドを使用して 1 つ以上のファイルを生成します。

genrule は、タスクに特定のルールがない場合に使用できる汎用のビルドルールです。たとえば、Bash のワンライナーを実行できます。ただし、C++ ファイルをコンパイルする必要がある場合は、煩雑な処理がすべてすでに完了しているため、既存の cc_* ルールに従います。

なお、genrule にはコマンド引数を解釈するためのシェルが必要です。PATH 上の任意のプログラムを簡単に参照できますが、これによりコマンドが非密閉型になり、再現できない場合があります。1 つのツールを実行するだけでよい場合は、代わりに run_binary の使用を検討してください。

テストの実行に genrule を使用しないでください。テストとテスト結果には、キャッシュ ポリシーや環境変数など、特別な割り当てがあります。テストは通常、ビルドの完了後にターゲット アーキテクチャで実行する必要がありますが、genrules はビルド中に exec アーキテクチャで実行されます（この 2 つが異なる場合があります）。汎用のテストルールが必要な場合は、sh_test を使用します。

クロスコンパイルの考慮事項

クロスコンパイルの詳細については、ユーザー マニュアルをご覧ください。

genrule はビルド中に実行されますが、その出力はビルド後にデプロイやテストに使用されることがよくあります。マイクロコントローラの C コードをコンパイルする場合を考えてみます。コンパイラは C ソースファイルを受け入れ、マイクロコントローラで実行されるコードを生成します。生成されたコードはビルドに使用した CPU では実行できませんが、C コンパイラ（ソースからコンパイルする場合）自体は実行する必要があります。

ビルドシステムは exec 構成を使用してビルドを実行するマシンを記述し、ターゲット構成を使用してビルドの出力を実行するマシンを記述します。これらのそれぞれを構成するオプションが提供され、対応するファイルを別々のディレクトリに分離して競合を回避します。

genrules の場合、ビルドシステムは依存関係が適切にビルドされていることを確認します。srcs は（必要に応じて）ターゲット構成用にビルドされ、tools は exec 構成用にビルドされ、出力はターゲット構成用のものとみなされます。また、genrule コマンドが対応するツールに渡すことができる 「Make」変数も用意されています。

genrule で deps 属性を定義しないという意図があります。他の組み込みルールは、ルール間で渡された言語依存のメタ情報を使用して、依存ルールの処理方法を自動的に決定しますが、genrule ではこのレベルの自動化は不可能です。genrule はファイル レベルとランファイル レベルでのみ機能します。

特殊なケース

Exec-exec コンパイル: 場合によっては、ビルドシステムで genrules を実行して、ビルド中に出力も実行できるようにする必要があります。たとえば、genrule がカスタム コンパイラをビルドする場合、そのカスタム コンパイラは後で別の genrule で使用されます。最初の genrule で exec 構成の出力を生成する必要があります。これは、コンパイラがもう一方の genrule で実行されるためです。この場合、ビルドシステムは適切な処理を自動的に行います。つまり、ターゲット構成ではなく、exec 構成に対して最初の genrule の srcs と outs をビルドします。詳しくは、ユーザー マニュアルをご覧ください。

JDK と C++ のツール: JDK または C++ コンパイラ スイートのツールを使用するために、ビルドシステムには、使用する一連の変数が用意されています。詳細については、Make 変数をご覧ください。

Genrule 環境

genrule コマンドは、set -e -o pipefail を使用してコマンドまたはパイプラインが失敗した場合に失敗するように構成された Bash シェルで実行されます。

ビルドツールは、PATH、PWD、TMPDIR などのコア変数のみを定義するサニタイズされたプロセス環境で Bash コマンドを実行します。ビルドを再現可能にするため、ユーザーのシェル環境で定義されている変数のほとんどは genrule のコマンドに渡されません。ただし、Bazel は（Blaze ではなく）ユーザーの PATH 環境変数の値を渡します。 PATH の値を変更すると、Bazel は次のビルドでコマンドを再実行します。

genrule コマンドでは、コマンド自体の子プロセスを接続する場合を除き、ネットワークにアクセスできません。ただし、これは現在は適用されていません。

ビルドシステムは既存の出力ファイルを自動的に削除しますが、必要な親ディレクトリは、genrule を実行する前に作成します。エラーが発生した場合は、出力ファイルも削除されます。

一般的なアドバイス

• genrule によって実行されるツールが決定的かつ密閉型であることを確認してください。出力にはタイムスタンプを書き込まないでください。また、セットとマップには安定した順序を使用します。また、絶対パスではなく、出力への相対ファイルパスのみを書き出す必要があります。このルールに従わないと、予期しないビルド動作（Bazel が予想した genrule を再構築しない）が発生し、キャッシュのパフォーマンスが低下します。
• 出力、ツール、ソースに $(location) を幅広く使用します。構成ごとに出力ファイルが分離されているため、genrules はハードコードされたパスや絶対パスに依存できません。
• 同一または非常に類似した genrule が複数の場所で使用される場合は、共通の Starlark マクロを作成します。genrule が複雑な場合は、スクリプトまたは Starlark ルールとして実装することを検討してください。これにより、可読性とテスト性が向上します。
• 終了コードが正しく genrule の成功または失敗を示していることを確認してください。
• stdout または stderr に情報メッセージを書き込まないでください。これはデバッグには役立ちますが、ノイズになる可能性があります。genrule が成功すると、サイレントである必要があります。一方、genrule が失敗すると、適切なエラー メッセージが出力されます。
• $$ evaluates to a $, a literal dollar-sign, so in order to invoke a shell command containing dollar-signs such as ls $(dirname $x), one must escape it thus: ls $$(dirname $$x).
• シンボリック リンクとディレクトリを作成しないようにします。Bazel は、genrules によって作成されたディレクトリ/シンボリック リンク構造をコピーせず、ディレクトリの依存関係チェックは機能しません。
• 他のルールで genrule を参照する場合は、genrule のラベルまたは個々の出力ファイルのラベルを使用できます。一方のアプローチのほうが読みやすい場合もありますが、使用ルールの srcs で出力を名前で参照すると、genrule の他の出力が意図せず取得されるのを回避できますが、genrule が多数の出力を生成する場合は面倒な場合があります。

例

この例では、foo.h を生成します。このコマンドは入力を取らないため、ソースはありません。このコマンドによって実行される「binary」は、genrule と同じパッケージ内の perl スクリプトです。

genrule(
    name = "foo",
    srcs = [],
    outs = ["foo.h"],
    cmd = "./$(location create_foo.pl) > \"$@\"",
    tools = ["create_foo.pl"],
)

次の例は、filegroup の使用方法と、別の genrule の出力を示しています。なお、明示的な $(location) ディレクティブの代わりに $(SRCS) を使用することもできます。この例では、デモ用として後者を使用しています。

genrule(
    name = "concat_all_files",
    srcs = [
        "//some:files",  # a filegroup with multiple files in it ==> $(locations)
        "//other:gen",   # a genrule with a single output ==> $(location)
    ],
    outs = ["concatenated.txt"],
    cmd = "cat $(locations //some:files) $(location //other:gen) > $@",
)

引数

starlark_doc_extract

starlark_doc_extract(name, deps, src, data, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, features, licenses, render_main_repo_name, restricted_to, symbol_names, tags, target_compatible_with, testonly, visibility)

starlark_doc_extract() は、指定された .bzl ファイルまたは .scl ファイルで定義または再エクスポートされたルール、関数（マクロを含む）、アスペクト、プロバイダのドキュメントを抽出します。このルールの出力は、Bazel ソースツリーの stardoc_output.proto で定義されている ModuleInfo バイナリ proto です。

暗黙的な出力ターゲット

• name.binaryproto（デフォルト出力）: ModuleInfo バイナリ proto。
• name.textproto（明示的にリクエストされた場合にのみビルド）: name.binaryproto のテキスト proto バージョン。

警告: このルールの出力形式は、必ずしも安定しているとは限りません。これは、主に Stardoc による内部使用を想定しています。

引数

test_suite

test_suite(name, compatible_with, deprecation, distribs, features, licenses, restricted_to, tags, target_compatible_with, testonly, tests, visibility)

test_suite は人間にとって「有用」とみなされる一連のテストを定義します。これにより、プロジェクトで「チェックイン前に実行する必要があるテスト」、「プロジェクトのストレステスト」、「すべて小規模なテスト」などの一連のテストを定義できます。blaze test コマンドは、このような編成に従います。blaze test //some/test:suite のような呼び出しでは、Blaze はまず //some/test:suite ターゲットに推移的に含まれているすべてのテスト ターゲットを列挙し（これを「test_suite 拡張」と呼んでいます）、その後、これらのターゲットをビルドおよびテストします。

例

現在のパッケージ内の小規模なテストをすべて実行するテストスイート。

test_suite(
    name = "small_tests",
    tags = ["small"],
)

指定されたテストセットを実行するテストスイート:

test_suite(
    name = "smoke_tests",
    tests = [
        "system_unittest",
        "public_api_unittest",
    ],
)

現在のパッケージ内の不安定でないすべてのテストを実行するためのテストスイート。

test_suite(
    name = "non_flaky_test",
    tags = ["-flaky"],
)

引数