มาโครเดิม

มาโครเดิมคือฟังก์ชันที่ไม่มีโครงสร้างซึ่งเรียกจากไฟล์ BUILD ที่สร้างเป้าหมายได้ เมื่อสิ้นสุดระยะการโหลด มาโครเดิมจะไม่มีอยู่อีกต่อไป และ Bazel จะเห็นเฉพาะชุดกฎที่สร้างขึ้นจริง

เหตุผลที่คุณไม่ควรใช้มาโครเดิม (และควรใช้มาโครสัญลักษณ์แทน)

หากเป็นไปได้ คุณควรใช้มาโครสัญลักษณ์

มาโครเชิงสัญลักษณ์

• ป้องกันการกระทำจากระยะไกล
• ทำให้ซ่อนรายละเอียดการใช้งานได้ผ่านระดับการมองเห็นแบบละเอียด
• ใช้แอตทริบิวต์ที่พิมพ์ ซึ่งหมายถึงป้ายกำกับและการเลือก Conversion โดยอัตโนมัติ
• อ่านง่ายขึ้น
• จะมีการประเมินแบบเลื่อนเวลาในเร็วๆ นี้

การใช้งาน

กรณีการใช้งานทั่วไปของมาโครคือเมื่อคุณต้องการนำกฎมาใช้ซ้ำ

ตัวอย่างเช่น genrule ในไฟล์ BUILD จะสร้างไฟล์โดยใช้ //:generator โดยมีอาร์กิวเมนต์ some_arg ที่ฮาร์ดโค้ดในคำสั่ง

genrule(
    name = "file",
    outs = ["file.txt"],
    cmd = "$(location //:generator) some_arg > $@",
    tools = ["//:generator"],
)

หากต้องการสร้างไฟล์เพิ่มเติมด้วยอาร์กิวเมนต์ที่แตกต่างกัน คุณอาจต้อง แยกโค้ดนี้ไปยังฟังก์ชันมาโคร หากต้องการสร้างมาโครชื่อ file_generator ซึ่งมีพารามิเตอร์ name และ arg เราสามารถแทนที่ genrule ด้วยมาโครต่อไปนี้

load("//path:generator.bzl", "file_generator")

file_generator(
    name = "file",
    arg = "some_arg",
)

file_generator(
    name = "file-two",
    arg = "some_arg_two",
)

file_generator(
    name = "file-three",
    arg = "some_arg_three",
)

ในที่นี้ คุณจะโหลดสัญลักษณ์ file_generator จากไฟล์ .bzl ที่อยู่ในแพ็กเกจ //path การใส่คำจำกัดความฟังก์ชันมาโครใน.bzl ไฟล์แยกจะช่วยให้ไฟล์ BUILD สะอาดและประกาศได้ โดยสามารถโหลดไฟล์ .bzl จากแพ็กเกจใดก็ได้ในพื้นที่ทำงาน

สุดท้าย ใน path/generator.bzl ให้เขียนคำจำกัดความของมาโครเพื่อ แคปซูลและกำหนดพารามิเตอร์คำจำกัดความ genrule เดิม

def file_generator(name, arg, visibility=None):
  native.genrule(
    name = name,
    outs = [name + ".txt"],
    cmd = "$(location //:generator) %s > $@" % arg,
    tools = ["//:generator"],
    visibility = visibility,
  )

นอกจากนี้ คุณยังใช้มาโครเพื่อเชื่อมโยงกฎต่างๆ เข้าด้วยกันได้ด้วย ตัวอย่างนี้แสดง genrule ที่เชื่อมโยงกัน ซึ่ง genrule ใช้เอาต์พุตของ genrule ก่อนหน้าเป็นอินพุต

def chained_genrules(name, visibility=None):
  native.genrule(
    name = name + "-one",
    outs = [name + ".one"],
    cmd = "$(location :tool-one) $@",
    tools = [":tool-one"],
    visibility = ["//visibility:private"],
  )

  native.genrule(
    name = name + "-two",
    srcs = [name + ".one"],
    outs = [name + ".two"],
    cmd = "$(location :tool-two) $< $@",
    tools = [":tool-two"],
    visibility = visibility,
  )

