มาโครเดิม

มาโครเดิมคือฟังก์ชันที่ไม่มีโครงสร้างซึ่งเรียกจากไฟล์ BUILD ที่สร้างเป้าหมายได้ เมื่อสิ้นสุดระยะการโหลด มาโครเดิมจะไม่มีอยู่อีกต่อไป และ Bazel จะมองเห็นเฉพาะชุดกฎที่สร้างขึ้น

เหตุผลที่ไม่ควรใช้มาโครเดิม (และควรใช้มาโครเชิงสัญลักษณ์แทน)

คุณควรใช้มาโครสัญลักษณ์เมื่อเป็นไปได้

มาโครสัญลักษณ์

• ป้องกันการดำเนินการจากระยะไกล
• ซ่อนรายละเอียดการใช้งานผ่านระดับการเข้าถึงแบบละเอียดได้
• ใช้แอตทริบิวต์ที่พิมพ์ ซึ่งหมายความว่าใช้ป้ายกำกับอัตโนมัติและเลือก Conversion
• อ่านได้ง่ายขึ้น
• จะมีการประเมินแบบเลื่อนเวลาในเร็วๆ นี้

การใช้งาน

Use Case ทั่วไปสำหรับมาโครคือเมื่อคุณต้องการใช้กฎซ้ำ

ตัวอย่างเช่น genrule ในไฟล์ BUILD จะสร้างไฟล์โดยใช้ //:generator โดยมีอาร์กิวเมนต์ some_arg ที่กำหนดค่าไว้ล่วงหน้าในคำสั่ง

genrule(
    name = "file",
    outs = ["file.txt"],
    cmd = "$(location //:generator) some_arg > $@",
    tools = ["//:generator"],
)

หากต้องการสร้างไฟล์เพิ่มเติมโดยใช้อาร์กิวเมนต์อื่น คุณอาจต้องดึงข้อมูลโค้ดนี้ไปยังฟังก์ชันมาโคร หากต้องการสร้างมาโครชื่อ file_generator ซึ่งมีพารามิเตอร์ name และ arg เราอาจแทนที่ genrule ด้วยสิ่งต่อไปนี้

load("//path:generator.bzl", "file_generator")

file_generator(
    name = "file",
    arg = "some_arg",
)

file_generator(
    name = "file-two",
    arg = "some_arg_two",
)

file_generator(
    name = "file-three",
    arg = "some_arg_three",
)

ในส่วนนี้ คุณโหลดสัญลักษณ์ file_generator จากไฟล์ .bzl ที่อยู่ในแพ็กเกจ //path การวางคําจํากัดความของฟังก์ชันมาโครไว้ใน.bzlไฟล์แยกต่างหากจะช่วยให้ไฟล์ BUILD ของคุณสะอาดและเป็นระเบียบ และสามารถโหลดไฟล์ .bzl ได้จากแพ็กเกจใดก็ได้ในเวิร์กสเปซ

สุดท้าย ใน path/generator.bzl ให้เขียนคําจํากัดความของมาโครเพื่อรวมและกำหนดพารามิเตอร์ให้กับคําจํากัดความ genrule เดิม ดังนี้

def file_generator(name, arg, visibility=None):
  native.genrule(
    name = name,
    outs = [name + ".txt"],
    cmd = "$(location //:generator) %s > $@" % arg,
    tools = ["//:generator"],
    visibility = visibility,
  )

นอกจากนี้ คุณยังใช้มาโครเพื่อเชื่อมโยงกฎเข้าด้วยกันได้ด้วย ตัวอย่างนี้แสดง genrule ที่ต่อกัน โดย genrule หนึ่งใช้เอาต์พุตของ genrule ก่อนหน้าเป็นอินพุต

def chained_genrules(name, visibility=None):
  native.genrule(
    name = name + "-one",
    outs = [name + ".one"],
    cmd = "$(location :tool-one) $@",
    tools = [":tool-one"],
    visibility = ["//visibility:private"],
  )

  native.genrule(
    name = name + "-two",
    srcs = [name + ".one"],
    outs = [name + ".two"],
    cmd = "$(location :tool-two) $< $@",
    tools = [":tool-two"],
    visibility = visibility,
  )

