การเพิ่มประสิทธิภาพ

เมื่อเขียนกฎ ข้อผิดพลาดด้านประสิทธิภาพที่พบบ่อยที่สุดคือการข้ามหรือคัดลอกข้อมูลที่สะสมจาก Dependency เมื่อรวมการดำเนินการเหล่านี้ตลอดการ สร้างแล้ว การดำเนินการเหล่านี้อาจใช้เวลาหรือพื้นที่ O(N^2) ได้อย่างง่ายดาย คุณจึงควรทำความเข้าใจวิธีใช้ชุดทรัพยากร Dependency อย่างมีประสิทธิภาพเพื่อหลีกเลี่ยงปัญหานี้

การทำเช่นนี้อาจเป็นเรื่องยาก Bazel จึงมีโปรไฟล์เลอร์หน่วยความจำที่ ช่วยคุณค้นหาจุดที่คุณอาจทำผิดพลาด โปรดทราบว่า ค่าใช้จ่ายในการเขียนกฎที่ไม่มีประสิทธิภาพอาจไม่ชัดเจนจนกว่าจะมีการใช้งานอย่างแพร่หลาย

ใช้ชุดทรัพยากร Dependency

เมื่อใดก็ตามที่คุณรวบรวมข้อมูลจากการขึ้นต่อกันของกฎ คุณควรใช้ depsets ใช้เฉพาะรายการหรือพจนานุกรมธรรมดาเพื่อเผยแพร่ข้อมูล ที่เกี่ยวข้องกับกฎปัจจุบัน

Depset แสดงข้อมูลเป็นกราฟที่ซ้อนกันซึ่งช่วยให้แชร์ได้

ลองพิจารณากราฟต่อไปนี้

C -> B -> A
D ---^

แต่ละโหนดจะเผยแพร่สตริงเดียว เมื่อใช้ชุดทรัพยากรที่ต้องใช้ ข้อมูลจะมีลักษณะดังนี้

a = depset(direct=['a'])
b = depset(direct=['b'], transitive=[a])
c = depset(direct=['c'], transitive=[b])
d = depset(direct=['d'], transitive=[b])

โปรดทราบว่าแต่ละรายการจะกล่าวถึงเพียงครั้งเดียว โดยรายการจะแสดงข้อมูลต่อไปนี้

a = ['a']
b = ['b', 'a']
c = ['c', 'b', 'a']
d = ['d', 'b', 'a']

โปรดทราบว่าในกรณีนี้มีการกล่าวถึง 'a' ถึง 4 ครั้ง ยิ่งกราฟมีขนาดใหญ่ขึ้น ปัญหานี้ก็จะยิ่งแย่ลง

ตัวอย่างการใช้กฎที่ใช้ depsets อย่างถูกต้องเพื่อเผยแพร่ข้อมูลที่ส่งผ่านมีดังนี้ โปรดทราบว่าคุณสามารถเผยแพร่ข้อมูลระดับกฎ โดยใช้รายการได้หากต้องการ เนื่องจากไม่ได้เป็น O(N^2)

MyProvider = provider()

def _impl(ctx):
  my_things = ctx.attr.things
  all_things = depset(
      direct=my_things,
      transitive=[dep[MyProvider].all_things for dep in ctx.attr.deps]
  )
  ...
  return [MyProvider(
    my_things=my_things,  # OK, a flat list of rule-local things only
    all_things=all_things,  # OK, a depset containing dependencies
  )]

ดูข้อมูลเพิ่มเติมได้ที่หน้าภาพรวมของ Depset

หลีกเลี่ยงการโทรหา depset.to_list()

คุณสามารถบังคับให้ depset เป็นรายการแบบเรียบได้โดยใช้ to_list() แต่การทำเช่นนี้มักจะส่งผลให้มีค่าใช้จ่าย O(N^2) หากเป็นไปได้ ให้หลีกเลี่ยงการทำให้ชุดทรัพยากรย่อยแบน ยกเว้นเพื่อวัตถุประสงค์ในการแก้ไขข้อบกพร่อง

ความเข้าใจผิดที่พบบ่อยคือคุณสามารถลดความซับซ้อนของ Depset ได้อย่างอิสระหากคุณทำเฉพาะที่เป้าหมายระดับบนสุด เช่น <xx>_binary rule เนื่องจากต้นทุนจะไม่สะสมในแต่ละระดับของกราฟการสร้าง แต่ยังคงเป็น O(N^2) เมื่อ คุณสร้างชุดเป้าหมายที่มีทรัพยากร Dependency ทับซ้อนกัน กรณีนี้จะเกิดขึ้นเมื่อ สร้างการทดสอบ //foo/tests/... หรือเมื่อนำเข้าโปรเจ็กต์ IDE

ลดจำนวนการโทรเป็น depset

การเรียก depset ภายในลูปมักเป็นข้อผิดพลาด ซึ่งอาจทำให้เกิดชุดทรัพยากรที่มีการซ้อนกันลึกมาก ซึ่งมีประสิทธิภาพต่ำ เช่น

x = depset()
for i in inputs:
    # Do not do that.
    x = depset(transitive = [x, i.deps])