ตัวอย่างจะกำหนดค่าการแสดงผลให้กับ genrule ที่ 2 เท่านั้น ซึ่งจะช่วยให้ผู้เขียนมาโครซ่อนเอาต์พุตของกฎระดับกลางไม่ให้เป้าหมายอื่นๆ ในพื้นที่ทำงานต้องพึ่งพา

การขยายมาโคร

เมื่อต้องการตรวจสอบว่ามาโครทำอะไร ให้ใช้คำสั่ง query กับ --output=build เพื่อดูรูปแบบที่ขยายแล้ว

$ bazel query --output=build :file
# /absolute/path/test/ext.bzl:42:3
genrule(
  name = "file",
  tools = ["//:generator"],
  outs = ["//test:file.txt"],
  cmd = "$(location //:generator) some_arg > $@",
)

การสร้างอินสแตนซ์ของกฎเนทีฟ

สร้างอินสแตนซ์ของกฎเนทีฟ (กฎที่ไม่ต้องมีคำสั่ง load()) ได้ จากโมดูล native ดังนี้

def my_macro(name, visibility=None):
  native.cc_library(
    name = name,
    srcs = ["main.cc"],
    visibility = visibility,
  )

หากต้องการทราบชื่อแพ็กเกจ (เช่น ไฟล์ BUILD ใดเรียกใช้มาโคร) ให้ใช้ฟังก์ชัน native.package_name() โปรดทราบว่า native ใช้ได้เฉพาะในไฟล์ .bzl เท่านั้น และใช้ในไฟล์ BUILD ไม่ได้

การแก้ไขป้ายกำกับในมาโคร

เนื่องจากระบบจะประเมินมาโครเดิมในระยะการโหลด สตริงป้ายกำกับ เช่น "//foo:bar" ที่อยู่ในมาโครเดิมจะได้รับการตีความโดยอิงตามไฟล์ BUILD ที่ใช้มาโครนั้น ไม่ใช่ไฟล์ .bzl ที่กำหนดมาโคร โดยทั่วไปแล้วลักษณะการทำงานนี้ไม่พึงประสงค์สำหรับมาโครที่ มีไว้เพื่อใช้ในที่เก็บข้อมูลอื่นๆ เช่น เนื่องจากเป็นส่วนหนึ่งของ ชุดกฎ Starlark ที่เผยแพร่

หากต้องการให้มีลักษณะการทำงานเหมือนกับกฎ Starlark ให้ห่อหุ้มสตริงป้ายกำกับด้วยตัวสร้าง Label

# @my_ruleset//rules:defs.bzl
def my_cc_wrapper(name, deps = [], **kwargs):
  native.cc_library(
    name = name,
    deps = deps + select({
      # Due to the use of Label, this label is resolved within @my_ruleset,
      # regardless of its site of use.
      Label("//config:needs_foo"): [
        # Due to the use of Label, this label will resolve to the correct target
        # even if the canonical name of @dep_of_my_ruleset should be different
        # in the main repo, such as due to repo mappings.
        Label("@dep_of_my_ruleset//tools:foo"),
      ],
      "//conditions:default": [],
    }),
    **kwargs,
  )

การแก้ไขข้อบกพร่อง

• bazel query --output=build //my/path:all จะแสดงให้เห็นว่าไฟล์ BUILD มีลักษณะอย่างไรหลังจากการประเมิน ขยายมาโคร Globs และลูปเดิมทั้งหมด ข้อจำกัดที่ทราบ: ระบบจะไม่แสดงนิพจน์ select ในเอาต์พุต

• คุณอาจกรองเอาต์พุตตาม generator_function (ฟังก์ชันที่สร้างกฎ) หรือ generator_name (แอตทริบิวต์ชื่อของมาโคร) ได้ bash $ bazel query --output=build 'attr(generator_function, my_macro, //my/path:all)'

