本頁面由 Cloud Translation API 翻譯而成。

搭配 Bazel 使用 Android 原生開發套件

如果您是第一次使用 Bazel，請先瀏覽使用 Bazel 建構 Android 教學課程。

總覽

Bazel 可以在許多不同的建構設定中執行，包括使用 Android Native Development Kit (NDK) 工具鍊的數種建構設定。這表示可以直接在 Bazel 中針對 Android 編譯一般的 cc_library 和 cc_binary 規則。Bazel 會使用 android_ndk_repository 存放區規則來完成這項作業。

必要條件

請確認您已安裝 Android SDK 和 NDK。

如要設定 SDK 和 NDK，請將下列程式碼片段加入 WORKSPACE：

android_sdk_repository(
    name = "androidsdk", # Required. Name *must* be "androidsdk".
    path = "/path/to/sdk", # Optional. Can be omitted if `ANDROID_HOME` environment variable is set.
)

android_ndk_repository(
    name = "androidndk", # Required. Name *must* be "androidndk".
    path = "/path/to/ndk", # Optional. Can be omitted if `ANDROID_NDK_HOME` environment variable is set.
)

如要進一步瞭解 android_ndk_repository 規則，請參閱「建構百科全書項目」。

快速入門

如要建構 Android 適用的 C++，只要在 android_binary 或 android_library 規則中加入 cc_library 依附元件即可。

舉例來說，假設 Android 應用程式有下列 BUILD 檔案：

# In <project>/app/src/main/BUILD.bazel

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
)

android_library(
    name = "lib",
    srcs = ["java/com/example/android/bazel/MainActivity.java"],
    resource_files = glob(["res/**/*"]),
    custom_package = "com.example.android.bazel",
    manifest = "LibraryManifest.xml",
    deps = [":jni_lib"],
)

android_binary(
    name = "app",
    deps = [":lib"],
    manifest = "AndroidManifest.xml",
)

這個 BUILD 檔案會產生以下目標圖表：

搜尋結果範例

圖 1 含有 cc_library 依附元件的 Android 專案建構圖。

如要建構應用程式，只要執行以下程式碼即可：

bazel build //app/src/main:app

bazel build 指令會編譯 Java 檔案、Android 資源檔案和 cc_library 規則，然後將所有內容封裝到 APK：

$ zipinfo -1 bazel-bin/app/src/main/app.apk
nativedeps
lib/armeabi-v7a/libapp.so
classes.dex
AndroidManifest.xml
...
res/...
...
META-INF/CERT.SF
META-INF/CERT.RSA
META-INF/MANIFEST.MF

Bazel 將所有 cc_Library 編譯為單一共用物件 (.so) 檔案，並預設以 armeabi-v7a ABI 為目標。如要同時變更此設定或為多個 ABI 進行建構，請參閱「設定目標 ABI」一節。

設定範例

您可以在 Bazel 範例存放區中找到這個範例。

在 BUILD.bazel 檔案中，使用 android_binary、android_library 和 cc_library 規則定義三個目標。

android_binary 頂層目標會建構 APK。

cc_library 目標包含一個 C++ 來源檔案及實作 JNI 函式：

#include <jni.h>
#include <string>

extern "C"
JNIEXPORT jstring

JNICALL
Java_com_example_android_bazel_MainActivity_stringFromJNI(
        JNIEnv *env,
        jobject /* this */) {
    std::string hello = "Hello from C++";
    return env->NewStringUTF(hello.c_str());
}

android_library 目標會指定 Java 來源、資源檔案和 cc_library 目標的依附元件。在這個範例中，MainActivity.java 會載入共用物件檔案 libapp.so，並定義 JNI 函式的方法簽章：

public class MainActivity extends AppCompatActivity {

    static {
        System.loadLibrary("app");
    }

    @Override
    protected void onCreate(Bundle savedInstanceState) {
       // ...
    }

    public native String stringFromJNI();

}

設定 STL

如要設定 C++ STL，請使用旗標 --android_crosstool_top。

bazel build //:app --android_crosstool_top=target label

@androidndk 可用的 STL：

