Chương trình đăng ký tham gia sự kiện BazelCon 2024 đã bắt đầu!

Trang này được dịch bởi Cloud Translation API.

Mức độ hiển thị

Báo cáo vấn đề Xem nguồn Nightly · 8.0 . 7.4 . 7.3 · 7.2 · 7.1 · 7.0 · 6.5

Trang này trình bày về hai hệ thống chế độ hiển thị của Bazel: chế độ hiển thị mục tiêu và chế độ hiển thị tải.

Cả hai loại chế độ hiển thị này đều giúp các nhà phát triển khác phân biệt giữa API công khai của thư viện và thông tin chi tiết về cách triển khai API đó, đồng thời giúp thực thi cấu trúc khi không gian làm việc của bạn phát triển. Bạn cũng có thể sử dụng chế độ hiển thị khi ngừng sử dụng API công khai để cho phép người dùng hiện tại trong khi từ chối người dùng mới.

Mức độ hiển thị mục tiêu

Chế độ hiển thị mục tiêu kiểm soát những đối tượng có thể phụ thuộc vào mục tiêu của bạn, tức là những đối tượng có thể sử dụng nhãn của mục tiêu bên trong một thuộc tính như deps. Một mục tiêu sẽ không tạo được trong giai đoạn phân tích nếu mục tiêu đó vi phạm chế độ hiển thị của một trong các phần phụ thuộc.

Thông thường, mục tiêu A hiển thị với mục tiêu B nếu chúng ở cùng một vị trí hoặc nếu A cấp quyền hiển thị cho vị trí của B. Khi không có macro tượng trưng, bạn có thể đơn giản hoá thuật ngữ "vị trí" thành "gói"; hãy xem phần dưới đây để biết thêm về macro tượng trưng.

Chế độ hiển thị được chỉ định bằng cách liệt kê các gói được phép. Việc cho phép một gói không nhất thiết có nghĩa là các gói con của gói đó cũng được phép. Để biết thêm thông tin chi tiết về gói và gói con, hãy xem phần Khái niệm và thuật ngữ.

Để tạo bản mô hình, bạn có thể tắt tính năng thực thi chế độ hiển thị mục tiêu bằng cách đặt cờ --check_visibility=false. Bạn không nên thực hiện việc này để sử dụng trong phiên bản chính thức trong mã đã gửi.

Cách chính để kiểm soát chế độ hiển thị là sử dụng thuộc tính visibility của quy tắc. Các tiểu mục sau đây mô tả định dạng của thuộc tính, cách áp dụng thuộc tính đó cho nhiều loại mục tiêu và hoạt động tương tác giữa hệ thống chế độ hiển thị và các macro tượng trưng.

Thông số kỹ thuật về chế độ hiển thị

Tất cả mục tiêu quy tắc đều có thuộc tính visibility chứa danh sách nhãn. Mỗi nhãn có một trong các dạng sau. Ngoại trừ biểu mẫu cuối cùng, đây chỉ là các phần giữ chỗ cú pháp không tương ứng với bất kỳ mục tiêu thực tế nào.

"//visibility:public": Cấp quyền truy cập vào tất cả các gói.
"//visibility:private": Không cấp thêm quyền truy cập nào; chỉ các mục tiêu trong gói của vị trí này mới có thể sử dụng mục tiêu này.
"//foo/bar:__pkg__": Cấp quyền truy cập vào //foo/bar (nhưng không phải các gói con của gói này).
"//foo/bar:__subpackages__": Cấp quyền truy cập //foo/bar và tất cả các gói con trực tiếp và gián tiếp của gói này.
"//some_pkg:my_package_group": Cấp quyền truy cập vào tất cả các gói thuộc package_group đã cho.
- Nhóm gói sử dụng cú pháp khác để chỉ định gói. Trong một nhóm gói, các biểu mẫu "//foo/bar:__pkg__" và "//foo/bar:__subpackages__" tương ứng được thay thế bằng "//foo/bar" và "//foo/bar/...". Tương tự, "//visibility:public" và "//visibility:private" chỉ là "public" và "private".

Ví dụ: nếu //some/package:mytarget đặt visibility thành [":__subpackages__", "//tests:__pkg__"], thì bất kỳ mục tiêu nào thuộc cây nguồn //some/package/... cũng như các mục tiêu được khai báo trong //tests/BUILD đều có thể sử dụng mục tiêu này, nhưng không phải các mục tiêu được xác định trong //tests/integration/BUILD.

