टेस्ट करना

Bazel में, Starlark कोड की जांच करने के कई तरीके हैं. इस पेज पर, इस्तेमाल के उदाहरण के हिसाब से, मौजूदा सबसे सही तरीके और फ़्रेमवर्क की जानकारी दी गई है.

नियमों की जांच करना

Skylib में, unittest.bzl नाम का एक टेस्ट फ़्रेमवर्क है. इसका इस्तेमाल, नियमों के विश्लेषण के समय के व्यवहार की जांच करने के लिए किया जाता है. जैसे, उनकी कार्रवाइयां और प्रोवाइडर. इस तरह के टेस्ट को "विश्लेषण टेस्ट" कहा जाता है. फ़िलहाल, ये टेस्ट, नियमों के अंदरूनी कामकाज की जांच करने का सबसे अच्छा तरीका है.

कुछ चेतावनियां:

• टेस्ट के दावे, बिल्ड के अंदर होते हैं. ये दावे, टेस्ट रनर की अलग प्रोसेस में नहीं होते. टेस्ट से बनाए गए टारगेट के नाम ऐसे होने चाहिए कि वे दूसरे टेस्ट या बिल्ड के टारगेट से न टकराएं. टेस्ट के दौरान होने वाली गड़बड़ी को Bazel, टेस्ट फ़ेलियर के बजाय बिल्ड में होने वाली गड़बड़ी के तौर पर देखता है.

• टेस्ट किए जा रहे नियमों और टेस्ट के दावे वाले नियमों को सेट अप करने के लिए, काफ़ी मात्रा में बॉयलरप्लेट की ज़रूरत होती है. शुरुआत में, यह बॉयलरप्लेट मुश्किल लग सकता है. यह ध्यान रखना ज़रूरी है कि मैक्रो का आकलन और टारगेट, लोडिंग फ़ेज़ के दौरान जनरेट होते हैं. वहीं, नियम लागू करने वाले फ़ंक्शन, विश्लेषण फ़ेज़ के दौरान ही चलते हैं.

• विश्लेषण टेस्ट, छोटे और हल्के-फुल्के होने चाहिए. विश्लेषण टेस्ट फ़्रेमवर्क की कुछ सुविधाएं, ट्रांज़िटिव डिपेंडेंसी वाले टारगेट की पुष्टि करने तक सीमित हैं. फ़िलहाल, इनकी संख्या 500 है. ऐसा इसलिए है, क्योंकि बड़े टेस्ट के साथ इन सुविधाओं का इस्तेमाल करने से परफ़ॉर्मेंस पर असर पड़ता है.

इसका बुनियादी सिद्धांत यह है कि टेस्ट करने का एक नियम तय किया जाए, जो टेस्ट किए जा रहे नियम पर निर्भर हो. इससे, टेस्ट करने वाले नियम को, टेस्ट किए जा रहे नियम के प्रोवाइडर का ऐक्सेस मिल जाता है.

टेस्ट करने वाले नियम का लागू करने वाला फ़ंक्शन, दावे करता है. अगर कोई गड़बड़ी होती है, तो fail() को कॉल करके तुरंत गड़बड़ी की जानकारी नहीं दी जाती. ऐसा करने पर, विश्लेषण के समय बिल्ड में गड़बड़ी ट्रिगर हो जाएगी. इसके बजाय, गड़बड़ियों को जनरेट की गई स्क्रिप्ट में सेव किया जाता है. यह स्क्रिप्ट, टेस्ट के एक्ज़ीक्यूशन के समय फ़ेल हो जाती है.

यहां एक छोटा सा उदाहरण दिया गया है. इसके बाद, कार्रवाइयों की जांच करने वाला उदाहरण दिया गया है.

छोटा उदाहरण

//mypkg/myrules.bzl:

MyInfo = provider(fields = {
    "val": "string value",
    "out": "output File",
})

def _myrule_impl(ctx):
    """Rule that just generates a file and returns a provider."""
    out = ctx.actions.declare_file(ctx.label.name + ".out")
    ctx.actions.write(out, "abc")
    return [MyInfo(val="some value", out=out)]

myrule = rule(
    implementation = _myrule_impl,
)

//mypkg/myrules_test.bzl:

load("@bazel_skylib//lib:unittest.bzl", "asserts", "analysistest")
load(":myrules.bzl", "myrule", "MyInfo")