ซึ่งสามารถแทนที่โค้ดนี้ได้อย่างง่ายดาย ก่อนอื่น ให้รวบรวมชุดข้อมูลการอ้างอิงแบบทรานซิทีฟและ ผสานรวมทั้งหมดพร้อมกัน

transitive = []

for i in inputs:
    transitive.append(i.deps)

x = depset(transitive = transitive)

บางครั้งอาจลดขนาดได้โดยใช้การทำความเข้าใจรายการ

x = depset(transitive = [i.deps for i in inputs])

ใช้ ctx.actions.args() สำหรับบรรทัดคำสั่ง

เมื่อสร้างบรรทัดคำสั่ง คุณควรใช้ ctx.actions.args() ซึ่งจะเลื่อนการขยายชุดการอ้างอิงไปยังระยะการดำเนินการ

นอกเหนือจากความเร็วที่เพิ่มขึ้นอย่างมากแล้ว วิธีนี้ยังช่วยลดการใช้หน่วยความจำของกฎได้ด้วย ซึ่งบางครั้งอาจลดได้ถึง 90% หรือมากกว่า

เคล็ดลับบางส่วนมีดังนี้

• ส่งชุดทรัพยากรและรายการโดยตรงเป็นอาร์กิวเมนต์แทนการทำให้แบนด้วยตัวเอง ctx.actions.args() จะขยายรูปภาพให้คุณ หากต้องการทำการเปลี่ยนแปลงเนื้อหาของ Depset ให้ดูที่ ctx.actions.args#add เพื่อดูว่ามีอะไรที่ตรงกับความต้องการหรือไม่

• คุณส่ง File#path เป็นอาร์กิวเมนต์ใช่ไหม ไม่จำเป็น ระบบจะเปลี่ยน ไฟล์เป็น เส้นทางโดยอัตโนมัติและเลื่อนเวลาไปเป็นเวลาขยาย

• หลีกเลี่ยงการสร้างสตริงโดยการต่อสตริงเข้าด้วยกัน อาร์กิวเมนต์สตริงที่ดีที่สุดคือค่าคงที่ เนื่องจากระบบจะแชร์หน่วยความจำระหว่าง อินสแตนซ์ทั้งหมดของกฎ

• หากอาร์กิวเมนต์ยาวเกินไปสำหรับบรรทัดคำสั่ง คุณจะเขียนออบเจ็กต์ ctx.actions.args() ลงในไฟล์พารามิเตอร์แบบมีเงื่อนไขหรือไม่มีเงื่อนไขได้โดยใช้ ctx.actions.args#use_param_file ซึ่งจะ ดำเนินการเบื้องหลังเมื่อมีการเรียกใช้การดำเนินการ หากต้องการควบคุมไฟล์พารามิเตอร์อย่างชัดเจน คุณสามารถเขียนด้วยตนเองโดยใช้ ctx.actions.write

ตัวอย่าง