Phương pháp hay nhất: Để hiển thị một số mục tiêu cho cùng một nhóm gói, hãy sử dụng package_group thay vì lặp lại danh sách trong thuộc tính visibility của mỗi mục tiêu. Điều này giúp tăng khả năng đọc và ngăn các danh sách bị mất đồng bộ hoá.

Phương pháp hay nhất: Khi cấp quyền hiển thị cho dự án của một nhóm khác, hãy ưu tiên __subpackages__ hơn __pkg__ để tránh tình trạng thay đổi chế độ hiển thị không cần thiết khi dự án đó phát triển và thêm các gói con mới.

Mức hiển thị mục tiêu của quy tắc

Mức độ hiển thị của mục tiêu quy tắc được xác định bằng cách lấy thuộc tính visibility của mục tiêu đó (hoặc giá trị mặc định phù hợp nếu không được cung cấp) và thêm vị trí đã khai báo mục tiêu. Đối với các mục tiêu không được khai báo trong macro tượng trưng, nếu gói chỉ định default_visibility, thì giá trị mặc định này sẽ được sử dụng; đối với tất cả các gói khác và đối với các mục tiêu được khai báo trong macro tượng trưng, giá trị mặc định chỉ là ["//visibility:private"].

# //mypkg/BUILD

package(default_visibility = ["//friend:__pkg__"])

cc_library(
    name = "t1",
    ...
    # No visibility explicitly specified.
    # Effective visibility is ["//friend:__pkg__", "//mypkg:__pkg__"].
    # If no default_visibility were given in package(...), the visibility would
    # instead default to ["//visibility:private"], and the effective visibility
    # would be ["//mypkg:__pkg__"].
)

cc_library(
    name = "t2",
    ...
    visibility = [":clients"],
    # Effective visibility is ["//mypkg:clients, "//mypkg:__pkg__"], which will
    # expand to ["//another_friend:__subpackages__", "//mypkg:__pkg__"].
)

cc_library(
    name = "t3",
    ...
    visibility = ["//visibility:private"],
    # Effective visibility is ["//mypkg:__pkg__"]
)

package_group(
    name = "clients",
    packages = ["//another_friend/..."],
)

Phương pháp hay nhất: Tránh đặt default_visibility thành công khai. Điều này có thể thuận tiện cho việc tạo bản mô hình hoặc trong cơ sở mã nhỏ, nhưng nguy cơ vô tình tạo mục tiêu công khai sẽ tăng lên khi cơ sở mã phát triển. Bạn nên nêu rõ những mục tiêu nào thuộc giao diện công khai của gói.

Chế độ hiển thị mục tiêu tệp đã tạo

Mục tiêu tệp được tạo có chế độ hiển thị giống với mục tiêu quy tắc tạo ra mục tiêu đó.

# //mypkg/BUILD

java_binary(
    name = "foo",
    ...
    visibility = ["//friend:__pkg__"],
)

# //friend/BUILD

some_rule(
    name = "bar",
    deps = [
        # Allowed directly by visibility of foo.
        "//mypkg:foo",
        # Also allowed. The java_binary's "_deploy.jar" implicit output file
        # target the same visibility as the rule target itself.
        "//mypkg:foo_deploy.jar",
    ]
    ...
)

Chế độ hiển thị mục tiêu của tệp nguồn

Bạn có thể khai báo rõ ràng mục tiêu tệp nguồn bằng cách sử dụng exports_files hoặc tạo ngầm mục tiêu đó bằng cách tham chiếu đến tên tệp trong thuộc tính nhãn của một quy tắc (bên ngoài macro tượng trưng). Cũng như các mục tiêu quy tắc, vị trí của lệnh gọi đến exports_files hoặc tệp BUILD tham chiếu đến tệp đầu vào, luôn được tự động thêm vào chế độ hiển thị của tệp.

Các tệp do exports_files khai báo có thể được tham số visibility đặt chế độ hiển thị cho hàm đó. Nếu bạn không cung cấp tham số này, chế độ hiển thị sẽ là công khai.

Đối với các tệp không xuất hiện trong lệnh gọi đến exports_files, chế độ hiển thị phụ thuộc vào giá trị của cờ --incompatible_no_implicit_file_export:

Nếu cờ này là true, thì chế độ hiển thị sẽ là riêng tư.
Nếu không, hành vi cũ sẽ áp dụng: Chế độ hiển thị giống với default_visibility của tệp BUILD hoặc chế độ riêng tư nếu bạn không chỉ định chế độ hiển thị mặc định.

Tránh dựa vào hành vi cũ. Luôn viết nội dung khai báo exports_files bất cứ khi nào mục tiêu tệp nguồn cần chế độ hiển thị không riêng tư.

Phương pháp hay nhất: Khi có thể, hãy ưu tiên hiển thị mục tiêu quy tắc thay vì tệp nguồn. Ví dụ: thay vì gọi exports_files trên tệp .java, hãy gói tệp đó trong mục tiêu java_library không riêng tư. Nhìn chung, mục tiêu quy tắc chỉ nên tham chiếu trực tiếp đến các tệp nguồn nằm trong cùng một gói.

Ví dụ:

Tệp //frobber/data/BUILD:

exports_files(["readme.txt"])

Tệp //frobber/bin/BUILD:

cc_binary(
  name = "my-program",
  data = ["//frobber/data:readme.txt"],
)

Chế độ hiển thị chế độ cài đặt cấu hình

Trước đây, Bazel không thực thi chế độ hiển thị cho các mục tiêu config_setting được tham chiếu trong các khoá của select(). Có hai cờ để xoá hành vi cũ này:

--incompatible_enforce_config_setting_visibility bật tính năng kiểm tra chế độ hiển thị cho các mục tiêu này. Để hỗ trợ quá trình di chuyển, tính năng này cũng khiến mọi config_setting không chỉ định visibility sẽ được coi là công khai (bất kể default_visibility cấp gói).
--incompatible_config_setting_private_default_visibility khiến các config_setting không chỉ định visibility tuân theo default_visibility của gói và sử dụng chế độ hiển thị riêng tư, giống như bất kỳ mục tiêu quy tắc nào khác. Phương thức này sẽ không hoạt động nếu bạn không đặt --incompatible_enforce_config_setting_visibility.

Tránh dựa vào hành vi cũ. Mọi config_setting dự định sử dụng bên ngoài gói hiện tại phải có visibility rõ ràng, nếu gói chưa chỉ định default_visibility phù hợp.

Mức hiển thị mục tiêu của nhóm gói

Mục tiêu package_group không có thuộc tính visibility. Các thông tin này luôn hiển thị công khai.

Mức độ hiển thị của các phần phụ thuộc ngầm ẩn

Một số quy tắc có phần phụ thuộc ngầm ẩn – các phần phụ thuộc không được nêu rõ trong tệp BUILD nhưng vốn có trong mọi thực thể của quy tắc đó. Ví dụ: quy tắc cc_library có thể tạo một phần phụ thuộc ngầm ẩn từ mỗi mục tiêu quy tắc đến một mục tiêu có thể thực thi đại diện cho trình biên dịch C++.

Chế độ hiển thị của phần phụ thuộc ngầm ẩn như vậy được kiểm tra liên quan đến gói chứa tệp .bzl trong đó quy tắc (hoặc khía cạnh) được xác định. Trong ví dụ của chúng ta, trình biên dịch C++ có thể là riêng tư miễn là trình biên dịch đó nằm trong cùng một gói với định nghĩa của quy tắc cc_library. Để dự phòng, nếu phần phụ thuộc ngầm ẩn không hiển thị trong định nghĩa, thì phần phụ thuộc đó sẽ được kiểm tra liên quan đến mục tiêu cc_library.

Nếu bạn muốn hạn chế việc sử dụng một quy tắc cho một số gói nhất định, hãy sử dụng chế độ hiển thị tải.

Chế độ hiển thị và macro tượng trưng

Phần này mô tả cách hệ thống chế độ hiển thị tương tác với macro tượng trưng.

Vị trí trong macro tượng trưng

Một chi tiết chính của hệ thống chế độ hiển thị là cách chúng ta xác định vị trí của một nội dung khai báo. Đối với các mục tiêu không được khai báo trong một macro tượng trưng, vị trí chỉ là gói chứa mục tiêu đó – gói của tệp BUILD. Tuy nhiên, đối với các mục tiêu được tạo trong một macro tượng trưng, vị trí là gói chứa tệp .bzl nơi định nghĩa của macro (câu lệnh my_macro = macro(...)) xuất hiện. Khi một mục tiêu được tạo bên trong nhiều mục tiêu lồng nhau, mục tiêu đó luôn là định nghĩa của macro tượng trưng ở trong cùng.

