Regras gerais

Regras

• alias
• config_setting
• filegroup
• genquery
• genrule
• starlark_doc_extract
• test_suite

alias

alias(name, actual, compatible_with, deprecation, features, restricted_to, tags, target_compatible_with, testonly, visibility)

A regra alias cria outro nome que pode ser usado para se referir a uma regra.

A atribuição de alias só funciona para segmentações "regulares". Especificamente, package_group e test_suite não podem ter um alias.

A atribuição de alias pode ser útil em grandes repositórios em que renomear um destino exigiria alterações em muitos arquivos. Também é possível usar a regra de alias para armazenar uma chamada de função select se você quiser reutilizar essa lógica para vários destinos.

A regra de alias tem a própria declaração de visibilidade. Em todos os outros aspectos, ele se comporta como a regra a que faz referência (por exemplo, o teste no alias é ignorado; o teste da regra referenciada é usado) com algumas exceções menores:

• Os testes não serão executados se o alias for mencionado na linha de comando. Para definir um alias que execute o teste referenciado, use uma regra test_suite com um único destino no atributo tests.
• Ao definir grupos de ambiente, os aliases para regras environment não são aceitos. Eles também não são compatíveis com a opção de linha de comando --target_environment.

Exemplos

filegroup(
    name = "data",
    srcs = ["data.txt"],
)

alias(
    name = "other",
    actual = ":data",
)

Argumentos

config_setting

config_setting(name, constraint_values, define_values, deprecation, distribs, features, flag_values, licenses, tags, testonly, values, visibility)

Corresponde a um estado de configuração esperado (expresso como flags de build ou restrições de plataforma) para acionar atributos configuráveis. Consulte selecionar para saber como usar essa regra e Atributos configuráveis para ter uma visão geral do recurso geral.

Exemplos

O seguinte corresponde a qualquer build que defina --compilation_mode=opt ou -c opt, seja explicitamente na linha de comando ou implicitamente a partir de arquivos .bazelrc:

  config_setting(
      name = "simple",
      values = {"compilation_mode": "opt"}
  )
  

O exemplo a seguir corresponde a qualquer build destinado a ARM e aplica a definição personalizada FOO=bar (por exemplo, bazel build --cpu=arm --define FOO=bar ...):

  config_setting(
      name = "two_conditions",
      values = {
          "cpu": "arm",
          "define": "FOO=bar"
      }
  )
  

O seguinte corresponde a qualquer build que defina a sinalização definida pelo usuário --//custom_flags:foo=1 (explicitamente na linha de comando ou implicitamente a partir de arquivos .bazelrc):

  config_setting(
      name = "my_custom_flag_is_set",
      flag_values = { "//custom_flags:foo": "1" },
  )
  

O exemplo a seguir corresponde a qualquer build direcionado a uma plataforma com arquitetura x86_64 e glibc versão 2.25, considerando a existência de um constraint_value com o rótulo //example:glibc_2_25. Uma plataforma ainda corresponde se definir valores de restrição adicionais além desses dois.

  config_setting(
      name = "64bit_glibc_2_25",
      constraint_values = [
          "@platforms//cpu:x86_64",
          "//example:glibc_2_25",
      ]
  )
  

Observações

• Consulte Selecionar para saber o que acontece quando vários config_settings correspondem ao estado de configuração atual.
• Para flags que oferecem suporte a formas abreviadas (por exemplo, --compilation_mode em vez de -c), as definições de values precisam usar o formato completo. Elas correspondem automaticamente a invocações usando qualquer um dos formatos.
• Se uma flag tiver vários valores (como --copt=-Da --copt=-Db ou uma flag do tipo lista Starlark), values = { "flag": "a" } vai corresponder se "a" estiver presente em qualquer lugar da lista.

  values = { "myflag": "a,b" } funciona da mesma maneira: ele corresponde a --myflag=a --myflag=b, --myflag=a --myflag=b --myflag=c, --myflag=a,b e --myflag=c,b,a. A semântica exata varia entre as flags. Por exemplo, --copt não aceita vários valores na mesma instância: --copt=a,b produz ["a,b"] enquanto --copt=a --copt=b produz ["a", "b"]. Portanto, values = { "copt": "a,b" } corresponde ao primeiro, mas não ao segundo. No entanto, --ios_multi_cpus (para regras da Apple) faz: -ios_multi_cpus=a,b e ios_multi_cpus=a --ios_multi_cpus=b produzem ["a", "b"]. Verifique as definições de sinalização e teste suas condições com cuidado para confirmar as expectativas exatas.

