BazelCon 2024 註冊現已開放！

本頁面由 Cloud Translation API 翻譯而成。

搭配 Bazel 使用 Android 原生開發套件

回報問題查看原始碼 Nightly · 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

如果您是 Bazel 新手，請先參閱「使用 Bazel 建構 Android」教學課程。

總覽

Bazel 可在許多不同的建構設定中執行，包括使用 Android Native Development Kit (NDK) 工具鍊。也就是說 cc_library 和 cc_binary 規則可直接在 Android 中編譯 Bazel。Bazel 會利用 android_ndk_repository 存放區來完成這項作業規則。

必要條件

請確認您已安裝 Android SDK 和 NDK。

如要設定 SDK 和 NDK，請在 WORKSPACE 中加入下列程式碼片段：

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

如要進一步瞭解 android_ndk_repository 規則，請參閱 Build 百科全書條目。

如果您使用的是最新版 Android NDK (r22 以上版本)，請使用 android_ndk_repository 的 Starlark 實作。請遵循指示：其讀物。

快速入門

如要建構 Android 適用的 C++，只要在 android_binary 或 android_library 規則中加入 cc_library 依附元件即可。

以下列 Android 應用程式專用 BUILD 檔案為例：

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

這個 BUILD 檔案會產生下列目標圖表：

搜尋結果範例

圖 1. 使用 cc_library 依附元件建構 Android 專案的圖表。

如要建構應用程式，只要執行以下指令即可：

bazel build //app/src/main:app

bazel build 指令會編譯 Java 檔案、Android 資源檔案 cc_library 規則，將所有內容封裝至 APK：

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel 會將所有 cc_libraries 編譯成單一共用物件 (.so) 檔案，預設會指定 armeabi-v7a ABI。如要變更此類別，或是針對同時參閱「設定目標 ABI。

設定範例

這個範例可在 Bazel 範例存放區中找到。

在 BUILD.bazel 檔案中，android_binary 定義了三個目標， android_library和 cc_library 規則

android_binary 頂層目標會建構 APK。

cc_library 目標包含單一 C++ 來源檔案，其中包含 JNI 函式實作：

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library 目標會指定 Java 來源、資源檔案和對 cc_library 目標的依附元件。在這個範例中，MainActivity.java 會載入共用物件檔案 libapp.so，並定義 JNI 的方法簽章函式：

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

設定 STL

如要設定 C++ STL，請使用標記 --android_crosstool_top。

bazel build //:app --android_crosstool_top=target label

@androidndk 中可用的 STL 如下：

STL	目標標籤
STLport	`@androidndk//:toolchain-stlport`
libc++	`@androidndk//:toolchain-libcpp`
gnustl	`@androidndk//:toolchain-gnu-libstdcpp`

r16 以下版本的預設 STL 為 gnustl。如果是 r17 以上版本，則 libc++。為了方便起見，目標 @androidndk//:default_crosstool 為稱為個別預設 STL。

請注意，從 r18 開始，STLport 和 gnustl 將會移除，使 libc++ 成為 NDK 中唯一的 STL。

如要進一步瞭解這些 STL，請參閱 NDK 說明文件。

設定目標 ABI

如要設定目標 ABI，請使用 --fat_apk_cpu 旗標，如下所示：

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

根據預設，Bazel 會為 armeabi-v7a 建構原生 Android 程式碼。為了針對 x86 建構 (例如模擬器) 請傳遞 --fat_apk_cpu=x86。如要為多個架構建立單一 APK，您可以指定多個 CPU：--fat_apk_cpu=armeabi-v7a,x86。

如果指定多個 ABI，Bazel 將會建構含有共用 ABI 的 APK 物件

視 NDK 修訂版本和 Android API 級別而定，可用的 ABI 如下：

NDK 修訂版本	ABI
16 歲以下	armeabi、armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64
17 以上版本	armeabi-v7a、arm64-v8a、x86、x86_64

請參閱 NDK 說明文件，進一步瞭解這些 ABI。