Hệ thống tương tự được dùng để xác định vị trí cần kiểm tra dựa trên chế độ hiển thị của một phần phụ thuộc nhất định. Nếu mục tiêu sử dụng được tạo bên trong một macro, chúng ta sẽ xem định nghĩa của macro bên trong cùng thay vì gói chứa mục tiêu sử dụng.

Điều này có nghĩa là tất cả các macro có mã được xác định trong cùng một gói sẽ tự động "là bạn bè" với nhau. Bạn có thể xem mọi mục tiêu do một macro được xác định trong //lib:defs.bzl tạo trực tiếp từ mọi macro khác được xác định trong //lib, bất kể các macro đó thực sự được tạo bản sao trong gói nào. Tương tự, các mục tiêu được khai báo trực tiếp trong //lib/BUILD và các macro cũ có thể xem và được các mục tiêu này xem. Ngược lại, các mục tiêu nằm trong cùng một gói không nhất thiết phải nhìn thấy nhau nếu ít nhất một trong số các mục tiêu đó được tạo bằng một macro tượng trưng.

Trong hàm triển khai của một macro tượng trưng, tham số visibility có giá trị hiệu quả của thuộc tính visibility của macro sau khi thêm vị trí mà macro được gọi. Cách tiêu chuẩn để một macro xuất một trong các mục tiêu của nó đến phương thức gọi là chuyển tiếp giá trị này cùng với phần khai báo của mục tiêu, như trong some_rule(..., visibility = visibility). Phương thức gọi của macro sẽ không thấy các mục tiêu bỏ qua thuộc tính này, trừ phi phương thức gọi đó nằm trong cùng một gói với định nghĩa macro. Hành vi này kết hợp, theo nghĩa là một chuỗi các lệnh gọi lồng nhau đến các macro con có thể truyền visibility = visibility, xuất lại các mục tiêu đã xuất của macro bên trong cho phương thức gọi ở mỗi cấp, mà không hiển thị bất kỳ chi tiết triển khai nào của macro.

Uỷ quyền đặc quyền cho một macro con

Mô hình chế độ hiển thị có một tính năng đặc biệt cho phép một macro uỷ quyền các quyền của nó cho một macro con. Điều này rất quan trọng để phân tích và soạn các macro.

Giả sử bạn có một macro my_macro tạo một cạnh phần phụ thuộc bằng cách sử dụng quy tắc some_library từ một gói khác:

# //macro/defs.bzl
load("//lib:defs.bzl", "some_library")

def _impl(name, visibility, ...):
    ...
    native.genrule(
        name = name + "_dependency"
        ...
    )
    some_library(
        name = name + "_consumer",
        deps = [name + "_dependency"],
        ...
    )

my_macro = macro(implementation = _impl, ...)

# //pkg/BUILD

load("//macro:defs.bzl", "my_macro")

my_macro(name = "foo", ...)

Mục tiêu //pkg:foo_dependency không có visibility được chỉ định, vì vậy, mục tiêu này chỉ xuất hiện trong //macro và hoạt động tốt cho mục tiêu sử dụng. Bây giờ, điều gì sẽ xảy ra nếu tác giả của //lib tái cấu trúc some_library để triển khai bằng macro?

# //lib:defs.bzl

def _impl(name, visibility, deps, ...):
    some_rule(
        # Main target, exported.
        name = name,
        visibility = visibility,
        deps = deps,
        ...)

some_library = macro(implementation = _impl, ...)

Với thay đổi này, vị trí của //pkg:foo_consumer hiện là //lib thay vì //macro, vì vậy, việc sử dụng //pkg:foo_dependency của nó vi phạm chế độ hiển thị của phần phụ thuộc. Tác giả của my_macro không thể truyền visibility = ["//lib"] vào phần khai báo phần phụ thuộc chỉ để xử lý thông tin chi tiết về cách triển khai này.

Vì lý do này, khi một phần phụ thuộc của một mục tiêu cũng là một giá trị thuộc tính của macro đã khai báo mục tiêu đó, chúng ta sẽ kiểm tra chế độ hiển thị của phần phụ thuộc đó so với vị trí của macro thay vì vị trí của mục tiêu sử dụng.

