Tutorial Bazel: Mem-build Aplikasi Android

Laporkan masalah Lihat sumber {/18/}{/1/}

Tutorial ini membahas cara membuat aplikasi Android sederhana menggunakan Bazel.

Bazel mendukung pembuatan aplikasi Android menggunakan aturan Android.

Tutorial ini ditujukan untuk pengguna Windows, macOS, dan Linux, serta tidak memerlukan pengalaman pengembangan aplikasi Bazel atau Android. Anda tidak perlu menulis kode Android dalam tutorial ini.

Yang akan Anda pelajari

Dalam tutorial ini, Anda akan mempelajari cara:

  • Siapkan lingkungan Anda dengan menginstal Bazel dan Android Studio, serta mendownload project contoh.
  • Siapkan ruang kerja Bazel yang berisi kode sumber untuk aplikasi dan file WORKSPACE yang mengidentifikasi tingkat teratas direktori ruang kerja.
  • Update file WORKSPACE agar berisi referensi ke dependensi eksternal yang diperlukan, seperti Android SDK.
  • Buat file BUILD.
  • Bangun aplikasi dengan Bazel.
  • Men-deploy dan menjalankan aplikasi di emulator Android atau perangkat fisik.

Sebelum memulai

Instal Bazel

Sebelum memulai tutorial, instal software berikut:

  • Bazel. Untuk menginstal, ikuti petunjuk penginstalan.
  • Android Studio. Untuk menginstal, ikuti langkah-langkah untuk mendownload Android Studio. Jalankan wizard penyiapan untuk mendownload SDK dan mengonfigurasi lingkungan Anda.
  • (Opsional) Git. Gunakan git untuk mendownload project aplikasi Android.

Mendapatkan contoh project

Untuk project contoh, gunakan project aplikasi Android dasar di repositori contoh Bazel.

Aplikasi ini memiliki satu tombol yang mencetak ucapan saat diklik:

Sambutan tombol

Gambar 1. Sambutan tombol aplikasi Android.

Clone repositori dengan git (atau download file ZIP secara langsung):

git clone https://github.com/bazelbuild/examples

Project contoh untuk tutorial ini ada dalam examples/android/tutorial. Untuk tutorial selanjutnya, Anda akan mengeksekusi perintah dalam direktori ini.

Meninjau file sumber

Lihat file sumber untuk aplikasi.

.
├── README.md
└── src
    └── main
        ├── AndroidManifest.xml
        └── java
            └── com
                └── example
                    └── bazel
                        ├── AndroidManifest.xml
                        ├── Greeter.java
                        ├── MainActivity.java
                        └── res
                            ├── layout
                            │   └── activity_main.xml
                            └── values
                                ├── colors.xml
                                └── strings.xml

File dan direktori utama adalah:

Name Lokasi
File manifes Android src/main/AndroidManifest.xml dan src/main/java/com/example/bazel/AndroidManifest.xml
File sumber Android src/main/java/com/example/bazel/MainActivity.java dan Greeter.java
Direktori file resource src/main/java/com/example/bazel/res/

Membangun dengan Bazel

Menyiapkan ruang kerja

Ruang kerja adalah direktori yang berisi file sumber untuk satu atau beberapa project software, dan memiliki file WORKSPACE di root-nya.

File WORKSPACE mungkin kosong atau mungkin berisi referensi ke dependensi eksternal yang diperlukan untuk membuat project Anda.

Pertama, jalankan perintah berikut untuk membuat file WORKSPACE kosong:

OS Perintah
Linux, macOS touch WORKSPACE
Windows (Command Prompt) type nul > WORKSPACE
Windows (PowerShell) New-Item WORKSPACE -ItemType file

Bazel Lari

Sekarang Anda dapat memeriksa apakah Bazel berjalan dengan benar menggunakan perintah:

bazel info workspace

Jika Bazel mencetak jalur direktori saat ini, Anda siap! Jika file WORKSPACE tidak ada, Anda mungkin melihat pesan error seperti:

ERROR: The 'info' command is only supported from within a workspace.

Mengintegrasikan dengan Android SDK

Bazel perlu menjalankan alat build Android SDK untuk membuat aplikasi. Artinya, Anda perlu menambahkan beberapa informasi ke file WORKSPACE agar Bazel dapat mengetahui tempat menemukannya.

Tambahkan baris berikut ke file WORKSPACE Anda:

android_sdk_repository(name = "androidsdk")

Tindakan ini akan menggunakan Android SDK di jalur yang dirujuk oleh variabel lingkungan ANDROID_HOME, dan otomatis mendeteksi level API tertinggi dan versi terbaru alat build yang diinstal di lokasi tersebut.

Anda dapat menetapkan variabel ANDROID_HOME ke lokasi Android SDK. Temukan jalur ke SDK yang diinstal menggunakan SDK Manager Android Studio. Dengan asumsi bahwa SDK diinstal ke lokasi default, Anda dapat menggunakan perintah berikut untuk menetapkan variabel ANDROID_HOME:

OS Perintah
Linux export ANDROID_HOME=$HOME/Android/Sdk/
macOS export ANDROID_HOME=$HOME/Library/Android/sdk
Windows (Command Prompt) set ANDROID_HOME=%LOCALAPPDATA%\Android\Sdk
Windows (PowerShell) $env:ANDROID_HOME="$env:LOCALAPPDATA\Android\Sdk"

Perintah di atas menetapkan variabel hanya untuk sesi shell saat ini. Untuk membuatnya permanen, jalankan perintah berikut:

OS Perintah
Linux echo "export ANDROID_HOME=$HOME/Android/Sdk/" >> ~/.bashrc
macOS echo "export ANDROID_HOME=$HOME/Library/Android/Sdk/" >> ~/.bashrc
Windows (Command Prompt) setx ANDROID_HOME "%LOCALAPPDATA%\Android\Sdk"
Windows (PowerShell) [System.Environment]::SetEnvironmentVariable('ANDROID_HOME', "$env:LOCALAPPDATA\Android\Sdk", [System.EnvironmentVariableTarget]::User)

Anda juga dapat secara eksplisit menentukan jalur absolut Android SDK, level API, dan versi alat build yang akan digunakan dengan menyertakan atribut path, api_level, dan build_tools_version. Jika api_level dan build_tools_version tidak ditentukan, aturan android_sdk_repository akan menggunakan versi terbaru masing-masing yang tersedia di SDK. Anda dapat menentukan kombinasi atribut ini, selama ada di SDK, misalnya:

android_sdk_repository(
    name = "androidsdk",
    path = "/path/to/Android/sdk",
    api_level = 25,
    build_tools_version = "30.0.3"
)

Di Windows, perhatikan bahwa atribut path harus menggunakan jalur gaya campuran, yaitu jalur Windows dengan garis miring ke depan:

android_sdk_repository(
    name = "androidsdk",
    path = "c:/path/to/Android/sdk",
)

Opsional: Jika ingin mengompilasi kode native ke aplikasi Android, Anda juga harus mendownload Android NDK dan memberi tahu Bazel tempat menemukannya dengan menambahkan baris berikut ke file WORKSPACE:

android_ndk_repository(name = "androidndk")

Serupa dengan android_sdk_repository, jalur ke Android NDK disimpulkan dari variabel lingkungan ANDROID_NDK_HOME secara default. Jalur ini juga dapat ditentukan secara eksplisit dengan atribut path di android_ndk_repository.

Untuk informasi selengkapnya, baca Menggunakan Android Native Development Kit dengan Bazel.

api_level adalah versi Android API yang ditargetkan oleh SDK dan NDK - misalnya, 23 untuk Android 6.0 dan 25 untuk Android 7.1. Jika tidak ditetapkan secara eksplisit, api_level akan ditetapkan secara default ke level API tertinggi yang tersedia untuk android_sdk_repository dan android_ndk_repository.

Anda tidak perlu menyetel API level ke nilai yang sama untuk SDK dan NDK. Halaman ini berisi peta dari rilis Android ke API level yang didukung NDK.

Membuat file BUILD

File BUILD menjelaskan hubungan antara serangkaian output build, seperti resource Android yang dikompilasi dari aapt atau file class dari javac, dan dependensinya. Dependensi ini dapat berupa file sumber (Java, C++) di ruang kerja Anda atau output build lainnya. File BUILD ditulis dalam bahasa yang disebut Starlark.

File BUILD adalah bagian dari konsep di Bazel yang dikenal sebagai hierarki paket. Hierarki paket adalah struktur logis yang menempatkan struktur direktori di ruang kerja Anda. Setiap paket adalah direktori (dan subdirektorinya) yang berisi kumpulan file sumber terkait dan file BUILD. Paket ini juga menyertakan subdirektori apa pun, tidak termasuk subdirektori yang berisi file BUILD-nya sendiri. package name adalah jalur ke file BUILD yang terkait dengan WORKSPACE.

Perlu diperhatikan bahwa hierarki paket Bazel secara konseptual berbeda dengan hierarki paket Java pada direktori Aplikasi Android tempat file BUILD berada, meskipun direktori tersebut mungkin diatur secara identik.

Untuk aplikasi Android sederhana dalam tutorial ini, file sumber di src/main/ terdiri dari satu paket Bazel. Project yang lebih kompleks mungkin memiliki banyak paket bertingkat.

Menambahkan aturan android_library

File BUILD berisi beberapa jenis deklarasi yang berbeda untuk Bazel. Jenis yang paling penting adalah aturan build, yang memberi tahu Bazel cara membuat output software perantara atau akhir dari sekumpulan file sumber atau dependensi lainnya. Bazel menyediakan dua aturan build, android_library dan android_binary, yang dapat Anda gunakan untuk membuat aplikasi Android.

Untuk tutorial ini, pertama-tama Anda akan menggunakan aturan android_library untuk memberi tahu Bazel agar membuat modul library Android dari kode sumber dan file resource aplikasi. Kemudian, Anda akan menggunakan aturan android_binary untuk memberi tahu Bazel cara membuat paket aplikasi Android.

Buat file BUILD baru di direktori src/main/java/com/example/bazel, dan deklarasikan target android_library baru:

src/main/java/com/example/bazel/BUILD:

package(
    default_visibility = ["//src:__subpackages__"],
)

android_library(
    name = "greeter_activity",
    srcs = [
        "Greeter.java",
        "MainActivity.java",
    ],
    manifest = "AndroidManifest.xml",
    resource_files = glob(["res/**"]),
)

Aturan build android_library berisi kumpulan atribut yang menentukan informasi yang diperlukan Bazel untuk mem-build modul library dari file sumber. Perhatikan juga bahwa nama aturannya adalah greeter_activity. Anda akan mereferensikan aturan menggunakan nama ini sebagai dependensi dalam aturan android_binary.

Menambahkan aturan android_binary

Aturan android_binary membangun paket aplikasi Android (file .apk) untuk aplikasi Anda.

Buat file BUILD baru di direktori src/main/, dan deklarasikan target android_binary baru:

src/main/BUILD:

android_binary(
    name = "app",
    manifest = "AndroidManifest.xml",
    deps = ["//src/main/java/com/example/bazel:greeter_activity"],
)

Di sini, atribut deps mereferensikan output aturan greeter_activity yang Anda tambahkan ke file BUILD di atas. Artinya, saat Bazel membuat output dari aturan ini, Bazel akan memeriksa terlebih dahulu untuk mengetahui apakah output aturan library greeter_activity telah dibuat dan merupakan yang terbaru. Jika tidak, Bazel akan membuatnya, lalu menggunakan output tersebut untuk mem-build file paket aplikasi.

Sekarang, simpan dan tutup {i>file<i}.

Membangun aplikasi

Coba buat aplikasi Jalankan perintah berikut untuk membangun target android_binary:

bazel build //src/main:app

Subperintah build menginstruksikan Bazel untuk membuat target yang mengikutinya. Target ditetapkan sebagai nama aturan build di dalam file BUILD, beserta jalur paket yang terkait dengan direktori ruang kerja Anda. Untuk contoh ini, targetnya adalah app dan jalur paketnya adalah //src/main/.

Perhatikan bahwa terkadang Anda dapat menghilangkan jalur paket atau nama target, bergantung pada direktori kerja Anda saat ini pada command line dan nama target. Untuk mengetahui detail selengkapnya tentang label dan jalur target, lihat Label.

Bazel akan mulai membangun aplikasi contoh. Selama proses build, outputnya akan tampak seperti berikut:

INFO: Analysed target //src/main:app (0 packages loaded, 0 targets configured).
INFO: Found 1 target...
Target //src/main:app up-to-date:
  bazel-bin/src/main/app_deploy.jar
  bazel-bin/src/main/app_unsigned.apk
  bazel-bin/src/main/app.apk

Menemukan output build

Bazel menempatkan output operasi build menengah dan akhir dalam sekumpulan direktori output per pengguna dan per ruang kerja. Direktori ini disimpulkan dari lokasi berikut di tingkat teratas direktori project, dengan WORKSPACE:

  • bazel-bin menyimpan file biner yang dapat dieksekusi dan output build lainnya yang dapat dijalankan
  • bazel-genfiles menyimpan file sumber perantara yang dihasilkan oleh aturan Bazel
  • bazel-out menyimpan jenis output build lainnya

Bazel menyimpan file .apk Android yang dibuat menggunakan aturan android_binary dalam direktori bazel-bin/src/main, tempat nama subdirektori src/main diambil dari nama paket Bazel.

Di command prompt, tampilkan isi direktori ini dan cari file app.apk:

OS Perintah
Linux, macOS ls bazel-bin/src/main
Windows (Command Prompt) dir bazel-bin\src\main
Windows (PowerShell) ls bazel-bin\src\main

Menjalankan aplikasi

Kini Anda dapat men-deploy aplikasi ke perangkat Android atau emulator yang terhubung dari command line menggunakan perintah bazel mobile-install. Perintah ini menggunakan Android Debug Bridge (adb) untuk berkomunikasi dengan perangkat. Anda harus menyiapkan perangkat untuk menggunakan adb dengan mengikuti petunjuk di Android Debug Bridge sebelum deployment. Anda juga dapat memilih untuk menginstal aplikasi di emulator Android yang disertakan dalam Android Studio. Pastikan emulator berjalan sebelum menjalankan perintah di bawah.

Masukkan:

bazel mobile-install //src/main:app

Selanjutnya, cari dan luncurkan "Aplikasi Tutorial Bazel":

Aplikasi tutorial Bazel

Gambar 2. Aplikasi tutorial Bazel.

Selamat! Anda baru saja menginstal aplikasi Android pertama yang dibuat oleh Bazel.

Perhatikan bahwa subperintah mobile-install juga mendukung flag --incremental yang dapat digunakan untuk men-deploy hanya bagian-bagian aplikasi yang telah berubah sejak deployment terakhir.

Kode ini juga mendukung flag --start_app untuk langsung memulai aplikasi setelah menginstal.

Bacaan lebih lanjut

Untuk detail selengkapnya, lihat halaman ini:

Selamat membangun!