สำหรับเอกสารรุ่นที่เสถียร โปรดใช้รายการแบบเลื่อนลง "เอกสารที่มีเวอร์ชัน" มุมมองเริ่มต้นจะแสดงเวอร์ชันล่าสุดที่ HEAD

หน้านี้ได้รับการแปลโดย Cloud Translation API

การใช้ชุดพัฒนาซอฟต์แวร์แบบเนทีฟของ Android กับ Bazel

หากคุณเพิ่งเคยใช้ Bazel โปรดเริ่มต้นด้วยบทแนะนำการสร้าง Android ด้วย Bazel

ภาพรวม

Bazel ทำงานได้ในการกำหนดค่าบิวด์ต่างๆ มากมาย ซึ่งรวมถึงหลายรูปแบบที่ใช้เชนเครื่องมือ Android Native Development Kit (NDK) ซึ่งหมายความว่าระบบจะคอมไพล์กฎ cc_library และ cc_binary ปกติสำหรับ Android ได้โดยตรงใน Bazel Bazel ดำเนินการนี้ด้วยการใช้กฎที่เก็บ android_ndk_repository

ข้อกำหนดเบื้องต้น

โปรดตรวจสอบว่าคุณติดตั้ง Android SDK และ NDK แล้ว

หากต้องการตั้งค่า SDK และ NDK ให้เพิ่มข้อมูลโค้ดต่อไปนี้ลงใน WORKSPACE

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

ดูข้อมูลเพิ่มเติมเกี่ยวกับกฎ android_ndk_repository ได้ที่รายการสร้างสารานุกรม

หากคุณใช้ Android NDK เวอร์ชันล่าสุด (r22 ขึ้นไป) ให้ใช้การใช้งาน Starlark ของ android_ndk_repository ทำตามวิธีการใน README

คู่มือเริ่มต้นฉบับย่อ

หากต้องการสร้าง C++ สำหรับ Android เพียงเพิ่มทรัพยากร Dependency cc_library ลงในกฎ android_binary หรือ android_library

เช่น ระบุไฟล์ BUILD ต่อไปนี้สำหรับแอป Android

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

ไฟล์ BUILD นี้จะส่งผลให้เกิดกราฟเป้าหมายต่อไปนี้

ตัวอย่างผลการแข่ง

รูปที่ 1 สร้างกราฟสำหรับโปรเจ็กต์ Android ด้วยทรัพยากร Dependency ของ cc_library

หากต้องการสร้างแอป เพียงเรียกใช้:

bazel build //app/src/main:app

คำสั่ง bazel build จะรวมไฟล์ Java, ไฟล์ทรัพยากรของ Android และกฎ cc_library และรวมทุกอย่างลงใน APK ดังนี้

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel คอมไพล์ cc_libraries ทั้งหมดเป็นไฟล์ออบเจ็กต์ที่แชร์ไฟล์เดียว (.so) ซึ่งกำหนดเป้าหมายสำหรับ armeabi-v7a ABI ตามค่าเริ่มต้น หากต้องการเปลี่ยนการตั้งค่านี้หรือบิลด์สำหรับ ABI หลายรายการพร้อมกัน ให้ดูหัวข้อการกำหนดค่า ABI เป้าหมาย

ตัวอย่างการตั้งค่า

ตัวอย่างนี้อยู่ในที่เก็บตัวอย่าง Bazel

ในไฟล์ BUILD.bazel จะมีการกำหนดเป้าหมาย 3 รายการไว้ด้วยกฎ android_binary, android_library และ cc_library

เป้าหมายระดับบนสุด android_binary จะสร้าง APK

เป้าหมาย cc_library มีไฟล์แหล่งที่มา C++ ไฟล์เดียวที่มีการติดตั้งใช้งานฟังก์ชัน JNI ดังนี้

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

เป้าหมาย android_library จะระบุแหล่งที่มาของ Java, ไฟล์ทรัพยากร และความเกี่ยวข้องกับเป้าหมาย cc_library สำหรับตัวอย่างนี้ MainActivity.java จะโหลดไฟล์ออบเจ็กต์ที่แชร์ libapp.so และกำหนดลายเซ็นของเมธอดสำหรับฟังก์ชัน JNI ดังนี้

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

การกำหนดค่า ABI เป้าหมาย

หากต้องการกำหนดค่า ABI เป้าหมาย ให้ใช้แฟล็ก --android_platforms ดังนี้

bazel build //:app --android_platforms=comma-separated list of platforms

เช่นเดียวกับแฟล็ก --platforms ค่าที่ส่งไปยัง --android_platforms คือป้ายกำกับของเป้าหมาย platform โดยใช้ค่าจำกัดมาตรฐานเพื่ออธิบายอุปกรณ์ของคุณ