Trong ví dụ này, để xác thực xem //pkg:foo_consumer có thể thấy //pkg:foo_dependency hay không, chúng ta thấy rằng //pkg:foo_dependency cũng được truyền dưới dạng dữ liệu đầu vào cho lệnh gọi đến some_library bên trong my_macro, thay vào đó, hãy kiểm tra chế độ hiển thị của phần phụ thuộc so với vị trí của lệnh gọi này, //macro.

Quá trình này có thể lặp lại đệ quy, miễn là khai báo mục tiêu hoặc macro nằm bên trong một macro tượng trưng khác lấy nhãn của phần phụ thuộc trong một trong các thuộc tính được nhập nhãn.

Tải chế độ hiển thị

Load visibility (Chế độ hiển thị tải) kiểm soát việc tệp .bzl có thể được tải từ các tệp BUILD hoặc .bzl khác bên ngoài gói hiện tại hay không.

Tương tự như cách chế độ hiển thị mục tiêu bảo vệ mã nguồn được đóng gói bằng các mục tiêu, chế độ hiển thị tải sẽ bảo vệ logic bản dựng được đóng gói bằng các tệp .bzl. Ví dụ: tác giả tệp BUILD có thể muốn đưa một số nội dung khai báo mục tiêu lặp lại vào một macro trong tệp .bzl. Nếu không có tính năng bảo vệ chế độ hiển thị tải, họ có thể thấy macro của mình được các cộng tác viên khác sử dụng lại trong cùng một không gian làm việc, do đó việc sửa đổi macro sẽ làm hỏng bản dựng của các nhóm khác.

Xin lưu ý rằng tệp .bzl có thể có hoặc không có mục tiêu tệp nguồn tương ứng. Nếu có, không có gì đảm bảo rằng chế độ hiển thị tải và chế độ hiển thị mục tiêu trùng khớp với nhau. Tức là cùng một tệp BUILD có thể tải tệp .bzl nhưng không liệt kê tệp đó trong srcs của filegroup hoặc ngược lại. Đôi khi, điều này có thể gây ra sự cố cho các quy tắc muốn sử dụng tệp .bzl làm mã nguồn, chẳng hạn như để tạo tài liệu hoặc kiểm thử.

Để tạo bản mô hình, bạn có thể tắt tính năng thực thi chế độ hiển thị tải bằng cách đặt --check_bzl_visibility=false. Cũng như --check_visibility=false, bạn không nên làm điều này cho mã đã gửi.

Bạn có thể sử dụng tính năng hiển thị tải kể từ Bazel 6.0.

Khai báo chế độ hiển thị tải

Để đặt chế độ hiển thị tải của tệp .bzl, hãy gọi hàm visibility() từ bên trong tệp. Đối số cho visibility() là danh sách thông số kỹ thuật của gói, giống như thuộc tính packages của package_group. Tuy nhiên, visibility() không chấp nhận thông số kỹ thuật gói âm.

Lệnh gọi đến visibility() chỉ được xảy ra một lần cho mỗi tệp, ở cấp cao nhất (không phải bên trong một hàm) và tốt nhất là ngay sau câu lệnh load().

Không giống như chế độ hiển thị mục tiêu, chế độ hiển thị tải mặc định luôn là công khai. Các tệp không gọi visibility() luôn có thể tải được từ bất kỳ đâu trong không gian làm việc. Bạn nên thêm visibility("private") vào đầu mọi tệp .bzl mới không dành riêng cho việc sử dụng bên ngoài gói.

Ví dụ:

# //mylib/internal_defs.bzl

# Available to subpackages and to mylib's tests.
visibility(["//mylib/...", "//tests/mylib/..."])

def helper(...):
    ...

# //mylib/rules.bzl

load(":internal_defs.bzl", "helper")
# Set visibility explicitly, even though public is the default.
# Note the [] can be omitted when there's only one entry.
visibility("public")

myrule = rule(
    ...
)

# //someclient/BUILD

load("//mylib:rules.bzl", "myrule")          # ok
load("//mylib:internal_defs.bzl", "helper")  # error

...

Các phương pháp hiển thị tải

Phần này mô tả các mẹo để quản lý việc khai báo chế độ hiển thị tải.

