Quy tắc chung

Quy tắc

• email đại diện
• config_setting
• nhóm tệp
• truy vấn tạo sinh
• tạo sinh
• test_suite

bí danh

alias(name, actual, compatible_with, deprecation, features, restricted_to, tags, target_compatible_with, testonly, visibility)

Quy tắc alias tạo ra một tên khác mà quy tắc có thể được dùng.

Tình trạng chồng phổ (aliasing) chỉ hoạt động đối với sản phẩm "thông thường" mục tiêu. Cụ thể, package_group và test_suite không thể đặt bí danh.

Quy tắc bí danh có phần khai báo chế độ hiển thị riêng. Trong tất cả các khía cạnh khác, nó hoạt động giống như quy tắc mà nó tham chiếu (ví dụ: chỉ kiểm thử trên bí danh sẽ bị bỏ qua; quy tắc chỉ kiểm thử của quy tắc được tham chiếu sẽ được sử dụng) với một số ngoại lệ nhỏ:

• Quá trình kiểm thử sẽ không chạy nếu email đại diện của chúng được đề cập trên dòng lệnh. Để xác định bí danh chạy kiểm thử được tham chiếu, hãy sử dụng test_suite quy tắc có một mục tiêu duy nhất trong tests .
• Khi xác định nhóm môi trường, bí danh cho quy tắc environment không được hỗ trợ. Các thành phần này không được hỗ trợ trong dòng lệnh --target_environment lựa chọn.

Ví dụ

filegroup(
    name = "data",
    srcs = ["data.txt"],
)

alias(
    name = "other",
    actual = ":data",
)

Đối số

config_setting

config_setting(name, constraint_values, define_values, deprecation, distribs, features, flag_values, licenses, tags, testonly, values, visibility)

Khớp với trạng thái cấu hình dự kiến (được biểu thị dưới dạng cờ bản dựng hoặc quy tắc ràng buộc của nền tảng) đối với mục đích của việc kích hoạt các thuộc tính có thể định cấu hình. Xem mục chọn cho cách áp dụng quy tắc này và Thuộc tính có thể định cấu hình để xem thông tin tổng quan về tính năng chung.

Ví dụ

Mã sau đây khớp với mọi bản dựng đặt --compilation_mode=opt hoặc -c opt (thể hiện rõ ràng tại dòng lệnh hoặc ngầm ẩn từ các tệp .bazelrc):

  config_setting(
      name = "simple",
      values = {"compilation_mode": "opt"}
  )
  

Mã sau đây khớp với mọi bản dựng nhắm mục tiêu đến ARM và áp dụng định nghĩa tuỳ chỉnh FOO=bar (ví dụ: bazel build --cpu=arm --define FOO=bar ...):

  config_setting(
      name = "two_conditions",
      values = {
          "cpu": "arm",
          "define": "FOO=bar"
      }
  )
  

Các mã sau đây khớp với bất kỳ bản dựng nào đặt cờ do người dùng xác định --//custom_flags:foo=1 (thể hiện rõ ràng tại dòng lệnh hoặc ngầm ẩn từ tệp .bazelrc):

  config_setting(
      name = "my_custom_flag_is_set",
      flag_values = { "//custom_flags:foo": "1" },
  )
  

Nội dung sau đây phù hợp với mọi bản dựng nhắm đến nền tảng có cấu trúc x86_64 và glibc phiên bản 2.25, giả định tồn tại của constraint_value có nhãn //example:glibc_2_25 Xin lưu ý rằng nền tảng vẫn so khớp nếu nền tảng đó xác định các thông số bổ sung các giá trị ràng buộc khác ngoài hai giới hạn này.

  config_setting(
      name = "64bit_glibc_2_25",
      constraint_values = [
          "@platforms//cpu:x86_64",
          "//example:glibc_2_25",
      ]
  )
  

Ghi chú