เช่น สำหรับอุปกรณ์ Android ที่ใช้โปรเซสเซอร์ ARM 64 บิต คุณควรกำหนดแพลตฟอร์มดังนี้

platform(
    name = "android_arm64",
    constraint_values = [
        "@platforms//os:android",
        "@platforms//cpu:arm64",
    ],
)

Android platform ทุกเครื่องควรใช้ข้อจำกัดของระบบปฏิบัติการ @platforms//os:android หากต้องการย้ายข้อมูลข้อจำกัด CPU โปรดตรวจสอบแผนภูมินี้

ค่า CPU	แพลตฟอร์ม
`armeabi-v7a`	`@platforms//cpu:arm`
`arm64-v8a`	`@platforms//cpu:arm64`
`x86`	`@platforms//cpu:x86_32`
`x86_64`	`@platforms//cpu:x86_64`

และแน่นอนว่าสำหรับ APK แบบหลายสถาปัตยกรรม คุณส่งป้ายกำกับหลายรายการ เช่น --android_platforms=//:arm64,//:x86_64 (สมมติว่าคุณกำหนด APK เหล่านั้นไว้ในไฟล์ BUILD.bazel ระดับบนสุด)

Bazel เลือกแพลตฟอร์ม Android เริ่มต้นไม่ได้ จึงต้องกำหนดและระบุแพลตฟอร์มด้วย --android_platforms

ABI ต่อไปนี้จะพร้อมใช้งานโดยขึ้นอยู่กับการแก้ไข NDK และระดับ API ของ Android

การแก้ไข NDK	ABI
ไม่เกิน 16 ปี	Armeabi, Armeabi-V7a, Arm64-V8a, Mips, Mips64, X86, X86_64
17 ปีขึ้นไป	Armeabi-V7a, Arm64-V8a, X86, x86_64

ดูข้อมูลเพิ่มเติมเกี่ยวกับ ABI เหล่านี้ได้ในเอกสาร NDK

ไม่แนะนำให้ใช้ APK ของ Multi-ABI Fat สำหรับบิลด์ที่เผยแพร่ เนื่องจากจะเพิ่มขนาดของ APK แต่อาจมีประโยชน์สำหรับบิลด์การพัฒนาและ QA

การเลือกมาตรฐาน C++

ใช้แฟล็กต่อไปนี้เพื่อสร้างตามมาตรฐาน C++

มาตรฐาน C++	ธง
C++98	ค่าเริ่มต้น ไม่ต้องมีการแจ้งว่าไม่เหมาะสม
ซี++11	`--cxxopt=-std=c++11`
C++14	`--cxxopt=-std=c++14`
ซี++17	`--cxxopt=-std=c++17`

เช่น

bazel build //:app --cxxopt=-std=c++11

อ่านข้อมูลเพิ่มเติมเกี่ยวกับการส่งแฟล็กคอมไพเลอร์และ Linker ด้วย --cxxopt, --copt และ --linkopt ในคู่มือผู้ใช้

คุณยังระบุแฟล็กผู้คอมไพล์และ Linker เป็นแอตทริบิวต์ใน cc_library โดยใช้ copts และ linkopts ได้ด้วย เช่น

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

การสร้าง `cc_library` สำหรับ Android โดยไม่ใช้ `android_binary`

หากต้องการสร้าง cc_binary หรือ cc_library แบบสแตนด์อโลนสำหรับ Android โดยไม่ใช้ android_binary ให้ใช้แฟล็ก --platforms

ตัวอย่างเช่น สมมติว่าคุณกำหนดแพลตฟอร์ม Android ใน my/platforms/BUILD

bazel build //my/cc/jni:target \
      --platforms=//my/platforms:x86_64

วิธีนี้ทำให้โครงสร้างบิลด์ทั้งหมดได้รับผลกระทบ

แฟล็กเหล่านี้สามารถใส่ลงในการกำหนดค่า bazelrc (1 รายการสำหรับ ABI แต่ละรายการ) ใน project/.bazelrc

common:android_x86 --platforms=//my/platforms:x86

common:android_armeabi-v7a --platforms=//my/platforms:armeabi-v7a

# In general
common:android_<abi> --platforms=//my/platforms:<abi>

จากนั้นหากต้องการสร้าง cc_library สำหรับ x86 ให้เรียกใช้คำสั่งต่อไปนี้

bazel build //my/cc/jni:target --config=android_x86

โดยทั่วไป ใช้วิธีนี้กับเป้าหมายระดับต่ำ (เช่น cc_library) หรือเมื่อทราบแน่ชัดว่ากำลังสร้างอะไร ใช้การเปลี่ยนการกำหนดค่าอัตโนมัติจาก android_binary สำหรับเป้าหมายระดับสูงที่คุณคาดว่าจะสร้างเป้าหมายจำนวนมากที่คุณไม่ได้ควบคุม