Depset คือโครงสร้างข้อมูลที่เฉพาะเจาะจงสำหรับการรวบรวมข้อมูลจากข้อกําหนดที่เกี่ยวข้องแบบเปลี่ยนผ่านของเป้าหมายอย่างมีประสิทธิภาพ เงื่อนไขเป็นองค์ประกอบสําคัญของการดำเนินการตามกฎ
ฟีเจอร์ที่โดดเด่นของ depset คือการดำเนินการรวมที่ประหยัดเวลาและพื้นที่เก็บข้อมูล ตัวสร้าง Depset ยอมรับรายการองค์ประกอบ ("โดยตรง") และรายการ Depset อื่นๆ ("สกรรมกริยา") และแสดงผล Depset ที่แสดงถึงชุดที่มีเอลิเมนต์โดยตรงทั้งหมดและการรวมของชุดทางอ้อมทั้งหมด โดยหลักการแล้ว ตัวสร้างจะสร้างโหนดกราฟใหม่ที่มีโหนดโดยตรงและโหนดทรานซิทีฟเป็นตัวสืบทอด Depset มีการเรียงลำดับความหมายที่กำหนดไว้แล้ว โดยอิงตามการข้ามผ่านของกราฟนี้
ตัวอย่างการใช้ชุดข้อมูลต่อไปนี้
จัดเก็บเส้นทางของไฟล์ออบเจ็กต์ทั้งหมดสำหรับไลบรารีของโปรแกรม ซึ่งสามารถส่งต่อไปยังการดำเนินการของโปรแกรมลิงก์ผ่านผู้ให้บริการได้
สำหรับภาษาที่แปลโดยอินเทอร์พรีเตอร์ ให้จัดเก็บไฟล์ต้นทางทรานซิทีฟที่รวมอยู่ในไฟล์รันไฟล์ปฏิบัติการ
คำอธิบายและการดำเนินการ
ในแง่แนวคิด ชุดข้อมูล Dependency คือกราฟแบบ Directed Acyclic Graph (DAG) ซึ่งโดยทั่วไปจะมีลักษณะคล้ายกับกราฟเป้าหมาย โดยสร้างขึ้นจากใบไม้ขึ้นไปจนถึงราก เป้าหมายแต่ละรายการในเชนการพึ่งพาสามารถเพิ่มเนื้อหาของตัวเองไว้ด้านบนของรายการก่อนหน้าได้โดยไม่ต้องอ่านหรือคัดลอก
โหนดแต่ละโหนดใน DAG จะมีรายการองค์ประกอบโดยตรงและรายการโหนดย่อย เนื้อหาของ depset คือองค์ประกอบแบบเปลี่ยนผ่าน เช่น องค์ประกอบโดยตรงของโหนดทั้งหมด คุณสามารถสร้าง depset ใหม่ได้โดยใช้คอนสตรัคเตอร์ depset ซึ่งจะยอมรับรายการองค์ประกอบโดยตรงและรายการโหนดย่อยอีกรายการ
s = depset(["a", "b", "c"])
t = depset(["d", "e"], transitive = [s])
print(s) # depset(["a", "b", "c"])
print(t) # depset(["d", "e", "a", "b", "c"])
หากต้องการเรียกข้อมูลชุด Dep ให้ใช้เมธอด to_list() โดยจะแสดงรายการองค์ประกอบแบบทรานซิทีฟทั้งหมดโดยไม่รวมรายการที่ซ้ำกัน ไม่มีวิธีตรวจสอบโครงสร้างที่แม่นยำของ DAG โดยตรง แม้ว่าโครงสร้างนี้จะมีผลต่อลำดับการแสดงองค์ประกอบ
s = depset(["a", "b", "c"])
print("c" in s.to_list()) # True
print(s.to_list() == ["a", "b", "c"]) # True
ระบบจะจํากัดรายการที่อนุญาตในชุดข้อมูล เช่นเดียวกับที่จํากัดคีย์ที่อนุญาตในพจนานุกรม โดยเฉพาะอย่างยิ่ง เนื้อหา depset จะเปลี่ยนแปลงไม่ได้
ชุดข้อมูลจะขึ้นอยู่กับความเท่าเทียมของการอ้างอิง: ชุดข้อมูลหนึ่งจะเท่ากับตัวเอง แต่ไม่เท่ากับชุดข้อมูลอื่น แม้ว่าจะมีเนื้อหาและโครงสร้างภายในเหมือนกันก็ตาม
s = depset(["a", "b", "c"])
t = s
print(s == t) # True
t = depset(["a", "b", "c"])
print(s == t) # False
d = {}
d[s] = None
d[t] = None
print(len(d)) # 2
หากต้องการเปรียบเทียบชุดข้อมูลตามเนื้อหา ให้แปลงชุดข้อมูลเป็นรายการที่จัดเรียง
s = depset(["a", "b", "c"])
t = depset(["c", "b", "a"])
print(sorted(s.to_list()) == sorted(t.to_list())) # True
คุณไม่สามารถนําองค์ประกอบออกจากชุดข้อมูล หากจำเป็น คุณต้องอ่านเนื้อหาทั้งหมดของชุดข้อมูล กรององค์ประกอบที่ต้องการนำออก และสร้างชุดข้อมูลใหม่ ซึ่งไม่มีประสิทธิภาพมากนัก
s = depset(["a", "b", "c"])
t = depset(["b", "c"])
# Compute set difference s - t. Precompute t.to_list() so it's not done
# in a loop, and convert it to a dictionary for fast membership tests.
t_items = {e: None for e in t.to_list()}
diff_items = [x for x in s.to_list() if x not in t_items]
# Convert back to depset if it's still going to be used for union operations.
s = depset(diff_items)
print(s) # depset(["a"])
สั่งซื้อ
การดำเนินการ to_list จะทำการเรียกใช้ DAG ประเภทการส่งผ่านขึ้นอยู่กับลำดับที่ระบุไว้ในเวลาที่สร้าง Depset การรองรับลําดับหลายรายการมีประโยชน์สําหรับ Bazel เนื่องจากบางครั้งเครื่องมือจะสนใจลําดับของอินพุต ตัวอย่างเช่น การดําเนินการของ Linker อาจต้องตรวจสอบว่าหาก B ขึ้นอยู่กับ A A.o จะมาก่อน B.o ในบรรทัดคําสั่งของ Linker เครื่องมืออื่นๆ อาจมีข้อกำหนดที่ตรงกันข้าม
ระบบรองรับลําดับการเรียกดู 3 รายการ ได้แก่ postorder, preorder และ
topological 2 รายการแรกทํางานเหมือนกับการทํางานกับต้นไม้ทุกประการ ยกเว้นว่าทํางานกับ DAG และข้ามโหนดที่เคยเข้าชมแล้ว ลำดับที่ 3 ทำหน้าที่เป็นการเรียงทางโทโพโลยีตั้งแต่รากไปจนถึงใบไม้ โดยพื้นฐานแล้วก็เหมือนกับการสั่งจองล่วงหน้า เว้นแต่ว่าจะมีการแสดงรายการย่อยต่อจากพ่อแม่ทั้งหมดเท่านั้น
การดำเนินการแบบก่อนการสั่งซื้อและหลังการสั่งซื้อจะทํางานแบบการวนจากซ้ายไปขวา แต่โปรดทราบว่าภายในโหนดแต่ละโหนด องค์ประกอบโดยตรงจะไม่มีลําดับที่เกี่ยวข้องกับโหนดย่อย สำหรับลําดับเชิงทอพอโลยี ไม่มีการรับประกันจากซ้ายไปขวา และแม้แต่การรับประกันว่าองค์ประกอบหลักทั้งหมดจะมาก่อนองค์ประกอบย่อยก็ไม่มีผลในกรณีที่มีองค์ประกอบที่ซ้ำกันในโหนดต่างๆ ของ DAG
# This demonstrates different traversal orders.
def create(order):
cd = depset(["c", "d"], order = order)
gh = depset(["g", "h"], order = order)
return depset(["a", "b", "e", "f"], transitive = [cd, gh], order = order)
print(create("postorder").to_list()) # ["c", "d", "g", "h", "a", "b", "e", "f"]
print(create("preorder").to_list()) # ["a", "b", "e", "f", "c", "d", "g", "h"]
# This demonstrates different orders on a diamond graph.
def create(order):
a = depset(["a"], order=order)
b = depset(["b"], transitive = [a], order = order)
c = depset(["c"], transitive = [a], order = order)
d = depset(["d"], transitive = [b, c], order = order)
return d
print(create("postorder").to_list()) # ["a", "b", "c", "d"]
print(create("preorder").to_list()) # ["d", "b", "a", "c"]
print(create("topological").to_list()) # ["d", "b", "c", "a"]
เนื่องจากมีการใช้การเรียกใช้ คุณต้องระบุลําดับเมื่อสร้างชุดข้อมูล Dependency ด้วยอาร์กิวเมนต์คีย์เวิร์ด order ของคอนสตรคเตอร์ หากไม่ระบุอาร์กิวเมนต์นี้ Depset จะมีลำดับ default พิเศษ ซึ่งในกรณีนี้ไม่มีการรับประกันเกี่ยวกับลำดับองค์ประกอบใดๆ ของเอลิเมนต์ (ยกเว้นแต่เป็นการกำหนด)
ตัวอย่างแบบเต็ม
ตัวอย่างนี้มีอยู่ที่ https://github.com/bazelbuild/examples/tree/main/rules/depsets
สมมติว่ามีภาษา Foo ที่ตีความโดยสมมุติ หากต้องการสร้างfoo_binaryแต่ละรายการ คุณต้องทราบไฟล์ *.foo ทั้งหมดที่ foo_binary นั้นใช้โดยตรงหรือโดยอ้อม
# //depsets:BUILD
load(":foo.bzl", "foo_library", "foo_binary")
# Our hypothetical Foo compiler.
py_binary(
name = "foocc",
srcs = ["foocc.py"],
)
foo_library(
name = "a",
srcs = ["a.foo", "a_impl.foo"],
)
foo_library(
name = "b",
srcs = ["b.foo", "b_impl.foo"],
deps = [":a"],
)
foo_library(
name = "c",
srcs = ["c.foo", "c_impl.foo"],
deps = [":a"],
)
foo_binary(
name = "d",
srcs = ["d.foo"],
deps = [":b", ":c"],
)
# //depsets:foocc.py
# "Foo compiler" that just concatenates its inputs to form its output.
import sys
if __name__ == "__main__":
assert len(sys.argv) >= 1
output = open(sys.argv[1], "wt")
for path in sys.argv[2:]:
input = open(path, "rt")
output.write(input.read())
ในที่นี้ แหล่งที่มาแบบทรานซิทีฟของไบนารี d คือไฟล์ *.foo ทั้งหมดในช่อง srcs ของ a, b, c และ d หากต้องการให้เป้าหมาย foo_binary ทราบเกี่ยวกับไฟล์อื่นๆ นอกเหนือจาก d.foo เป้าหมาย foo_library จะต้องส่งต่อไฟล์เหล่านั้นในผู้ให้บริการ ไลบรารีแต่ละรายการจะได้รับผู้ให้บริการจากข้อกำหนดของตัวเอง เพิ่มแหล่งที่มาโดยตรงของตัวเอง และส่งต่อผู้ให้บริการใหม่ที่มีเนื้อหาที่เพิ่มเข้ามา กฎ foo_binary ก็ทำตามในลักษณะเดียวกัน ยกเว้นว่าแทนการส่งคืนผู้ให้บริการ กฎจะใช้รายการแหล่งที่มาทั้งหมดเพื่อสร้างบรรทัดคำสั่งสำหรับการดำเนินการ
นี่คือการใช้กฎ foo_library และ foo_binary ที่สมบูรณ์
# //depsets/foo.bzl
# A provider with one field, transitive_sources.
FooFiles = provider(fields = ["transitive_sources"])
def get_transitive_srcs(srcs, deps):
"""Obtain the source files for a target and its transitive dependencies.
Args:
srcs: a list of source files
deps: a list of targets that are direct dependencies
Returns:
a collection of the transitive sources
"""
return depset(
srcs,
transitive = [dep[FooFiles].transitive_sources for dep in deps])
def _foo_library_impl(ctx):
trans_srcs = get_transitive_srcs(ctx.files.srcs, ctx.attr.deps)
return [FooFiles(transitive_sources=trans_srcs)]
foo_library = rule(
implementation = _foo_library_impl,
attrs = {
"srcs": attr.label_list(allow_files=True),
"deps": attr.label_list(),
},
)
def _foo_binary_impl(ctx):
foocc = ctx.executable._foocc
out = ctx.outputs.out
trans_srcs = get_transitive_srcs(ctx.files.srcs, ctx.attr.deps)
srcs_list = trans_srcs.to_list()
ctx.actions.run(executable = foocc,
arguments = [out.path] + [src.path for src in srcs_list],
inputs = srcs_list + [foocc],
outputs = [out])
foo_binary = rule(
implementation = _foo_binary_impl,
attrs = {
"srcs": attr.label_list(allow_files=True),
"deps": attr.label_list(),
"_foocc": attr.label(default=Label("//depsets:foocc"),
allow_files=True, executable=True, cfg="host")
},
outputs = {"out": "%{name}.out"},
)
ซึ่งทดสอบได้โดยการคัดลอกไฟล์เหล่านี้ลงในแพ็กเกจใหม่ เปลี่ยนชื่อป้ายกำกับให้เหมาะสม สร้างไฟล์ *.foo ต้นทางที่มีเนื้อหาจำลอง และสร้างเป้าหมาย d
ประสิทธิภาพ
หากต้องการทราบเหตุผลในการใช้ depset ให้ลองพิจารณาว่าจะเกิดอะไรขึ้นหาก get_transitive_srcs() รวบรวมแหล่งที่มาไว้ในรายการ
def get_transitive_srcs(srcs, deps):
trans_srcs = []
for dep in deps:
trans_srcs += dep[FooFiles].transitive_sources
trans_srcs += srcs
return trans_srcs
ซึ่งจะไม่รวมไฟล์ที่ซ้ำกัน ดังนั้นไฟล์ต้นฉบับของ a จะปรากฏ 2 ครั้งในบรรทัดคำสั่งและ 2 ครั้งในเนื้อหาของไฟล์เอาต์พุต
อีกทางเลือกหนึ่งคือใช้ชุดทั่วไปซึ่งสามารถจำลองโดยพจนานุกรมซึ่งคีย์เป็นองค์ประกอบและคีย์ทั้งหมดแมปกับ True
def get_transitive_srcs(srcs, deps):
trans_srcs = {}
for dep in deps:
for file in dep[FooFiles].transitive_sources:
trans_srcs[file] = True
for file in srcs:
trans_srcs[file] = True
return trans_srcs
วิธีนี้จะช่วยกำจัดรายการที่ซ้ำกัน แต่จะทำให้ลำดับของอาร์กิวเมนต์บรรทัดคำสั่ง (และเนื้อหาของไฟล์) ไม่มีการระบุ แม้ว่าจะยังคงเป็นแบบกำหนดได้
นอกจากนี้ แนวทางทั้ง 2 แนวทางมีประสิทธิภาพต่ำกว่าแนวทางที่อิงตามชุดข้อมูล พิจารณากรณีที่เชน Dependency ของห้องสมุด Foo มีความยาว การประมวลผลกฎทุกกฎต้องมีการคัดลอกแหล่งที่มาทรานซิชันทั้งหมดที่อยู่ก่อนหน้าไปยังโครงสร้างข้อมูลใหม่ ซึ่งหมายความว่าเวลาและพื้นที่ที่ใช้วิเคราะห์ไลบรารีหรือเป้าหมายไบนารีแต่ละรายการจะแปรผันตามลําดับชั้นในเชน สําหรับเชนที่มีความยาว n, foolib_1 ← foolib_2 ← … ← foolib_n ต้นทุนโดยรวมจะมีประสิทธิภาพเป็น O(n^2)
โดยทั่วไปแล้ว คุณควรใช้ depset ทุกครั้งที่รวบรวมข้อมูลผ่าน transitive dependencies ซึ่งจะช่วยให้มั่นใจว่าการสร้างของคุณปรับขนาดและกราฟเป้าหมายมีขนาดใหญ่ขึ้น
สุดท้าย สิ่งสำคัญคืออย่าดึงข้อมูลของ depset โดยไม่จำเป็นในการใช้งานกฎ การเรียกใช้ to_list()
1 ครั้งในตอนท้ายในกฎไบนารีนั้นไม่มีปัญหา เนื่องจากต้นทุนโดยรวมเป็นเพียง O(n) ลักษณะการทํางานแบบสี่เหลี่ยมจัตุรัสจะเกิดขึ้นเมื่อเป้าหมายที่ไม่ใช่ปลายทางหลายรายการพยายามเรียก to_list()
ดูข้อมูลเพิ่มเติมเกี่ยวกับการใช้ชุดข้อมูลอย่างมีประสิทธิภาพได้ในหน้าประสิทธิภาพ
เอกสารอ้างอิง API
โปรดดูรายละเอียดเพิ่มเติมที่นี่