모듈 확장 프로그램

모듈 확장 프로그램을 사용하면 종속 항목 그래프에서 모듈의 입력 데이터를 읽고, 종속 항목을 해결하는 데 필요한 로직을 실행하고, 마지막으로 저장소 규칙을 호출하여 저장소를 만들어 모듈 시스템을 확장할 수 있습니다. 이러한 확장 프로그램은 저장소 규칙과 유사한 기능을 가지므로 파일 I/O를 수행하고 네트워크 요청을 전송하는 등의 작업을 할 수 있습니다. 무엇보다도 Bazel이 다른 패키지 관리 시스템과 상호작용할 수 있는 동시에 Bazel 모듈로부터 빌드된 종속 항목 그래프를 존중합니다.

저장소 규칙과 마찬가지로 .bzl 파일에 모듈 확장자를 정의할 수 있습니다. 직접 호출되지 않습니다. 대신 각 모듈은 확장 프로그램이 읽을 태그라는 데이터 조각을 지정합니다. Bazel은 확장 프로그램을 평가하기 전에 모듈 확인을 실행합니다. 확장 프로그램은 전체 종속 항목 그래프에서 자신에게 속한 모든 태그를 읽습니다.

확장 프로그램 사용

확장 프로그램은 Bazel 모듈 자체에서 호스팅됩니다. 모듈에서 확장 프로그램을 사용하려면 먼저 확장 프로그램을 호스팅하는 모듈에 bazel_dep를 추가한 다음 use_extension 내장 함수를 호출하여 범위로 가져옵니다. rules_jvm_external 모듈에 정의된 'maven' 확장 프로그램을 사용하기 위한 MODULE.bazel 파일의 스니펫인 다음 예를 살펴보세요.

bazel_dep(name = "rules_jvm_external", version = "4.5")
maven = use_extension("@rules_jvm_external//:extensions.bzl", "maven")

이렇게 하면 use_extension의 반환 값이 변수에 결합되어 사용자가 점 문법을 사용하여 확장 프로그램의 태그를 지정할 수 있습니다. 태그는 확장 프로그램 정의에 지정된 해당 태그 클래스에서 정의한 스키마를 따라야 합니다. 다음은 maven.install 및 maven.artifact 태그를 지정하는 예입니다.

maven.install(artifacts = ["org.junit:junit:4.13.2"])
maven.artifact(group = "com.google.guava",
               artifact = "guava",
               version = "27.0-jre",
               exclusions = ["com.google.j2objc:j2objc-annotations"])

use_repo 지시어를 사용하여 확장 프로그램에서 생성한 저장소를 현재 모듈의 범위로 가져옵니다.

use_repo(maven, "maven")

확장 프로그램에서 생성한 저장소는 API의 일부입니다. 이 예에서 'maven' 모듈 확장 프로그램은 maven라는 저장소를 생성하겠다고 약속합니다. 위의 선언을 통해 확장 프로그램은 @maven//:org_junit_junit와 같은 라벨을 올바르게 확인하여 'maven' 확장 프로그램에서 생성된 저장소를 가리킵니다.

확장 프로그램 정의

저장소 규칙과 유사하게 module_extension 함수를 사용하여 모듈 확장 프로그램을 정의할 수 있습니다. 그러나 저장소 규칙에는 여러 속성이 있는 반면 모듈 확장 프로그램에는 tag_class이 있으며 각 속성에는 여러 개의 속성이 있습니다. 태그 클래스는 이 확장 프로그램에서 사용하는 태그의 스키마를 정의합니다. 예를 들어 위의 'maven' 확장 프로그램은 다음과 같이 정의될 수 있습니다.

# @rules_jvm_external//:extensions.bzl

_install = tag_class(attrs = {"artifacts": attr.string_list(), ...})
_artifact = tag_class(attrs = {"group": attr.string(), "artifact": attr.string(), ...})
maven = module_extension(
  implementation = _maven_impl,
  tag_classes = {"install": _install, "artifact": _artifact},
)

이러한 선언은 지정된 속성 스키마를 사용하여 maven.install 및 maven.artifact 태그를 지정할 수 있음을 보여줍니다.

모듈 확장 프로그램의 구현 함수는 module_ctx 객체를 가져온다는 점을 제외하면 저장소 규칙과 유사합니다. 이 객체는 확장 프로그램 및 모든 관련 태그를 사용하는 모든 모듈에 대한 액세스 권한을 부여합니다. 그런 다음 구현 함수가 저장소 규칙을 호출하여 저장소를 생성합니다.

# @rules_jvm_external//:extensions.bzl

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_file")  # a repo rule
def _maven_impl(ctx):
  # This is a fake implementation for demonstration purposes only

  # collect artifacts from across the dependency graph
  artifacts = []
  for mod in ctx.modules:
    for install in mod.tags.install:
      artifacts += install.artifacts
    artifacts += [_to_artifact(artifact) for artifact in mod.tags.artifact]

  # call out to the coursier CLI tool to resolve dependencies
  output = ctx.execute(["coursier", "resolve", artifacts])
  repo_attrs = _process_coursier_output(output)

  # call repo rules to generate repos
  for attrs in repo_attrs:
    http_file(**attrs)
  _generate_hub_repo(name = "maven", repo_attrs)