STL	目標標籤
STLport	`@androidndk//:toolchain-stlport`
libc++	`@androidndk//:toolchain-libcpp`
gnustl	`@androidndk//:toolchain-gnu-libstdcpp`

r16 以下版本的預設 STL 為 gnustl。r17 以上版本則為 libc++。為了方便起見，目標 @androidndk//:default_crosstool 會別名為各個預設的 STL。

請注意，自 r18 起，STLport 和 gnustl 將移除，使 libc++ 成為 NDK 中唯一的 STL。

如要進一步瞭解這些 STL，請參閱 NDK 說明文件。

設定目標 ABI

如要設定目標 ABI，請使用 --fat_apk_cpu 標記，如下所示：

bazel build //:app --fat_apk_cpu=comma-separated list of ABIs

根據預設，Bazel 會為 armeabi-v7a 建構原生 Android 程式碼。如要針對 x86 進行建構 (例如用於模擬器)，請傳遞 --fat_apk_cpu=x86。如要為多個架構建立笨重的 APK，您可以指定多個 CPU：--fat_apk_cpu=armeabi-v7a,x86。

如果指定了多個 ABI，Bazel 會為每個 ABI 建構含有共用物件的 APK。

視 NDK 修訂版本和 Android API 級別而定，您可以使用下列 ABI：

NDK 修訂版本	ABI
16 以下版本	armeabi、 armeabi-v7a、arm64-v8a、mips、mips64、x86、x86_64
17 歲以上	armeabi-v7a、arm64-v8a、x86、x86_64

如要進一步瞭解這些 ABI，請參閱 NDK 說明文件。

我們不建議在發布子版本中使用 Multi-ABI Fat APK，因為 APK 會增加 APK 的大小，但對於開發和品質確保版本非常實用。

選取 C++ 標準

請使用以下旗標，根據 C++ 標準進行建構：

C++ 標準	旗幟
C++98	預設，不需旗標
C++11	`--cxxopt=-std=c++11`
C++14	`--cxxopt=-std=c++14`

例如：

bazel build //:app --cxxopt=-std=c++11

如要進一步瞭解如何透過 --cxxopt、--copt 和 --linkopt 傳遞編譯器和連結器標記，請參閱使用手冊。

您也可以使用 copts 和 linkopts，將編譯器和連結器旗標指定為 cc_library 中的屬性。例如：

cc_library(
    name = "jni_lib",
    srcs = ["cpp/native-lib.cpp"],
    copts = ["-std=c++11"],
    linkopts = ["-ldl"], # link against libdl
)

與平台和工具鍊整合

Bazel 的設定模型即將移至平台和工具鍊。如果您的建構使用 --platforms 旗標選取要建構的架構或作業系統，您必須將 --extra_toolchains 標記傳遞至 Bazel，才能使用 NDK。

舉例來說，如要整合 Go 規則提供的 android_arm64_cgo 工具鍊，除了 --platforms 旗標之外，也請傳遞 --extra_toolchains=@androidndk//:all。

bazel build //my/cc:lib \
  --platforms=@io_bazel_rules_go//go/toolchain:android_arm64_cgo \
  --extra_toolchains=@androidndk//:all

您也可以直接在 WORKSPACE 檔案中註冊這些憑證：

android_ndk_repository(name = "androidndk")
register_toolchains("@androidndk//:all")

註冊這些工具鍊會指示 Bazel 在解決架構和作業系統限制時，在 NDK BUILD 檔案 (適用於 NDK 20) 中查看這些工具：

toolchain(
  name = "x86-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_32",
  ],
  toolchain = "@androidndk//:x86-clang8.0.7-libcpp",
)

toolchain(
  name = "x86_64-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:x86_64",
  ],
  toolchain = "@androidndk//:x86_64-clang8.0.7-libcpp",
)

toolchain(
  name = "arm-linux-androideabi-clang8.0.7-v7a-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:arm",
  ],
  toolchain = "@androidndk//:arm-linux-androideabi-clang8.0.7-v7a-libcpp",
)

