Bermigrasi dari Maven ke Bazel

Laporkan masalah Lihat sumber

Halaman ini menjelaskan cara bermigrasi dari Maven ke Bazel, termasuk prasyarat dan langkah penginstalan. Panduan ini menjelaskan perbedaan antara Maven dan Bazel, serta memberikan contoh migrasi menggunakan project Guava.

Saat bermigrasi dari alat build apa pun ke Bazel, sebaiknya jalankan alat build secara paralel sampai Anda memigrasikan sepenuhnya tim pengembangan, sistem CI, dan sistem lain yang relevan. Anda dapat menjalankan Maven dan Bazel di repositori yang sama.

Sebelum memulai

  • Instal Bazel jika belum diinstal.
  • Jika Anda baru menggunakan Bazel, baca tutorial Pengantar Bazel: Build Java sebelum mulai memigrasikan. Tutorial ini menjelaskan konsep, struktur, dan sintaksis label Bazel.

Perbedaan antara Maven dan Bazel

  • Maven menggunakan file pom.xml level teratas. Bazel mendukung beberapa file build dan beberapa target per file BUILD, sehingga memungkinkan build yang lebih inkremental daripada build Maven.
  • Maven bertanggung jawab atas langkah-langkah proses deployment. Bazel tidak mengotomatiskan deployment.
  • Bazel memungkinkan Anda untuk mengekspresikan dependensi antarbahasa.
  • Saat menambahkan bagian baru ke project, dengan Bazel, Anda mungkin perlu menambahkan file BUILD baru. Praktik terbaik adalah menambahkan file BUILD ke setiap paket Java baru.

Bermigrasi dari Maven ke Bazel

Langkah-langkah di bawah ini menjelaskan cara memigrasikan project Anda ke Bazel:

  1. Membuat file WORKSPACE
  2. Membuat satu file BUILD
  3. Membuat lebih banyak file BUILD
  4. Mem-build menggunakan Bazel

Contoh di bawah berasal dari migrasi project Guava dari Maven ke Bazel. Project Guava yang digunakan adalah rilis v31.1. Contoh yang menggunakan Guava tidak menjelaskan setiap langkah dalam migrasi, tetapi menunjukkan file dan konten yang dibuat atau ditambahkan secara manual untuk migrasi.

$ git clone https://github.com/google/guava.git && cd guava
$ git checkout v31.1

1. Membuat file WORKSPACE

Buat file bernama WORKSPACE di root project Anda. Jika project Anda tidak memiliki dependensi eksternal, file workspace boleh kosong.

Jika project Anda bergantung pada file atau paket yang tidak ada dalam salah satu direktori project, tentukan dependensi eksternal ini dalam file ruang kerja. Untuk mengotomatiskan listingan dependensi eksternal untuk file ruang kerja, gunakan rules_jvm_external. Untuk mengetahui petunjuk tentang penggunaan kumpulan aturan ini, lihat README.

Contoh project Guava: dependensi eksternal

Anda dapat mencantumkan dependensi eksternal project Guava dengan kumpulan aturan rules_jvm_external.

Tambahkan cuplikan berikut ke file WORKSPACE:

load("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

RULES_JVM_EXTERNAL_TAG = "4.3"
RULES_JVM_EXTERNAL_SHA = "6274687f6fc5783b589f56a2f1ed60de3ce1f99bc4e8f9edef3de43bdf7c6e74"

http_archive(
    name = "rules_jvm_external",
    sha256 = RULES_JVM_EXTERNAL_SHA,
    strip_prefix = "rules_jvm_external-%s" % RULES_JVM_EXTERNAL_TAG,
    url = "https://github.com/bazelbuild/rules_jvm_external/archive/%s.zip" % RULES_JVM_EXTERNAL_TAG,
)

load("@rules_jvm_external//:defs.bzl", "maven_install")

maven_install(
    artifacts = [
        "com.google.code.findbugs:jsr305:3.0.2",
        "com.google.errorprone:error_prone_annotations:2.11.0",
        "com.google.j2objc:j2objc-annotations:1.3",
        "org.codehaus.mojo:animal-sniffer-annotations:1.20",
        "org.checkerframework:checker-qual:3.12.0",
    ],
    repositories = [
        "https://repo1.maven.org/maven2",
    ],
)

2. Membuat satu file BUILD

Setelah menentukan ruang kerja dan dependensi eksternal (jika berlaku), Anda perlu membuat file BUILD untuk menjelaskan cara mem-build project. Tidak seperti Maven dengan satu file pom.xml-nya, Bazel dapat menggunakan banyak file BUILD untuk membuat project. File-file ini menentukan beberapa target build, yang memungkinkan Bazel menghasilkan build inkremental.

Tambahkan file BUILD secara bertahap. Mulailah dengan menambahkan satu file BUILD di root project Anda dan menggunakannya untuk melakukan build awal menggunakan Bazel. Kemudian, Anda akan meningkatkan kualitas build dengan menambahkan lebih banyak file BUILD yang memiliki target yang lebih terperinci.

  1. Dalam direktori yang sama dengan file WORKSPACE Anda, buat file teks dan beri nama BUILD.

  2. Dalam file BUILD ini, gunakan aturan yang sesuai untuk membuat satu target guna mem-build project Anda. Berikut ini beberapa tips:

    • Gunakan aturan yang sesuai:

      • Untuk mem-build project dengan satu modul Maven, gunakan aturan java_library sebagai berikut:

        java_library(
    name = "everything",
    srcs = glob(["src/main/java/**/*.java"]),
    resources = glob(["src/main/resources/**"]),
    deps = ["//:all-external-targets"],
)

      • Untuk membuat project dengan beberapa modul Maven, gunakan aturan java_library sebagai berikut:

        java_library(
    name = "everything",
    srcs = glob([
        "Module1/src/main/java/**/*.java",
        "Module2/src/main/java/**/*.java",
        ...
    ]),
    resources = glob([
        "Module1/src/main/resources/**",
        "Module2/src/main/resources/**",
        ...
    ]),
    deps = ["//:all-external-targets"],
)

      • Untuk membuat biner, gunakan aturan java_binary:

        java_binary(
    name = "everything",
    srcs = glob(["src/main/java/**/*.java"]),
    resources = glob(["src/main/resources/**"]),
    deps = ["//:all-external-targets"],
    main_class = "com.example.Main"
)

    • Tentukan atribut:

      • name: Memberi target nama yang bermakna. Dalam contoh di atas, target disebut "semuanya".
      • srcs: Menggunakan globbing untuk mencantumkan semua file .java dalam project Anda.
      • resources: Menggunakan globbing untuk mencantumkan semua resource dalam project Anda.
      • deps: Anda perlu menentukan dependensi eksternal yang diperlukan project Anda. Misalnya, jika Anda membuat daftar dependensi eksternal menggunakan alat generate_workspace, dependensi untuk java_library adalah library yang tercantum dalam makro generated_java_libraries.

    • Lihat contoh file BUILD level atas di bawah ini dari migrasi project Guava.

  3. Setelah Anda memiliki file BUILD di root project, bangun project Anda untuk memastikannya berfungsi. Di command line, dari direktori ruang kerja, gunakan bazel build //:everything untuk membuat project dengan Bazel.

    Sekarang project telah berhasil dibuat dengan Bazel. Anda perlu menambahkan lebih banyak file BUILD untuk mengizinkan build inkremental project.

Contoh project Guava: memulai dengan satu file BUILD

Saat memigrasikan project Guava ke Bazel, awalnya satu file BUILD akan digunakan untuk mem-build seluruh project. Berikut adalah isi file BUILD awal ini di direktori workspace:

java_library(
    name = "everything",
    srcs = glob([
        "guava/src/**/*.java",
        "futures/failureaccess/src/**/*.java",
    ]),
    javacopts = ["-XepDisableAllChecks"],
    deps = [
        "@maven//:com_google_code_findbugs_jsr305",
        "@maven//:com_google_errorprone_error_prone_annotations",
        "@maven//:com_google_j2objc_j2objc_annotations",
        "@maven//:org_checkerframework_checker_qual",
        "@maven//:org_codehaus_mojo_animal_sniffer_annotations",
    ],
)

3. Membuat lebih banyak file BUILD (opsional)

Bazel hanya berfungsi dengan satu BUILD file, seperti yang Anda lihat setelah menyelesaikan build pertama Anda. Sebaiknya pertimbangkan untuk membagi build menjadi potongan-potongan yang lebih kecil dengan menambahkan lebih banyak file BUILD dengan target terperinci.

Beberapa file BUILD dengan beberapa target akan meningkatkan perincian build, sehingga memungkinkan:

  • peningkatan bertahap untuk kemajuan proyek,
  • meningkatkan eksekusi paralel build,
  • pemeliharaan build yang lebih baik untuk pengguna di masa depan, dan
  • kontrol atas visibilitas target antar-paket, yang dapat mencegah masalah seperti library yang berisi detail implementasi yang bocor ke API publik.

Tips untuk menambahkan lebih banyak file BUILD:

  • Anda dapat mulai dengan menambahkan file BUILD ke setiap paket Java. Mulailah dengan paket Java yang memiliki paling sedikit dependensi dan lanjutkan ke paket dengan dependensi terbanyak.
  • Saat Anda menambahkan file BUILD dan menentukan target, tambahkan target baru ini ke bagian deps target yang bergantung padanya. Perhatikan bahwa fungsi glob() tidak melewati batas paket, sehingga jumlah paket bertambah, ukuran file yang cocok dengan glob() akan menyusut.
  • Setiap kali menambahkan file BUILD ke direktori main, pastikan Anda menambahkan file BUILD ke direktori test yang sesuai.
  • Berhati-hatilah untuk membatasi visibilitas antar-paket dengan benar.
  • Untuk menyederhanakan pemecahan masalah error dalam penyiapan file BUILD, pastikan project terus di-build dengan Bazel saat Anda menambahkan setiap file build. Jalankan bazel build //... untuk memastikan semua target Anda masih dibuat.

4. Membangun aplikasi menggunakan Bazel

Anda telah membuat aplikasi menggunakan Bazel saat menambahkan file BUILD untuk memvalidasi penyiapan build.

Saat memiliki file BUILD pada tingkat perincian yang diinginkan, Anda dapat menggunakan Bazel untuk memproduksi semua build.