構成

問題を報告 ソースを表示

このページでは、プロジェクトのビルド方法をカスタマイズするための Bazel の API である Starlark 構成のメリットと基本的な使用方法について説明します。ビルド設定を定義する方法と例について説明します。

これにより、次のことが可能になります。

  • プロジェクトのカスタムフラグを定義することで、--define が不要になります
  • 親とは異なる構成(--compilation_mode=opt--cpu=arm など)で依存関係を構成する遷移を書き込む
  • デフォルトをより適切にルールに組み込む(指定された SDK で //my:android_app を自動的にビルドするなど)

など、すべて .bzl ファイルから取得されます(Bazel リリースは不要です)。については、bazelbuild/examples リポジトリをご覧ください。

ユーザー定義のビルド設定

ビルド設定は単一の構成情報です。構成は Key-Value のマップと考えることができます。--cpu=ppc--copt="-DFoo" を設定すると、{cpu: ppc, copt: "-DFoo"} のような構成が生成されます。各エントリはビルドの設定です。

cpucopt などの従来のフラグはネイティブ設定です。キーは定義され、値はネイティブ bazel Java コード内で設定されます。Bazel ユーザーは、コマンドラインと、ネイティブに維持されている他の API を介してのみ、読み取りと書き込みを行うことができます。ネイティブ フラグとそれを公開する API を変更するには、bazel リリースが必要です。ユーザー定義のビルド設定は .bzl ファイルで定義されます(したがって、変更を登録するために bazel リリースは必要ありません)。これらはコマンドラインでも設定できます(flags として指定されている場合、詳細は下記をご覧ください)が、ユーザー定義の遷移でも設定できます。

ビルド設定の定義

エンドツーエンドの例

build_setting rule() パラメータ

ビルド設定は他のルールと同じルールで、Starlark の rule() 関数の build_setting 属性によって区別されます。

# example/buildsettings/build_settings.bzl
string_flag = rule(
    implementation = _impl,
    build_setting = config.string(flag = True)
)

build_setting 属性には、ビルド設定のタイプを指定する関数を使用します。この型は、boolstring など、基本的な Starlark 型のセットに制限されます。詳しくは、config モジュールのドキュメントをご覧ください。より複雑な入力は、ルールの実装関数で行うことができます。詳しくは以下をご覧ください。

config モジュールの関数は、省略可能なブール値パラメータ flag を取ります。これはデフォルトでは false に設定されています。flag が true に設定されている場合、ユーザーはコマンドラインでも、デフォルト値と遷移を介してルール作成者によって内部でもビルド設定を設定できます。すべての設定をユーザーが設定できるわけではありません。たとえば、ルール作成者がテストルール内でデバッグモードを有効にする場合、テスト以外のルール内でユーザーがその機能を無差別にオンにできないようにする必要があります。

resourcemanager.build_setting_value の使用

他のルールと同様に、ビルド設定ルールには実装関数があります。ビルド設定の基本的な Starlark タイプの値には、ctx.build_setting_value メソッドでアクセスできます。このメソッドは、ビルド設定ルールの ctx オブジェクトでのみ使用できます。これらの実装メソッドでは、ビルド設定値を直接転送できます。また、型チェックやより複雑な構造体の作成など、追加の作業を行うこともできます。enum 型のビルド設定を実装する方法を次に示します。

# example/buildsettings/build_settings.bzl
TemperatureProvider = provider(fields = ['type'])

temperatures = ["HOT", "LUKEWARM", "ICED"]

def _impl(ctx):
    raw_temperature = ctx.build_setting_value
    if raw_temperature not in temperatures:
        fail(str(ctx.label) + " build setting allowed to take values {"
             + ", ".join(temperatures) + "} but was set to unallowed value "
             + raw_temperature)
    return TemperatureProvider(type = raw_temperature)

temperature = rule(
    implementation = _impl,
    build_setting = config.string(flag = True)
)

マルチセット文字列フラグの定義

文字列設定には allow_multiple パラメータが追加され、コマンドラインまたは bazelrcs でフラグを複数回設定できます。デフォルト値は引き続き文字列型の属性で設定されます。

# example/buildsettings/build_settings.bzl
allow_multiple_flag = rule(
    implementation = _impl,
    build_setting = config.string(flag = True, allow_multiple = True)
)
# example/BUILD
load("//example/buildsettings:build_settings.bzl", "allow_multiple_flag")
allow_multiple_flag(
    name = "roasts",
    build_setting_default = "medium"
)

フラグの各設定は単一の値として扱われます。

$ bazel build //my/target --//example:roasts=blonde \
    --//example:roasts=medium,dark

上記が {"//example:roasts": ["blonde", "medium,dark"]} に解析され、ctx.build_setting_value がリスト ["blonde", "medium,dark"] を返します。

ビルド設定のインスタンス化

build_setting パラメータで定義したルールには、暗黙的に必須の build_setting_default 属性があります。この属性は build_setting パラメータで宣言される型と同じ型になります。

# example/buildsettings/build_settings.bzl
FlavorProvider = provider(fields = ['type'])

def _impl(ctx):
    return FlavorProvider(type = ctx.build_setting_value)

flavor = rule(
    implementation = _impl,
    build_setting = config.string(flag = True)
)
# example/BUILD
load("//example/buildsettings:build_settings.bzl", "flavor")
flavor(
    name = "favorite_flavor",
    build_setting_default = "APPLE"
)

事前定義された設定

エンドツーエンドの例

Skylib ライブラリには事前定義された設定のセットが含まれており、カスタムの Starlark を記述せずにインスタンス化できます。

たとえば、一部の文字列値を受け入れる設定を定義するには、次のようにします。

# example/BUILD
load("@bazel_skylib//rules:common_settings.bzl", "string_flag")
string_flag(
    name = "myflag",
    values = ["a", "b", "c"],
    build_setting_default = "a",
)

詳細なリストについては、一般的なビルド設定ルールをご覧ください。

ビルド設定の使用

ビルド設定によって異なる

ターゲットが構成情報の一部を読み取る必要がある場合は、通常の属性依存関係を介してビルド設定に直接依存できます。

# example/rules.bzl
load("//example/buildsettings:build_settings.bzl", "FlavorProvider")
def _rule_impl(ctx):
    if ctx.attr.flavor[FlavorProvider].type == "ORANGE":
        ...

drink_rule = rule(
    implementation = _rule_impl,
    attrs = {
        "flavor": attr.label()
    }
)
# example/BUILD
load("//example:rules.bzl", "drink_rule")
load("//example/buildsettings:build_settings.bzl", "flavor")
flavor(
    name = "favorite_flavor",
    build_setting_default = "APPLE"
)
drink_rule(
    name = "my_drink",
    flavor = ":favorite_flavor",
)

各言語で、その言語のすべてのルールが依存する、正規のビルド設定のセットを作成したい場合。fragments のネイティブなコンセプトは、Starlark 構成の世界ではハードコードされたオブジェクトとして存在なくなりましたが、このコンセプトを変換する 1 つの方法は、一般的な暗黙的属性のセットを使用することです。次に例を示します。

# kotlin/rules.bzl
_KOTLIN_CONFIG = {
    "_compiler": attr.label(default = "//kotlin/config:compiler-flag"),
    "_mode": attr.label(default = "//kotlin/config:mode-flag"),
    ...
}

...

kotlin_library = rule(
    implementation = _rule_impl,
    attrs = dicts.add({
        "library-attr": attr.string()
    }, _KOTLIN_CONFIG)
)

kotlin_binary = rule(
    implementation = _binary_impl,
    attrs = dicts.add({
        "binary-attr": attr.label()
    }, _KOTLIN_CONFIG)

コマンドラインでビルド設定を使用する

ほとんどのネイティブ フラグと同様に、コマンドラインを使用して、フラグとしてマークされたビルド設定を指定できます。ビルド設定の名前は、name=value 構文を使用した完全なターゲット パスです。

$ bazel build //my/target --//example:string_flag=some-value # allowed
$ bazel build //my/target --//example:string_flag some-value # not allowed

特別なブール構文がサポートされています。

$ bazel build //my/target --//example:boolean_flag
$ bazel build //my/target --no//example:boolean_flag

ビルド設定エイリアスの使用

ビルド設定のターゲット パスにエイリアスを設定すると、コマンドラインで読みやすくなります。エイリアスはネイティブ フラグと同様に機能し、2 重ダッシュ オプション構文を使用します。

エイリアスを設定するには、.bazelrc--flag_alias=ALIAS_NAME=TARGET_PATH を追加します。たとえば、エイリアスを coffee に設定するには、次のようにします。

# .bazelrc
build --flag_alias=coffee=//experimental/user/starlark_configurations/basic_build_setting:coffee-temp

ベスト プラクティス: エイリアスを複数回設定すると、最新のものが優先されます。意図しない解析結果を避けるため、一意のエイリアス名を使用してください。

エイリアスを使用するには、ビルド設定のターゲット パスの代わりにそのエイリアスを入力します。 上記の例では、ユーザーの .bazelrccoffee を設定しています。

$ bazel build //my/target --coffee=ICED

これは、以下を置き換えるものです。

$ bazel build //my/target --//experimental/user/starlark_configurations/basic_build_setting:coffee-temp=ICED

ベスト プラクティス: コマンドラインでエイリアスを設定できますが、.bazelrc に残しておくと、コマンドラインが煩雑になります。

ラベルタイプのビルド設定

エンドツーエンドの例

他のビルド設定とは異なり、ラベルタイプの設定は、build_setting ルール パラメータを使用して定義することはできません。代わりに、bazel には label_flaglabel_setting の 2 つの組み込みルールがあります。これらのルールにより、ビルド設定が設定されている実際のターゲットのプロバイダが転送されます。label_flaglabel_setting は遷移によって読み書きでき、ユーザーは他の build_setting ルールと同じように label_flag を設定できます。唯一の違いは カスタム定義できない点です

遅延バインドのデフォルト機能は、最終的にはラベルタイプの設定に置き換わる予定です。遅延バインドのデフォルト属性はラベル型の属性であり、最終的な値が構成の影響を受ける可能性があります。Starlark では、これは configuration_field API に代わるものです。

# example/rules.bzl
MyProvider = provider(fields = ["my_field"])

def _dep_impl(ctx):
    return MyProvider(my_field = "yeehaw")

dep_rule = rule(
    implementation = _dep_impl
)

def _parent_impl(ctx):
    if ctx.attr.my_field_provider[MyProvider].my_field == "cowabunga":
        ...

parent_rule = rule(
    implementation = _parent_impl,
    attrs = { "my_field_provider": attr.label() }
)

# example/BUILD
load("//example:rules.bzl", "dep_rule", "parent_rule")

dep_rule(name = "dep")

parent_rule(name = "parent", my_field_provider = ":my_field_provider")

label_flag(
    name = "my_field_provider",
    build_setting_default = ":dep"
)

ビルド設定と select()

エンドツーエンドの例

ユーザーは、select() を使用してビルド設定で属性を構成できます。ビルド設定ターゲットは、config_settingflag_values 属性に渡すことができます。構成と一致する値は String として渡され、照合用のビルド設定のタイプに解析されます。

config_setting(
    name = "my_config",
    flag_values = {
        "//example:favorite_flavor": "MANGO"
    }
)

ユーザー定義の移行

構成の遷移は、構成済みのターゲットから別のターゲットへの変換をビルドグラフ内でマッピングします。

定義

遷移は、ルール間の構成の変更を定義します。たとえば、「親とは異なる CPU の依存関係をコンパイルする」などのリクエストは遷移によって処理されます。

正式には、遷移は入力構成から 1 つ以上の出力構成への関数です。「--cpu=ppc で入力構成をオーバーライドする」など、ほとんどの遷移は 1 対 1 です。1 対 2 以上の遷移も存在しますが、特別な制限があります。

Starlark では、遷移はルールと同様に定義され、transition() 関数の定義と実装関数を使用します。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return {"//example:favorite_flavor" : "MINT"}

hot_chocolate_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//example:favorite_flavor"]
)

transition() 関数は、実装関数、読み取るビルド設定のセット(inputs)、書き込むビルド設定のセット(outputs)を受け取ります。実装関数には settingsattr の 2 つのパラメータがあります。settings は、transition() に対する inputs パラメータで宣言されたすべての設定の辞書 {String:Object} です。

attr は、遷移を適用するルールの属性と値の辞書です。出力エッジ遷移としてアタッチされる場合、これらの属性の値はすべて post-select() の解決に構成されます。受信エッジ遷移としてアタッチされた場合、attr には、セレクタを使用して値を解決する属性は含まれません。--foo の入力エッジ遷移で属性 bar が読み取られ、さらに --foo を選択して属性 bar を設定すると、受信エッジ遷移が遷移内の bar の誤った値を読み取る可能性があります。

実装関数は、適用する新しいビルド設定値の辞書(複数の出力構成を伴う遷移の場合は辞書のリスト)を返す必要があります。返される辞書キーセットには、遷移関数の outputs パラメータに渡されたビルド設定のセットを正確に含める必要があります。これは、遷移の過程でビルド設定が実際に変更されない場合でも当てはまります。返された辞書で元の値を明示的に渡す必要があります。

1:2 以上の遷移の定義

エンドツーエンドの例

出力エッジ遷移は、1 つの入力構成を 2 つ以上の出力構成にマッピングできます。これは、マルチアーキテクチャ コードをバンドルするルールを定義するのに役立ちます。

1 対 2 以上の遷移は、遷移実装関数で辞書のリストを返すことで定義されます。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return [
        {"//example:favorite_flavor" : "LATTE"},
        {"//example:favorite_flavor" : "MOCHA"},
    ]

coffee_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//example:favorite_flavor"]
)

