Workspace 규칙

워크스페이스 규칙은 일반적으로 기본 저장소 외부에 있는 소스 코드인 외부 종속 항목을 가져오는 데 사용됩니다.

참고: Bazel은 네이티브 워크스페이스 규칙 외에도 다양한 Starlark 워크스페이스 규칙을 삽입합니다. 특히 웹에 호스팅된 git 저장소 또는 보관 파일을 처리하는 규칙이 여기에 포함됩니다.

규칙

• bind
• local_repository
• new_local_repository

바인드

bind(name, actual, compatible_with, deprecation, distribs, features, licenses, restricted_to, tags, target_compatible_with, testonly, visibility)

경고: bind() 사용은 권장되지 않습니다. 문제와 대안에 관한 자세한 내용은 'bind 삭제 고려'를 참고하세요. 특히 repo_mapping 저장소 속성을 사용하는 것이 좋습니다.

경고: select()은 bind()에서 사용할 수 없습니다. 자세한 내용은 구성 가능한 속성 FAQ를 참고하세요.

//external 패키지에서 타겟에 별칭을 지정합니다.

//external 패키지는 '일반' 패키지가 아닙니다. external/ 디렉터리가 없으므로 모든 바인딩된 타겟이 포함된 '가상 패키지'로 간주할 수 있습니다.

예

타겟에 별칭을 지정하려면 WORKSPACE 파일에서 bind합니다. 예를 들어 //third_party/javacc-v2라는 java_library 타겟이 있다고 가정해 보겠습니다. WORKSPACE 파일에 다음을 추가하여 별칭을 지정할 수 있습니다.

bind(
    name = "javacc-latest",
    actual = "//third_party/javacc-v2",
)

이제 타겟이 //third_party/javacc-v2 대신 //external:javacc-latest에 종속될 수 있습니다. javacc-v3이 출시되면 bind 규칙을 업데이트할 수 있으며 //external:javacc-latest에 종속된 모든 BUILD 파일은 수정할 필요 없이 javacc-v3에 종속됩니다.

바인딩은 외부 저장소의 타겟을 작업공간에서 사용할 수 있도록 하는 데도 사용할 수 있습니다. 예를 들어 WORKSPACE 파일에 가져온 @my-ssl라는 원격 저장소가 있고 여기에 cc_library 타겟 //src:openssl-lib가 있는 경우 bind를 사용하여 이 타겟의 별칭을 만들 수 있습니다.

bind(
    name = "openssl",
    actual = "@my-ssl//src:openssl-lib",
)

그런 다음 작업공간의 BUILD 파일에서 바인딩된 타겟을 다음과 같이 사용할 수 있습니다.

cc_library(
    name = "sign-in",
    srcs = ["sign_in.cc"],
    hdrs = ["sign_in.h"],
    deps = ["//external:openssl"],
)

sign_in.cc 및 sign_in.h 내에서 //external:openssl에 의해 노출된 헤더 파일은 저장소 루트에 상대적인 경로를 사용하여 참조할 수 있습니다. 예를 들어 @my-ssl//src:openssl-lib의 규칙 정의가 다음과 같다고 가정해 보겠습니다.

cc_library(
    name = "openssl-lib",
    srcs = ["openssl.cc"],
    hdrs = ["openssl.h"],
)

그러면 sign_in.cc의 포함은 다음과 같이 표시될 수 있습니다.

#include "sign_in.h"
#include "src/openssl.h"

인수

local_repository

local_repository(name, path, repo_mapping)

로컬 디렉터리의 타겟을 바인딩할 수 있습니다. 즉, 현재 저장소는 이 다른 디렉터리에 정의된 타겟을 사용할 수 있습니다. 자세한 내용은 결합 섹션을 참고하세요.

예

현재 저장소가 ~/chat-app 디렉터리에 루팅된 채팅 클라이언트라고 가정해 보겠습니다. 이 클라이언트는 다른 저장소인 ~/ssl에 정의된 SSL 라이브러리를 사용하려 합니다. SSL 라이브러리에 대상 //src:openssl-lib가 있습니다.

사용자는 다음 줄을 ~/chat-app/WORKSPACE에 추가하여 이 타겟에 종속 항목을 추가할 수 있습니다.

local_repository(
    name = "my-ssl",
    path = "/home/user/ssl",
)

타겟은 이 라이브러리에 종속되도록 @my-ssl//src:openssl-lib를 종속 항목으로 지정합니다.

인수

new_local_repository

new_local_repository(name, build_file, build_file_content, path, repo_mapping, workspace_file, workspace_file_content)

로컬 디렉터리를 Bazel 저장소로 전환할 수 있습니다. 즉, 현재 저장소는 파일 시스템의 어느 곳에서나 타겟을 정의하고 사용할 수 있습니다.

이 규칙은 WORKSPACE 파일과 지정된 BUILD 파일 및 경로에 대한 심볼릭 링크가 포함된 하위 디렉터리를 만들어 Bazel 저장소를 만듭니다. 빌드 파일은 path를 기준으로 타겟을 만들어야 합니다. 이미 WORKSPACE 파일과 BUILD 파일이 포함된 디렉터리의 경우 local_repository 규칙을 사용할 수 있습니다.

예

현재 저장소가 ~/chat-app 디렉터리에 루팅된 채팅 클라이언트라고 가정해 보겠습니다. 이 클라이언트는 다른 디렉터리인 ~/ssl에 정의된 SSL 라이브러리를 사용하려 합니다.

사용자는 다음을 포함하는 SSL 라이브러리의 BUILD 파일(~/chat-app/BUILD.my-ssl)을 만들어 종속 항목을 추가할 수 있습니다.

java_library(
    name = "openssl",
    srcs = glob(['*.java'])
    visibility = ["//visibility:public"],
)

그런 다음 ~/chat-app/WORKSPACE에 다음 줄을 추가할 수 있습니다.

new_local_repository(
    name = "my-ssl",
    path = "/home/user/ssl",
    build_file = "BUILD.my-ssl",
)

이렇게 하면 /home/user/ssl에 대한 심볼릭 링크를 만드는 @my-ssl 저장소가 생성됩니다. 타겟은 타겟의 종속 항목에 @my-ssl//:openssl를 추가하여 이 라이브러리에 종속될 수 있습니다.

new_local_repository를 사용하여 디렉터리뿐만 아니라 단일 파일도 포함할 수 있습니다. 예를 들어 /home/username/Downloads/piano.jar에 jar 파일이 있다고 가정해 보겠습니다. WORKSPACE 파일에 다음을 추가하여 빌드에 해당 파일만 추가할 수 있습니다.

new_local_repository(
    name = "piano",
    path = "/home/username/Downloads/piano.jar",
    build_file = "BUILD.piano",
)

다음과 같은 BUILD.piano 파일을 만듭니다.

java_import(
    name = "play-music",
    jars = ["piano.jar"],
    visibility = ["//visibility:public"],
)

인수