# ==== Check the provider contents ====

def _provider_contents_test_impl(ctx):
    env = analysistest.begin(ctx)

    target_under_test = analysistest.target_under_test(env)
    # If preferred, could pass these values as "expected" and "actual" keyword
    # arguments.
    asserts.equals(env, "some value", target_under_test[MyInfo].val)

    # If you forget to return end(), you will get an error about an analysis
    # test needing to return an instance of AnalysisTestResultInfo.
    return analysistest.end(env)

# Create the testing rule to wrap the test logic. This must be bound to a global
# variable, not called in a macro's body, since macros get evaluated at loading
# time but the rule gets evaluated later, at analysis time. Since this is a test
# rule, its name must end with "_test".
provider_contents_test = analysistest.make(_provider_contents_test_impl)

# Macro to setup the test.
def _test_provider_contents():
    # Rule under test. Be sure to tag 'manual', as this target should not be
    # built using `:all` except as a dependency of the test.
    myrule(name = "provider_contents_subject", tags = ["manual"])
    # Testing rule.
    provider_contents_test(name = "provider_contents_test",
                           target_under_test = ":provider_contents_subject")
    # Note the target_under_test attribute is how the test rule depends on
    # the real rule target.

# Entry point from the BUILD file; macro for running each test case's macro and
# declaring a test suite that wraps them together.
def myrules_test_suite(name):
    # Call all test functions and wrap their targets in a suite.
    _test_provider_contents()
    # ...

    native.test_suite(
        name = name,
        tests = [
            ":provider_contents_test",
            # ...
        ],
    )

//mypkg/BUILD:

load(":myrules.bzl", "myrule")
load(":myrules_test.bzl", "myrules_test_suite")

# Production use of the rule.
myrule(
    name = "mytarget",
)

# Call a macro that defines targets that perform the tests at analysis time,
# and that can be executed with "bazel test" to return the result.
myrules_test_suite(name = "myrules_test")

bazel test //mypkg:myrules_test की मदद से, टेस्ट चलाया जा सकता है.

शुरुआती load() स्टेटमेंट के अलावा, फ़ाइल के दो मुख्य हिस्से होते हैं:

• टेस्ट. इनमें से हर टेस्ट में ये चीज़ें शामिल होती हैं: 1) टेस्ट करने वाले नियम के लिए, विश्लेषण के समय लागू करने वाला फ़ंक्शन, 2) analysistest.make() के ज़रिए, टेस्ट करने वाले नियम का एलान, और 3) टेस्ट किए जा रहे नियम (और उसकी डिपेंडेंसी) और टेस्ट करने वाले नियम का एलान करने के लिए, लोडिंग के समय का फ़ंक्शन (मैक्रो). अगर टेस्ट केस के बीच दावे नहीं बदलते हैं, तो 1) और 2) को कई टेस्ट केस के साथ शेयर किया जा सकता है.

• टेस्ट सुइट फ़ंक्शन. यह हर टेस्ट के लिए, लोडिंग के समय के फ़ंक्शन को कॉल करता है. साथ ही, test_suite टारगेट का एलान करता है, जो सभी टेस्ट को एक साथ बंडल करता है.

एक जैसी जानकारी देने के लिए, नाम रखने के सुझाए गए तरीके का पालन करें: मान लें कि foo, टेस्ट के नाम का वह हिस्सा है जिससे यह पता चलता है कि टेस्ट किस चीज़ की जांच कर रहा है. ऊपर दिए गए उदाहरण में, यह provider_contents है. उदाहरण के लिए, JUnit टेस्ट के तरीके का नाम testFoo होगा.

इसके बाद:

• टेस्ट और टेस्ट किए जा रहे टारगेट को जनरेट करने वाले मैक्रो का नाम _test_foo (_test_provider_contents) होना चाहिए

• इसके टेस्ट नियम के टाइप का नाम foo_test (provider_contents_test) होना चाहिए

• इस नियम के टाइप के टारगेट का लेबल foo_test (provider_contents_test) होना चाहिए

• टेस्ट करने वाले नियम के लिए, लागू करने वाले फ़ंक्शन का नाम _foo_test_impl (_provider_contents_test_impl) होना चाहिए