• หากต้องการดูว่ากฎ foo สร้างขึ้นที่ใดในไฟล์ BUILD คุณ ลองใช้เคล็ดลับต่อไปนี้ได้ แทรกบรรทัดนี้ไว้ใกล้ด้านบนของไฟล์ BUILD cc_library(name = "foo") เรียกใช้ Bazel คุณจะได้รับการยกเว้นเมื่อ สร้างกฎ foo (เนื่องจากชื่อซ้ำ) ซึ่งจะแสดง การติดตามสแต็กแบบเต็ม

• นอกจากนี้ คุณยังใช้ print เพื่อแก้ไขข้อบกพร่องได้ด้วย โดยจะ แสดงข้อความเป็นDEBUGบรรทัดบันทึกระหว่างระยะการโหลด ยกเว้นในกรณีที่พบได้ยาก ให้นำการเรียกใช้ print ออก หรือทำให้เป็นแบบมีเงื่อนไขภายใต้พารามิเตอร์ debugging ที่มีค่าเริ่มต้นเป็น False ก่อนส่งโค้ดไปยังที่เก็บ

ข้อผิดพลาด

หากต้องการแสดงข้อผิดพลาด ให้ใช้ฟังก์ชัน fail อธิบายให้ผู้ใช้ทราบอย่างชัดเจนว่าเกิดข้อผิดพลาดใดและวิธีแก้ไขBUILDไฟล์ คุณไม่สามารถตรวจหาข้อผิดพลาดได้

def my_macro(name, deps, visibility=None):
  if len(deps) < 2:
    fail("Expected at least two values in deps")
  # ...

การประชุม

• ฟังก์ชันสาธารณะทั้งหมด (ฟังก์ชันที่ไม่ได้ขึ้นต้นด้วยขีดล่าง) ที่สร้างอินสแตนซ์ของกฎต้องมีอาร์กิวเมนต์ name อาร์กิวเมนต์นี้ไม่ควรเป็น อาร์กิวเมนต์ที่ไม่บังคับ (อย่าระบุค่าเริ่มต้น)

• ฟังก์ชันสาธารณะควรใช้สตริงเอกสารตาม รูปแบบของ Python

• ในไฟล์ BUILD อาร์กิวเมนต์ name ของมาโครต้องเป็นอาร์กิวเมนต์คีย์เวิร์ด (ไม่ใช่อาร์กิวเมนต์ตำแหน่ง)

• แอตทริบิวต์ name ของกฎที่สร้างโดยมาโครควรมีอาร์กิวเมนต์ชื่อเป็นคำนำหน้า เช่น macro(name = "foo") สามารถสร้าง cc_library foo และ genrule foo_gen

• ในกรณีส่วนใหญ่ พารามิเตอร์ที่ไม่บังคับควรมีค่าเริ่มต้นเป็น None None สามารถส่งไปยังกฎเนทีฟได้โดยตรง ซึ่งจะถือว่าเหมือนกับว่าคุณไม่ได้ส่งอาร์กิวเมนต์ใดๆ ดังนั้นจึงไม่จำเป็นต้องแทนที่ด้วย 0, False หรือ [] เพื่อจุดประสงค์นี้ แต่แมโครควรเลื่อน ไปใช้กฎที่สร้างขึ้น เนื่องจากค่าเริ่มต้นของกฎอาจซับซ้อนหรืออาจเปลี่ยนแปลงไป ตามเวลา นอกจากนี้ พารามิเตอร์ที่ตั้งค่าเริ่มต้นอย่างชัดเจน จะดูแตกต่างจากพารามิเตอร์ที่ไม่เคยตั้งค่า (หรือตั้งค่าเป็น None) เมื่อเข้าถึง ผ่านภาษาการค้นหาหรือส่วนประกอบภายในของระบบบิลด์

• มาโครควรมีอาร์กิวเมนต์ visibility ที่ไม่บังคับ