toolchain(
  name = "aarch64-linux-android-clang8.0.7-libcpp_toolchain",
  toolchain_type = "@bazel_tools//tools/cpp:toolchain_type",
  target_compatible_with = [
      "@platforms//os:android",
      "@platforms//cpu:aarch64",
  ],
  toolchain = "@androidndk//:aarch64-linux-android-clang8.0.7-libcpp",
)

運作方式：導入 Android 設定轉換功能

android_binary 規則可明確要求 Bazel 在與 Android 相容的設定中建構依附元件，讓 Bazel 建構作業「都能正常運作」，但 ABI 和 STL 設定的 --fat_apk_cpu 和 --android_crosstool_top 除外。

這項自動設定會在背景使用 Android 設定轉換。

相容的規則 (例如 android_binary) 會自動將其依附元件的設定變更為 Android 設定，因此只有建構作業的 Android 專屬子樹狀結構才會受到影響。建構圖的其他部分則會使用頂層目標設定進行處理。如果透過建構圖有支援該路徑的路徑，系統甚至可能會在兩種設定中處理單一目標。

一旦 Bazel 進入與 Android 相容的設定 (無論是在頂層指定或為了較高層級的轉換點)，就不會發生額外的轉換點，也不會進一步修改設定。

唯一會觸發轉換到 Android 設定的內建位置是 android_binary 的 deps 屬性。

舉例來說，如果您嘗試建構具有 cc_library 依附元件且沒有任何旗標的 android_library 目標，可能會遇到缺少 JNI 標頭的錯誤：

ERROR: project/app/src/main/BUILD.bazel:16:1: C++ compilation of rule '//app/src/main:jni_lib' failed (Exit 1)
app/src/main/cpp/native-lib.cpp:1:10: fatal error: 'jni.h' file not found
#include <jni.h>
         ^~~~~~~
1 error generated.
Target //app/src/main:lib failed to build
Use --verbose_failures to see the command lines of failed build steps.

在理想情況下，這些自動轉換作業應可讓 Bazel 在大部分情況下正確執行動作。但是，如果 Bazel 指令列的目標已低於任何上述轉換規則 (例如 C++ 開發人員測試特定的 cc_library)，則必須使用自訂 --crosstool_top。

在不使用 `android_binary` 的情況下建構 Android 適用的 `cc_library`

如要在不使用 android_binary 的情況下建構 Android 適用的獨立 cc_binary 或 cc_library，請使用 --crosstool_top、--cpu 和 --host_crosstool_top 旗標。

例如：

bazel build //my/cc/jni:target \
      --crosstool_top=@androidndk//:default_crosstool \
      --cpu=<abi> \
      --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

在這個範例中，頂層 cc_library 和 cc_binary 目標是使用 NDK 工具鍊建構。不過，這會導致 Bazel 本身的主機工具使用 NDK 工具鍊建構 (因此如果是 Android)，因為主機工具鍊是從目標工具鍊複製而來。如要解決這個問題，請將 --host_crosstool_top 的值指定為 @bazel_tools//tools/cpp:toolchain，以明確設定主機的 C++ 工具鍊。

使用這個方法時，整個建構樹狀結構都會受到影響。

這些標記可以放入 project/.bazelrc 中的 bazelrc 設定 (每個 ABI 各一個)：

common:android_x86 --crosstool_top=@androidndk//:default_crosstool
common:android_x86 --cpu=x86
common:android_x86 --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

common:android_armeabi-v7a --crosstool_top=@androidndk//:default_crosstool
common:android_armeabi-v7a --cpu=armeabi-v7a
common:android_armeabi-v7a --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

# In general
common:android_<abi> --crosstool_top=@androidndk//:default_crosstool
common:android_<abi> --cpu=<abi>
common:android_<abi> --host_crosstool_top=@bazel_tools//tools/cpp:toolchain

接著，如要為 x86 建構 cc_library，請執行：

bazel build //my/cc/jni:target --config=android_x86

一般來說，對於低階目標 (例如 cc_library) 或確切建構目標時，請使用這個方法；對於預期建構許多不可控管的高階目標，依賴 android_binary 的自動設定轉場功能。