• टेस्ट किए जा रहे नियमों और उनकी डिपेंडेंसी के टारगेट के लेबल के पहले foo_ (provider_contents_) होना चाहिए

ध्यान दें कि सभी टारगेट के लेबल, एक ही BUILD पैकेज में मौजूद अन्य लेबल से टकरा सकते हैं. इसलिए, टेस्ट के लिए कोई यूनीक नाम इस्तेमाल करना मददगार होता है.

फ़ेलियर की जांच करना

यह पुष्टि करना काम का हो सकता है कि कुछ इनपुट या किसी खास स्थिति में, कोई नियम फ़ेल हो जाता है. ऐसा, विश्लेषण टेस्ट फ़्रेमवर्क का इस्तेमाल करके किया जा सकता है:

analysistest.make से बनाए गए टेस्ट नियम में, expect_failure तय किया जाना चाहिए:

failure_testing_test = analysistest.make(
    _failure_testing_test_impl,
    expect_failure = True,
)

टेस्ट नियम के लागू करने वाले फ़ंक्शन में, फ़ेलियर की वजह के बारे में दावे किए जाने चाहिए. खास तौर पर, फ़ेलियर का मैसेज:

def _failure_testing_test_impl(ctx):
    env = analysistest.begin(ctx)
    asserts.expect_failure(env, "This rule should never work")
    return analysistest.end(env)

यह भी पक्का करें कि टेस्ट किए जा रहे टारगेट को 'मैन्युअल' के तौर पर टैग किया गया हो. ऐसा न करने पर, :all का इस्तेमाल करके अपने पैकेज में मौजूद सभी टारगेट को बनाने पर, जान-बूझकर फ़ेल होने वाले टारगेट का बिल्ड बनेगा और बिल्ड फ़ेल हो जाएगा. 'मैन्युअल' के साथ, टेस्ट किया जा रहा टारगेट सिर्फ़ तब बनेगा, जब उसे साफ़ तौर पर तय किया जाएगा या जब वह किसी ऐसे टारगेट की डिपेंडेंसी के तौर पर तय किया जाएगा जिसे 'मैन्युअल' के तौर पर टैग नहीं किया गया है. जैसे, आपका टेस्ट नियम:

def _test_failure():
    myrule(name = "this_should_fail", tags = ["manual"])

    failure_testing_test(name = "failure_testing_test",
                         target_under_test = ":this_should_fail")

# Then call _test_failure() in the macro which generates the test suite and add
# ":failure_testing_test" to the suite's test targets.

रजिस्टर की गई कार्रवाइयों की पुष्टि करना

आपके पास ऐसे टेस्ट लिखने का विकल्प होता है जो आपके नियम से रजिस्टर की गई कार्रवाइयों के बारे में दावे करते हैं. उदाहरण के लिए, ctx.actions.run() का इस्तेमाल करना. ऐसा, विश्लेषण टेस्ट नियम के लागू करने वाले फ़ंक्शन में किया जा सकता है. एक उदाहरण:

def _inspect_actions_test_impl(ctx):
    env = analysistest.begin(ctx)

    target_under_test = analysistest.target_under_test(env)
    actions = analysistest.target_actions(env)
    asserts.equals(env, 1, len(actions))
    action_output = actions[0].outputs.to_list()[0]
    asserts.equals(
        env, target_under_test.label.name + ".out", action_output.basename)
    return analysistest.end(env)

ध्यान दें कि analysistest.target_actions(env) ऑब्जेक्ट की एक सूची दिखाता है. ये ऑब्जेक्ट, टेस्ट किए जा रहे टारगेट से रजिस्टर की गई कार्रवाइयों को दिखाते हैं.Action

अलग-अलग फ़्लैग के तहत, नियम के व्यवहार की पुष्टि करना

आपके पास यह पुष्टि करने का विकल्प होता है कि आपके असली नियम, कुछ खास बिल्ड फ़्लैग के हिसाब से काम करते हैं. उदाहरण के लिए, अगर कोई उपयोगकर्ता यह तय करता है, तो आपका नियम अलग-अलग तरीके से काम कर सकता है:

bazel build //mypkg:real_target -c opt

बनाम

bazel build //mypkg:real_target -c dbg

पहली नज़र में, ऐसा, टेस्ट किए जा रहे टारगेट की जांच करके किया जा सकता है. इसके लिए, मनचाहे बिल्ड फ़्लैग का इस्तेमाल किया जा सकता है:

bazel test //mypkg:myrules_test -c opt

हालांकि, इसके बाद आपके टेस्ट सुइट के लिए, एक साथ ऐसा टेस्ट करना मुमकिन नहीं होगा जो -c opt के तहत नियम के व्यवहार की पुष्टि करता हो. साथ ही, ऐसा टेस्ट करना भी मुमकिन नहीं होगा जो -c dbg के तहत नियम के व्यवहार की पुष्टि करता हो. दोनों टेस्ट, एक ही बिल्ड में नहीं चल पाएंगे!

टेस्ट नियम तय करते समय, मनचाहे बिल्ड फ़्लैग तय करके इस समस्या को हल किया जा सकता है:

myrule_c_opt_test = analysistest.make(
    _myrule_c_opt_test_impl,
    config_settings = {
        "//command_line_option:compilation_mode": "opt",
    },
)

आम तौर पर, टेस्ट किए जा रहे टारगेट का विश्लेषण, मौजूदा बिल्ड फ़्लैग के हिसाब से किया जाता है. config_settings तय करने से, तय किए गए कमांड लाइन विकल्पों की वैल्यू बदल जाती हैं. (तय नहीं किए गए किसी भी विकल्प की वैल्यू, असल कमांड लाइन से बनी रहेंगी).

तय की गई config_settings डिक्शनरी में, कमांड लाइन फ़्लैग के पहले, खास प्लेसहोल्डर वैल्यू //command_line_option: होनी चाहिए. जैसा कि ऊपर दिखाया गया है.

आर्टफ़ैक्ट की पुष्टि करना

जनरेट की गई फ़ाइलों के सही होने की पुष्टि करने के मुख्य तरीके ये हैं:

• शेल, Python या किसी अन्य भाषा में टेस्ट स्क्रिप्ट लिखी जा सकती है. साथ ही, *_test नियम के टाइप का कोई टारगेट बनाया जा सकता है.

• आपके पास, जिस तरह का टेस्ट करना है उसके लिए, खास नियम का इस्तेमाल करने का विकल्प होता है.

टेस्ट टारगेट का इस्तेमाल करना

किसी आर्टफ़ैक्ट की पुष्टि करने का सबसे आसान तरीका है कि कोई स्क्रिप्ट लिखी जाए और अपनी BUILD फ़ाइल में *_test टारगेट जोड़ा जाए. जिन आर्टफ़ैक्ट की पुष्टि करनी है उन्हें इस टारगेट की डेटा डिपेंडेंसी होना चाहिए. अगर पुष्टि करने की लॉजिक को कई टेस्ट के लिए फिर से इस्तेमाल किया जा सकता है, तो यह एक स्क्रिप्ट होनी चाहिए. यह स्क्रिप्ट, कमांड लाइन आर्ग्युमेंट लेती है. इन आर्ग्युमेंट को टेस्ट टारगेट के args एट्रिब्यूट से कंट्रोल किया जाता है. यहां एक उदाहरण दिया गया है. इससे यह पुष्टि की जाती है कि ऊपर दिए गए myrule का आउटपुट "abc" है.

//mypkg/myrule_validator.sh:

if [ "$(cat $1)" = "abc" ]; then
  echo "Passed"
  exit 0
else
  echo "Failed"
  exit 1
fi

//mypkg/BUILD:

...

myrule(
    name = "mytarget",
)

...

# Needed for each target whose artifacts are to be checked.
sh_test(
    name = "validate_mytarget",
    srcs = [":myrule_validator.sh"],
    args = ["$(location :mytarget.out)"],
    data = [":mytarget.out"],
)

कस्टम नियम का इस्तेमाल करना

एक और मुश्किल तरीका यह है कि शेल स्क्रिप्ट को एक टेंप्लेट के तौर पर लिखा जाए. इस टेंप्लेट को, नए नियम से इंस्टैंशिएट किया जाता है. इसमें ज़्यादा इंडायरेक्शन और Starlark लॉजिक शामिल होता है, लेकिन इससे BUILD फ़ाइलें ज़्यादा व्यवस्थित हो जाती हैं. इसके अलावा, आर्ग्युमेंट की किसी भी प्री-प्रोसेसिंग को स्क्रिप्ट के बजाय Starlark में किया जा सकता है. साथ ही, स्क्रिप्ट थोड़ी ज़्यादा सेल्फ-डॉक्यूमेंटिंग होती है, क्योंकि इसमें संख्या वाले प्लेसहोल्डर (आर्ग्युमेंट के लिए) के बजाय सिंबॉलिक प्लेसहोल्डर (सबस्टिट्यूशन के लिए) का इस्तेमाल किया जाता है.

