Ele pode compilar e testar o código em vários hardwares, sistemas operacionais e configurações de sistema usando várias versões diferentes de ferramentas de compilação, como vinculadores e compiladores. Para ajudar a gerenciar essa complexidade, o Bazel tem um conceito de restrições e plataformas. Uma restrição é uma dimensão em que os ambientes de build ou produção podem ser diferentes, como a arquitetura da CPU, a presença ou ausência de uma GPU ou a versão de um compilador instalado pelo sistema. Uma plataforma é uma coleção nomeada de opções para essas restrições, representando os recursos específicos disponíveis em algum ambiente.
Modelar o ambiente como uma plataforma ajuda o Bazel a selecionar automaticamente os conjuntos de ferramentas adequados para ações de compilação. As plataformas também podem ser usadas em combinação com a regra config_setting para gravar atributos configuráveis.
O Bazel reconhece três papéis que uma plataforma pode atender:
- Host: a plataforma em que o próprio Bazel é executado.
- Execution: uma plataforma em que as ferramentas de build executam ações para produzir saídas intermediárias e finais.
- Destino: uma plataforma em que uma saída final reside e é executada.
O Bazel é compatível com os seguintes cenários de build nas plataformas:
Builds de plataforma única (padrão): as plataformas de host, execução e destino são iguais. Por exemplo, a criação de um executável do Linux no Ubuntu em execução em uma CPU Intel x64.
Builds de compilação cruzada: as plataformas de host e execução são as mesmas, mas a plataforma de destino é diferente. Por exemplo, criar um app iOS no macOS executado em um MacBook Pro.
Builds de várias plataformas: as plataformas de host, execução e destino são diferentes.
Como definir restrições e plataformas
O espaço de opções possíveis para plataformas é definido usando as regras constraint_setting
e constraint_value
nos arquivos BUILD
. constraint_setting
cria uma nova dimensão, enquanto
constraint_value
cria um novo valor para uma determinada dimensão. Juntos, eles
definem efetivamente uma enumeração e os valores possíveis dela. Por exemplo, o snippet a seguir de um arquivo BUILD
introduz uma restrição para a versão glibc do sistema com dois valores possíveis.
constraint_setting(name = "glibc_version")
constraint_value(
name = "glibc_2_25",
constraint_setting = ":glibc_version",
)
constraint_value(
name = "glibc_2_26",
constraint_setting = ":glibc_version",
)
Restrições e os respectivos valores podem ser definidos em diferentes pacotes no espaço de trabalho. Eles são referenciados por rótulo e estão sujeitos aos controles de visibilidade usuais. Se a visibilidade permitir, você poderá estender uma configuração de restrição existente definindo seu próprio valor para ela.
A regra platform
introduz uma nova plataforma com
certas opções de valores de restrição. O código a seguir cria uma plataforma chamada linux_x86
e informa que ela descreve qualquer ambiente que execute um sistema operacional Linux em uma arquitetura x86_64 com uma versão glibc de 2.25. Confira abaixo mais informações sobre as restrições integradas do Bazel.
platform(
name = "linux_x86",
constraint_values = [
"@platforms//os:linux",
"@platforms//cpu:x86_64",
":glibc_2_25",
],
)
Restrições e plataformas geralmente úteis
Para manter o ecossistema consistente, a equipe do Bazel mantém um repositório com definições de restrição para as arquiteturas de CPU e os sistemas operacionais mais conhecidos. Todos eles estão localizados em https://github.com/bazelbuild/platforms.
O Bazel é enviado com a seguinte definição especial de plataforma:
@local_config_platform//:host
. Esse é o valor da plataforma do host detectado automaticamente.
representa a plataforma detectada automaticamente no sistema em que o Bazel está sendo executado.
Como especificar uma plataforma para um build
É possível especificar as plataformas de host e destino para um build usando as seguintes flags de linha de comando:
--host_platform
: o padrão é@bazel_tools//platforms:host_platform
.--platforms
: o padrão é@bazel_tools//platforms:target_platform
.
Como ignorar destinos incompatíveis
Ao criar para uma plataforma de destino específica, muitas vezes é desejável pular
destinos que nunca vão funcionar nessa plataforma. Por exemplo, o driver do dispositivo
Windows provavelmente vai gerar muitos erros do compilador ao criar em uma
máquina Linux com //...
. Use o atributo
target_compatible_with
para informar ao Bazel quais restrições da plataforma de destino seu código tem.
O uso mais simples desse atributo restringe um destino a uma única plataforma.
O destino não será criado para nenhuma plataforma que não atenda a todas as
restrições. O exemplo a seguir restringe win_driver_lib.cc
ao Windows de 64 bits.
cc_library(
name = "win_driver_lib",
srcs = ["win_driver_lib.cc"],
target_compatible_with = [
"@platforms//cpu:x86_64",
"@platforms//os:windows",
],
)
O :win_driver_lib
é compatível apenas com a criação com o Windows de 64 bits e
incompatível com todo o restante. A incompatibilidade é transitiva. Todos os destinos que dependem transitivamente de um destino incompatível são considerados incompatíveis.
Quando as segmentações são ignoradas?
Os destinos são ignorados quando são considerados incompatíveis e incluídos no build como parte de uma expansão de padrão de destino. Por exemplo, as duas invocações a seguir ignoram todos os destinos incompatíveis encontrados em uma expansão de padrão de destino.
$ bazel build --platforms=//:myplatform //...
$ bazel build --platforms=//:myplatform //:all
Testes incompatíveis em um test_suite
serão
ignorados da mesma forma se o test_suite
for especificado na linha de comando com
--expand_test_suites
.
Em outras palavras, os destinos test_suite
na linha de comando se comportam como :all
e
...
. O uso de --noexpand_test_suites
impede a expansão e faz com que destinos test_suite
com testes incompatíveis também sejam incompatíveis.
A especificação explícita de um destino incompatível na linha de comando resulta em uma mensagem de erro e em um build com falha.
$ bazel build --platforms=//:myplatform //:target_incompatible_with_myplatform
...
ERROR: Target //:target_incompatible_with_myplatform is incompatible and cannot be built, but was explicitly requested.
...
FAILED: Build did NOT complete successfully
Restrições mais expressivas
Para ter mais flexibilidade ao expressar restrições, use o
@platforms//:incompatible
constraint_value
que nenhuma plataforma
atenda.
Use select()
em combinação com
@platforms//:incompatible
para expressar restrições mais complicadas. Por
exemplo, use-o para implementar a lógica básica "OR". O código abaixo marca uma biblioteca
compatível com macOS e Linux, mas nenhuma outra plataforma.
cc_library(
name = "unixish_lib",
srcs = ["unixish_lib.cc"],
target_compatible_with = select({
"@platforms//os:osx": [],
"@platforms//os:linux": [],
"//conditions:default": ["@platforms//:incompatible"],
}),
)
Isso pode ser interpretado da seguinte maneira:
- Ao segmentar o macOS, o destino não tem restrições.
- Ao segmentar o Linux, o destino não tem restrições.
- Caso contrário, o destino tem a restrição
@platforms//:incompatible
. Como@platforms//:incompatible
não faz parte de nenhuma plataforma, o destino é considerado incompatível.
Para tornar suas restrições mais legíveis, use o
selects.with_or()
do
skylib.
É possível expressar compatibilidade inversa de forma semelhante. O exemplo a seguir descreve uma biblioteca compatível com tudo, exceto ARM.
cc_library(
name = "non_arm_lib",
srcs = ["non_arm_lib.cc"],
target_compatible_with = select({
"@platforms//cpu:arm": ["@platforms//:incompatible"],
"//conditions:default": [],
],
)
Como detectar destinos incompatíveis usando bazel cquery
Use o
IncompatiblePlatformProvider
no formato de saída do Starlark (link em inglês)
de bazel cquery
para distinguir
destinos incompatíveis dos compatíveis.
Isso pode ser usado para filtrar destinos incompatíveis. O exemplo abaixo imprimirá apenas os rótulos de destinos compatíveis. Destinos incompatíveis não são impressos.
$ cat example.cquery
def format(target):
if "IncompatiblePlatformProvider" not in providers(target):
return target.label
return ""
$ bazel cquery //... --output=starlark --starlark:file=example.cquery
Problemas conhecidos
Destinos incompatíveis ignoram as restrições de visibilidade.