ตัวอย่างนี้กําหนดค่าการแสดงผลให้กับ genrule ที่ 2 เท่านั้น ซึ่งช่วยให้ผู้เขียนมาโครซ่อนเอาต์พุตของกฎระดับกลางไม่ให้เป้าหมายอื่นๆ ในเวิร์กスペースใช้

มาโครที่ขยาย

หากต้องการตรวจสอบว่ามาโครทํางานอย่างไร ให้ใช้คําสั่ง query กับ --output=build เพื่อดูแบบขยาย

$ bazel query --output=build :file
# /absolute/path/test/ext.bzl:42:3
genrule(
  name = "file",
  tools = ["//:generator"],
  outs = ["//test:file.txt"],
  cmd = "$(location //:generator) some_arg > $@",
)

การสร้างอินสแตนซ์กฎเนทีฟ

คุณสามารถสร้างอินสแตนซ์กฎเนทีฟ (กฎที่ไม่ต้องใช้คำสั่ง load()) จากโมดูลเนทีฟ ดังนี้

def my_macro(name, visibility=None):
  native.cc_library(
    name = name,
    srcs = ["main.cc"],
    visibility = visibility,
  )

หากต้องการทราบชื่อแพ็กเกจ (เช่น ไฟล์ BUILD ไฟล์ใดเรียกใช้มาโคร) ให้ใช้ฟังก์ชัน native.package_name() โปรดทราบว่า native ใช้ได้เฉพาะในไฟล์ .bzl เท่านั้น และไม่ใช้ในไฟล์ BUILD

การแก้ไขป้ายกำกับในมาโคร

เนื่องจากมาโครเดิมจะได้รับการประเมินในระยะการโหลด สตริงป้ายกำกับ เช่น "//foo:bar" ที่ปรากฏในมาโครเดิมจะได้รับการตีความตามไฟล์ BUILD ที่ใช้มาโครนั้น ไม่ใช่ตามไฟล์ .bzl ที่กําหนดมาโคร โดยทั่วไปแล้ว ลักษณะการทำงานนี้ไม่เหมาะสมสำหรับมาโครที่มีไว้เพื่อใช้ในที่เก็บข้อมูลอื่นๆ เช่น เนื่องจากเป็นส่วนหนึ่งของชุดกฎ Starlark ที่เผยแพร่แล้ว

หากต้องการให้มีลักษณะการทำงานเหมือนกับกฎ Starlark ให้ตัดสตริงป้ายกำกับด้วยตัวสร้างLabel ดังนี้

# @my_ruleset//rules:defs.bzl
def my_cc_wrapper(name, deps = [], **kwargs):
  native.cc_library(
    name = name,
    deps = deps + select({
      # Due to the use of Label, this label is resolved within @my_ruleset,
      # regardless of its site of use.
      Label("//config:needs_foo"): [
        # Due to the use of Label, this label will resolve to the correct target
        # even if the canonical name of @dep_of_my_ruleset should be different
        # in the main repo, such as due to repo mappings.
        Label("@dep_of_my_ruleset//tools:foo"),
      ],
      "//conditions:default": [],
    }),
    **kwargs,
  )

การแก้ไขข้อบกพร่อง

• bazel query --output=build //my/path:all จะแสดงลักษณะของBUILDไฟล์หลังจากการประเมิน ระบบจะขยายมาโคร นิพจน์ทั่วไป และลูปเดิมทั้งหมด ข้อจํากัดที่ทราบ: นิพจน์ select จะไม่แสดงในเอาต์พุต

• คุณอาจกรองเอาต์พุตตาม generator_function (ฟังก์ชันที่สร้างขึ้นกฎ) หรือ generator_name (แอตทริบิวต์ชื่อของมาโคร) ดังนี้ bash $ bazel query --output=build 'attr(generator_function, my_macro, //my/path:all)'