• Xem phần chọn để biết điều gì sẽ xảy ra khi nhiều config_setting khớp với trạng thái cấu hình hiện tại.
• Đối với cờ hỗ trợ dạng viết tắt (ví dụ: --compilation_mode so với -c), values định nghĩa phải sử dụng biểu mẫu đầy đủ. Tự động khớp các lệnh gọi bằng một trong hai biểu mẫu này.
• Nếu một cờ nhận nhiều giá trị (như --copt=-Da --copt=-Db hoặc kiểu danh sách Cờ Starlark), values = { "flag": "a" } sẽ khớp nếu "a" là hiển thị ở bất cứ đâu trong danh sách thực tế.

  values = { "myflag": "a,b" } cũng hoạt động theo cách tương tự: khớp với --myflag=a --myflag=b, --myflag=a --myflag=b --myflag=c --myflag=a,b và --myflag=c,b,a. Ngữ nghĩa chính xác khác nhau giữa cờ. Ví dụ: --copt không hỗ trợ nhiều giá trị trong cùng một thực thể: --copt=a,b tạo ["a,b"] trong khi --copt=a --copt=b tạo ["a", "b"] (do đó values = { "copt": "a,b" } phù hợp với cái trước nhưng không khớp với cái sau). Nhưng --ios_multi_cpus (đối với các quy tắc của Apple) có: -ios_multi_cpus=a,b và ios_multi_cpus=a --ios_multi_cpus=b đều tạo ra ["a", "b"]. Kiểm tra định nghĩa cờ và kiểm tra các điều kiện cụ thể để xác minh các kỳ vọng chính xác.

• Nếu bạn cần xác định các điều kiện không được lập mô hình bằng cờ bản dựng tích hợp, hãy sử dụng Cờ do Starlark xác định. Bạn cũng có thể sử dụng --define, nhưng miền này cung cấp yếu hơn và không được khuyến khích. Xem tại đây để thảo luận thêm.
• Tránh lặp lại định nghĩa config_setting giống hệt nhau trong các gói khác nhau. Thay vào đó, hãy tham chiếu đến một config_setting chung được xác định trong một gói chuẩn.
• values! define_values và constraint_values có thể được sử dụng kết hợp bất kỳ trong cùng config_setting nhưng ít nhất một mục phải được đặt cho bất kỳ config_setting cho trước.

Đối số

            config_setting(
                name = "a_and_b",
                values = {
                    "define": "a=1",
                    "define": "b=2",
                })
          

            config_setting(
                name = "a_and_b",
                define_values = {
                    "a": "1",
                    "b": "2",
                })
          

nhóm tệp

filegroup(name, srcs, data, compatible_with, deprecation, distribs, features, licenses, output_group, restricted_to, tags, target_compatible_with, testonly, visibility)

Sử dụng filegroup để đặt tên thuận tiện cho một tập hợp mục tiêu. Sau đó, bạn có thể tham chiếu các quy tắc này từ các quy tắc khác.

Bạn nên sử dụng filegroup thay vì tham chiếu trực tiếp đến các thư mục. Tệp sau không hợp lệ vì hệ thống xây dựng không có đầy đủ kiến thức về tất cả các tệp bên dưới thư mục này, nên có thể tệp sẽ không tạo lại khi các tệp này thay đổi. Khi kết hợp với glob, filegroup có thể đảm bảo rằng tất cả các tệp được được hệ thống xây dựng biết rõ.

Ví dụ

Để tạo một filegroup bao gồm hai tệp nguồn, hãy làm

filegroup(
    name = "mygroup",
    srcs = [
        "a_file.txt",
        "some/subdirectory/another_file.txt",
    ],
)

Bạn cũng có thể sử dụng glob để thu gọn thư mục dữ liệu kiểm thử:

filegroup(
    name = "exported_testdata",
    srcs = glob([
        "testdata/*.dat",
        "testdata/logs/**/*.log",
    ]),
)

Để sử dụng các định nghĩa này, hãy tham chiếu filegroup cùng với nhãn từ bất kỳ quy tắc nào:

cc_library(
    name = "my_library",
    srcs = ["foo.cc"],
    data = [
        "//my_package:exported_testdata",
        "//my_package:mygroup",
    ],
)

Đối số

truy vấn tạo

genquery(name, deps, data, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, expression, features, licenses, opts, restricted_to, scope, strict, tags, target_compatible_with, testonly, visibility)

genquery() chạy một truy vấn được chỉ định trong Ngôn ngữ truy vấn đăng tải và kết xuất kết quả vào một tệp.

Để giữ công trình xây dựng nhất quán, truy vấn chỉ được phép truy cập đóng bắc cầu của các mục tiêu được chỉ định trong scope . Các truy vấn vi phạm quy tắc này sẽ không thực thi được nếu strict là không xác định hoặc true (nếu strict là false, các mục tiêu nằm ngoài phạm vi sẽ bị bỏ qua kèm theo cảnh báo). Chiến lược phát hành đĩa đơn cách dễ nhất để đảm bảo điều này không xảy ra là đề cập đến cùng một nhãn trong phạm vi như trong biểu thức truy vấn.