Phân tích mức độ hiển thị

Khi nhiều tệp .bzl có cùng chế độ hiển thị, bạn nên đưa thông số kỹ thuật của gói vào một danh sách chung. Ví dụ:

# //mylib/internal_defs.bzl

visibility("private")

clients = [
    "//foo",
    "//bar/baz/...",
    ...
]

# //mylib/feature_A.bzl

load(":internal_defs.bzl", "clients")
visibility(clients)

...

# //mylib/feature_B.bzl

load(":internal_defs.bzl", "clients")
visibility(clients)

...

Điều này giúp ngăn chặn sự cố vô tình lệch giữa các chế độ hiển thị của nhiều tệp .bzl. Mã này cũng dễ đọc hơn khi danh sách clients lớn.

Soạn chế độ hiển thị

Đôi khi, tệp .bzl có thể cần hiển thị với danh sách cho phép bao gồm nhiều danh sách cho phép nhỏ hơn. Điều này tương tự như cách package_group có thể kết hợp các package_group khác thông qua thuộc tính includes.

Giả sử bạn đang ngừng sử dụng một macro được sử dụng rộng rãi. Bạn chỉ muốn người dùng hiện tại và các gói thuộc quyền sở hữu của nhóm của bạn mới xem được. Bạn có thể viết:

# //mylib/macros.bzl

load(":internal_defs.bzl", "our_packages")
load("//some_big_client:defs.bzl", "their_remaining_uses")

# List concatenation. Duplicates are fine.
visibility(our_packages + their_remaining_uses)

Loại bỏ trùng lặp bằng nhóm gói

Không giống như chế độ hiển thị mục tiêu, bạn không thể xác định chế độ hiển thị tải theo package_group. Nếu bạn muốn sử dụng lại cùng một danh sách cho phép cho cả chế độ hiển thị mục tiêu và chế độ hiển thị tải, tốt nhất bạn nên di chuyển danh sách thông số kỹ thuật của gói vào tệp .bzl, trong đó cả hai loại khai báo đều có thể tham chiếu đến tệp đó. Dựa trên ví dụ trong phần Tính đến chế độ hiển thị ở trên, bạn có thể viết:

# //mylib/BUILD

load(":internal_defs", "clients")

package_group(
    name = "my_pkg_grp",
    packages = clients,
)

Điều này chỉ hoạt động nếu danh sách không chứa bất kỳ thông số kỹ thuật gói phủ định nào.

Bảo vệ từng ký hiệu

Bất kỳ biểu tượng Starlark nào có tên bắt đầu bằng dấu gạch dưới đều không thể tải từ một tệp khác. Điều này giúp bạn dễ dàng tạo các ký hiệu riêng tư, nhưng không cho phép bạn chia sẻ các ký hiệu này với một nhóm tệp tin đáng tin cậy có giới hạn. Mặt khác, chế độ hiển thị tải cho phép bạn kiểm soát những gói nào khác có thể thấy .bzl file của bạn, nhưng không cho phép bạn ngăn tải bất kỳ ký hiệu nào không có dấu gạch dưới.

May mắn là bạn có thể kết hợp hai tính năng này để có được quyền kiểm soát chi tiết.

# //mylib/internal_defs.bzl

# Can't be public, because internal_helper shouldn't be exposed to the world.
visibility("private")

# Can't be underscore-prefixed, because this is
# needed by other .bzl files in mylib.
def internal_helper(...):
    ...

def public_util(...):
    ...

# //mylib/defs.bzl

load(":internal_defs", "internal_helper", _public_util="public_util")
visibility("public")

# internal_helper, as a loaded symbol, is available for use in this file but
# can't be imported by clients who load this file.
...

# Re-export public_util from this file by assigning it to a global variable.
# We needed to import it under a different name ("_public_util") in order for
# this assignment to be legal.
public_util = _public_util

Tìm lỗi mã nguồn bzl-visibility Buildifier

Có một trình tìm lỗi mã nguồn Buildifier sẽ đưa ra cảnh báo nếu người dùng tải một tệp từ thư mục có tên internal hoặc private, khi tệp của người dùng không nằm trong thư mục mẹ của thư mục đó. Công cụ tìm lỗi mã nguồn này có trước tính năng hiển thị tải và không cần thiết trong các không gian làm việc mà tệp .bzl khai báo chế độ hiển thị.