• Se você precisar definir condições que não sejam modeladas por flags de build integradas, use Flags definidas pelo Starlark. Você também pode usar --define, mas isso oferece um suporte mais fraco e não é recomendado. Clique aqui para mais discussões.
• Evite repetir definições idênticas de config_setting em pacotes diferentes. Em vez disso, faça referência a um config_setting comum definido em um pacote canônico.
• values, define_values e constraint_values podem ser usados em qualquer combinação no mesmo config_setting, mas pelo menos um precisa ser definido para qualquer config_setting.

Argumentos

            config_setting(
                name = "a_and_b",
                values = {
                    "define": "a=1",
                    "define": "b=2",
                })
          

            config_setting(
                name = "a_and_b",
                define_values = {
                    "a": "1",
                    "b": "2",
                })
          

grupo de arquivos

filegroup(name, srcs, data, compatible_with, deprecation, distribs, features, licenses, output_group, restricted_to, tags, target_compatible_with, testonly, visibility)

Use filegroup para dar um nome conveniente a uma coleção de destinos. Elas podem ser referenciadas em outras regras.

Recomendamos o uso de filegroup em vez de referenciar diretórios diretamente. O último método não é bom, já que o sistema de compilação não tem conhecimento total de todos os arquivos abaixo do diretório, então ele pode não ser recriado quando esses arquivos mudam. Quando combinado com glob, o filegroup pode garantir que todos os arquivos sejam explicitamente conhecidos pelo sistema de build.

Exemplos

Para criar um filegroup que consiste em dois arquivos de origem, faça o seguinte:

filegroup(
    name = "mygroup",
    srcs = [
        "a_file.txt",
        "some/subdirectory/another_file.txt",
    ],
)

Ou use um glob para criar um diretório de dados de teste:

filegroup(
    name = "exported_testdata",
    srcs = glob([
        "testdata/*.dat",
        "testdata/logs/**/*.log",
    ]),
)

Para usar essas definições, faça referência ao filegroup com um rótulo de qualquer regra:

cc_library(
    name = "my_library",
    srcs = ["foo.cc"],
    data = [
        "//my_package:exported_testdata",
        "//my_package:mygroup",
    ],
)

Argumentos

genquery

genquery(name, deps, data, compatible_with, compressed_output, deprecation, distribs, exec_compatible_with, exec_properties, expression, features, licenses, opts, restricted_to, scope, strict, tags, target_compatible_with, testonly, visibility)

genquery() executa uma consulta especificada na linguagem de consulta Blaze e salva o resultado em um arquivo.

Para manter o build consistente, a consulta só pode acessar o fechamento transitivo dos destinos especificados no atributo scope. As consultas que violarem essa regra vão falhar durante a execução se strict não for especificado ou for verdadeiro. Se strict for falso, os destinos fora do escopo serão ignorados com um aviso. A maneira mais fácil de garantir que isso não aconteça é mencionar os mesmos rótulos no escopo e na expressão de consulta.