//mypkg/myrule_validator.sh.template:

if [ "$(cat %TARGET%)" = "abc" ]; then
  echo "Passed"
  exit 0
else
  echo "Failed"
  exit 1
fi

//mypkg/myrule_validation.bzl:

def _myrule_validation_test_impl(ctx):
  """Rule for instantiating myrule_validator.sh.template for a given target."""
  exe = ctx.outputs.executable
  target = ctx.file.target
  ctx.actions.expand_template(output = exe,
                              template = ctx.file._script,
                              is_executable = True,
                              substitutions = {
                                "%TARGET%": target.short_path,
                              })
  # This is needed to make sure the output file of myrule is visible to the
  # resulting instantiated script.
  return [DefaultInfo(runfiles=ctx.runfiles(files=[target]))]

myrule_validation_test = rule(
    implementation = _myrule_validation_test_impl,
    attrs = {"target": attr.label(allow_single_file=True),
             # You need an implicit dependency in order to access the template.
             # A target could potentially override this attribute to modify
             # the test logic.
             "_script": attr.label(allow_single_file=True,
                                   default=Label("//mypkg:myrule_validator"))},
    test = True,
)

//mypkg/BUILD:

...

myrule(
    name = "mytarget",
)

...

# Needed just once, to expose the template. Could have also used export_files(),
# and made the _script attribute set allow_files=True.
filegroup(
    name = "myrule_validator",
    srcs = [":myrule_validator.sh.template"],
)

# Needed for each target whose artifacts are to be checked. Notice that you no
# longer have to specify the output file name in a data attribute, or its
# $(location) expansion in an args attribute, or the label for the script
# (unless you want to override it).
myrule_validation_test(
    name = "validate_mytarget",
    target = ":mytarget",
)

इसके अलावा, टेंप्लेट के एक्सपैंशन ऐक्शन का इस्तेमाल करने के बजाय, .bzl फ़ाइल में टेंप्लेट को स्ट्रिंग के तौर पर इनलाइन किया जा सकता है. साथ ही, विश्लेषण फ़ेज़ के दौरान, str.format तरीके या %-फ़ॉर्मैटिंग का इस्तेमाल करके इसे एक्सपैंड किया जा सकता है.

Starlark यूटिलिटी की जांच करना

Skylib's unittest.bzl फ़्रेमवर्क का इस्तेमाल, यूटिलिटी फ़ंक्शन की जांच करने के लिए किया जा सकता है. ये ऐसे फ़ंक्शन होते हैं जो न तो मैक्रो होते हैं और न ही नियम लागू करने वाले फ़ंक्शन. unittest.bzl की analysistest लाइब्रेरी के बजाय, unittest का इस्तेमाल किया जा सकता है. इस तरह के टेस्ट सुइट के लिए, बॉयलरप्लेट को कम करने के लिए, सुविधा वाले फ़ंक्शन unittest.suite() का इस्तेमाल किया जा सकता है.

//mypkg/myhelpers.bzl:

def myhelper():
    return "abc"

//mypkg/myhelpers_test.bzl:

load("@bazel_skylib//lib:unittest.bzl", "asserts", "unittest")
load(":myhelpers.bzl", "myhelper")

def _myhelper_test_impl(ctx):
  env = unittest.begin(ctx)
  asserts.equals(env, "abc", myhelper())
  return unittest.end(env)

myhelper_test = unittest.make(_myhelper_test_impl)

# No need for a test_myhelper() setup function.

def myhelpers_test_suite(name):
  # unittest.suite() takes care of instantiating the testing rules and creating
  # a test_suite.
  unittest.suite(
    name,
    myhelper_test,
    # ...
  )

//mypkg/BUILD:

load(":myhelpers_test.bzl", "myhelpers_test_suite")

myhelpers_test_suite(name = "myhelpers_tests")

ज़्यादा उदाहरण के लिए, Skylib के अपने टेस्ट देखें.