我們不建議對發布子版本使用多重 ABI Fat APK，因為這類 APK 會增加 APK 的大小，但對於開發和品質確保版本來說非常實用。

選取 C++ 標準

使用下列標記，按照 C++ 標準進行建構：

C++ 標準	檢舉
C++98	預設，不需要標記
C++11	`--cxxopt=-std=c++11`
C++14	`--cxxopt=-std=c++14`

例如：

bazel build //:app --cxxopt=-std=c++11

如要進一步瞭解如何使用 --cxxopt、--copt 和 --linkopt 傳遞編譯器和連結器標記，請參閱使用者手冊。

在 cc_library 中，您也可以將編譯器和連結器標記指定為屬性使用 copts 和 linkopts。例如：

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

與平台和工具鏈整合

Bazel 的設定模型正朝著平台和工具鏈發展。如果您的建構作業使用 --platforms 標記來選取要建構的架構或作業系統，您必須將 --extra_toolchains 標記傳遞至 Bazel，才能使用 NDK。

舉例來說，如要與 Go 規則提供的 android_arm64_cgo 工具鏈整合，請傳遞 --extra_toolchains=@androidndk//:all 和 --platforms 標記。

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

您也可以直接在 WORKSPACE 檔案中註冊：

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

註冊這些工具鏈會告知 Bazel 在解析架構和作業系統限制時，在 NDK BUILD 檔案 (適用於 NDK 20) 中尋找這些工具鏈：

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

運作方式：介紹 Android 設定轉換

android_binary 規則可明確要求 Bazel 在與 Android 相容設定，讓 Bazel 建構作業「可以正常運作」任何特殊標記 (--fat_apk_cpu 和 --android_crosstool_top 除外) ABI 和 STL 設定。

在背景，這項自動設定會使用 Android 設定轉場效果。

android_binary 等相容規則會自動將依附元件的設定變更為 Android 設定，因此只有 Android 專屬的子樹會受到影響。建構圖的其他部分會使用頂層目標設定進行處理。如果建構圖表中含有支援的路徑，它甚至可以處理兩種設定中的單一目標。

一旦 Bazel 處於與 Android 相容的設定中 (無論是在頂層指定，還是因為更高層級的轉換點)，遇到的其他轉換點都不會進一步修改設定。

觸發 Android 設定轉換的唯一內建位置是 android_binary 的 deps 屬性。

舉例來說，如果您嘗試使用 cc_library 建構 android_library 目標如果依附元件沒有任何旗標，就可能遇到缺少 JNI 的錯誤標題：

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

在理想情況下，這些自動轉換作業應能讓 Bazel 在大多數情況不過，如果 Bazel 指令列上的目標已低於任何這些轉換規則 (例如 C++ 開發人員測試特定 cc_library)，則必須使用自訂 --crosstool_top。

不使用 `android_binary` 建構 Android 版 `cc_library`

如要建構 Android 專用的獨立 cc_binary 或 cc_library，而不使用 android_binary，請使用 --crosstool_top、--cpu 和 --host_crosstool_top 標記。

例如：

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

在這個範例中，頂層 cc_library 和 cc_binary 目標是使用 NDK 工具鍊建構。不過，這會導致 Bazel 的自身主機工具使用 NDK 工具鏈 (因此是針對 Android) 進行建構，因為主機工具鏈是從目標工具鏈複製而來。如要解決這個問題，請指定將--host_crosstool_top變更為@bazel_tools//tools/cpp:toolchain到明確設定主機的 C++ 工具鍊。

採用這種做法會影響整個建構樹狀結構。

這些旗標可放入 bazelrc 設定 (每個 ABI 各一個)， project/.bazelrc：

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

接著，如要為 x86 建構 cc_library，請執行：

bazel build //my/cc/jni:target --config=android_x86

一般來說，這個方法適用於低層級目標 (例如 cc_library)，或確切知道要建構什麼內容仰賴自動設定將超出 android_binary 的層級用於預期成效目標建立很多您無法控管的目標