Sự khác biệt duy nhất giữa các truy vấn được phép ở đây và trong lệnh là những truy vấn chứa thông số kỹ thuật đích ký tự đại diện (ví dụ: //pkg:* hoặc //pkg:all) không được phép ở đây. Có hai lý do dẫn đến điều này, thứ nhất là vì genquery đã để chỉ định phạm vi ngăn chặn các mục tiêu nằm ngoài hệ thống đóng bắc cầu của truy vấn để tác động đến kết quả của truy vấn đó; và thứ hai là vì BUILD tệp không hỗ trợ phần phụ thuộc ký tự đại diện (ví dụ: deps=["//a/..."] là không được phép).

Kết quả của truy vấn tạo được sắp xếp bằng cách sử dụng --order_output=full trong để thực thi đầu ra xác định.

Tên của tệp đầu ra là tên của quy tắc.

Ví dụ

Ví dụ này viết danh sách các nhãn trong đóng cầu nối của đích được chỉ định vào một tệp.

genquery(
    name = "kiwi-deps",
    expression = "deps(//kiwi:kiwi_lib)",
    scope = ["//kiwi:kiwi_lib"],
)

Đối số

quy tắc tạo sinh

genrule(name, srcs, outs, cmd, cmd_bash, cmd_bat, cmd_ps, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, exec_tools, executable, features, licenses, local, message, output_licenses, output_to_bindir, restricted_to, tags, target_compatible_with, testonly, toolchains, tools, visibility)

genrule tạo một hoặc nhiều tệp bằng lệnh Bash do người dùng xác định.

Quy tắc tạo quy tắc là các quy tắc xây dựng chung mà bạn có thể sử dụng nếu không có quy tắc cụ thể nào cho tác vụ. Ví dụ: bạn có thể chạy một dòng chữ Bash. Tuy nhiên, nếu bạn cần biên dịch các tệp C++, hãy tiếp tục theo các quy tắc cc_* hiện tại, vì tất cả các công việc khó khăn đã được thực hiện cho bạn.

Không sử dụng quy tắc tạo sinh để chạy kiểm thử. Có những sự khác biệt đặc biệt cho các bài kiểm thử và kiểm thử kết quả, bao gồm cả chính sách lưu vào bộ nhớ đệm và các biến môi trường. Thông thường, bạn cần chạy chương trình kiểm thử sau khi quá trình tạo bản dựng hoàn tất và trên cấu trúc mục tiêu, trong khi genrules được thực thi trong bản dựng và kiến trúc máy chủ lưu trữ (hai có thể khác nhau). Nếu bạn cần mục đích chung quy tắc thử nghiệm, sử dụng sh_test.

Những điểm cần cân nhắc khi biên dịch chéo

Xem hướng dẫn sử dụng để biết thêm thông tin về biên dịch chéo.

Mặc dù genrules chạy trong quá trình tạo bản dựng, nhưng dữ liệu đầu ra của chúng thường được dùng sau khi tạo bản dựng, để triển khai hoặc kiểm thử. Hãy xem xét ví dụ về việc biên dịch mã C cho một bộ vi điều khiển: trình biên dịch chấp nhận C tệp nguồn và tạo mã chạy trên vi điều khiển. Mã được tạo một cách rõ ràng không thể chạy trên CPU dùng để tạo ứng dụng đó, nhưng trình biên dịch C (nếu được biên dịch từ nguồn) phải làm.

Hệ thống xây dựng sử dụng cấu hình máy chủ lưu trữ để mô tả(các) máy mà bản dựng chạy và cấu hình mục tiêu để mô tả(các) máy mà đầu ra của bản dựng là phải chạy. Lớp này cung cấp các tuỳ chọn để định cấu hình từng yếu tố trong số này và tách riêng các tệp tương ứng vào các thư mục riêng biệt để tránh xung đột.

Đối với genrules, hệ thống xây dựng đảm bảo rằng các phần phụ thuộc được tạo phù hợp: srcs được tạo (nếu cần) cho cấu hình mục tiêu, tools được xây dựng cho cấu hình máy chủ và đầu ra được coi là dành cho cấu hình target. API này cũng cung cấp "Nhãn hiệu" các biến mà các lệnh genRule có thể truyền đến các công cụ tương ứng.

Có chủ ý rằng quy tắc gen không xác định thuộc tính deps nào: các quy tắc tích hợp sẵn khác sử dụng thông tin meta phụ thuộc vào ngôn ngữ được chuyển giữa các quy tắc để tự động xác định cách xử lý các quy tắc phụ thuộc, nhưng không thể tự động hoá quy tắc genrules. Hoạt động tạo quy tắc chỉ ở cấp độ tệp và runfile.

Các trường hợp đặc biệt

Biên dịch máy chủ-máy chủ: trong một số trường hợp, hệ thống xây dựng cần chạy genrules sao cho đầu ra cũng có thể được thực thi trong quá trình tạo. Ví dụ: nếu một genrules tạo một số trình biên dịch tuỳ chỉnh sau đó được một quy tắc sinh khác sử dụng, quy tắc đầu tiên phải tạo đầu ra cho quy tắc cấu hình máy chủ lưu trữ vì đó là nơi trình biên dịch sẽ chạy trong quy tắc gen khác. Trong trường hợp này, hệ thống xây dựng sẽ tự động thực hiện hoạt động đúng cách: hệ thống tạo srcs và outs của quy tắc tạo đầu tiên cho cấu hình máy chủ thay vì mục tiêu . Xem hướng dẫn sử dụng để biết thêm thông tin của bạn.

JDK và Công cụ C++: để sử dụng công cụ của JDK hoặc bộ biên dịch C++, hệ thống xây dựng sẽ cung cấp một tập hợp các biến để sử dụng. Xem phần "Nhãn hiệu" biến cho chi tiết.

Môi trường tạo quy tắc

Lệnh genrules được thực thi bằng một shell Bash được định cấu hình để không thành công khi một lệnh hoặc một quy trình bị lỗi, sử dụng set -e -o pipefail.

Công cụ bản dựng thực thi lệnh Bash trong một môi trường quy trình được dọn dẹp chỉ xác định các biến cốt lõi như PATH, PWD, TMPDIR và một vài người khác. Để đảm bảo rằng các bản dựng có thể tái tạo, hầu hết các biến được xác định trong shell của người dùng môi trường không được truyền qua lệnh của quy tắc gen. Tuy nhiên, Bazel (nhưng không phải là Blaze) chuyển qua giá trị của biến môi trường PATH của người dùng. Mọi thay đổi đối với giá trị của PATH sẽ khiến Bazel thực thi lại lệnh này trên bản dựng tiếp theo.

Lệnh tạo quy tắc không được truy cập vào mạng, ngoại trừ việc kết nối các quy trình phần tử con của chính lệnh đó, mặc dù lệnh này hiện không được thực thi.

Hệ thống xây dựng tự động xoá mọi tệp đầu ra hiện có, nhưng sẽ tạo bất kỳ tệp mẹ nào cần thiết trước khi chạy quy tắc gen. Thao tác này cũng xoá mọi tệp đầu ra nếu xảy ra lỗi.

Lời khuyên chung

• Đảm bảo rằng các công cụ chạy theo quy tắc tạo sinh có tính tất định và mang tính khép kín. Họ không nên ghi dấu thời gian cho đầu ra và nên sử dụng thứ tự ổn định cho các tập hợp và bản đồ, cũng như chỉ ghi các đường dẫn tệp tương đối cho kết quả, không ghi đường dẫn tuyệt đối. Không tuân theo quy tắc này sẽ dẫn đến hành vi xây dựng không mong muốn (Bazel không xây dựng lại một quy tắc chung mà bạn từng nghĩ) và làm giảm hiệu suất của bộ nhớ đệm.
• Sử dụng $(location) một cách rộng rãi cho dữ liệu đầu ra, công cụ và nguồn. Do phân tách các tệp đầu ra cho các cấu hình khác nhau, genrules không thể dựa vào mã hoá cứng và/hoặc đường dẫn tuyệt đối.
• Viết một macro Starlark phổ biến trong trường hợp sử dụng genrules giống hoặc rất giống nhau trong nhiều địa điểm. Nếu quy tắc tạo sinh phức tạp, hãy cân nhắc triển khai quy tắc đó trong một tập lệnh hoặc dưới dạng Quy tắc Starlark. Điều này giúp cải thiện khả năng đọc cũng như khả năng kiểm thử.
• Hãy đảm bảo rằng mã thoát cho biết chính xác quy tắc gen được tạo thành công hay không thành công.
• Không viết thư cung cấp thông tin cho stdout hoặc stderr. Mặc dù hữu ích khi gỡ lỗi, nhưng bạn có thể dễ trở thành tiếng ồn; một quy tắc tạo sinh thành công phải im lặng. Mặt khác, một quy tắc gen không thành công sẽ phát ra thông báo lỗi tốt.
• $$ evaluates to a $, a literal dollar-sign, so in order to invoke a shell command containing dollar-signs such as ls $(dirname $x), one must escape it thus: ls $$(dirname $$x).
• Tránh tạo đường liên kết tượng trưng và thư mục. Bazel không sao chép thư mục/đường liên kết tượng trưng cấu trúc do genrules tạo ra và việc kiểm tra phần phụ thuộc của thư mục là không phù hợp.
• Khi tham chiếu quy tắc gen trong các quy tắc khác, bạn có thể sử dụng nhãn của quy tắc gen hoặc nhãn của từng tệp đầu ra. Đôi khi, một phương pháp dễ đọc hơn, đôi khi phương pháp khác: tham chiếu kết quả theo tên trong srcs của quy tắc tiêu thụ sẽ tránh được vô tình chọn các đầu ra khác của quy tắc tạo sinh, nhưng có thể trở nên tẻ nhạt nếu quy tắc tạo sinh tạo ra nhiều đầu ra.

Ví dụ

Ví dụ này tạo ra foo.h. Không có nguồn nào vì lệnh này không lấy bất kỳ đầu vào nào. "Tệp nhị phân" chạy bằng lệnh này là một tập lệnh perl trong cùng một gói với quy tắc gen.

genrule(
    name = "foo",
    srcs = [],
    outs = ["foo.h"],
    cmd = "./$(location create_foo.pl) > \"$@\"",
    tools = ["create_foo.pl"],
)

Ví dụ sau đây trình bày cách sử dụng filegroup và kết quả của một genrule khác. Lưu ý rằng bạn nên dùng $(SRCS) để thay thế lệnh $(location) rõ ràng cũng sẽ hoạt động; Ví dụ này sử dụng URL sau cho nhằm mục đích minh hoạ.

genrule(
    name = "concat_all_files",
    srcs = [
        "//some:files",  # a filegroup with multiple files in it ==> $(locations)
        "//other:gen",   # a genrule with a single output ==> $(location)
    ],
    outs = ["concatenated.txt"],
    cmd = "cat $(locations //some:files) $(location //other:gen) > $@",
)

Đối số

test_suite

test_suite(name, compatible_with, deprecation, distribs, features, licenses, restricted_to, tags, target_compatible_with, testonly, tests, visibility)

test_suite xác định một tập hợp kiểm thử được xem là "hữu ích" cho con người. Chiến dịch này cho phép các dự án xác định tập hợp các bài kiểm thử, chẳng hạn như "các chương trình kiểm thử bạn phải chạy trước khi kiểm tra", "các chương trình kiểm thử của chúng tôi chương trình kiểm thử nghiêm ngặt" hoặc "tất cả các thử nghiệm nhỏ". Lệnh blaze test tuân theo cách sắp xếp này của tổ chức: Đối với lệnh gọi như blaze test //some/test:suite, trước tiên là Blaze liệt kê tất cả các mục tiêu kiểm thử được mục tiêu //some/test:suite đưa vào theo cách bắc cầu (chúng ta gọi đây là "mở rộng test_suite"), sau đó Blaze sẽ tạo và kiểm thử các mục tiêu đó.

Ví dụ

Một bộ kiểm thử để chạy mọi bài kiểm thử nhỏ trong gói hiện tại.

test_suite(
    name = "small_tests",
    tags = ["small"],
)

Một bộ kiểm thử chạy một tập hợp các chương trình kiểm thử đã chỉ định:

test_suite(
    name = "smoke_tests",
    tests = [
        "system_unittest",
        "public_api_unittest",
    ],
)

Một bộ kiểm thử để chạy tất cả các kiểm thử trong gói hiện tại mà không bị gián đoạn.

test_suite(
    name = "non_flaky_test",
    tags = ["-flaky"],
)

Đối số