def _impl(ctx):
  ...
  args = ctx.actions.args()
  file = ctx.declare_file(...)
  files = depset(...)

  # Bad, constructs a full string "--foo=<file path>" for each rule instance
  args.add("--foo=" + file.path)

  # Good, shares "--foo" among all rule instances, and defers file.path to later
  # It will however pass ["--foo", <file path>] to the action command line,
  # instead of ["--foo=<file_path>"]
  args.add("--foo", file)

  # Use format if you prefer ["--foo=<file path>"] to ["--foo", <file path>]
  args.add(format="--foo=%s", value=file)

  # Bad, makes a giant string of a whole depset
  args.add(" ".join(["-I%s" % file.short_path for file in files])

  # Good, only stores a reference to the depset
  args.add_all(files, format_each="-I%s", map_each=_to_short_path)

# Function passed to map_each above
def _to_short_path(f):
  return f.short_path

อินพุตการดำเนินการแบบทรานซิทีฟควรเป็น Depset

เมื่อสร้างการดำเนินการโดยใช้ ctx.actions.run อย่าลืมว่าฟิลด์ inputs ยอมรับ DepSet ใช้เมื่อใดก็ตามที่มีการรวบรวมอินพุตจากทรัพยากร Dependency แบบทรานซิทีฟ

inputs = depset(...)
ctx.actions.run(
  inputs = inputs,  # Do *not* turn inputs into a list
  ...
)

แขวน

หาก Bazel ดูเหมือนจะค้าง คุณสามารถกด Ctrl-\ หรือส่งสัญญาณ SIGQUIT (kill -3 $(bazel info server_pid)) ไปยัง Bazel เพื่อรับการดัมพ์เธรดในไฟล์ $(bazel info output_base)/server/jvm.out

เนื่องจากคุณอาจเรียกใช้ bazel info ไม่ได้หาก Bazel ค้าง ไดเรกทอรี output_base มักจะเป็นไดเรกทอรีหลักของ bazel-<workspace> Symlink ในไดเรกทอรีพื้นที่ทำงาน

การสร้างโปรไฟล์ประสิทธิภาพ

โปรไฟล์การติดตาม JSON มีประโยชน์อย่างมาก ในการทำความเข้าใจอย่างรวดเร็วว่า Bazel ใช้เวลาไปกับอะไรบ้างในระหว่างการเรียกใช้

คุณอาจใช้แฟล็ก --experimental_command_profile เพื่อบันทึกโปรไฟล์ Java Flight Recorder ประเภทต่างๆ (เวลา CPU, เวลาจริง, การจัดสรรหน่วยความจำ และการแย่งชิงล็อก)

คุณอาจใช้แฟล็ก --starlark_cpu_profile เพื่อเขียนโปรไฟล์ pprof ของการใช้งาน CPU โดยเธรด Starlark ทั้งหมด

การสร้างโปรไฟล์หน่วยความจำ

Bazel มาพร้อมกับโปรไฟล์เลอร์หน่วยความจำในตัวที่จะช่วยให้คุณตรวจสอบการใช้หน่วยความจำของกฎได้ หากมีปัญหา คุณสามารถทิ้งฮีปเพื่อค้นหาบรรทัดโค้ดที่แน่นอนซึ่งทำให้เกิดปัญหาได้

การเปิดใช้การติดตามหน่วยความจำ

คุณต้องส่งแฟล็กการเริ่มต้น 2 รายการนี้ไปยังการเรียกใช้ Bazel ทุกครั้ง

  STARTUP_FLAGS=\
  --host_jvm_args=-javaagent:<path to java-allocation-instrumenter-3.3.4.jar> \
  --host_jvm_args=-DRULE_MEMORY_TRACKER=1

ซึ่งจะเริ่มเซิร์ฟเวอร์ในโหมดการติดตามหน่วยความจำ หากคุณลืมข้อมูลเหล่านี้แม้แต่การเรียกใช้ Bazel เพียงครั้งเดียว เซิร์ฟเวอร์จะรีสตาร์ทและคุณจะต้องเริ่มต้นใหม่

การใช้เครื่องมือติดตามหน่วยความจำ

ตัวอย่างเช่น ดูที่เป้าหมาย foo แล้วดูว่าเป้าหมายทำอะไร หากต้องการเรียกใช้เฉพาะการวิเคราะห์และไม่เรียกใช้ระยะการดำเนินการบิลด์ ให้เพิ่มแฟล็ก --nobuild

$ bazel $(STARTUP_FLAGS) build --nobuild //foo:foo

จากนั้นดูว่าอินสแตนซ์ Bazel ทั้งหมดใช้หน่วยความจำเท่าใด

$ bazel $(STARTUP_FLAGS) info used-heap-size-after-gc
> 2594MB

แยกตามคลาสของกฎโดยใช้ bazel dump --rules ดังนี้

$ bazel $(STARTUP_FLAGS) dump --rules
>

RULE                                 COUNT     ACTIONS          BYTES         EACH
genrule                             33,762      33,801    291,538,824        8,635
config_setting                      25,374           0     24,897,336          981
filegroup                           25,369      25,369     97,496,272        3,843
cc_library                           5,372      73,235    182,214,456       33,919
proto_library                        4,140     110,409    186,776,864       45,115
android_library                      2,621      36,921    218,504,848       83,366
java_library                         2,371      12,459     38,841,000       16,381
_gen_source                            719       2,157      9,195,312       12,789
_check_proto_library_deps              719         668      1,835,288        2,552
... (more output)

ดูว่าหน่วยความจำจะไปที่ใดโดยสร้างpprofไฟล์ โดยใช้ bazel dump --skylark_memory

$ bazel $(STARTUP_FLAGS) dump --skylark_memory=$HOME/prof.gz
> Dumping Starlark heap to: /usr/local/google/home/$USER/prof.gz

ใช้เครื่องมือ pprof เพื่อตรวจสอบฮีป จุดเริ่มต้นที่ดีคือการรับกราฟเปลวไฟโดยใช้ pprof -flame $HOME/prof.gz

ดาวน์โหลด pprof จาก https://github.com/google/pprof

รับการดัมพ์ข้อความของเว็บไซต์การโทรที่ได้รับความนิยมมากที่สุดซึ่งมีคำอธิบายประกอบเป็นบรรทัดดังนี้

$ pprof -text -lines $HOME/prof.gz
>
      flat  flat%   sum%        cum   cum%
  146.11MB 19.64% 19.64%   146.11MB 19.64%  android_library <native>:-1
  113.02MB 15.19% 34.83%   113.02MB 15.19%  genrule <native>:-1
   74.11MB  9.96% 44.80%    74.11MB  9.96%  glob <native>:-1
   55.98MB  7.53% 52.32%    55.98MB  7.53%  filegroup <native>:-1
   53.44MB  7.18% 59.51%    53.44MB  7.18%  sh_test <native>:-1
   26.55MB  3.57% 63.07%    26.55MB  3.57%  _generate_foo_files /foo/tc/tc.bzl:491
   26.01MB  3.50% 66.57%    26.01MB  3.50%  _build_foo_impl /foo/build_test.bzl:78
   22.01MB  2.96% 69.53%    22.01MB  2.96%  _build_foo_impl /foo/build_test.bzl:73
   ... (more output)