การสร้างมาโคร

สมมติว่าคุณต้องเรียกใช้เครื่องมือเป็นส่วนหนึ่งของการสร้าง เช่น คุณอาจต้องการสร้างหรือประมวลผลไฟล์ต้นฉบับก่อน หรือบีบอัดไฟล์ไบนารี ในบทแนะนำนี้ คุณจะได้สร้างมาโครที่ปรับขนาดรูปภาพ

มาโครเหมาะสำหรับงานง่ายๆ หากต้องการทำอะไรที่มีความซับซ้อนมากขึ้น เช่น เพิ่มการรองรับภาษาโปรแกรมใหม่ ให้พิจารณาสร้างกฎ กฎจะช่วยให้คุณควบคุมและมีความยืดหยุ่นได้มากขึ้น

วิธีที่ง่ายที่สุดในการสร้างมาโครที่ปรับขนาดรูปภาพคือการใช้ genrule

genrule(
    name = "logo_miniature",
    srcs = ["logo.png"],
    outs = ["small_logo.png"],
    cmd = "convert $< -resize 100x100 $@",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)

หากต้องการปรับขนาดรูปภาพเพิ่มเติม คุณอาจต้องนำโค้ดมาใช้ซ้ำ โดยให้กําหนดฟังก์ชันในไฟล์ .bzl แยกต่างหาก แล้วเรียกไฟล์ว่า miniature.bzl

def miniature(name, src, size="100x100", **kwargs):
  """Create a miniature of the src image.

  The generated file is prefixed with 'small_'.
  """
  native.genrule(
    name = name,
    srcs = [src],
    outs = ["small_" + src],
    cmd = "convert $< -resize " + size + " $@",
    **kwargs
  )

หมายเหตุบางประการมีดังนี้

• ตามธรรมเนียมแล้ว มาโครจะมีอาร์กิวเมนต์ name เช่นเดียวกับกฎ

• หากต้องการบันทึกลักษณะการทํางานของมาโคร ให้ใช้ docstring เช่นเดียวกับใน Python

• หากต้องการเรียก genrule หรือกฎเนทีฟอื่นๆ ให้ใช้ native.

• ใช้ **kwargs เพื่อส่งต่ออาร์กิวเมนต์เพิ่มเติมไปยัง genrule ที่อยู่เบื้องหลัง (ทำงานเหมือนกับใน Python) ซึ่งจะเป็นประโยชน์เพื่อให้ผู้ใช้ใช้แอตทริบิวต์มาตรฐานได้ เช่น visibility หรือ tags

ตอนนี้ให้ใช้มาโครจากไฟล์ BUILD โดยทำดังนี้

load("//path/to:miniature.bzl", "miniature")

miniature(
    name = "logo_miniature",
    src = "image.png",
)

cc_binary(
    name = "my_app",
    srcs = ["my_app.cc"],
    data = [":logo_miniature"],
)