• หากต้องการดูตําแหน่งที่ระบบสร้างกฎ foo ในไฟล์ BUILD ให้ลองใช้เคล็ดลับต่อไปนี้ แทรกบรรทัดนี้ไว้ใกล้กับด้านบนของไฟล์ BUILD cc_library(name = "foo") เรียกใช้ Bazel คุณจะได้รับข้อยกเว้นเมื่อสร้างกฎ foo (เนื่องจากชื่อทับซ้อนกัน) ซึ่งจะแสดงสแต็กเทรซแบบเต็ม

• คุณยังใช้ print สำหรับการแก้ไขข้อบกพร่องได้ด้วย โดยจะแสดงข้อความเป็นDEBUGบรรทัดบันทึกระหว่างระยะการโหลด ยกเว้นในกรณีที่เกิดขึ้นไม่บ่อยนัก ให้นําการเรียก print ออก หรือทําให้เป็นการเรียกแบบมีเงื่อนไขภายใต้พารามิเตอร์ debugging ที่เป็นค่าเริ่มต้นเป็น False ก่อนส่งโค้ดไปยังที่เก็บ

ข้อผิดพลาด

หากต้องการแสดงข้อผิดพลาด ให้ใช้ฟังก์ชัน fail อธิบายให้ผู้ใช้ทราบอย่างชัดเจนว่าเกิดข้อผิดพลาดอะไรขึ้นและวิธีแก้ไขไฟล์BUILD ไม่สามารถจับข้อผิดพลาดได้

def my_macro(name, deps, visibility=None):
  if len(deps) < 2:
    fail("Expected at least two values in deps")
  # ...

การประชุม

• ฟังก์ชันสาธารณะทั้งหมด (ฟังก์ชันที่ไม่ขึ้นต้นด้วยขีดล่าง) ที่ใช้สร้างอินสแตนซ์ของกฎต้องมีอาร์กิวเมนต์ name อาร์กิวเมนต์นี้ไม่ควรเป็นตัวเลือก (อย่าระบุค่าเริ่มต้น)

• ฟังก์ชันสาธารณะควรใช้สตริงเอกสารตามรูปแบบของ Python

• ในไฟล์ BUILD อาร์กิวเมนต์ name ของมาโครต้องเป็นอาร์กิวเมนต์คีย์เวิร์ด (ไม่ใช่อาร์กิวเมนต์ตำแหน่ง)

• แอตทริบิวต์ name ของกฎที่สร้างขึ้นโดยมาโครควรมีอาร์กิวเมนต์ชื่อเป็นคำนำหน้า ตัวอย่างเช่น macro(name = "foo") สามารถสร้าง cc_library foo และ genrule foo_gen

• ในกรณีส่วนใหญ่ พารามิเตอร์ที่ไม่บังคับควรมีค่าเริ่มต้นเป็น None None สามารถส่งไปยังกฎเนทีฟได้โดยตรง ซึ่งจะถือว่าเหมือนกับว่าคุณไม่ได้ส่งอาร์กิวเมนต์ใดๆ ดังนั้นจึงไม่จำเป็นต้องแทนที่ด้วย 0, False หรือ [] แต่ควรใช้กฎที่สร้างขึ้นแทน เนื่องจากค่าเริ่มต้นอาจซับซ้อนหรือเปลี่ยนแปลงได้เมื่อเวลาผ่านไป นอกจากนี้ พารามิเตอร์ที่ตั้งค่าเป็นค่าเริ่มต้นอย่างชัดเจนจะดูแตกต่างจากพารามิเตอร์ที่ไม่ได้ตั้งค่าไว้เลย (หรือตั้งค่าเป็น None) เมื่อเข้าถึงผ่านภาษาการค้นหาหรือข้อมูลภายในของระบบบิลด์

• มาโครควรมีอาร์กิวเมนต์ visibility ที่ไม่บังคับ