확장 프로그램 ID

모듈 확장 프로그램은 이름과 use_extension 호출에 표시되는 .bzl 파일로 식별됩니다. 다음 예에서 maven 확장자는 .bzl 파일 @rules_jvm_external//:extension.bzl과 이름 maven으로 식별됩니다.

maven = use_extension("@rules_jvm_external//:extensions.bzl", "maven")

다른 .bzl 파일에서 확장 프로그램을 다시 내보내면 새 ID가 제공되며, 두 확장 프로그램 버전이 전이 모듈 그래프에 모두 사용되면 별도로 평가되어 특정 ID와 연결된 태그만 볼 수 있습니다.

확장 프로그램 작성자는 사용자가 단일 .bzl 파일의 모듈 확장 프로그램만 사용하도록 해야 합니다.

저장소 이름 및 공개 상태

확장 프로그램에서 생성한 저장소에는 module_repo_canonical_name~extension_name~repo_name 형태의 표준 이름이 있습니다. 루트 모듈에서 호스팅되는 확장 프로그램의 경우 module_repo_canonical_name 부분이 _main 문자열로 대체됩니다. 표준 이름 형식은 개발자가 사용해야 하는 API가 아니며 언제든지 변경될 수 있습니다.

이 이름 지정 정책은 각 확장 프로그램에 자체 '저장소 네임스페이스'가 있음을 의미합니다. 서로 다른 두 확장 프로그램은 충돌 위험 없이 동일한 이름으로 저장소를 각각 정의할 수 있습니다. 또한 repository_ctx.name는 저장소의 표준 이름을 보고하며, 이는 저장소 규칙 호출에 지정된 이름과 같지 않습니다.

모듈 확장 프로그램에서 생성한 저장소를 고려할 때 다음과 같은 몇 가지 저장소 공개 상태 규칙이 있습니다.

Bazel 모듈 저장소는 bazel_dep 및 use_repo를 통해 MODULE.bazel 파일에 도입된 모든 저장소를 볼 수 있습니다.
모듈 확장 프로그램에서 생성된 저장소는 확장 프로그램을 호스팅하는 모듈에 표시되는 모든 저장소 및 동일한 모듈 확장 프로그램에서 생성된 다른 모든 저장소를 볼 수 있습니다 (저장소 규칙 호출에 지정된 이름을 실제 이름으로 사용).
- 충돌이 발생할 수 있습니다. 모듈 저장소가 명확한 이름이 foo인 저장소를 볼 수 있고 확장 프로그램이 지정된 이름이 foo인 저장소를 생성하는 경우, 이 확장 프로그램에서 생성한 모든 저장소에 대해 foo가 전자를 참조합니다.

권장사항

이 섹션에서는 사용하기 쉽고 유지관리가 쉬우며 시간 경과에 따른 변화에 잘 적응할 수 있도록 확장 프로그램을 작성할 때의 권장사항을 설명합니다.

각 확장 프로그램을 별도의 파일에 배치

확장 프로그램이 다른 파일에 있으면 한 확장 프로그램이 다른 확장 프로그램에서 생성된 저장소를 로드할 수 있습니다. 이 기능을 사용하지 않더라도 나중에 필요할 경우를 대비하여 별도의 파일에 저장하는 것이 가장 좋습니다. 확장 프로그램의 ID는 파일을 기반으로 하므로 나중에 확장 프로그램을 다른 파일로 이동하면 공개 API가 변경되고 사용자에게 이전 버전과 호환되지 않는 변경사항이 있기 때문입니다.

운영체제 및 아키텍처 지정

확장 프로그램이 운영체제나 아키텍처 유형을 사용하는 경우 os_dependent 및 arch_dependent 불리언 속성을 사용하여 확장 프로그램 정의에 이를 나타내야 합니다. 이렇게 하면 둘 중 하나라도 변경된 경우 Bazel이 재평가 필요성을 인식합니다.

루트 모듈만 저장소 이름에 직접 영향을 미칩니다.

확장 프로그램이 저장소를 만들면 확장 프로그램의 네임스페이스 내에 생성됩니다. 즉, 서로 다른 모듈이 동일한 확장 프로그램을 사용하여 동일한 이름의 저장소를 만들면 충돌이 발생할 수 있습니다. 이는 종종 저장소 규칙의 name 값으로 전달되는 name 인수를 갖는 모듈 확장 프로그램의 tag_class로 나타납니다.

예를 들어 루트 모듈 A는 모듈 B에 종속됩니다. 두 모듈 모두 mylang 모듈에 종속됩니다. A와 B가 모두 mylang.toolchain(name="foo")를 호출하는 경우 둘 다 mylang 모듈 내에 foo라는 저장소를 만들려고 하며 오류가 발생합니다.

이를 방지하려면 저장소 이름을 직접 설정하는 기능을 삭제하거나 루트 모듈에서만 이 작업을 하도록 허용하세요. 루트 모듈에는 종속되지 않으므로 이 기능을 루트 모듈에 허용하는 것은 괜찮습니다. 따라서 다른 모듈이 충돌하는 이름을 만드는 것에 대해 걱정할 필요가 없습니다.