また、ルール実装関数が個々の依存関係を読み取るために使用できるカスタムキーを設定することもできます。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return {
        "Apple deps": {"//command_line_option:cpu": "ppc"},
        "Linux deps": {"//command_line_option:cpu": "x86"},
    }

multi_arch_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//command_line_option:cpu"]
)

遷移を適用する

エンドツーエンドの例

遷移は、受信エッジと出力エッジの 2 か所に適用できます。つまり、ルールは独自の構成を移行(受信エッジ移行)し、依存関係の構成を移行(送信エッジ移行)できます。

注: 現時点では、Starlark 遷移をネイティブ ルールにアタッチする方法はありません。これを行う必要がある場合は、bazel-discuss@googlegroups.com に連絡して回避策を見つけてください。

着信エッジ遷移

受信エッジ遷移は、transition オブジェクト(transition() で作成)を rule()cfg パラメータにアタッチすることでアクティブになります。

# example/rules.bzl
load("example/transitions:transitions.bzl", "hot_chocolate_transition")
drink_rule = rule(
    implementation = _impl,
    cfg = hot_chocolate_transition,
    ...

受信エッジ遷移は 1:1 遷移である必要があります。

出力エッジ遷移

出力エッジ遷移は、transition オブジェクト(transition() で作成)を属性の cfg パラメータにアタッチすることでアクティブになります。

# example/rules.bzl
load("example/transitions:transitions.bzl", "coffee_transition")
drink_rule = rule(
    implementation = _impl,
    attrs = { "dep": attr.label(cfg = coffee_transition)}
    ...

出力エッジ遷移は 1:1 または 1:2 以上のいずれかです。

これらのキーの読み取り方法については、遷移による属性へのアクセスをご覧ください。

ネイティブ オプションでの遷移

エンドツーエンドの例

Starlark 遷移では、オプション名に特別な接頭辞を付けることで、ネイティブ ビルド構成オプションに対する読み取りと書き込みも宣言できます。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return {"//command_line_option:cpu": "k8"}

cpu_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//command_line_option:cpu"]

サポートされていないネイティブ オプション

Bazel は、"//command_line_option:define" を使用した --define での移行をサポートしていません。代わりに、カスタムのビルド設定を使用してください。一般的に、ビルド設定を優先して --define を新たに使用することはおすすめしません。

Bazel は、--config での移行をサポートしていません。これは、--config が他のフラグに展開される「拡張」フラグであるためです。

重要な点として、--config には、ビルド構成に影響しないフラグ(--spawn_strategy など)が含まれている場合があります。Bazel では、設計上、このようなフラグを個々のターゲットにバインドすることはできません。つまり、遷移でそれらを適用する一貫した方法がありません。

回避策として、移行の構成の一部であるフラグを明示的に項目化できます。そのためには、--config の拡張を 2 か所で維持する必要がありますが、これは既知の UI の問題です。

遷移で複数のビルド設定が許可される

複数の値を許可するビルド設定を行う場合は、設定の値をリストで設定する必要があります。

# example/buildsettings/build_settings.bzl
string_flag = rule(
    implementation = _impl,
    build_setting = config.string(flag = True, allow_multiple = True)
)
# example/BUILD
load("//example/buildsettings:build_settings.bzl", "string_flag")
string_flag(name = "roasts", build_setting_default = "medium")
# example/transitions/rules.bzl
def _transition_impl(settings, attr):
    # Using a value of just "dark" here will throw an error
    return {"//example:roasts" : ["dark"]},

coffee_transition = transition(
    implementation = _transition_impl,
    inputs = [],
    outputs = ["//example:roasts"]
)

NoOps の移行

遷移が {}[]、または None を返す場合、これは、すべての設定を元の値のままにするための省略形です。これは、各出力を明示的に自身に設定するよりも便利な場合があります。

# example/transitions/transitions.bzl
def _impl(settings, attr):
    _ignore = (attr)
    if settings["//example:already_chosen"] is True:
      return {}
    return {
      "//example:favorite_flavor": "dark chocolate",
      "//example:include_marshmallows": "yes",
      "//example:desired_temperature": "38C",
    }

hot_chocolate_transition = transition(
    implementation = _impl,
    inputs = ["//example:already_chosen"],
    outputs = [
        "//example:favorite_flavor",
        "//example:include_marshmallows",
        "//example:desired_temperature",
    ]
)

遷移による属性へのアクセス

エンドツーエンドの例

遷移を出力エッジに接続する場合(遷移が 1:1 か 1:2 以上の遷移かにかかわらず)、ctx.attr はまだリストになっていない場合、強制的にリストになります。このリスト内の要素の順序は指定されていません。

# example/transitions/rules.bzl
def _transition_impl(settings, attr):
    return {"//example:favorite_flavor" : "LATTE"},

coffee_transition = transition(
    implementation = _transition_impl,
    inputs = [],
    outputs = ["//example:favorite_flavor"]
)

def _rule_impl(ctx):
    # Note: List access even though "dep" is not declared as list
    transitioned_dep = ctx.attr.dep[0]

    # Note: Access doesn't change, other_deps was already a list
    for other_dep in ctx.attr.other_deps:
      # ...


coffee_rule = rule(
    implementation = _rule_impl,
    attrs = {
        "dep": attr.label(cfg = coffee_transition)
        "other_deps": attr.label_list(cfg = coffee_transition)
    })

遷移が 1:2+ で、カスタムキーが設定されている場合、ctx.split_attr を使用してキーごとに個別の依存関係を読み取ることができます。

# example/transitions/rules.bzl
def _impl(settings, attr):
    _ignore = (settings, attr)
    return {
        "Apple deps": {"//command_line_option:cpu": "ppc"},
        "Linux deps": {"//command_line_option:cpu": "x86"},
    }

multi_arch_transition = transition(
    implementation = _impl,
    inputs = [],
    outputs = ["//command_line_option:cpu"]
)

def _rule_impl(ctx):
    apple_dep = ctx.split_attr.dep["Apple deps"]
    linux_dep = ctx.split_attr.dep["Linux deps"]
    # ctx.attr has a list of all deps for all keys. Order is not guaranteed.
    all_deps = ctx.attr.dep

multi_arch_rule = rule(
    implementation = _rule_impl,
    attrs = {
        "dep": attr.label(cfg = multi_arch_transition)
    })

完全な例をご覧ください。

プラットフォームやツールチェーンとのインテグレーション

現在、--cpu--crosstool_top など、多くのネイティブ フラグはツールチェーンの解決に関連しています。将来的には、これらのタイプのフラグに対する明示的な移行は、ターゲット プラットフォームでの移行によって置き換えられる可能性があります。

メモリとパフォーマンスに関する考慮事項

遷移や新しい構成をビルドに追加すると、ビルドグラフが大きくなり、ビルドグラフがわかりにくく、ビルドが遅くなるなどの代償が伴います。ビルドルールで遷移を使用することを検討する際には、これらのコストを考慮することが重要です。遷移によってビルドグラフが指数関数的に増加する例を以下に示します。

不適切な動作のビルド: 事例紹介

スケーラビリティ グラフ

図 1. 最上位のターゲットとその依存関係を示すスケーラビリティ グラフ。

このグラフは、//pkg:1_0//pkg:1_1 の 2 つのターゲットに依存するトップレベル ターゲット //pkg:app を示しています。これらのターゲットはどちらも //pkg:2_0//pkg:2_1 の 2 つのターゲットに依存します。これらのターゲットはどちらも //pkg:3_0//pkg:3_1 の 2 つのターゲットに依存します。これは、どちらも単一のターゲット //pkg:dep に依存する //pkg:n_0//pkg:n_1 まで継続します。

//pkg:app の構築には、 \(2n+2\) ターゲットが必要です。

  • //pkg:app
  • //pkg:dep
  • //pkg:i_0//pkg:i_1( \(i\) 内 \([1..n]\))

--//foo:owner=<STRING> フラグをimplementすると、//pkg:i_b

depConfig = myConfig + depConfig.owner="$(myConfig.owner)$(b)"

つまり、//pkg:i_b はすべての依存関係の古い値 --ownerb を追加します。

これにより、次の構成済みターゲットが生成されます。

//pkg:app                              //foo:owner=""
//pkg:1_0                              //foo:owner=""
//pkg:1_1                              //foo:owner=""
//pkg:2_0 (via //pkg:1_0)              //foo:owner="0"
//pkg:2_0 (via //pkg:1_1)              //foo:owner="1"
//pkg:2_1 (via //pkg:1_0)              //foo:owner="0"
//pkg:2_1 (via //pkg:1_1)              //foo:owner="1"
//pkg:3_0 (via //pkg:1_0 → //pkg:2_0)  //foo:owner="00"
//pkg:3_0 (via //pkg:1_0 → //pkg:2_1)  //foo:owner="01"
//pkg:3_0 (via //pkg:1_1 → //pkg:2_0)  //foo:owner="10"
//pkg:3_0 (via //pkg:1_1 → //pkg:2_1)  //foo:owner="11"
...

//pkg:dep が \(2^n\) 構成済みターゲット config.owner= を生成します。 \(b_i\) \(\{0,1\}\)内のすべてに対して「\(b_0b_1...b_n\)」

これにより、ビルドグラフはターゲット グラフよりも指数関数的に大きくなり、対応するメモリとパフォーマンスに影響が生じます。

TODO: これらの問題の測定と軽減のための戦略を追加する。

参考資料

ビルド構成の変更について詳しくは、以下をご覧ください。