このチュートリアルでは、プロジェクトの C++ ツールチェーンを構成する方法について、サンプル シナリオを使用して説明します。これは、
サンプル C++ プロジェクト
に基づいています。これは、clang を使用してエラーなくビルドします。
学習内容
このチュートリアルでは、以下の方法について学習します。
- ビルド環境を設定する
- C++ ツールチェーンを構成する
cc_toolchainの追加構成を提供する Starlark ルールを作成して、Bazel がclangでアプリケーションをビルドできるようにする- Linux マシンで
bazel build --config=clang_config //main:hello-worldを実行して、想定される結果を確認する - C++ アプリケーションをビルドする
始める前に
ビルド環境を設定する
このチュートリアルでは、Linux を使用し、C++ アプリケーションを正常にビルドして、適切なツールとライブラリをインストールしていることを前提としています。
このチュートリアルでは、clang version 9.0.1 を使用します。これはシステムにインストールできます。
ビルド環境を次のように設定します。
まだ行っていない場合は、 Bazel 0.23 以降をダウンロードしてインストールします。
GitHub から サンプル C++ プロジェクト をダウンロードし、ローカルマシンの空のディレクトリに配置します。
次の
cc_binaryターゲットをmain/BUILDファイルに追加します。cc_binary( name = "hello-world", srcs = ["hello-world.cc"], )ワークスペース ディレクトリのルートに次の内容の
.bazelrcファイルを作成して、--configフラグを使用できるようにします。# Use our custom-configured c++ toolchain. build:clang_config --crosstool_top=//toolchain:clang_suite # Use --cpu as a differentiator. build:clang_config --cpu=k8 # Use the default Bazel C++ toolchain to build the tools used during the # build. build:clang_config --host_crosstool_top=@bazel_tools//tools/cpp:toolchain
エントリ build:{config_name} --flag=value の場合、コマンドライン フラグ --config={config_name} はその特定のフラグに関連付けられます。使用されているフラグ
crosstool_top、
cpu、
host_crosstool_top のドキュメントをご覧ください。
ターゲット
を bazel build --config=clang_config //main:hello-world でビルドすると、Bazel は
cc_toolchain_suite
//toolchain:clang_suite のカスタム ツールチェーンを使用します。スイートには、CPU ごとに異なる
ツールチェーンがリストされる場合があります。
そのため、フラグ --cpu=k8 で区別されます。
Bazel は、ビルド中にプロセス ラッパーなど、C++ で記述された多くの内部ツールを使用します。そのため、これらのツールがこのチュートリアルで作成されたツールチェーンではなく、既存のデフォルトの C++ ツールチェーンを使用してビルドされるように、ホスト プラットフォームに指定されています。
C++ ツールチェーンを構成する
C++ ツールチェーンを構成するには、以下に示すように、アプリケーションを繰り返しビルドして、エラーを 1 つずつ解消します。
次のコマンドでビルドを実行します。
bazel build --config=clang_config //main:hello-world.bazelrcファイルで--crosstool_top=//toolchain:clang_suiteを指定したため、Bazel は次のエラーをスローします。No such package `toolchain`: BUILD file not found on package path.ワークスペース ディレクトリに、パッケージの
toolchainディレクトリを作成し、toolchainディレクトリ内に空のBUILDファイルを作成します。もう一度ビルドを実行します。
toolchainパッケージでclang_suiteターゲットがまだ定義されていないため、Bazel は次のエラーをスローします。No such target '//toolchain:clang_suite': target 'clang_suite' not declared in package 'toolchain' defined by .../toolchain/BUILDtoolchain/BUILDファイルで、次のように空の filegroup を定義します。package(default_visibility = ["//visibility:public"]) filegroup(name = "clang_suite")もう一度ビルドを実行します。Bazel は次のエラーをスローします。
'//toolchain:clang_suite' does not have mandatory providers: 'ToolchainInfo'Bazel は、
--crosstool_topフラグが、必要なToolchainInfoプロバイダを提供しないルールを指していることを検出しました。そのため、--crosstool_topをToolchainInfoを提供するルール（cc_toolchain_suiteルール）に指定する必要があります。toolchain/BUILDファイルで、空の filegroup を次のコードに置き換えます。cc_toolchain_suite( name = "clang_suite", toolchains = { "k8": ":k8_toolchain", }, )toolchains属性は、--cpu（および指定されている場合は--compiler）の値をcc_toolchainに自動的にマッピングします。cc_toolchainターゲットはまだ定義されていません。Bazel はすぐにこのことを通知します。もう一度ビルドを実行します。Bazel は次のエラーをスローします。
Rule '//toolchain:k8_toolchain' does not exist次に、
cc_toolchainターゲットをcc_toolchain_suite.toolchains属性のすべての値に対して定義する必要があります。toolchain/BUILDファイルに以下を追加します。filegroup(name = "empty") cc_toolchain( name = "k8_toolchain", toolchain_identifier = "k8-toolchain", toolchain_config = ":k8_toolchain_config", all_files = ":empty", compiler_files = ":empty", dwp_files = ":empty", linker_files = ":empty", objcopy_files = ":empty", strip_files = ":empty", supports_param_files = 0, )もう一度ビルドを実行します。Bazel は次のエラーをスローします。
Rule '//toolchain:k8_toolchain_config' does not exist次に、":k8_toolchain_config" ターゲットを
toolchain/BUILDファイルに追加します。filegroup(name = "k8_toolchain_config")もう一度ビルドを実行します。Bazel は次のエラーをスローします。
'//toolchain:k8_toolchain_config' does not have mandatory providers: 'CcToolchainConfigInfo'CcToolchainConfigInfoは、C++ ツールチェーンの構成に使用するプロバイダです。このエラーを修正するには、次の内容でtoolchain/cc_toolchain_config.bzlファイルを作成して、CcToolchainConfigInfoを Bazel に提供する Starlark ルールを作成します。def _impl(ctx): return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "k8-toolchain", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )cc_common.create_cc_toolchain_config_info()は、必要なプロバイダCcToolchainConfigInfoを作成します。cc_toolchain_configルールを使用するには、パッケージ ステートメントの直下のtoolchain/BUILDに load ステートメントを追加します。load(":cc_toolchain_config.bzl", "cc_toolchain_config")「k8_toolchain_config」filegroup を
cc_toolchain_configルールの宣言に置き換えます。cc_toolchain_config(name = "k8_toolchain_config")もう一度ビルドを実行します。Bazel は次のエラーをスローします。
.../BUILD:1:1: C++ compilation of rule '//:hello-world' failed (Exit 1) src/main/tools/linux-sandbox-pid1.cc:421: "execvp(toolchain/DUMMY_GCC_TOOL, 0x11f20e0)": No such file or directory Target //:hello-world failed to build`この時点で、Bazel はコードのビルドを試行するのに十分な情報を取得していますが、必要なビルドアクションを完了するために使用するツールはまだわかりません。Starlark ルールの実装を変更して、使用するツールを Bazel に伝えます。そのためには、
@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzlの tool_path() コンストラクタが必要です。# toolchain/cc_toolchain_config.bzl: # NEW load("@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "tool_path") def _impl(ctx): tool_paths = [ # NEW tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/usr/bin/ar", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, # NEW )/usr/bin/clangと/usr/bin/ldがシステムの正しいパスであることを確認します。もう一度ビルドを実行します。Bazel は次のエラーをスローします。
..../BUILD:3:1: undeclared inclusion(s) in rule '//main:hello-world': this rule is missing dependency declarations for the following files included by 'main/hello-world.cc': '/usr/include/c++/9/ctime' '/usr/include/x86_64-linux-gnu/c++/9/bits/c++config.h' '/usr/include/x86_64-linux-gnu/c++/9/bits/os_defines.h' ....Bazel は、インクルードされたヘッダーを検索する場所を知る必要があります。これを解決する方法は複数あります。たとえば、
cc_binaryのincludes属性を使用する方法などです。ここでは、cc_common.create_cc_toolchain_config_infoのcxx_builtin_include_directoriesパラメータを使用して、ツールチェーン レベルで解決します。clangのバージョンが異なる場合、インクルード パスは 異なります。これらのパスは、ディストリビューションによって異なる場合もあります。toolchain/cc_toolchain_config.bzlの戻り値を次のように変更します。return cc_common.create_cc_toolchain_config_info( ctx = ctx, cxx_builtin_include_directories = [ # NEW "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, )ビルドコマンドをもう一度実行すると、次のようなエラーが表示されます。
/usr/bin/ld: bazel-out/k8-fastbuild/bin/main/_objs/hello-world/hello-world.o: in function `print_localtime()': hello-world.cc:(.text+0x68): undefined reference to `std::cout'これは、リンカーに C++ 標準ライブラリがなく、そのシンボルが見つからないためです。これを解決する方法はたくさんあります。たとえば、
cc_binaryのlinkopts属性を使用する方法などです。ここでは、ツールチェーンを使用するターゲットでこのフラグを指定する必要がないようにすることで解決します。次のコードを
cc_toolchain_config.bzlにコピーします。# NEW load("@bazel_tools//tools/build_defs/cc:action_names.bzl", "ACTION_NAMES") # NEW load( "@bazel_tools//tools/cpp:cc_toolchain_config_lib.bzl", "feature", "flag_group", "flag_set", "tool_path", ) all_link_actions = [ # NEW ACTION_NAMES.cpp_link_executable, ACTION_NAMES.cpp_link_dynamic_library, ACTION_NAMES.cpp_link_nodeps_dynamic_library, ] def _impl(ctx): tool_paths = [ tool_path( name = "gcc", path = "/usr/bin/clang", ), tool_path( name = "ld", path = "/usr/bin/ld", ), tool_path( name = "ar", path = "/bin/false", ), tool_path( name = "cpp", path = "/bin/false", ), tool_path( name = "gcov", path = "/bin/false", ), tool_path( name = "nm", path = "/bin/false", ), tool_path( name = "objdump", path = "/bin/false", ), tool_path( name = "strip", path = "/bin/false", ), ] features = [ # NEW feature( name = "default_linker_flags", enabled = True, flag_sets = [ flag_set( actions = all_link_actions, flag_groups = ([ flag_group( flags = [ "-lstdc++", ], ), ]), ), ], ), ] return cc_common.create_cc_toolchain_config_info( ctx = ctx, features = features, # NEW cxx_builtin_include_directories = [ "/usr/lib/llvm-9/lib/clang/9.0.1/include", "/usr/include", ], toolchain_identifier = "local", host_system_name = "local", target_system_name = "local", target_cpu = "k8", target_libc = "unknown", compiler = "clang", abi_version = "unknown", abi_libc_version = "unknown", tool_paths = tool_paths, ) cc_toolchain_config = rule( implementation = _impl, attrs = {}, provides = [CcToolchainConfigInfo], )bazel build --config=clang_config //main:hello-worldを実行すると、最終的にビルドされます。
実施したタスクを確認する
このチュートリアルでは、基本的な C++ ツールチェーンを構成する方法について説明しましたが、ツールチェーンはこれよりも強力なものです。
重要なポイントは次のとおりです:
- コマンドラインで --crosstool_top フラグを指定する必要があります。これは cc_toolchain_suite を指している必要があります。
- .bazelrc ファイルを使用して、特定の構成のショートカットを作成できます。
- cc_toolchain_suite には、CPU とコンパイラごとに異なる cc_toolchains がリストされる場合があります。--cpu などのコマンドライン フラグを使用して区別できます。- ツールチェーンにツールの場所を知らせる必要があります。このチュートリアル
では、システムからツールにアクセスする簡略化されたバージョンを使用します。より自己完結型の方法に関心がある場合は、ワークスペースを
ご覧ください
。ツールは別のワークスペースから取得できます。その場合、
などの属性のターゲット依存関係を使用して、それらのファイルを cc_toolchain で使用できるようにする必要があります。compiler_filestool_paths も変更する必要があります。- リンクやその他のタイプのアクションなど、
さまざまなアクションに渡すフラグをカスタマイズする機能を作成できます。
関連情報
詳細については、 C++ ツールチェーンの構成をご覧ください。