A única diferença entre as consultas permitidas aqui e na linha de comando é que as consultas que contêm especificações de destino de caractere curinga (por exemplo, //pkg:* ou //pkg:all) não são permitidas aqui. Os motivos para isso são duplos: primeiro, porque genquery precisa especificar um escopo para evitar destinos fora do fechamento transitivo da consulta para influenciar a saída e, segundo, porque arquivos BUILD não são compatíveis com dependências de caracteres curinga (por exemplo, deps=["//a/..."] não é permitido).

A saída do genquery é ordenada lexicograficamente para impor a saída determinística, com exceção de --output=graph|minrank|maxrank ou quando somepath é usada como a função de nível superior.

O nome do arquivo de saída é o nome da regra.

Exemplos

Este exemplo grava a lista dos rótulos no fechamento transitivo do destino especificado em um arquivo.

genquery(
    name = "kiwi-deps",
    expression = "deps(//kiwi:kiwi_lib)",
    scope = ["//kiwi:kiwi_lib"],
)

Argumentos

genrule

genrule(name, srcs, outs, cmd, cmd_bash, cmd_bat, cmd_ps, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, executable, features, licenses, local, message, output_licenses, output_to_bindir, restricted_to, tags, target_compatible_with, testonly, toolchains, tools, visibility)

Um genrule gera um ou mais arquivos usando um comando Bash definido pelo usuário.

As regras genéricas de build podem ser usadas se não houver uma regra específica para a tarefa. Por exemplo, você pode executar um comando Bash de uma linha. No entanto, se você precisar compilar arquivos C++, siga as regras cc_* existentes, porque todo o trabalho pesado já foi feito para você.

Observe que a genrule exige um shell para interpretar o argumento do comando. Também é fácil referenciar programas arbitrários disponíveis no PATH. No entanto, isso torna o comando não hermético e pode não ser reproduzível. Se você precisar executar apenas uma ferramenta, use run_binary em vez disso.

Não use uma regra geral para executar testes. Há dispensas especiais para testes e resultados de teste, incluindo políticas de armazenamento em cache e variáveis de ambiente. Os testes geralmente precisam ser executados depois que o build é concluído e na arquitetura de destino, enquanto as regras de geração são executadas durante o build e na arquitetura de execução (as duas podem ser diferentes). Se você precisar de uma regra de teste de uso geral, use sh_test.

Considerações sobre compilação cruzada

Consulte o manual do usuário para saber mais sobre a compilação cruzada.

Embora as regras gerais sejam executadas durante um build, as saídas delas costumam ser usadas após a build, para implantação ou teste. Considere o exemplo de compilação de código C para um microcontrolador: o compilador aceita arquivos de origem C e gera código que é executado em um microcontrolador. Obviamente, o código gerado não pode ser executado na CPU usada para criá-lo, mas o compilador C (se compilado da origem) precisa fazer isso.

O sistema de build usa a configuração de execução para descrever as máquinas em que o build é executado e a configuração de destino para descrever as máquinas em que a saída do build precisa ser executada. Ele oferece opções para configurar cada um deles e separa os arquivos correspondentes em diretórios separados para evitar conflitos.

Para regras de geração, o sistema de build garante que as dependências sejam criadas de maneira adequada: srcs são criadas (se necessário) para a configuração target, tools são criadas para a configuração exec e a saída é considerada para a configuração target. Ela também fornece variáveis "Make" que os comandos genrule podem passar para as ferramentas correspondentes.

É intencional que a genrule não defina nenhum atributo deps: outras regras integradas usam metainformações dependentes da linguagem transmitidas entre as regras para determinar automaticamente como lidar com regras dependentes, mas esse nível de automação não é possível para regras gerais. As regras gerais funcionam puramente no nível do arquivo e dos arquivos de execução.

Casos especiais

Compilação Exec-exec: em alguns casos, o sistema de compilação precisa executar regras gerais para que a saída também possa ser executada durante a compilação. Se, por exemplo, uma regra geral criar um compilador personalizado que é usado posteriormente por outra regra geral, o primeiro precisa produzir a saída para a configuração "exec", porque é nesse local que o compilador será executado na outra regra geral. Nesse caso, o sistema de build faz a coisa certa automaticamente: ele gera o srcs e o outs da primeira genrule para a configuração de execução em vez da configuração de destino. Consulte o manual do usuário para mais informações.

Ferramentas do JDK e C++: para usar uma ferramenta do JDK ou do conjunto de compiladores C++, o sistema de build fornece um conjunto de variáveis para usar. Consulte Variável "Criar" para mais detalhes.

Ambiente de regra geral

O comando genrule é executado por um shell Bash configurado para falhar quando um comando ou um pipeline falha, usando set -e -o pipefail.

A ferramenta de build executa o comando Bash em um ambiente de processo limpo que define apenas variáveis principais, como PATH, PWD, TMPDIR e algumas outras. Para garantir que as builds sejam reproduzíveis, a maioria das variáveis definidas no ambiente shell do usuário não são passadas para o comando da genrule. No entanto, o Bazel (mas não o Blaze) transmite o valor da variável de ambiente PATH do usuário. Qualquer mudança no valor de PATH fará com que o Bazel execute o comando novamente no próximo build.

Um comando genrule não deve acessar a rede, exceto para conectar processos que são filhos do próprio comando, embora isso não seja aplicado no momento.

O sistema de compilação exclui automaticamente todos os arquivos de saída existentes, mas cria todos os diretórios pais necessários antes de executar uma regra geral. Ele também remove todos os arquivos de saída em caso de falha.

Conselhos gerais

• Garantir que as ferramentas executadas por uma regra geral sejam determinísticas e herméticas. Eles não devem gravar carimbos de data/hora nas saídas e precisam usar a ordem estável para conjuntos e mapas, bem como gravar apenas caminhos de arquivo relativos para a saída, e não caminhos absolutos. Não seguir essa regra vai levar a um comportamento de build inesperado (o Bazel não recria uma genrule que você achava que ele recria) e vai degradar a performance do cache.
• Use $(location) extensivamente para saídas, ferramentas e fontes. Devido à segregação dos arquivos de saída para diferentes configurações, as regras gerais não podem depender de caminhos absolutos e/ou codificados.
• Escreva uma macro Starlark comum caso as mesmas regras de geração ou regras muito semelhantes sejam usadas em vários lugares. Se a regra de geração for complexa, implemente-a em um script ou como uma regra do Starlark. Isso melhora a legibilidade e a capacidade de teste.
• Verifique se o código de saída indica corretamente o sucesso ou a falha da regra geral.
• Não grave mensagens informativas em stdout ou stderr. Embora útil para depuração, isso pode facilmente se tornar ruído. Uma regra geral bem-sucedida precisa ser silenciosa. Por outro lado, uma regra geral com falha deve emitir boas mensagens de erro.
• $$ evaluates to a $, a literal dollar-sign, so in order to invoke a shell command containing dollar-signs such as ls $(dirname $x), one must escape it thus: ls $$(dirname $$x).
• Evite criar links simbólicos e diretórios. O Bazel não copia a estrutura de diretório/link simbólico criada por regras gerais, e a verificação de dependência de diretórios é inválida.
• Ao fazer referência à genrule em outras regras, você pode usar o rótulo da genrule ou os rótulos de arquivos de saída individuais. Às vezes, uma abordagem é mais legível, às vezes, a outra: referenciar saídas por nome em uma srcs de regra de consumo evita a seleção não intencional de outras saídas da regra, mas pode ser tedioso se a regra produzir muitas saídas.

Exemplos

Este exemplo gera foo.h. Não há fontes porque o comando não recebe nenhuma entrada. O "binário" executado pelo comando é um script Perl no mesmo pacote que a genrule.

genrule(
    name = "foo",
    srcs = [],
    outs = ["foo.h"],
    cmd = "./$(location create_foo.pl) > \"$@\"",
    tools = ["create_foo.pl"],
)

O exemplo a seguir mostra como usar um filegroup e as saídas de outro genrule. O uso de $(SRCS) em vez de diretivas $(location) explícitas também funciona. Este exemplo usa o último para fins de demonstração.

genrule(
    name = "concat_all_files",
    srcs = [
        "//some:files",  # a filegroup with multiple files in it ==> $(locations)
        "//other:gen",   # a genrule with a single output ==> $(location)
    ],
    outs = ["concatenated.txt"],
    cmd = "cat $(locations //some:files) $(location //other:gen) > $@",
)

Argumentos

starlark_doc_extract

starlark_doc_extract(name, deps, src, data, compatible_with, deprecation, distribs, exec_compatible_with, exec_properties, features, licenses, render_main_repo_name, restricted_to, symbol_names, tags, target_compatible_with, testonly, visibility)

starlark_doc_extract() extrai a documentação de regras, funções (incluindo macros), aspectos e provedores definidos ou reexportados em um determinado arquivo .bzl ou .scl. A saída dessa regra é um proto binário ModuleInfo, conforme definido em stardoc_output.proto na árvore de origem do Bazel.

Alvos de saída implícitos

• name.binaryproto (a saída padrão): um ModuleInfo proto binário.
• name.textproto (criado apenas se solicitado explicitamente): a versão .proto de texto de name.binaryproto.

Aviso: não há garantia de que o formato de saída dessa regra seja estável. Ele é destinado principalmente ao uso interno da Stardoc.

Argumentos

test_suite

test_suite(name, compatible_with, deprecation, distribs, features, licenses, restricted_to, tags, target_compatible_with, testonly, tests, visibility)

Um test_suite define um conjunto de testes que são considerados "úteis" para humanos. Isso permite que os projetos definam conjuntos de testes, como "testes que você precisa executar antes do check-in", "testes de estresse do nosso projeto" ou "todos os testes pequenos". O comando blaze test respeita esse tipo de organização: para uma invocação como blaze test //some/test:suite, o Blaze primeiro enumera todos os destinos de teste incluídos transitivamente pelo destino //some/test:suite (chamamos isso de "expansão test_suite"). Em seguida, o Blaze cria e testa esses destinos.

Exemplos

Um conjunto de testes para executar todos os pequenos testes no pacote atual.

test_suite(
    name = "small_tests",
    tags = ["small"],
)

Um pacote que executa um conjunto específico de testes:

test_suite(
    name = "smoke_tests",
    tests = [
        "system_unittest",
        "public_api_unittest",
    ],
)

Um pacote para executar todos os testes não instáveis no pacote atual.

test_suite(
    name = "non_flaky_test",
    tags = ["-flaky"],
)

Argumentos